qcsrc/common/weapons/w_porto.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ PORTO,
   4 /* function  */ w_porto,
   5 /* ammotype  */ 0,
   6 /* impulse   */ 0,
   7 /* flags     */ WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON,
   8 /* rating    */ 0,
   9 /* model     */ "porto" ,
  10 /* shortname */ "porto",
  11 /* fullname  */ _("Port-O-Launch")
  12 );
  13 #else
  14 #ifdef SVQC
  15 .entity porto_current;
  16 .vector porto_v_angle; // holds "held" view angles
  17 .float porto_v_angle_held;
  18 .vector right_vector;
  19
  20 void W_Porto_Success (void)
  21 {
  22         if(self.realowner == world)
  23         {
  24                 objerror("Cannot succeed successfully: no owner\n");
  25                 return;
  26         }
  27
  28         self.realowner.porto_current = world;
  29         remove(self);
  30 }
  31
  32 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  33 void W_Porto_Fail (float failhard)
  34 {
  35         if(self.realowner == world)
  36         {
  37                 objerror("Cannot fail successfully: no owner\n");
  38                 return;
  39         }
  40
  41         // no portals here!
  42         if(self.cnt < 0)
  43         {
  44                 Portal_ClearWithID(self.realowner, self.portal_id);
  45         }
  46
  47         self.realowner.porto_current = world;
  48
  49         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !WEPSET_CONTAINS_EW(self.realowner, WEP_PORTO))
  50         {
  51                 setsize (self, '-16 -16 0', '16 16 32');
  52                 setorigin(self, self.origin + trace_plane_normal);
  53                 if(move_out_of_solid(self))
  54                 {
  55                         self.flags = FL_ITEM;
  56                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  57                         tracetoss(self, self);
  58                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  59                         {
  60                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO, 0, self.origin, self.velocity);
  61                                 centerprint(self.realowner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  62                         }
  63                 }
  64         }
  65         remove(self);
  66 }
  67
  68 void W_Porto_Remove (entity p)
  69 {
  70         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
  71         {
  72                 entity oldself;
  73                 oldself = self;
  74                 self = p.porto_current;
  75                 W_Porto_Fail(1);
  76                 self = oldself;
  77         }
  78 }
  79
  80 void W_Porto_Think (void)
  81 {
  82         trace_plane_normal = '0 0 0';
  83         if(self.realowner.playerid != self.playerid)
  84                 remove(self);
  85         else
  86                 W_Porto_Fail(0);
  87 }
  88
  89 void W_Porto_Touch (void)
  90 {
  91         vector norm;
  92
  93         // do not use PROJECTILE_TOUCH here
  94         // FIXME but DO handle warpzones!
  95
  96         if(other.classname == "portal")
  97                 return; // handled by the portal
  98
  99         norm = trace_plane_normal;
 100         if(trace_ent.iscreature)
 101         {
 102                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN_z, MOVE_WORLDONLY, self);
 103                 if(trace_fraction >= 1)
 104                         return;
 105                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 106                         return;
 107                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 108                         return;
 109         }
 110
 111         if(self.realowner.playerid != self.playerid)
 112         {
 113                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 114                 remove(self);
 115         }
 116         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 117         {
 118                 spamsound(self, CH_SHOTS, "porto/bounce.wav", VOL_BASE, ATTN_NORM);
 119                 // just reflect
 120                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 121                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 122         }
 123         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 124         {
 125                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 126                 W_Porto_Fail(0);
 127                 if(self.cnt < 0)
 128                         Portal_ClearAll_PortalsOnly(self.realowner);
 129         }
 130         else if(self.cnt == 0)
 131         {
 132                 // in-portal only
 133                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 134                 {
 135                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 136                         trace_plane_normal = norm;
 137                         centerprint(self.realowner, "^1In^7-portal created.");
 138                         W_Porto_Success();
 139                 }
 140                 else
 141                 {
 142                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 143                         trace_plane_normal = norm;
 144                         W_Porto_Fail(0);
 145                 }
 146         }
 147         else if(self.cnt == 1)
 148         {
 149                 // out-portal only
 150                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 151                 {
 152                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 153                         trace_plane_normal = norm;
 154                         centerprint(self.realowner, "^4Out^7-portal created.");
 155                         W_Porto_Success();
 156                 }
 157                 else
 158                 {
 159                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 160                         trace_plane_normal = norm;
 161                         W_Porto_Fail(0);
 162                 }
 163         }
 164         else if(self.effects & EF_RED)
 165         {
 166                 self.effects += EF_BLUE - EF_RED;
 167                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 168                 {
 169                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 170                         trace_plane_normal = norm;
 171                         centerprint(self.realowner, "^1In^7-portal created.");
 172                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 173                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 174                         CSQCProjectile(self, TRUE, PROJECTILE_PORTO_BLUE, TRUE); // change type
 175                 }
 176                 else
 177                 {
 178                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 179                         trace_plane_normal = norm;
 180                         Portal_ClearAll_PortalsOnly(self.realowner);
 181                         W_Porto_Fail(0);
 182                 }
 183         }
 184         else
 185         {
 186                 if(self.realowner.portal_in.portal_id == self.portal_id)
 187                 {
 188                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 189                         {
 190                                 sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTN_NORM);
 191                                 trace_plane_normal = norm;
 192                                 centerprint(self.realowner, "^4Out^7-portal created.");
 193                                 W_Porto_Success();
 194                         }
 195                         else
 196                         {
 197                                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 198                                 Portal_ClearAll_PortalsOnly(self.realowner);
 199                                 W_Porto_Fail(0);
 200                         }
 201                 }
 202                 else
 203                 {
 204                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTN_NORM);
 205                         Portal_ClearAll_PortalsOnly(self.realowner);
 206                         W_Porto_Fail(0);
 207                 }
 208         }
 209 }
 210
 211 void W_Porto_Attack (float type)
 212 {
 213         entity gren;
 214
 215         W_SetupShot (self, FALSE, 4, "porto/fire.wav", CH_WEAPON_A, 0);
 216         // always shoot from the eye
 217         w_shotdir = v_forward;
 218         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 219
 220         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 221
 222         gren = spawn ();
 223         gren.cnt = type;
 224         gren.owner = gren.realowner = self;
 225         gren.playerid = self.playerid;
 226         gren.classname = "porto";
 227         gren.bot_dodge = TRUE;
 228         gren.bot_dodgerating = 200;
 229         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 230         PROJECTILE_MAKETRIGGER(gren);
 231         gren.effects = EF_RED;
 232         gren.scale = 4;
 233         setorigin(gren, w_shotorg);
 234         setsize(gren, '0 0 0', '0 0 0');
 235
 236         if(type > 0)
 237                 gren.nextthink = time + autocvar_g_balance_porto_secondary_lifetime;
 238         else
 239                 gren.nextthink = time + autocvar_g_balance_porto_primary_lifetime;
 240         gren.think = W_Porto_Think;
 241         gren.touch = W_Porto_Touch;
 242
 243         if(type > 0)
 244         {
 245                 if(self.items & IT_STRENGTH)
 246                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_secondary_speed * autocvar_g_balance_powerup_strength_force, 0);
 247                 else
 248                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_secondary_speed, 0);
 249         }
 250         else
 251         {
 252                 if(self.items & IT_STRENGTH)
 253                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_primary_speed * autocvar_g_balance_powerup_strength_force, 0);
 254                 else
 255                         W_SetupProjectileVelocity(gren, autocvar_g_balance_porto_primary_speed, 0);
 256         }
 257
 258         gren.angles = vectoangles (gren.velocity);
 259         gren.flags = FL_PROJECTILE;
 260
 261         gren.portal_id = time;
 262         self.porto_current = gren;
 263         gren.playerid = self.playerid;
 264         fixedmakevectors(fixedvectoangles(gren.velocity));
 265         gren.right_vector = v_right;
 266
 267         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 268
 269         if(type > 0)
 270                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_BLUE, TRUE);
 271         else
 272                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_RED, TRUE);
 273
 274         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 275 }
 276
 277 void spawnfunc_weapon_porto (void)
 278 {
 279         weapon_defaultspawnfunc(WEP_PORTO);
 280 }
 281
 282 float w_nexball_weapon(float req);
 283 float w_porto(float req)
 284 {
 285         //vector v_angle_save;
 286
 287         if (g_nexball) { return w_nexball_weapon(req); }
 288
 289         switch(req)
 290         {
 291                 case WR_AIM:
 292                 {
 293                         self.BUTTON_ATCK = FALSE;
 294                         self.BUTTON_ATCK2 = FALSE;
 295                         if(!autocvar_g_balance_porto_secondary)
 296                                 if(bot_aim(autocvar_g_balance_porto_primary_speed, 0, autocvar_g_balance_mortar_primary_lifetime, FALSE)) // WEAPONTODO
 297                                         self.BUTTON_ATCK = TRUE;
 298
 299                         return TRUE;
 300                 }
 301                 case WR_THINK:
 302                 {
 303                         if(autocvar_g_balance_porto_secondary)
 304                         {
 305                                 if (self.BUTTON_ATCK)
 306                                 if (!self.porto_current)
 307                                 if (!self.porto_forbidden)
 308                                 if (weapon_prepareattack(0, autocvar_g_balance_porto_primary_refire))
 309                                 {
 310                                         W_Porto_Attack(0);
 311                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_porto_primary_animtime, w_ready);
 312                                 }
 313
 314                                 if (self.BUTTON_ATCK2)
 315                                 if (!self.porto_current)
 316                                 if (!self.porto_forbidden)
 317                                 if (weapon_prepareattack(1, autocvar_g_balance_porto_secondary_refire))
 318                                 {
 319                                         W_Porto_Attack(1);
 320                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_porto_secondary_animtime, w_ready);
 321                                 }
 322                         }
 323                         else
 324                         {
 325                                 if(self.porto_v_angle_held)
 326                                 {
 327                                         if(!self.BUTTON_ATCK2)
 328                                         {
 329                                                 self.porto_v_angle_held = 0;
 330
 331                                                 ClientData_Touch(self);
 332                                         }
 333                                 }
 334                                 else
 335                                 {
 336                                         if(self.BUTTON_ATCK2)
 337                                         {
 338                                                 self.porto_v_angle = self.v_angle;
 339                                                 self.porto_v_angle_held = 1;
 340
 341                                                 ClientData_Touch(self);
 342                                         }
 343                                 }
 344                                 if(self.porto_v_angle_held)
 345                                         makevectors(self.porto_v_angle); // override the previously set angles
 346
 347                                 if (self.BUTTON_ATCK)
 348                                 if (!self.porto_current)
 349                                 if (!self.porto_forbidden)
 350                                 if (weapon_prepareattack(0, autocvar_g_balance_porto_primary_refire))
 351                                 {
 352                                         W_Porto_Attack(-1);
 353                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_porto_primary_animtime, w_ready);
 354                                 }
 355                         }
 356
 357                         return TRUE;
 358                 }
 359                 case WR_PRECACHE:
 360                 {
 361                         precache_model ("models/weapons/g_porto.md3");
 362                         precache_model ("models/weapons/v_porto.md3");
 363                         precache_model ("models/weapons/h_porto.iqm");
 364                         precache_model ("models/portal.md3");
 365                         precache_sound ("porto/bounce.wav");
 366                         precache_sound ("porto/create.wav");
 367                         precache_sound ("porto/expire.wav");
 368                         precache_sound ("porto/explode.wav");
 369                         precache_sound ("porto/fire.wav");
 370                         precache_sound ("porto/unsupported.wav");
 371                         return TRUE;
 372                 }
 373                 case WR_SETUP:
 374                 {
 375                         weapon_setup(WEP_PORTO);
 376                         self.current_ammo = ammo_none;
 377                         return TRUE;
 378                 }
 379                 case WR_RESETPLAYER:
 380                 {
 381                         self.porto_current = world;
 382                         return TRUE;
 383                 }
 384         }
 385         return TRUE;
 386 }
 387 #endif
 388 #ifdef CSQC
 389 float w_porto(float req)
 390 {
 391         switch(req)
 392         {
 393                 case WR_IMPACTEFFECT:
 394                 {
 395                         print("Since when does Porto send DamageInfo?\n");
 396                         return TRUE;
 397                 }
 398                 case WR_PRECACHE:
 399                 {
 400                         // nothing to do
 401                         return TRUE;
 402                 }
 403         }
 404         return TRUE;
 405 }
 406 #endif
 407 #endif