qcsrc/common/weapons/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ SEEKER,
   4 /* function */ W_Seeker,
   5 /* ammotype */ ammo_rockets,
   6 /* impulse  */ 8,
   7 /* flags    */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating   */ BOT_PICKUP_RATING_MID,
   9 /* model    */ "seeker",
  10 /* netname  */ "seeker",
  11 /* fullname */ _("T.A.G. Seeker")
  12 );
  13
  14 #define SEEKER_SETTINGS(w_cvar,w_prop) SEEKER_SETTINGS_LIST(w_cvar, w_prop, SEEKER, seeker)
  15 #define SEEKER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  16         w_cvar(id, sn, NONE, type) \
  17         w_cvar(id, sn, NONE, flac_ammo) \
  18         w_cvar(id, sn, NONE, flac_animtime) \
  19         w_cvar(id, sn, NONE, flac_damage) \
  20         w_cvar(id, sn, NONE, flac_edgedamage) \
  21         w_cvar(id, sn, NONE, flac_force) \
  22         w_cvar(id, sn, NONE, flac_lifetime) \
  23         w_cvar(id, sn, NONE, flac_lifetime_rand) \
  24         w_cvar(id, sn, NONE, flac_radius) \
  25         w_cvar(id, sn, NONE, flac_refire) \
  26         w_cvar(id, sn, NONE, flac_speed) \
  27         w_cvar(id, sn, NONE, flac_speed_up) \
  28         w_cvar(id, sn, NONE, flac_speed_z) \
  29         w_cvar(id, sn, NONE, flac_spread) \
  30         w_cvar(id, sn, NONE, missile_accel) \
  31         w_cvar(id, sn, NONE, missile_ammo) \
  32         w_cvar(id, sn, NONE, missile_animtime) \
  33         w_cvar(id, sn, NONE, missile_count) \
  34         w_cvar(id, sn, NONE, missile_damage) \
  35         w_cvar(id, sn, NONE, missile_damageforcescale) \
  36         w_cvar(id, sn, NONE, missile_decel) \
  37         w_cvar(id, sn, NONE, missile_delay) \
  38         w_cvar(id, sn, NONE, missile_edgedamage) \
  39         w_cvar(id, sn, NONE, missile_force) \
  40         w_cvar(id, sn, NONE, missile_health) \
  41         w_cvar(id, sn, NONE, missile_lifetime) \
  42         w_cvar(id, sn, NONE, missile_proxy) \
  43         w_cvar(id, sn, NONE, missile_proxy_delay) \
  44         w_cvar(id, sn, NONE, missile_proxy_maxrange) \
  45         w_cvar(id, sn, NONE, missile_radius) \
  46         w_cvar(id, sn, NONE, missile_refire) \
  47         w_cvar(id, sn, NONE, missile_smart) \
  48         w_cvar(id, sn, NONE, missile_smart_mindist) \
  49         w_cvar(id, sn, NONE, missile_smart_trace_max) \
  50         w_cvar(id, sn, NONE, missile_smart_trace_min) \
  51         w_cvar(id, sn, NONE, missile_speed) \
  52         w_cvar(id, sn, NONE, missile_speed_max) \
  53         w_cvar(id, sn, NONE, missile_speed_up) \
  54         w_cvar(id, sn, NONE, missile_speed_z) \
  55         w_cvar(id, sn, NONE, missile_spread) \
  56         w_cvar(id, sn, NONE, missile_turnrate) \
  57         w_cvar(id, sn, NONE, tag_ammo) \
  58         w_cvar(id, sn, NONE, tag_animtime) \
  59         w_cvar(id, sn, NONE, tag_damageforcescale) \
  60         w_cvar(id, sn, NONE, tag_health) \
  61         w_cvar(id, sn, NONE, tag_lifetime) \
  62         w_cvar(id, sn, NONE, tag_refire) \
  63         w_cvar(id, sn, NONE, tag_speed) \
  64         w_cvar(id, sn, NONE, tag_spread) \
  65         w_cvar(id, sn, NONE, tag_tracker_lifetime) \
  66         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  67         w_prop(id, sn, float,  reloading_time, reload_time) \
  68         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  69         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  70         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  71         w_prop(id, sn, float,  weaponstart, weaponstart) \
  72         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  73
  74 #ifdef SVQC
  75 SEEKER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  76 .entity tag_target, wps_tag_tracker;
  77 .float tag_time;
  78 #endif
  79 #else
  80 #ifdef SVQC
  81 void spawnfunc_weapon_seeker (void) { weapon_defaultspawnfunc(WEP_SEEKER); }
  82
  83 // ============================
  84 // Begin: Missile functions, these are general functions to be manipulated by other code
  85 // ============================
  86 void W_Seeker_Missile_Explode()
  87 {
  88         self.event_damage = func_null;
  89         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  90
  91         remove (self);
  92 }
  93
  94 void W_Seeker_Missile_Touch()
  95 {
  96         PROJECTILE_TOUCH;
  97
  98         W_Seeker_Missile_Explode();
  99 }
 100
 101 void W_Seeker_Missile_Think()
 102 {
 103         entity e;
 104         vector desireddir, olddir, newdir, eorg;
 105         float turnrate;
 106         float dist;
 107         float spd;
 108
 109         if (time > self.cnt)
 110         {
 111                 self.projectiledeathtype |= HITTYPE_SPLASH;
 112                 W_Seeker_Missile_Explode();
 113         }
 114
 115         spd = vlen(self.velocity);
 116         spd = bound(
 117                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 118                 WEP_CVAR(seeker, missile_speed_max),
 119                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 120         );
 121
 122         if (self.enemy != world)
 123                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 124                         self.enemy = world;
 125
 126         if (self.enemy != world)
 127         {
 128                 e               = self.enemy;
 129                 eorg            = 0.5 * (e.absmin + e.absmax);
 130                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 131                 desireddir      = normalize(eorg - self.origin);
 132                 olddir          = normalize(self.velocity); // get my current direction
 133                 dist            = vlen(eorg - self.origin);
 134
 135                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 136                 if (WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 137                 {
 138                         // Is it a better idea (shorter distance) to trace to the target itself?
 139                         if ( vlen(self.origin + olddir * self.wait) < dist)
 140                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
 141                         else
 142                                 traceline(self.origin, eorg, FALSE, self);
 143
 144                         // Setup adaptive tracelength
 145                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 146
 147                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 148                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 149                 }
 150
 151                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 152                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 153         }
 154         else
 155                 dist = 0;
 156
 157         // Proxy
 158         if (WEP_CVAR(seeker, missile_proxy))
 159         {
 160                 if ( dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 161                 {
 162                         if (self.autoswitch == 0)
 163                         {
 164                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 165                         }
 166                         else
 167                         {
 168                                 if (self.autoswitch <= time)
 169                                 {
 170                                         W_Seeker_Missile_Explode();
 171                                         self.autoswitch = 0;
 172                                 }
 173                         }
 174                 }
 175                 else
 176                 {
 177                         if (self.autoswitch != 0)
 178                                 self.autoswitch = 0;
 179                 }
 180         }
 181         ///////////////
 182
 183         if (self.enemy.deadflag != DEAD_NO)
 184         {
 185                 self.enemy = world;
 186                 self.cnt = time + 1 + (random() * 4);
 187                 self.nextthink = self.cnt;
 188                 return;
 189         }
 190
 191         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 192         self.nextthink = time;// + 0.05; // csqc projectiles
 193         UpdateCSQCProjectile(self);
 194 }
 195
 196
 197
 198 void W_Seeker_Missile_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 199 {
 200         if (self.health <= 0)
 201                 return;
 202
 203         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 204                 return; // g_projectiles_damage says to halt
 205
 206         if (self.realowner == attacker)
 207                 self.health = self.health - (damage * 0.25);
 208         else
 209                 self.health = self.health - damage;
 210
 211         if (self.health <= 0)
 212                 W_PrepareExplosionByDamage(attacker, W_Seeker_Missile_Explode);
 213 }
 214
 215 /*
 216 void W_Seeker_Missile_Animate()
 217 {
 218         self.frame = self.frame +1;
 219         self.nextthink = time + 0.05;
 220
 221         if (self.enemy != world)
 222                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 223                         self.enemy = world;
 224
 225         if(self.frame == 5)
 226         {
 227                 self.think           = W_Seeker_Missile_Think;
 228                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 229
 230                 if (autocvar_g_balance_seeker_missile_proxy)
 231                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 232                 else
 233                         self.movetype    = MOVETYPE_FLYMISSILE;
 234         }
 235
 236         UpdateCSQCProjectile(self);
 237 }
 238 */
 239
 240 void W_Seeker_Fire_Missile(vector f_diff, entity m_target)
 241 {
 242         entity missile;
 243
 244         W_DecreaseAmmo(WEP_CVAR(seeker, missile_ammo));
 245
 246         makevectors(self.v_angle);
 247         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 248         w_shotorg += f_diff;
 249         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 250
 251         //self.detornator         = FALSE;
 252
 253         missile                 = spawn();
 254         missile.owner           = missile.realowner = self;
 255         missile.classname       = "seeker_missile";
 256         missile.bot_dodge       = TRUE;
 257         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 258
 259         missile.think           = W_Seeker_Missile_Think;
 260         missile.touch           = W_Seeker_Missile_Touch;
 261         missile.event_damage    = W_Seeker_Missile_Damage;
 262         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 263         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 264         missile.enemy           = m_target;
 265         missile.solid           = SOLID_BBOX;
 266         missile.scale           = 2;
 267         missile.takedamage      = DAMAGE_YES;
 268         missile.health          = WEP_CVAR(seeker, missile_health);
 269         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 270         missile.damagedbycontents = TRUE;
 271         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 272
 273         if (missile.enemy != world)
 274                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 275         else
 276                 missile.projectiledeathtype = WEP_SEEKER;
 277
 278
 279         setorigin (missile, w_shotorg);
 280         setsize (missile, '-4 -4 -4', '4 4 4');
 281         missile.movetype    = MOVETYPE_FLYMISSILE;
 282         missile.flags       = FL_PROJECTILE;
 283         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 284
 285         WEP_SETUPPROJVELOCITY_UP_NONE(missile, seeker, missile_);
 286
 287         missile.angles = vectoangles (missile.velocity);
 288
 289         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 290
 291         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 292 }
 293
 294 // ============================
 295 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 296 // ============================
 297 void W_Seeker_Flac_Explode()
 298 {
 299         self.event_damage = func_null;
 300
 301         RadiusDamage (self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 302
 303         remove (self);
 304 }
 305
 306 void W_Seeker_Flac_Touch()
 307 {
 308         PROJECTILE_TOUCH;
 309
 310         W_Seeker_Flac_Explode();
 311 }
 312
 313 void W_Seeker_Fire_Flac()
 314 {
 315         entity missile;
 316         vector f_diff;
 317         float c;
 318
 319         W_DecreaseAmmo(WEP_CVAR(seeker, flac_ammo));
 320
 321         c = mod(self.bulletcounter, 4);
 322         switch(c)
 323         {
 324                 case 0:
 325                         f_diff = '-1.25 -3.75 0';
 326                         break;
 327                 case 1:
 328                         f_diff = '+1.25 -3.75 0';
 329                         break;
 330                 case 2:
 331                         f_diff = '-1.25 +3.75 0';
 332                         break;
 333                 case 3:
 334                 default:
 335                         f_diff = '+1.25 +3.75 0';
 336                         break;
 337         }
 338         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 339         w_shotorg += f_diff;
 340
 341         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 342
 343         missile                                 = spawn ();
 344         missile.owner                   = missile.realowner = self;
 345         missile.classname               = "missile";
 346         missile.bot_dodge               = TRUE;
 347         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 348         missile.touch                   = W_Seeker_Flac_Explode;
 349         missile.use                     = W_Seeker_Flac_Explode;
 350         missile.think                   = adaptor_think2use_hittype_splash;
 351         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 352         missile.solid                   = SOLID_BBOX;
 353         missile.movetype                = MOVETYPE_FLY;
 354         missile.projectiledeathtype = WEP_SEEKER;
 355         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 356         missile.flags                           = FL_PROJECTILE;
 357         missile.missile_flags       = MIF_SPLASH;
 358
 359         // csqc projectiles
 360         //missile.angles                                = vectoangles (missile.velocity);
 361         //missile.scale = 0.4; // BUG: the model is too big
 362
 363         setorigin (missile, w_shotorg);
 364         setsize (missile, '-2 -2 -2', '2 2 2');
 365
 366         WEP_SETUPPROJVELOCITY_UP_NONE(missile, seeker, flac_);
 367         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 368
 369         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 370 }
 371
 372 // ============================
 373 // Begin: Tag and rocket controllers
 374 // ============================
 375 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
 376 {
 377         entity tag;
 378         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 379                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 380                         return tag;
 381
 382         return world;
 383 }
 384
 385 void W_Seeker_Attack()
 386 {
 387         entity tracker, closest_target;
 388
 389         closest_target = world;
 390         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 391         {
 392                 if (closest_target)
 393                 {
 394                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 395                                 closest_target = tracker.tag_target;
 396                 }
 397                 else
 398                         closest_target = tracker.tag_target;
 399         }
 400
 401         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 402         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 403                 closest_target = world;
 404
 405         W_Seeker_Fire_Missile('0 0 0', closest_target);
 406 }
 407
 408 void W_Seeker_Vollycontroller_Think() // TODO: Merge this with W_Seeker_Attack
 409 {
 410         float c;
 411         entity oldself,oldenemy;
 412         self.cnt = self.cnt - 1;
 413
 414         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.AMMO_VAL(WEP_SEEKER) < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 415         {
 416                 remove(self);
 417                 return;
 418         }
 419
 420         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 421
 422         oldself = self;
 423         self = self.realowner;
 424
 425         oldenemy = self.enemy;
 426         self.enemy = oldself.enemy;
 427
 428         c = mod(self.cnt, 4);
 429         switch(c)
 430         {
 431                 case 0:
 432                         W_Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 433                         break;
 434                 case 1:
 435                         W_Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 436                         break;
 437                 case 2:
 438                         W_Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 439                         break;
 440                 case 3:
 441                 default:
 442                         W_Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 443                         break;
 444         }
 445
 446         self.enemy = oldenemy;
 447         self = oldself;
 448 }
 449
 450 void W_Seeker_Tracker_Think()
 451 {
 452         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 453         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 454         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 455         {
 456                 if (self)
 457                 {
 458                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 459                         remove(self);
 460                 }
 461                 return;
 462         }
 463
 464         // Update the think method information
 465         self.nextthink = time;
 466 }
 467
 468 // ============================
 469 // Begin: Tag projectile
 470 // ============================
 471 void W_Seeker_Tag_Explode()
 472 {
 473         //if(other==self.realowner)
 474         //    return;
 475         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, other.species, self);
 476
 477         remove (self);
 478 }
 479
 480 void W_Seeker_Tag_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 481 {
 482         if (self.health <= 0)
 483                 return;
 484         self.health = self.health - damage;
 485         if (self.health <= 0)
 486                 W_Seeker_Tag_Explode();
 487 }
 488
 489 void W_Seeker_Tag_Touch()
 490 {
 491         vector dir;
 492         vector org2;
 493         entity e;
 494
 495         PROJECTILE_TOUCH;
 496
 497         dir     = normalize (self.realowner.origin - self.origin);
 498         org2    = findbetterlocation (self.origin, 8);
 499
 500         te_knightspike(org2);
 501
 502         self.event_damage = func_null;
 503         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 504
 505         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 506         {
 507                 // check to see if this person is already tagged by me
 508                 entity tag = W_Seeker_Tagged_Info(self.realowner, other);
 509
 510                 if (tag != world)
 511                 {
 512                         if (other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 513                                 WaypointSprite_Kill(other.wps_tag_tracker);
 514
 515                         tag.tag_time = time;
 516                 }
 517                 else
 518                 {
 519                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 520                         e             = spawn();
 521                         e.cnt         = WEP_CVAR(seeker, missile_count);
 522                         e.classname   = "tag_tracker";
 523                         e.owner       = self.owner;
 524                         e.realowner   = self.realowner;
 525
 526                         if(WEP_CVAR(seeker, type) == 1)
 527                         {
 528                                 e.tag_target  = other;
 529                                 e.tag_time    = time;
 530                                 e.think       = W_Seeker_Tracker_Think;
 531                         }
 532                         else
 533                         {
 534                                 e.enemy     = other;
 535                                 e.think     = W_Seeker_Vollycontroller_Think;
 536                         }
 537
 538                         e.nextthink   = time;
 539                 }
 540
 541                 if(WEP_CVAR(seeker, type) == 1)
 542                 {
 543                         WaypointSprite_Spawn("tagged-target", WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 544                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 545                 }
 546         }
 547
 548         remove(self);
 549         return;
 550 }
 551
 552 void W_Seeker_Fire_Tag()
 553 {
 554         entity missile;
 555         W_DecreaseAmmo(WEP_CVAR(seeker, tag_ammo));
 556
 557         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 558
 559         missile                 = spawn();
 560         missile.owner           = missile.realowner = self;
 561         missile.classname       = "seeker_tag";
 562         missile.bot_dodge       = TRUE;
 563         missile.bot_dodgerating = 50;
 564         missile.touch           = W_Seeker_Tag_Touch;
 565         missile.think           = SUB_Remove;
 566         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 567         missile.movetype        = MOVETYPE_FLY;
 568         missile.solid           = SOLID_BBOX;
 569
 570         missile.takedamage       = DAMAGE_YES;
 571         missile.event_damage     = W_Seeker_Tag_Damage;
 572         missile.health           = WEP_CVAR(seeker, tag_health);
 573         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 574
 575         setorigin (missile, w_shotorg);
 576         setsize (missile, '-2 -2 -2', '2 2 2');
 577
 578         missile.flags       = FL_PROJECTILE;
 579         //missile.missile_flags = MIF_..?;
 580
 581         missile.movetype    = MOVETYPE_FLY;
 582         WEP_SETUPPROJVELOCITY_NONE(missile, seeker, tag_);
 583         missile.angles = vectoangles (missile.velocity);
 584
 585         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 586
 587         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 588 }
 589
 590 // ============================
 591 // Begin: Genereal weapon functions
 592 // ============================
 593
 594 float W_Seeker(float req)
 595 {
 596         float ammo_amount;
 597
 598         switch(req)
 599         {
 600                 case WR_AIM:
 601                 {
 602                         if (WEP_CVAR(seeker, type) == 1)
 603                                 if (W_Seeker_Tagged_Info(self, self.enemy) != world)
 604                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), FALSE);
 605                                 else
 606                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 607                         else
 608                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), FALSE);
 609                         return TRUE;
 610                 }
 611                 case WR_THINK:
 612                 {
 613                         if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) // forced reload
 614                                 WEP_ACTION(self.weapon, WR_RELOAD);
 615
 616                         else if (self.BUTTON_ATCK)
 617                         {
 618                                 if (WEP_CVAR(seeker, type) == 1)
 619                                 {
 620                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, missile_refire)))
 621                                         {
 622                                                 W_Seeker_Attack();
 623                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 624                                         }
 625                                 }
 626                                 else
 627                                 {
 628                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 629                                         {
 630                                                 W_Seeker_Fire_Tag();
 631                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 632                                         }
 633                                 }
 634                         }
 635
 636                         else if (self.BUTTON_ATCK2)
 637                         {
 638                                 if (WEP_CVAR(seeker, type) == 1)
 639                                 {
 640                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 641                                         {
 642                                                 W_Seeker_Fire_Tag();
 643                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 644                                         }
 645                                 }
 646                                 else
 647                                 {
 648                                         if (weapon_prepareattack(0, WEP_CVAR(seeker, flac_refire)))
 649                                         {
 650                                                 W_Seeker_Fire_Flac();
 651                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 652                                         }
 653                                 }
 654                         }
 655
 656                         return TRUE;
 657                 }
 658                 case WR_INIT:
 659                 {
 660                         precache_model ("models/weapons/g_seeker.md3");
 661                         precache_model ("models/weapons/v_seeker.md3");
 662                         precache_model ("models/weapons/h_seeker.iqm");
 663                         precache_sound ("weapons/tag_fire.wav");
 664                         precache_sound ("weapons/flac_fire.wav");
 665                         precache_sound ("weapons/seeker_fire.wav");
 666                         SEEKER_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 667                         return TRUE;
 668                 }
 669                 case WR_CHECKAMMO1:
 670                 {
 671                         if (WEP_CVAR(seeker, type) == 1)
 672                         {
 673                                 ammo_amount = self.AMMO_VAL(WEP_SEEKER) >= WEP_CVAR(seeker, missile_ammo);
 674                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, missile_ammo);
 675                         }
 676                         else
 677                         {
 678                                 ammo_amount = self.AMMO_VAL(WEP_SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 679                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 680                         }
 681                         return ammo_amount;
 682                 }
 683                 case WR_CHECKAMMO2:
 684                 {
 685                         if (WEP_CVAR(seeker, type) == 1)
 686                         {
 687                                 ammo_amount = self.AMMO_VAL(WEP_SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 688                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, tag_ammo);
 689                         }
 690                         else
 691                         {
 692                                 ammo_amount = self.AMMO_VAL(WEP_SEEKER) >= WEP_CVAR(seeker, flac_ammo);
 693                                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= WEP_CVAR(seeker, flac_ammo);
 694                         }
 695                         return ammo_amount;
 696                 }
 697                 case WR_CONFIG:
 698                 {
 699                         SEEKER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 700                         return TRUE;
 701                 }
 702                 case WR_RELOAD:
 703                 {
 704                         W_Reload(min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), "weapons/reload.wav");
 705                         return TRUE;
 706                 }
 707                 case WR_SUICIDEMESSAGE:
 708                 {
 709                         return WEAPON_SEEKER_SUICIDE;
 710                 }
 711                 case WR_KILLMESSAGE:
 712                 {
 713                         if(w_deathtype & HITTYPE_SECONDARY)
 714                                 return WEAPON_SEEKER_MURDER_TAG;
 715                         else
 716                                 return WEAPON_SEEKER_MURDER_SPRAY;
 717                 }
 718         }
 719         return TRUE;
 720 }
 721 #endif
 722 #ifdef CSQC
 723 float W_Seeker(float req)
 724 {
 725         switch(req)
 726         {
 727                 case WR_IMPACTEFFECT:
 728                 {
 729                         vector org2;
 730                         org2 = w_org + w_backoff * 6;
 731                         if(w_deathtype & HITTYPE_BOUNCE)
 732                         {
 733                                 if(w_deathtype & HITTYPE_SECONDARY)
 734                                 {
 735                                         if(!w_issilent)
 736                                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTEN_NORM);
 737                                 }
 738                                 else
 739                                 {
 740                                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 741                                         if(!w_issilent)
 742                                         {
 743                                                 if (w_random<0.15)
 744                                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTEN_NORM);
 745                                                 else if (w_random<0.7)
 746                                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTEN_NORM);
 747                                                 else
 748                                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTEN_NORM);
 749                                         }
 750                                 }
 751                         }
 752                         else
 753                         {
 754                                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 755                                 if(!w_issilent)
 756                                 {
 757                                         if (w_random<0.15)
 758                                                 sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTEN_NORM);
 759                                         else if (w_random<0.7)
 760                                                 sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTEN_NORM);
 761                                         else
 762                                                 sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTEN_NORM);
 763                                 }
 764                         }
 765                         return TRUE;
 766                 }
 767                 case WR_INIT:
 768                 {
 769                         precache_sound("weapons/seekerexp1.wav");
 770                         precache_sound("weapons/seekerexp2.wav");
 771                         precache_sound("weapons/seekerexp3.wav");
 772                         precache_sound("weapons/tagexp1.wav");
 773                         precache_sound("weapons/tagexp2.wav");
 774                         precache_sound("weapons/tagexp3.wav");
 775                         precache_sound("weapons/tag_impact.wav");
 776                         return TRUE;
 777                 }
 778         }
 779
 780         return TRUE;
 781 }
 782 #endif
 783 #endif