qcsrc/common/weapons/w_porto.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ PORTO,
   4 /* function */ W_Porto,
   5 /* ammotype */ ammo_none,
   6 /* impulse  */ 0,
   7 /* flags    */ WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON,
   8 /* rating   */ 0,
   9 /* model    */ "porto" ,
  10 /* netname  */ "porto",
  11 /* fullname */ _("Port-O-Launch")
  12 );
  13
  14 #define PORTO_SETTINGS(w_cvar,w_prop) PORTO_SETTINGS_LIST(w_cvar, w_prop, PORTO, porto)
  15 #define PORTO_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  16         w_cvar(id, sn, BOTH, animtime) \
  17         w_cvar(id, sn, BOTH, lifetime) \
  18         w_cvar(id, sn, BOTH, refire) \
  19         w_cvar(id, sn, BOTH, speed) \
  20         w_cvar(id, sn, NONE, secondary) \
  21         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  22         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  23         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  24         w_prop(id, sn, float,  weaponstart, weaponstart) \
  25         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  26
  27 #ifdef SVQC
  28 PORTO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  29 .entity porto_current;
  30 .vector porto_v_angle; // holds "held" view angles
  31 .float porto_v_angle_held;
  32 .vector right_vector;
  33 #endif
  34 #else
  35 #ifdef SVQC
  36 void spawnfunc_weapon_porto (void) { weapon_defaultspawnfunc(WEP_PORTO); }
  37
  38 void W_Porto_Success (void)
  39 {
  40         if(self.realowner == world)
  41         {
  42                 objerror("Cannot succeed successfully: no owner\n");
  43                 return;
  44         }
  45
  46         self.realowner.porto_current = world;
  47         remove(self);
  48 }
  49
  50 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  51 void W_Porto_Fail (float failhard)
  52 {
  53         if(self.realowner == world)
  54         {
  55                 objerror("Cannot fail successfully: no owner\n");
  56                 return;
  57         }
  58
  59         // no portals here!
  60         if(self.cnt < 0)
  61         {
  62                 Portal_ClearWithID(self.realowner, self.portal_id);
  63         }
  64
  65         self.realowner.porto_current = world;
  66
  67         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !(self.realowner.weapons & WEPSET_PORTO))
  68         {
  69                 setsize (self, '-16 -16 0', '16 16 32');
  70                 setorigin(self, self.origin + trace_plane_normal);
  71                 if(move_out_of_solid(self))
  72                 {
  73                         self.flags = FL_ITEM;
  74                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  75                         tracetoss(self, self);
  76                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  77                         {
  78                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO, 0, self.origin, self.velocity);
  79                                 centerprint(self.realowner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  80                         }
  81                 }
  82         }
  83         remove(self);
  84 }
  85
  86 void W_Porto_Remove (entity p)
  87 {
  88         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
  89         {
  90                 entity oldself;
  91                 oldself = self;
  92                 self = p.porto_current;
  93                 W_Porto_Fail(1);
  94                 self = oldself;
  95         }
  96 }
  97
  98 void W_Porto_Think (void)
  99 {
 100         trace_plane_normal = '0 0 0';
 101         if(self.realowner.playerid != self.playerid)
 102                 remove(self);
 103         else
 104                 W_Porto_Fail(0);
 105 }
 106
 107 void W_Porto_Touch (void)
 108 {
 109         vector norm;
 110
 111         // do not use PROJECTILE_TOUCH here
 112         // FIXME but DO handle warpzones!
 113
 114         if(other.classname == "portal")
 115                 return; // handled by the portal
 116
 117         norm = trace_plane_normal;
 118         if(trace_ent.iscreature)
 119         {
 120                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN_z, MOVE_WORLDONLY, self);
 121                 if(trace_fraction >= 1)
 122                         return;
 123                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 124                         return;
 125                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 126                         return;
 127         }
 128
 129         if(self.realowner.playerid != self.playerid)
 130         {
 131                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 132                 remove(self);
 133         }
 134         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 135         {
 136                 spamsound(self, CH_SHOTS, "porto/bounce.wav", VOL_BASE, ATTEN_NORM);
 137                 // just reflect
 138                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 139                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 140         }
 141         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 142         {
 143                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 144                 W_Porto_Fail(0);
 145                 if(self.cnt < 0)
 146                         Portal_ClearAll_PortalsOnly(self.realowner);
 147         }
 148         else if(self.cnt == 0)
 149         {
 150                 // in-portal only
 151                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 152                 {
 153                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 154                         trace_plane_normal = norm;
 155                         centerprint(self.realowner, "^1In^7-portal created.");
 156                         W_Porto_Success();
 157                 }
 158                 else
 159                 {
 160                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 161                         trace_plane_normal = norm;
 162                         W_Porto_Fail(0);
 163                 }
 164         }
 165         else if(self.cnt == 1)
 166         {
 167                 // out-portal only
 168                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 169                 {
 170                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 171                         trace_plane_normal = norm;
 172                         centerprint(self.realowner, "^4Out^7-portal created.");
 173                         W_Porto_Success();
 174                 }
 175                 else
 176                 {
 177                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 178                         trace_plane_normal = norm;
 179                         W_Porto_Fail(0);
 180                 }
 181         }
 182         else if(self.effects & EF_RED)
 183         {
 184                 self.effects += EF_BLUE - EF_RED;
 185                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 186                 {
 187                         sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 188                         trace_plane_normal = norm;
 189                         centerprint(self.realowner, "^1In^7-portal created.");
 190                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 191                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 192                         CSQCProjectile(self, TRUE, PROJECTILE_PORTO_BLUE, TRUE); // change type
 193                 }
 194                 else
 195                 {
 196                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 197                         trace_plane_normal = norm;
 198                         Portal_ClearAll_PortalsOnly(self.realowner);
 199                         W_Porto_Fail(0);
 200                 }
 201         }
 202         else
 203         {
 204                 if(self.realowner.portal_in.portal_id == self.portal_id)
 205                 {
 206                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 207                         {
 208                                 sound(self, CH_SHOTS, "porto/create.wav", VOL_BASE, ATTEN_NORM);
 209                                 trace_plane_normal = norm;
 210                                 centerprint(self.realowner, "^4Out^7-portal created.");
 211                                 W_Porto_Success();
 212                         }
 213                         else
 214                         {
 215                                 sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 216                                 Portal_ClearAll_PortalsOnly(self.realowner);
 217                                 W_Porto_Fail(0);
 218                         }
 219                 }
 220                 else
 221                 {
 222                         sound(self, CH_SHOTS, "porto/unsupported.wav", VOL_BASE, ATTEN_NORM);
 223                         Portal_ClearAll_PortalsOnly(self.realowner);
 224                         W_Porto_Fail(0);
 225                 }
 226         }
 227 }
 228
 229 void W_Porto_Attack (float type)
 230 {
 231         entity gren;
 232
 233         W_SetupShot (self, FALSE, 4, "porto/fire.wav", CH_WEAPON_A, 0);
 234         // always shoot from the eye
 235         w_shotdir = v_forward;
 236         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 237
 238         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 239
 240         gren = spawn ();
 241         gren.cnt = type;
 242         gren.owner = gren.realowner = self;
 243         gren.playerid = self.playerid;
 244         gren.classname = "porto";
 245         gren.bot_dodge = TRUE;
 246         gren.bot_dodgerating = 200;
 247         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 248         PROJECTILE_MAKETRIGGER(gren);
 249         gren.effects = EF_RED;
 250         gren.scale = 4;
 251         setorigin(gren, w_shotorg);
 252         setsize(gren, '0 0 0', '0 0 0');
 253
 254         gren.nextthink = time + WEP_CVAR_BOTH(porto, (type <= 0), lifetime);
 255         gren.think = W_Porto_Think;
 256         gren.touch = W_Porto_Touch;
 257
 258         if(self.items & IT_STRENGTH)
 259                 W_SetupProjectileVelocity(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed) * autocvar_g_balance_powerup_strength_force, 0);
 260         else
 261                 W_SetupProjectileVelocity(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed), 0);
 262
 263         gren.angles = vectoangles (gren.velocity);
 264         gren.flags = FL_PROJECTILE;
 265
 266         gren.portal_id = time;
 267         self.porto_current = gren;
 268         gren.playerid = self.playerid;
 269         fixedmakevectors(fixedvectoangles(gren.velocity));
 270         gren.right_vector = v_right;
 271
 272         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 273
 274         if(type > 0)
 275                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_BLUE, TRUE);
 276         else
 277                 CSQCProjectile(gren, TRUE, PROJECTILE_PORTO_RED, TRUE);
 278
 279         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 280 }
 281
 282 float w_nexball_weapon(float req); // WEAPONTODO
 283 float W_Porto(float req)
 284 {
 285         //vector v_angle_save;
 286
 287         if (g_nexball) { return w_nexball_weapon(req); }
 288
 289         switch(req)
 290         {
 291                 case WR_AIM:
 292                 {
 293                         self.BUTTON_ATCK = FALSE;
 294                         self.BUTTON_ATCK2 = FALSE;
 295                         if(!WEP_CVAR(porto, secondary))
 296                                 if(bot_aim(WEP_CVAR_PRI(porto, speed), 0, WEP_CVAR_PRI(porto, lifetime), FALSE))
 297                                         self.BUTTON_ATCK = TRUE;
 298
 299                         return TRUE;
 300                 }
 301                 case WR_CONFIG:
 302                 {
 303                         PORTO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 304                         return TRUE;
 305                 }
 306                 case WR_THINK:
 307                 {
 308                         if(WEP_CVAR(porto, secondary))
 309                         {
 310                                 if (self.BUTTON_ATCK)
 311                                 if (!self.porto_current)
 312                                 if (!self.porto_forbidden)
 313                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 314                                 {
 315                                         W_Porto_Attack(0);
 316                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 317                                 }
 318
 319                                 if (self.BUTTON_ATCK2)
 320                                 if (!self.porto_current)
 321                                 if (!self.porto_forbidden)
 322                                 if (weapon_prepareattack(1, WEP_CVAR_SEC(porto, refire)))
 323                                 {
 324                                         W_Porto_Attack(1);
 325                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(porto, animtime), w_ready);
 326                                 }
 327                         }
 328                         else
 329                         {
 330                                 if(self.porto_v_angle_held)
 331                                 {
 332                                         if(!self.BUTTON_ATCK2)
 333                                         {
 334                                                 self.porto_v_angle_held = 0;
 335
 336                                                 ClientData_Touch(self);
 337                                         }
 338                                 }
 339                                 else
 340                                 {
 341                                         if(self.BUTTON_ATCK2)
 342                                         {
 343                                                 self.porto_v_angle = self.v_angle;
 344                                                 self.porto_v_angle_held = 1;
 345
 346                                                 ClientData_Touch(self);
 347                                         }
 348                                 }
 349                                 if(self.porto_v_angle_held)
 350                                         makevectors(self.porto_v_angle); // override the previously set angles
 351
 352                                 if (self.BUTTON_ATCK)
 353                                 if (!self.porto_current)
 354                                 if (!self.porto_forbidden)
 355                                 if (weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 356                                 {
 357                                         W_Porto_Attack(-1);
 358                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 359                                 }
 360                         }
 361
 362                         return TRUE;
 363                 }
 364                 case WR_INIT:
 365                 {
 366                         precache_model ("models/weapons/g_porto.md3");
 367                         precache_model ("models/weapons/v_porto.md3");
 368                         precache_model ("models/weapons/h_porto.iqm");
 369                         precache_model ("models/portal.md3");
 370                         precache_sound ("porto/bounce.wav");
 371                         precache_sound ("porto/create.wav");
 372                         precache_sound ("porto/expire.wav");
 373                         precache_sound ("porto/explode.wav");
 374                         precache_sound ("porto/fire.wav");
 375                         precache_sound ("porto/unsupported.wav");
 376                         PORTO_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 377                         return TRUE;
 378                 }
 379                 case WR_SETUP:
 380                 {
 381                         self.current_ammo = ammo_none;
 382                         return TRUE;
 383                 }
 384                 case WR_RESETPLAYER:
 385                 {
 386                         self.porto_current = world;
 387                         return TRUE;
 388                 }
 389         }
 390         return TRUE;
 391 }
 392 #endif
 393 #ifdef CSQC
 394 float W_Porto(float req)
 395 {
 396         switch(req)
 397         {
 398                 case WR_IMPACTEFFECT:
 399                 {
 400                         print("Since when does Porto send DamageInfo?\n");
 401                         return TRUE;
 402                 }
 403                 case WR_INIT:
 404                 {
 405                         // nothing to do
 406                         return TRUE;
 407                 }
 408         }
 409         return TRUE;
 410 }
 411 #endif
 412 #endif