qcsrc/common/weapons/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ SEEKER,
   4 /* function  */ W_Seeker,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 8,
   7 /* flags     */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* color     */ '0.5 1 0',
  10 /* model     */ "seeker",
  11 /* crosshair */ "gfx/crosshairseeker 0.8",
  12 /* refname   */ "seeker",
  13 /* wepname   */ _("T.A.G. Seeker")
  14 );
  15
  16 #define SEEKER_SETTINGS(w_cvar,w_prop) SEEKER_SETTINGS_LIST(w_cvar, w_prop, SEEKER, seeker)
  17 #define SEEKER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  18         w_cvar(id, sn, NONE, type) \
  19         w_cvar(id, sn, NONE, flac_ammo) \
  20         w_cvar(id, sn, NONE, flac_animtime) \
  21         w_cvar(id, sn, NONE, flac_damage) \
  22         w_cvar(id, sn, NONE, flac_edgedamage) \
  23         w_cvar(id, sn, NONE, flac_force) \
  24         w_cvar(id, sn, NONE, flac_lifetime) \
  25         w_cvar(id, sn, NONE, flac_lifetime_rand) \
  26         w_cvar(id, sn, NONE, flac_radius) \
  27         w_cvar(id, sn, NONE, flac_refire) \
  28         w_cvar(id, sn, NONE, flac_speed) \
  29         w_cvar(id, sn, NONE, flac_speed_up) \
  30         w_cvar(id, sn, NONE, flac_speed_z) \
  31         w_cvar(id, sn, NONE, flac_spread) \
  32         w_cvar(id, sn, NONE, missile_accel) \
  33         w_cvar(id, sn, NONE, missile_ammo) \
  34         w_cvar(id, sn, NONE, missile_animtime) \
  35         w_cvar(id, sn, NONE, missile_count) \
  36         w_cvar(id, sn, NONE, missile_damage) \
  37         w_cvar(id, sn, NONE, missile_damageforcescale) \
  38         w_cvar(id, sn, NONE, missile_decel) \
  39         w_cvar(id, sn, NONE, missile_delay) \
  40         w_cvar(id, sn, NONE, missile_edgedamage) \
  41         w_cvar(id, sn, NONE, missile_force) \
  42         w_cvar(id, sn, NONE, missile_health) \
  43         w_cvar(id, sn, NONE, missile_lifetime) \
  44         w_cvar(id, sn, NONE, missile_proxy) \
  45         w_cvar(id, sn, NONE, missile_proxy_delay) \
  46         w_cvar(id, sn, NONE, missile_proxy_maxrange) \
  47         w_cvar(id, sn, NONE, missile_radius) \
  48         w_cvar(id, sn, NONE, missile_refire) \
  49         w_cvar(id, sn, NONE, missile_smart) \
  50         w_cvar(id, sn, NONE, missile_smart_mindist) \
  51         w_cvar(id, sn, NONE, missile_smart_trace_max) \
  52         w_cvar(id, sn, NONE, missile_smart_trace_min) \
  53         w_cvar(id, sn, NONE, missile_speed) \
  54         w_cvar(id, sn, NONE, missile_speed_max) \
  55         w_cvar(id, sn, NONE, missile_speed_up) \
  56         w_cvar(id, sn, NONE, missile_speed_z) \
  57         w_cvar(id, sn, NONE, missile_spread) \
  58         w_cvar(id, sn, NONE, missile_turnrate) \
  59         w_cvar(id, sn, NONE, tag_ammo) \
  60         w_cvar(id, sn, NONE, tag_animtime) \
  61         w_cvar(id, sn, NONE, tag_damageforcescale) \
  62         w_cvar(id, sn, NONE, tag_health) \
  63         w_cvar(id, sn, NONE, tag_lifetime) \
  64         w_cvar(id, sn, NONE, tag_refire) \
  65         w_cvar(id, sn, NONE, tag_speed) \
  66         w_cvar(id, sn, NONE, tag_spread) \
  67         w_cvar(id, sn, NONE, tag_tracker_lifetime) \
  68         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  69         w_prop(id, sn, float,  reloading_time, reload_time) \
  70         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  71         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  72         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  73         w_prop(id, sn, float,  weaponstart, weaponstart) \
  74         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  75
  76 #ifdef SVQC
  77 SEEKER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  78 .entity tag_target, wps_tag_tracker;
  79 .float tag_time;
  80 #endif
  81 #else
  82 #ifdef SVQC
  83 void spawnfunc_weapon_seeker (void) { weapon_defaultspawnfunc(WEP_SEEKER); }
  84
  85 // ============================
  86 // Begin: Missile functions, these are general functions to be manipulated by other code
  87 // ============================
  88 void W_Seeker_Missile_Explode()
  89 {
  90         self.event_damage = func_null;
  91         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  92
  93         remove (self);
  94 }
  95
  96 void W_Seeker_Missile_Touch()
  97 {
  98         PROJECTILE_TOUCH;
  99
 100         W_Seeker_Missile_Explode();
 101 }
 102
 103 void W_Seeker_Missile_Think()
 104 {
 105         entity e;
 106         vector desireddir, olddir, newdir, eorg;
 107         float turnrate;
 108         float dist;
 109         float spd;
 110
 111         if (time > self.cnt)
 112         {
 113                 self.projectiledeathtype |= HITTYPE_SPLASH;
 114                 W_Seeker_Missile_Explode();
 115         }
 116
 117         spd = vlen(self.velocity);
 118         spd = bound(
 119                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 120                 WEP_CVAR(seeker, missile_speed_max),
 121                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 122         );
 123
 124         if (self.enemy != world)
 125                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 126                         self.enemy = world;
 127
 128         if (self.enemy != world)
 129         {
 130                 e               = self.enemy;
 131                 eorg            = 0.5 * (e.absmin + e.absmax);
 132                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 133                 desireddir      = normalize(eorg - self.origin);
 134                 olddir          = normalize(self.velocity); // get my current direction
 135                 dist            = vlen(eorg - self.origin);
 136
 137                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 138                 if (WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 139                 {
 140                         // Is it a better idea (shorter distance) to trace to the target itself?
 141                         if ( vlen(self.origin + olddir * self.wait) < dist)
 142                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 143                         else
 144                                 traceline(self.origin, eorg, FALSE, self);
 145
 146                         // Setup adaptive tracelength
 147                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 148
 149                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 150                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 151                 }
 152
 153                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 154                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 155         }
 156         else
 157                 dist = 0;
 158
 159         // Proxy
 160         if (WEP_CVAR(seeker, missile_proxy))
 161         {
 162                 if ( dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 163                 {
 164                         if (self.autoswitch == 0)
 165                         {
 166                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 167                         }
 168                         else
 169                         {
 170                                 if (self.autoswitch <= time)
 171                                 {
 172                                         W_Seeker_Missile_Explode();
 173                                         self.autoswitch = 0;
 174                                 }
 175                         }
 176                 }
 177                 else
 178                 {
 179                         if (self.autoswitch != 0)
 180                                 self.autoswitch = 0;
 181                 }
 182         }
 183         ///////////////
 184
 185         if (self.enemy.deadflag != DEAD_NO)
 186         {
 187                 self.enemy = world;
 188                 self.cnt = time + 1 + (random() * 4);
 189                 self.nextthink = self.cnt;
 190                 return;
 191         }
 192
 193         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 194         self.nextthink = time;// + 0.05; // csqc projectiles
 195         UpdateCSQCProjectile(self);
 196 }
 197
 198
 199
 200 void W_Seeker_Missile_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 201 {
 202         if (self.health <= 0)
 203                 return;
 204
 205         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 206                 return; // g_projectiles_damage says to halt
 207
 208         if (self.realowner == attacker)
 209                 self.health = self.health - (damage * 0.25);
 210         else
 211                 self.health = self.health - damage;
 212
 213         if (self.health <= 0)
 214                 W_PrepareExplosionByDamage(attacker, W_Seeker_Missile_Explode);
 215 }
 216
 217 /*
 218 void W_Seeker_Missile_Animate()
 219 {
 220         self.frame = self.frame +1;
 221         self.nextthink = time + 0.05;
 222
 223         if (self.enemy != world)
 224                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 225                         self.enemy = world;
 226
 227         if(self.frame == 5)
 228         {
 229                 self.think           = W_Seeker_Missile_Think;
 230                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 231
 232                 if (autocvar_g_balance_seeker_missile_proxy)
 233                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 234                 else
 235                         self.movetype    = MOVETYPE_FLYMISSILE;
 236         }
 237
 238         UpdateCSQCProjectile(self);
 239 }
 240 */
 241
 242 void W_Seeker_Fire_Missile(vector f_diff, entity m_target)
 243 {
 244         entity missile;
 245
 246         W_DecreaseAmmo(WEP_CVAR(seeker, missile_ammo));
 247
 248         makevectors(self.v_angle);
 249         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 250         w_shotorg += f_diff;
 251         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 252
 253         //self.detornator         = FALSE;
 254
 255         missile                 = spawn();
 256         missile.owner           = missile.realowner = self;
 257         missile.classname       = "seeker_missile";
 258         missile.bot_dodge       = TRUE;
 259         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 260
 261         missile.think           = W_Seeker_Missile_Think;
 262         missile.touch           = W_Seeker_Missile_Touch;
 263         missile.event_damage    = W_Seeker_Missile_Damage;
 264         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 265         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 266         missile.enemy           = m_target;
 267         missile.solid           = SOLID_BBOX;
 268         missile.scale           = 2;
 269         missile.takedamage      = DAMAGE_YES;
 270         missile.health          = WEP_CVAR(seeker, missile_health);
 271         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 272         missile.damagedbycontents = TRUE;
 273         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 274
 275         if (missile.enemy != world)
 276                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 277         else
 278                 missile.projectiledeathtype = WEP_SEEKER;
 279
 280
 281         setorigin (missile, w_shotorg);
 282         setsize (missile, '-4 -4 -4', '4 4 4');
 283         missile.movetype    = MOVETYPE_FLYMISSILE;
 284         missile.flags       = FL_PROJECTILE;
 285         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 286
 287         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 288
 289         missile.angles = vectoangles (missile.velocity);
 290
 291         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 292
 293         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 294 }
 295
 296 // ============================
 297 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 298 // ============================
 299 void W_Seeker_Flac_Explode()
 300 {
 301         self.event_damage = func_null;
 302
 303         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 304
 305         remove (self);
 306 }
 307
 308 void W_Seeker_Flac_Touch()
 309 {
 310         PROJECTILE_TOUCH;
 311
 312         W_Seeker_Flac_Explode();
 313 }
 314
 315 void W_Seeker_Fire_Flac()
 316 {
 317         entity missile;
 318         vector f_diff;
 319         float c;
 320
 321         W_DecreaseAmmo(WEP_CVAR(seeker, flac_ammo));
 322
 323         c = mod(self.bulletcounter, 4);
 324         switch(c)
 325         {
 326                 case 0:
 327                         f_diff = '-1.25 -3.75 0';
 328                         break;
 329                 case 1:
 330                         f_diff = '+1.25 -3.75 0';
 331                         break;
 332                 case 2:
 333                         f_diff = '-1.25 +3.75 0';
 334                         break;
 335                 case 3:
 336                 default:
 337                         f_diff = '+1.25 +3.75 0';
 338                         break;
 339         }
 340         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 341         w_shotorg += f_diff;
 342
 343         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 344
 345         missile                                 = spawn ();
 346         missile.owner                   = missile.realowner = self;
 347         missile.classname               = "missile";
 348         missile.bot_dodge               = TRUE;
 349         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 350         missile.touch                   = W_Seeker_Flac_Explode;
 351         missile.use                     = W_Seeker_Flac_Explode;
 352         missile.think                   = adaptor_think2use_hittype_splash;
 353         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 354         missile.solid                   = SOLID_BBOX;
 355         missile.movetype                = MOVETYPE_FLY;
 356         missile.projectiledeathtype = WEP_SEEKER;
 357         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 358         missile.flags                           = FL_PROJECTILE;
 359         missile.missile_flags       = MIF_SPLASH;
 360
 361         // csqc projectiles
 362         //missile.angles                                = vectoangles (missile.velocity);
 363         //missile.scale = 0.4; // BUG: the model is too big
 364
 365         setorigin (missile, w_shotorg);
 366         setsize (missile, '-2 -2 -2', '2 2 2');
 367
 368         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 369         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 370
 371         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 372 }
 373
 374 // ============================
 375 // Begin: Tag and rocket controllers
 376 // ============================
 377 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
 378 {
 379         entity tag;
 380         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 381                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 382                         return tag;
 383
 384         return world;
 385 }
 386
 387 void W_Seeker_Attack()
 388 {
 389         entity tracker, closest_target;
 390
 391         closest_target = world;
 392         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 393         {
 394                 if (closest_target)
 395                 {
 396                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 397                                 closest_target = tracker.tag_target;
 398                 }
 399                 else
 400                         closest_target = tracker.tag_target;
 401         }
 402
 403         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 404         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 405                 closest_target = world;
 406
 407         W_Seeker_Fire_Missile('0 0 0', closest_target);
 408 }
 409
 410 void W_Seeker_Vollycontroller_Think() // TODO: Merge this with W_Seeker_Attack
 411 {
 412         float c;
 413         entity oldself,oldenemy;
 414         self.cnt = self.cnt - 1;
 415
 416         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.WEP_AMMO(SEEKER) < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 417         {
 418                 remove(self);
 419                 return;
 420         }
 421
 422         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 423
 424         oldself = self;
 425         self = self.realowner;
 426
 427         oldenemy = self.enemy;
 428         self.enemy = oldself.enemy;
 429
 430         c = mod(self.cnt, 4);
 431         switch(c)
 432         {
 433                 case 0:
 434                         W_Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 435                         break;
 436                 case 1:
 437                         W_Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 438                         break;
 439                 case 2:
 440                         W_Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 441                         break;
 442                 case 3:
 443                 default:
 444                         W_Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 445                         break;
 446         }
 447
 448         self.enemy = oldenemy;
 449         self = oldself;
 450 }
 451
 452 void W_Seeker_Tracker_Think()
 453 {
 454         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 455         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 456         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 457         {
 458                 if (self)
 459                 {
 460                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 461                         remove(self);
 462                 }
 463                 return;
 464         }
 465
 466         // Update the think method information
 467         self.nextthink = time;
 468 }
 469
 470 // ============================
 471 // Begin: Tag projectile
 472 // ============================
 473 void W_Seeker_Tag_Explode()
 474 {
 475         //if(other==self.realowner)
 476         //    return;
 477         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, other.species, self);
 478
 479         remove (self);
 480 }
 481
 482 void W_Seeker_Tag_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 483 {
 484         if (self.health <= 0)
 485                 return;
 486         self.health = self.health - damage;
 487         if (self.health <= 0)
 488                 W_Seeker_Tag_Explode();
 489 }
 490
 491 void W_Seeker_Tag_Touch()
 492 {
 493         vector dir;
 494         vector org2;
 495         entity e;
 496
 497         PROJECTILE_TOUCH;
 498
 499         dir     = normalize (self.realowner.origin - self.origin);
 500         org2    = findbetterlocation (self.origin, 8);
 501
 502         te_knightspike(org2);
 503
 504         self.event_damage = func_null;
 505         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 506
 507         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 508         {
 509                 // check to see if this person is already tagged by me
 510                 entity tag = W_Seeker_Tagged_Info(self.realowner, other);
 511
 512                 if (tag != world)
 513                 {
 514                         if (other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 515                                 WaypointSprite_Kill(other.wps_tag_tracker);
 516
 517                         tag.tag_time = time;
 518                 }
 519                 else
 520                 {
 521                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 522                         e             = spawn();
 523                         e.cnt         = WEP_CVAR(seeker, missile_count);
 524                         e.classname   = "tag_tracker";
 525                         e.owner       = self.owner;
 526                         e.realowner   = self.realowner;
 527
 528                         if(WEP_CVAR(seeker, type) == 1)
 529                         {
 530                                 e.tag_target  = other;
 531                                 e.tag_time    = time;
 532                                 e.think       = W_Seeker_Tracker_Think;
 533                         }
 534                         else
 535                         {
 536                                 e.enemy     = other;
 537                                 e.think     = W_Seeker_Vollycontroller_Think;
 538                         }
 539
 540                         e.nextthink   = time;
 541                 }
 542
 543                 if(WEP_CVAR(seeker, type) == 1)
 544                 {
 545                         WaypointSprite_Spawn("tagged-target", WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 546                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 547                 }
 548         }
 549
 550         remove(self);
 551         return;
 552 }
 553
 554 void W_Seeker_Fire_Tag()
 555 {
 556         entity missile;
 557         W_DecreaseAmmo(WEP_CVAR(seeker, tag_ammo));
 558
 559         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 560
 561         missile                 = spawn();
 562         missile.owner           = missile.realowner = self;
 563         missile.classname       = "seeker_tag";
 564         missile.bot_dodge       = TRUE;
 565         missile.bot_dodgerating = 50;
 566         missile.touch           = W_Seeker_Tag_Touch;
 567         missile.think           = SUB_Remove;
 568         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 569         missile.movetype        = MOVETYPE_FLY;
 570         missile.solid           = SOLID_BBOX;
 571
 572         missile.takedamage       = DAMAGE_YES;
 573         missile.event_damage     = W_Seeker_Tag_Damage;
 574         missile.health           = WEP_CVAR(seeker, tag_health);
 575         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 576
 577         setorigin (missile, w_shotorg);
 578         setsize (missile, '-2 -2 -2', '2 2 2');
 579
 580         missile.flags       = FL_PROJECTILE;
 581         //missile.missile_flags = MIF_..?;
 582
 583         missile.movetype    = MOVETYPE_FLY;
 584         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 585         missile.angles = vectoangles (missile.velocity);
 586
 587         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 588
 589         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 590 }
 591
 592 // ============================
 593 // Begin: Genereal weapon functions
 594 // ============================
 595
 596 float W_Seeker(float req)
 597 {
 598         float ammo_amount;
 599
 600         switch(req)
 601         {
 602                 case WR_AIM:
 603                 {
 604                         if (WEP_CVAR(seeker, type) == 1)
 605                                 if (W_Seeker_Tagged_Info(self, self.enemy) != world)
 606                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), FALSE);
 607                                 else
 608                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 609                         else
 610                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 611                         return TRUE;
 612                 }
 613                 case WR_THINK:
 614                 {
 615                         if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) // forced reload
 616                                 WEP_ACTION(self.weapon, WR_RELOAD);
 617
 618                         else if (self.BUTTON_ATCK)
 619                         {
 620                                 if (WEP_CVAR(seeker, type) == 1)
 621                                 {
 622                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, missile_refire)))
 623                                         {
 624                                                 W_Seeker_Attack();
 625                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 626                                         }
 627                                 }
 628                                 else
 629                                 {
 630                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 631                                         {
 632                                                 W_Seeker_Fire_Tag();
 633                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 634                                         }
 635                                 }
 636                         }
 637
 638                         else if (self.BUTTON_ATCK2)
 639                         {
 640                                 if (WEP_CVAR(seeker, type) == 1)
 641                                 {
 642                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 643                                         {
 644                                                 W_Seeker_Fire_Tag();
 645                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 646                                         }
 647                                 }
 648                                 else
 649                                 {
 650                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, flac_refire)))
 651                                         {
 652                                                 W_Seeker_Fire_Flac();
 653                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 654                                         }
 655                                 }
 656                         }
 657
 658                         return TRUE;
 659                 }
 660                 case WR_INIT:
 661                 {
 662                         precache_model ("models/weapons/g_seeker.md3");
 663                         precache_model ("models/weapons/v_seeker.md3");
 664                         precache_model ("models/weapons/h_seeker.iqm");
 665                         precache_sound ("weapons/tag_fire.wav");
 666                         precache_sound ("weapons/flac_fire.wav");
 667                         precache_sound ("weapons/seeker_fire.wav");
 668                         SEEKER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 669                         return TRUE;
 670                 }
 671                 case WR_CHECKAMMO1:
 672                 {
 673                         if (WEP_CVAR(seeker, type) == 1)
 674                         {
 675                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, missile_ammo);
 676                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, missile_ammo);
 677                         }
 678                         else
 679                         {
 680                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 681                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 682                         }
 683                         return ammo_amount;
 684                 }
 685                 case WR_CHECKAMMO2:
 686                 {
 687                         if (WEP_CVAR(seeker, type) == 1)
 688                         {
 689                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 690                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 691                         }
 692                         else
 693                         {
 694                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, flac_ammo);
 695                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, flac_ammo);
 696                         }
 697                         return ammo_amount;
 698                 }
 699                 case WR_CONFIG:
 700                 {
 701                         SEEKER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 702                         return TRUE;
 703                 }
 704                 case WR_RELOAD:
 705                 {
 706                         W_Reload(min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), "weapons/reload.wav");
 707                         return TRUE;
 708                 }
 709                 case WR_SUICIDEMESSAGE:
 710                 {
 711                         return WEAPON_SEEKER_SUICIDE;
 712                 }
 713                 case WR_KILLMESSAGE:
 714                 {
 715                         if(w_deathtype & HITTYPE_SECONDARY)
 716                                 return WEAPON_SEEKER_MURDER_TAG;
 717                         else
 718                                 return WEAPON_SEEKER_MURDER_SPRAY;
 719                 }
 720         }
 721         return TRUE;
 722 }
 723 #endif
 724 #ifdef CSQC
 725 float W_Seeker(float req)
 726 {
 727         switch(req)
 728         {
 729                 case WR_IMPACTEFFECT:
 730                 {
 731                         vector org2;
 732                         org2 = w_org + w_backoff * 6;
 733                         if(w_deathtype & HITTYPE_BOUNCE)
 734                         {
 735                                 if(w_deathtype & HITTYPE_SECONDARY)
 736                                 {
 737                                         if(!w_issilent)
 738                                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTEN_NORM);
 739                                 }
 740                                 else
 741                                 {
 742                                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 743                                         if(!w_issilent)
 744                                         {
 745                                                 if (w_random<0.15)
 746                                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTEN_NORM);
 747                                                 else if (w_random<0.7)
 748                                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTEN_NORM);
 749                                                 else
 750                                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTEN_NORM);
 751                                         }
 752                                 }
 753                         }
 754                         else
 755                         {
 756                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 757                                 if(!w_issilent)
 758                                 {
 759                                         if (w_random<0.15)
 760                                                 sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTEN_NORM);
 761                                         else if (w_random<0.7)
 762                                                 sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTEN_NORM);
 763                                         else
 764                                                 sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTEN_NORM);
 765                                 }
 766                         }
 767                         return TRUE;
 768                 }
 769                 case WR_INIT:
 770                 {
 771                         precache_sound("weapons/seekerexp1.wav");
 772                         precache_sound("weapons/seekerexp2.wav");
 773                         precache_sound("weapons/seekerexp3.wav");
 774                         precache_sound("weapons/tagexp1.wav");
 775                         precache_sound("weapons/tagexp2.wav");
 776                         precache_sound("weapons/tagexp3.wav");
 777                         precache_sound("weapons/tag_impact.wav");
 778                         return TRUE;
 779                 }
 780                 case WR_ZOOMRETICLE:
 781                 {
 782                         // no weapon specific image for this weapon
 783                         return FALSE;
 784                 }
 785         }
 786
 787         return TRUE;
 788 }
 789 #endif
 790 #endif