qcsrc/common/weapons/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ SEEKER,
   4 /* function  */ W_Seeker,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 8,
   7 /* flags     */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* color     */ '0.5 1 0',
  10 /* modelname */ "seeker",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairseeker 0.8",
  13 /* wepimg    */ "weaponseeker",
  14 /* refname   */ "seeker",
  15 /* wepname   */ _("T.A.G. Seeker")
  16 );
  17
  18 #define SEEKER_SETTINGS(w_cvar,w_prop) SEEKER_SETTINGS_LIST(w_cvar, w_prop, SEEKER, seeker)
  19 #define SEEKER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, type) \
  21         w_cvar(id, sn, NONE, flac_ammo) \
  22         w_cvar(id, sn, NONE, flac_animtime) \
  23         w_cvar(id, sn, NONE, flac_damage) \
  24         w_cvar(id, sn, NONE, flac_edgedamage) \
  25         w_cvar(id, sn, NONE, flac_force) \
  26         w_cvar(id, sn, NONE, flac_lifetime) \
  27         w_cvar(id, sn, NONE, flac_lifetime_rand) \
  28         w_cvar(id, sn, NONE, flac_radius) \
  29         w_cvar(id, sn, NONE, flac_refire) \
  30         w_cvar(id, sn, NONE, flac_speed) \
  31         w_cvar(id, sn, NONE, flac_speed_up) \
  32         w_cvar(id, sn, NONE, flac_speed_z) \
  33         w_cvar(id, sn, NONE, flac_spread) \
  34         w_cvar(id, sn, NONE, missile_accel) \
  35         w_cvar(id, sn, NONE, missile_ammo) \
  36         w_cvar(id, sn, NONE, missile_animtime) \
  37         w_cvar(id, sn, NONE, missile_count) \
  38         w_cvar(id, sn, NONE, missile_damage) \
  39         w_cvar(id, sn, NONE, missile_damageforcescale) \
  40         w_cvar(id, sn, NONE, missile_decel) \
  41         w_cvar(id, sn, NONE, missile_delay) \
  42         w_cvar(id, sn, NONE, missile_edgedamage) \
  43         w_cvar(id, sn, NONE, missile_force) \
  44         w_cvar(id, sn, NONE, missile_health) \
  45         w_cvar(id, sn, NONE, missile_lifetime) \
  46         w_cvar(id, sn, NONE, missile_proxy) \
  47         w_cvar(id, sn, NONE, missile_proxy_delay) \
  48         w_cvar(id, sn, NONE, missile_proxy_maxrange) \
  49         w_cvar(id, sn, NONE, missile_radius) \
  50         w_cvar(id, sn, NONE, missile_refire) \
  51         w_cvar(id, sn, NONE, missile_smart) \
  52         w_cvar(id, sn, NONE, missile_smart_mindist) \
  53         w_cvar(id, sn, NONE, missile_smart_trace_max) \
  54         w_cvar(id, sn, NONE, missile_smart_trace_min) \
  55         w_cvar(id, sn, NONE, missile_speed) \
  56         w_cvar(id, sn, NONE, missile_speed_max) \
  57         w_cvar(id, sn, NONE, missile_speed_up) \
  58         w_cvar(id, sn, NONE, missile_speed_z) \
  59         w_cvar(id, sn, NONE, missile_spread) \
  60         w_cvar(id, sn, NONE, missile_turnrate) \
  61         w_cvar(id, sn, NONE, tag_ammo) \
  62         w_cvar(id, sn, NONE, tag_animtime) \
  63         w_cvar(id, sn, NONE, tag_damageforcescale) \
  64         w_cvar(id, sn, NONE, tag_health) \
  65         w_cvar(id, sn, NONE, tag_lifetime) \
  66         w_cvar(id, sn, NONE, tag_refire) \
  67         w_cvar(id, sn, NONE, tag_speed) \
  68         w_cvar(id, sn, NONE, tag_spread) \
  69         w_cvar(id, sn, NONE, tag_tracker_lifetime) \
  70         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  71         w_prop(id, sn, float,  reloading_time, reload_time) \
  72         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  73         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  74         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  75         w_prop(id, sn, float,  weaponstart, weaponstart) \
  76         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  77
  78 #ifdef SVQC
  79 SEEKER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  80 .entity tag_target, wps_tag_tracker;
  81 .float tag_time;
  82 #endif
  83 #else
  84 #ifdef SVQC
  85 void spawnfunc_weapon_seeker (void) { weapon_defaultspawnfunc(WEP_SEEKER); }
  86
  87 // ============================
  88 // Begin: Missile functions, these are general functions to be manipulated by other code
  89 // ============================
  90 void W_Seeker_Missile_Explode()
  91 {
  92         self.event_damage = func_null;
  93         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  94
  95         remove (self);
  96 }
  97
  98 void W_Seeker_Missile_Touch()
  99 {
 100         PROJECTILE_TOUCH;
 101
 102         W_Seeker_Missile_Explode();
 103 }
 104
 105 void W_Seeker_Missile_Think()
 106 {
 107         entity e;
 108         vector desireddir, olddir, newdir, eorg;
 109         float turnrate;
 110         float dist;
 111         float spd;
 112
 113         if (time > self.cnt)
 114         {
 115                 self.projectiledeathtype |= HITTYPE_SPLASH;
 116                 W_Seeker_Missile_Explode();
 117         }
 118
 119         spd = vlen(self.velocity);
 120         spd = bound(
 121                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 122                 WEP_CVAR(seeker, missile_speed_max),
 123                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 124         );
 125
 126         if (self.enemy != world)
 127                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 128                         self.enemy = world;
 129
 130         if (self.enemy != world)
 131         {
 132                 e               = self.enemy;
 133                 eorg            = 0.5 * (e.absmin + e.absmax);
 134                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 135                 desireddir      = normalize(eorg - self.origin);
 136                 olddir          = normalize(self.velocity); // get my current direction
 137                 dist            = vlen(eorg - self.origin);
 138
 139                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 140                 if (WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 141                 {
 142                         // Is it a better idea (shorter distance) to trace to the target itself?
 143                         if ( vlen(self.origin + olddir * self.wait) < dist)
 144                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 145                         else
 146                                 traceline(self.origin, eorg, FALSE, self);
 147
 148                         // Setup adaptive tracelength
 149                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 150
 151                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 152                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 153                 }
 154
 155                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 156                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 157         }
 158         else
 159                 dist = 0;
 160
 161         // Proxy
 162         if (WEP_CVAR(seeker, missile_proxy))
 163         {
 164                 if ( dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 165                 {
 166                         if (self.autoswitch == 0)
 167                         {
 168                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 169                         }
 170                         else
 171                         {
 172                                 if (self.autoswitch <= time)
 173                                 {
 174                                         W_Seeker_Missile_Explode();
 175                                         self.autoswitch = 0;
 176                                 }
 177                         }
 178                 }
 179                 else
 180                 {
 181                         if (self.autoswitch != 0)
 182                                 self.autoswitch = 0;
 183                 }
 184         }
 185         ///////////////
 186
 187         if (self.enemy.deadflag != DEAD_NO)
 188         {
 189                 self.enemy = world;
 190                 self.cnt = time + 1 + (random() * 4);
 191                 self.nextthink = self.cnt;
 192                 return;
 193         }
 194
 195         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 196         self.nextthink = time;// + 0.05; // csqc projectiles
 197         UpdateCSQCProjectile(self);
 198 }
 199
 200
 201
 202 void W_Seeker_Missile_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 203 {
 204         if (self.health <= 0)
 205                 return;
 206
 207         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 208                 return; // g_projectiles_damage says to halt
 209
 210         if (self.realowner == attacker)
 211                 self.health = self.health - (damage * 0.25);
 212         else
 213                 self.health = self.health - damage;
 214
 215         if (self.health <= 0)
 216                 W_PrepareExplosionByDamage(attacker, W_Seeker_Missile_Explode);
 217 }
 218
 219 /*
 220 void W_Seeker_Missile_Animate()
 221 {
 222         self.frame = self.frame +1;
 223         self.nextthink = time + 0.05;
 224
 225         if (self.enemy != world)
 226                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 227                         self.enemy = world;
 228
 229         if(self.frame == 5)
 230         {
 231                 self.think           = W_Seeker_Missile_Think;
 232                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 233
 234                 if (autocvar_g_balance_seeker_missile_proxy)
 235                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 236                 else
 237                         self.movetype    = MOVETYPE_FLYMISSILE;
 238         }
 239
 240         UpdateCSQCProjectile(self);
 241 }
 242 */
 243
 244 void W_Seeker_Fire_Missile(vector f_diff, entity m_target)
 245 {
 246         entity missile;
 247
 248         W_DecreaseAmmo(WEP_CVAR(seeker, missile_ammo));
 249
 250         makevectors(self.v_angle);
 251         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 252         w_shotorg += f_diff;
 253         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 254
 255         //self.detornator         = FALSE;
 256
 257         missile                 = spawn();
 258         missile.owner           = missile.realowner = self;
 259         missile.classname       = "seeker_missile";
 260         missile.bot_dodge       = TRUE;
 261         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 262
 263         missile.think           = W_Seeker_Missile_Think;
 264         missile.touch           = W_Seeker_Missile_Touch;
 265         missile.event_damage    = W_Seeker_Missile_Damage;
 266         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 267         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 268         missile.enemy           = m_target;
 269         missile.solid           = SOLID_BBOX;
 270         missile.scale           = 2;
 271         missile.takedamage      = DAMAGE_YES;
 272         missile.health          = WEP_CVAR(seeker, missile_health);
 273         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 274         missile.damagedbycontents = TRUE;
 275         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 276
 277         if (missile.enemy != world)
 278                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 279         else
 280                 missile.projectiledeathtype = WEP_SEEKER;
 281
 282
 283         setorigin (missile, w_shotorg);
 284         setsize (missile, '-4 -4 -4', '4 4 4');
 285         missile.movetype    = MOVETYPE_FLYMISSILE;
 286         missile.flags       = FL_PROJECTILE;
 287         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 288
 289         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 290
 291         missile.angles = vectoangles (missile.velocity);
 292
 293         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 294
 295         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 296 }
 297
 298 // ============================
 299 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 300 // ============================
 301 void W_Seeker_Flac_Explode()
 302 {
 303         self.event_damage = func_null;
 304
 305         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 306
 307         remove (self);
 308 }
 309
 310 void W_Seeker_Flac_Touch()
 311 {
 312         PROJECTILE_TOUCH;
 313
 314         W_Seeker_Flac_Explode();
 315 }
 316
 317 void W_Seeker_Fire_Flac()
 318 {
 319         entity missile;
 320         vector f_diff;
 321         float c;
 322
 323         W_DecreaseAmmo(WEP_CVAR(seeker, flac_ammo));
 324
 325         c = mod(self.bulletcounter, 4);
 326         switch(c)
 327         {
 328                 case 0:
 329                         f_diff = '-1.25 -3.75 0';
 330                         break;
 331                 case 1:
 332                         f_diff = '+1.25 -3.75 0';
 333                         break;
 334                 case 2:
 335                         f_diff = '-1.25 +3.75 0';
 336                         break;
 337                 case 3:
 338                 default:
 339                         f_diff = '+1.25 +3.75 0';
 340                         break;
 341         }
 342         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 343         w_shotorg += f_diff;
 344
 345         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 346
 347         missile                                 = spawn ();
 348         missile.owner                   = missile.realowner = self;
 349         missile.classname               = "missile";
 350         missile.bot_dodge               = TRUE;
 351         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 352         missile.touch                   = W_Seeker_Flac_Explode;
 353         missile.use                     = W_Seeker_Flac_Explode;
 354         missile.think                   = adaptor_think2use_hittype_splash;
 355         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 356         missile.solid                   = SOLID_BBOX;
 357         missile.movetype                = MOVETYPE_FLY;
 358         missile.projectiledeathtype = WEP_SEEKER;
 359         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 360         missile.flags                           = FL_PROJECTILE;
 361         missile.missile_flags       = MIF_SPLASH;
 362
 363         // csqc projectiles
 364         //missile.angles                                = vectoangles (missile.velocity);
 365         //missile.scale = 0.4; // BUG: the model is too big
 366
 367         setorigin (missile, w_shotorg);
 368         setsize (missile, '-2 -2 -2', '2 2 2');
 369
 370         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 371         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 372
 373         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 374 }
 375
 376 // ============================
 377 // Begin: Tag and rocket controllers
 378 // ============================
 379 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
 380 {
 381         entity tag;
 382         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 383                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 384                         return tag;
 385
 386         return world;
 387 }
 388
 389 void W_Seeker_Attack()
 390 {
 391         entity tracker, closest_target;
 392
 393         closest_target = world;
 394         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 395         {
 396                 if (closest_target)
 397                 {
 398                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 399                                 closest_target = tracker.tag_target;
 400                 }
 401                 else
 402                         closest_target = tracker.tag_target;
 403         }
 404
 405         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 406         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 407                 closest_target = world;
 408
 409         W_Seeker_Fire_Missile('0 0 0', closest_target);
 410 }
 411
 412 void W_Seeker_Vollycontroller_Think() // TODO: Merge this with W_Seeker_Attack
 413 {
 414         float c;
 415         entity oldself,oldenemy;
 416         self.cnt = self.cnt - 1;
 417
 418         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.WEP_AMMO(SEEKER) < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 419         {
 420                 remove(self);
 421                 return;
 422         }
 423
 424         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 425
 426         oldself = self;
 427         self = self.realowner;
 428
 429         oldenemy = self.enemy;
 430         self.enemy = oldself.enemy;
 431
 432         c = mod(self.cnt, 4);
 433         switch(c)
 434         {
 435                 case 0:
 436                         W_Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 437                         break;
 438                 case 1:
 439                         W_Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 440                         break;
 441                 case 2:
 442                         W_Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 443                         break;
 444                 case 3:
 445                 default:
 446                         W_Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 447                         break;
 448         }
 449
 450         self.enemy = oldenemy;
 451         self = oldself;
 452 }
 453
 454 void W_Seeker_Tracker_Think()
 455 {
 456         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 457         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 458         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 459         {
 460                 if (self)
 461                 {
 462                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 463                         remove(self);
 464                 }
 465                 return;
 466         }
 467
 468         // Update the think method information
 469         self.nextthink = time;
 470 }
 471
 472 // ============================
 473 // Begin: Tag projectile
 474 // ============================
 475 void W_Seeker_Tag_Explode()
 476 {
 477         //if(other==self.realowner)
 478         //    return;
 479         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, other.species, self);
 480
 481         remove (self);
 482 }
 483
 484 void W_Seeker_Tag_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 485 {
 486         if (self.health <= 0)
 487                 return;
 488         self.health = self.health - damage;
 489         if (self.health <= 0)
 490                 W_Seeker_Tag_Explode();
 491 }
 492
 493 void W_Seeker_Tag_Touch()
 494 {
 495         vector dir;
 496         vector org2;
 497         entity e;
 498
 499         PROJECTILE_TOUCH;
 500
 501         dir     = normalize (self.realowner.origin - self.origin);
 502         org2    = findbetterlocation (self.origin, 8);
 503
 504         te_knightspike(org2);
 505
 506         self.event_damage = func_null;
 507         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 508
 509         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 510         {
 511                 // check to see if this person is already tagged by me
 512                 entity tag = W_Seeker_Tagged_Info(self.realowner, other);
 513
 514                 if (tag != world)
 515                 {
 516                         if (other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 517                                 WaypointSprite_Kill(other.wps_tag_tracker);
 518
 519                         tag.tag_time = time;
 520                 }
 521                 else
 522                 {
 523                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 524                         e             = spawn();
 525                         e.cnt         = WEP_CVAR(seeker, missile_count);
 526                         e.classname   = "tag_tracker";
 527                         e.owner       = self.owner;
 528                         e.realowner   = self.realowner;
 529
 530                         if(WEP_CVAR(seeker, type) == 1)
 531                         {
 532                                 e.tag_target  = other;
 533                                 e.tag_time    = time;
 534                                 e.think       = W_Seeker_Tracker_Think;
 535                         }
 536                         else
 537                         {
 538                                 e.enemy     = other;
 539                                 e.think     = W_Seeker_Vollycontroller_Think;
 540                         }
 541
 542                         e.nextthink   = time;
 543                 }
 544
 545                 if(WEP_CVAR(seeker, type) == 1)
 546                 {
 547                         WaypointSprite_Spawn("tagged-target", WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 548                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 549                 }
 550         }
 551
 552         remove(self);
 553         return;
 554 }
 555
 556 void W_Seeker_Fire_Tag()
 557 {
 558         entity missile;
 559         W_DecreaseAmmo(WEP_CVAR(seeker, tag_ammo));
 560
 561         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 562
 563         missile                 = spawn();
 564         missile.owner           = missile.realowner = self;
 565         missile.classname       = "seeker_tag";
 566         missile.bot_dodge       = TRUE;
 567         missile.bot_dodgerating = 50;
 568         missile.touch           = W_Seeker_Tag_Touch;
 569         missile.think           = SUB_Remove;
 570         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 571         missile.movetype        = MOVETYPE_FLY;
 572         missile.solid           = SOLID_BBOX;
 573
 574         missile.takedamage       = DAMAGE_YES;
 575         missile.event_damage     = W_Seeker_Tag_Damage;
 576         missile.health           = WEP_CVAR(seeker, tag_health);
 577         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 578
 579         setorigin (missile, w_shotorg);
 580         setsize (missile, '-2 -2 -2', '2 2 2');
 581
 582         missile.flags       = FL_PROJECTILE;
 583         //missile.missile_flags = MIF_..?;
 584
 585         missile.movetype    = MOVETYPE_FLY;
 586         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 587         missile.angles = vectoangles (missile.velocity);
 588
 589         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 590
 591         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 592 }
 593
 594 // ============================
 595 // Begin: Genereal weapon functions
 596 // ============================
 597
 598 float W_Seeker(float req)
 599 {
 600         float ammo_amount;
 601
 602         switch(req)
 603         {
 604                 case WR_AIM:
 605                 {
 606                         if (WEP_CVAR(seeker, type) == 1)
 607                                 if (W_Seeker_Tagged_Info(self, self.enemy) != world)
 608                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), FALSE);
 609                                 else
 610                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 611                         else
 612                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 613                         return TRUE;
 614                 }
 615                 case WR_THINK:
 616                 {
 617                         if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) // forced reload
 618                                 WEP_ACTION(self.weapon, WR_RELOAD);
 619
 620                         else if (self.BUTTON_ATCK)
 621                         {
 622                                 if (WEP_CVAR(seeker, type) == 1)
 623                                 {
 624                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, missile_refire)))
 625                                         {
 626                                                 W_Seeker_Attack();
 627                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 628                                         }
 629                                 }
 630                                 else
 631                                 {
 632                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 633                                         {
 634                                                 W_Seeker_Fire_Tag();
 635                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 636                                         }
 637                                 }
 638                         }
 639
 640                         else if (self.BUTTON_ATCK2)
 641                         {
 642                                 if (WEP_CVAR(seeker, type) == 1)
 643                                 {
 644                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 645                                         {
 646                                                 W_Seeker_Fire_Tag();
 647                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 648                                         }
 649                                 }
 650                                 else
 651                                 {
 652                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, flac_refire)))
 653                                         {
 654                                                 W_Seeker_Fire_Flac();
 655                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 656                                         }
 657                                 }
 658                         }
 659
 660                         return TRUE;
 661                 }
 662                 case WR_INIT:
 663                 {
 664                         precache_model ("models/weapons/g_seeker.md3");
 665                         precache_model ("models/weapons/v_seeker.md3");
 666                         precache_model ("models/weapons/h_seeker.iqm");
 667                         precache_sound ("weapons/tag_fire.wav");
 668                         precache_sound ("weapons/flac_fire.wav");
 669                         precache_sound ("weapons/seeker_fire.wav");
 670                         SEEKER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 671                         return TRUE;
 672                 }
 673                 case WR_CHECKAMMO1:
 674                 {
 675                         if (WEP_CVAR(seeker, type) == 1)
 676                         {
 677                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, missile_ammo);
 678                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, missile_ammo);
 679                         }
 680                         else
 681                         {
 682                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 683                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 684                         }
 685                         return ammo_amount;
 686                 }
 687                 case WR_CHECKAMMO2:
 688                 {
 689                         if (WEP_CVAR(seeker, type) == 1)
 690                         {
 691                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 692                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 693                         }
 694                         else
 695                         {
 696                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, flac_ammo);
 697                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, flac_ammo);
 698                         }
 699                         return ammo_amount;
 700                 }
 701                 case WR_CONFIG:
 702                 {
 703                         SEEKER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 704                         return TRUE;
 705                 }
 706                 case WR_RELOAD:
 707                 {
 708                         W_Reload(min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), "weapons/reload.wav");
 709                         return TRUE;
 710                 }
 711                 case WR_SUICIDEMESSAGE:
 712                 {
 713                         return WEAPON_SEEKER_SUICIDE;
 714                 }
 715                 case WR_KILLMESSAGE:
 716                 {
 717                         if(w_deathtype & HITTYPE_SECONDARY)
 718                                 return WEAPON_SEEKER_MURDER_TAG;
 719                         else
 720                                 return WEAPON_SEEKER_MURDER_SPRAY;
 721                 }
 722         }
 723         return FALSE;
 724 }
 725 #endif
 726 #ifdef CSQC
 727 float W_Seeker(float req)
 728 {
 729         switch(req)
 730         {
 731                 case WR_IMPACTEFFECT:
 732                 {
 733                         vector org2;
 734                         org2 = w_org + w_backoff * 6;
 735                         if(w_deathtype & HITTYPE_BOUNCE)
 736                         {
 737                                 if(w_deathtype & HITTYPE_SECONDARY)
 738                                 {
 739                                         if(!w_issilent)
 740                                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTEN_NORM);
 741                                 }
 742                                 else
 743                                 {
 744                                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 745                                         if(!w_issilent)
 746                                         {
 747                                                 if (w_random<0.15)
 748                                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTEN_NORM);
 749                                                 else if (w_random<0.7)
 750                                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTEN_NORM);
 751                                                 else
 752                                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTEN_NORM);
 753                                         }
 754                                 }
 755                         }
 756                         else
 757                         {
 758                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 759                                 if(!w_issilent)
 760                                 {
 761                                         if (w_random<0.15)
 762                                                 sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTEN_NORM);
 763                                         else if (w_random<0.7)
 764                                                 sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTEN_NORM);
 765                                         else
 766                                                 sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTEN_NORM);
 767                                 }
 768                         }
 769                         return TRUE;
 770                 }
 771                 case WR_INIT:
 772                 {
 773                         precache_sound("weapons/seekerexp1.wav");
 774                         precache_sound("weapons/seekerexp2.wav");
 775                         precache_sound("weapons/seekerexp3.wav");
 776                         precache_sound("weapons/tagexp1.wav");
 777                         precache_sound("weapons/tagexp2.wav");
 778                         precache_sound("weapons/tagexp3.wav");
 779                         precache_sound("weapons/tag_impact.wav");
 780                         return TRUE;
 781                 }
 782                 case WR_ZOOMRETICLE:
 783                 {
 784                         // no weapon specific image for this weapon
 785                         return FALSE;
 786                 }
 787         }
 788         return FALSE;
 789 }
 790 #endif
 791 #endif