qcsrc/common/weapons/w_tuba.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ TUBA,
   4 /* function  */ W_Tuba,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 1,
   7 /* flags     */ WEP_FLAG_HIDDEN | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* color     */ '0 1 0',
  10 /* modelname */ "tuba",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairtuba",
  13 /* wepimg    */ "weapontuba",
  14 /* refname   */ "tuba",
  15 /* xgettext:no-c-format */
  16 /* wepname   */ _("@!#%'n Tuba")
  17 );
  18
  19 #define TUBA_SETTINGS(w_cvar,w_prop) TUBA_SETTINGS_LIST(w_cvar, w_prop, TUBA, tuba)
  20 #define TUBA_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  21         w_cvar(id, sn, NONE, animtime) \
  22         w_cvar(id, sn, NONE, attenuation) \
  23         w_cvar(id, sn, NONE, damage) \
  24         w_cvar(id, sn, NONE, edgedamage) \
  25         w_cvar(id, sn, NONE, fadetime) \
  26         w_cvar(id, sn, NONE, force) \
  27         w_cvar(id, sn, NONE, pitchstep) \
  28         w_cvar(id, sn, NONE, radius) \
  29         w_cvar(id, sn, NONE, refire) \
  30         w_cvar(id, sn, NONE, volume) \
  31         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  32         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  33         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  34         w_prop(id, sn, float,  weaponstart, weaponstart) \
  35         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  36         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  37
  38 #ifdef SVQC
  39 TUBA_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  40 float W_Tuba_MarkClientOnlyFieldsAsUsed() {
  41         // These variables are only used by client/tuba.qc. TODO: move client/tuba.qc code here.
  42         return WEP_CVAR(tuba, fadetime) + WEP_CVAR(tuba, pitchstep) + WEP_CVAR(tuba, volume);
  43 }
  44
  45 .entity tuba_note;
  46 .float tuba_smoketime;
  47 .float tuba_instrument;
  48
  49 #define MAX_TUBANOTES 32
  50 .float tuba_lastnotes_last;
  51 .float tuba_lastnotes_cnt; // over
  52 .vector tuba_lastnotes[MAX_TUBANOTES];
  53 #endif
  54 #else
  55 #ifdef SVQC
  56 void spawnfunc_weapon_tuba(void) { weapon_defaultspawnfunc(WEP_TUBA); }
  57
  58 float W_Tuba_HasPlayed(entity pl, string melody, float instrument, float ignorepitch, float mintempo, float maxtempo)
  59 {
  60         float i, j, mmin, mmax, nolength;
  61         float n = tokenize_console(melody);
  62         if(n > pl.tuba_lastnotes_cnt)
  63                 return false;
  64         float pitchshift = 0;
  65
  66         if(instrument >= 0)
  67                 if(pl.tuba_instrument != instrument)
  68                         return false;
  69
  70         // verify notes...
  71         nolength = false;
  72         for(i = 0; i < n; ++i)
  73         {
  74                 vector v = pl.(tuba_lastnotes[(pl.tuba_lastnotes_last - i + MAX_TUBANOTES) % MAX_TUBANOTES]);
  75                 float ai = stof(argv(n - i - 1));
  76                 float np = floor(ai);
  77                 if(ai == np)
  78                         nolength = true;
  79                 // n counts the last played notes BACKWARDS
  80                 // _x is start
  81                 // _y is end
  82                 // _z is note pitch
  83                 if(ignorepitch && i == 0)
  84                 {
  85                         pitchshift = np - v.z;
  86                 }
  87                 else
  88                 {
  89                         if(v.z + pitchshift != np)
  90                                 return false;
  91                 }
  92         }
  93
  94         // now we know the right NOTES were played
  95         if(!nolength)
  96         {
  97                 // verify rhythm...
  98                 float ti = 0;
  99                 if(maxtempo > 0)
 100                         mmin = 240 / maxtempo; // 60 = "0.25 means 1 sec", at 120 0.5 means 1 sec, at 240 1 means 1 sec
 101                 else
 102                         mmin = 0;
 103                 if(mintempo > 0)
 104                         mmax = 240 / mintempo; // 60 = "0.25 means 1 sec", at 120 0.5 means 1 sec, at 240 1 means 1 sec
 105                 else
 106                         mmax = 240; // you won't try THAT hard... (tempo 1)
 107                 //printf("initial tempo rules: %f %f\n", mmin, mmax);
 108
 109                 for(i = 0; i < n; ++i)
 110                 {
 111                         vector vi = pl.(tuba_lastnotes[(pl.tuba_lastnotes_last - i + MAX_TUBANOTES) % MAX_TUBANOTES]);
 112                         float ai = stof(argv(n - i - 1));
 113                         ti -= 1 / (ai - floor(ai));
 114                         float tj = ti;
 115                         for(j = i+1; j < n; ++j)
 116                         {
 117                                 vector vj = pl.(tuba_lastnotes[(pl.tuba_lastnotes_last - j + MAX_TUBANOTES) % MAX_TUBANOTES]);
 118                                 float aj = stof(argv(n - j - 1));
 119                                 tj -= (aj - floor(aj));
 120
 121                                 // note i should be at m*ti+b
 122                                 // note j should be at m*tj+b
 123                                 // so:
 124                                 // we have a LINE l, so that
 125                                 // vi_x <= l(ti) <= vi_y
 126                                 // vj_x <= l(tj) <= vj_y
 127                                 // what is m?
 128
 129                                 // vi_x <= vi_y <= vj_x <= vj_y
 130                                 // ti <= tj
 131                                 //printf("first note: %f to %f, should be %f\n", vi_x, vi_y, ti);
 132                                 //printf("second note: %f to %f, should be %f\n", vj_x, vj_y, tj);
 133                                 //printf("m1 = %f\n", (vi_x - vj_y) / (ti - tj));
 134                                 //printf("m2 = %f\n", (vi_y - vj_x) / (ti - tj));
 135                                 mmin = max(mmin, (vi.x - vj.y) / (ti - tj)); // lower bound
 136                                 mmax = min(mmax, (vi.y - vj.x) / (ti - tj)); // upper bound
 137                         }
 138                 }
 139
 140                 if(mmin > mmax) // rhythm fail
 141                         return false;
 142         }
 143
 144         pl.tuba_lastnotes_cnt = 0;
 145
 146         return true;
 147 }
 148
 149 void W_Tuba_NoteOff(void)
 150 {
 151         // we have a note:
 152         //   on: self.spawnshieldtime
 153         //   off: time
 154         //   note: self.cnt
 155         if(self.owner.tuba_note == self)
 156         {
 157                 self.owner.tuba_lastnotes_last = (self.owner.tuba_lastnotes_last + 1) % MAX_TUBANOTES;
 158                 self.owner.(tuba_lastnotes[self.owner.tuba_lastnotes_last]) = eX * self.spawnshieldtime + eY * time + eZ * self.cnt;
 159                 self.owner.tuba_note = world;
 160                 self.owner.tuba_lastnotes_cnt = bound(0, self.owner.tuba_lastnotes_cnt + 1, MAX_TUBANOTES);
 161
 162                 string s;
 163                 s = trigger_magicear_processmessage_forallears(self.owner, 0, world, string_null);
 164                 if(s != "")
 165                 {
 166                         // simulate a server message
 167                         switch(self.tuba_instrument)
 168                         {
 169                                 default:
 170                                 case 0: // Tuba
 171                                         bprint(strcat("\{1}\{13}* ^3", self.owner.netname, "^3 played on the @!#%'n Tuba: ^7", s, "\n"));
 172                                         break;
 173                                 case 1:
 174                                         bprint(strcat("\{1}\{13}* ^3", self.owner.netname, "^3 played on the @!#%'n Accordeon: ^7", s, "\n"));
 175                                         break;
 176                                 case 2:
 177                                         bprint(strcat("\{1}\{13}* ^3", self.owner.netname, "^3 played on the @!#%'n Klein Bottle: ^7", s, "\n"));
 178                                         break;
 179                         }
 180                 }
 181         }
 182         remove(self);
 183 }
 184
 185 float W_Tuba_GetNote(entity pl, float hittype)
 186 {
 187         float movestate = 5;
 188         if (pl.movement.x < 0)          movestate -= 3;
 189         else if (pl.movement.x > 0)     movestate += 3;
 190         if (pl.movement.y < 0)          movestate -= 1;
 191         else if (pl.movement.y > 0)     movestate += 1;
 192
 193         float note = 0;
 194         switch(movestate)
 195         {
 196         // layout: originally I wanted
 197         //   eb e  e#=f
 198         //   B  c  d
 199         //   Gb G  G#
 200         // but then you only use forward and right key. So to make things more
 201         // interesting, I swapped B with e#. Har har har...
 202         //   eb e  B
 203         // f=e# c  d
 204         //   Gb G  G#
 205                 case 1: note = -6; break; // Gb
 206                 case 2: note = -5; break; // G
 207                 case 3: note = -4; break; // G#
 208                 case 4: note = +5; break; // e#
 209                 default:
 210                 case 5: note =  0; break; // c
 211                 case 6: note = +2; break; // d
 212                 case 7: note = +3; break; // eb
 213                 case 8: note = +4; break; // e
 214                 case 9: note = -1; break; // B
 215         }
 216         if(pl.BUTTON_CROUCH)
 217                 note -= 12;
 218         if(pl.BUTTON_JUMP)
 219                 note += 12;
 220         if(hittype & HITTYPE_SECONDARY)
 221                 note += 7;
 222
 223         // we support two kinds of tubas, those tuned in Eb and those tuned in C
 224         // kind of tuba currently is player slot number, or team number if in
 225         // teamplay
 226         // that way, holes in the range of notes are "plugged"
 227         if(teamplay)
 228         {
 229                 if(pl.team == NUM_TEAM_2 || pl.team == NUM_TEAM_4)
 230                         note += 3;
 231         }
 232         else
 233         {
 234                 if(pl.clientcolors & 1)
 235                         note += 3;
 236         }
 237
 238         // total range of notes:
 239         //                       0
 240         //                 ***  ** ****
 241         //                        ***  ** ****
 242         //     ***  ** ****
 243         //            ***  ** ****
 244         //     ***  ********************* ****
 245         //     -18.........................+12
 246         //        ***  ********************* ****
 247         //     -18............................+15
 248         //     with jump: ... +24
 249         //     ... +27
 250         return note;
 251 }
 252
 253 float W_Tuba_NoteSendEntity(entity to, float sf)
 254 {
 255         float f;
 256
 257         msg_entity = to;
 258         if(!sound_allowed(MSG_ONE, self.realowner))
 259                 return false;
 260
 261         WriteByte(MSG_ENTITY, ENT_CLIENT_TUBANOTE);
 262         WriteByte(MSG_ENTITY, sf);
 263         if(sf & 1)
 264         {
 265                 WriteChar(MSG_ENTITY, self.cnt);
 266                 f = 0;
 267                 if(self.realowner != to)
 268                         f |= 1;
 269                 f |= 2 * self.tuba_instrument;
 270                 WriteByte(MSG_ENTITY, f);
 271         }
 272         if(sf & 2)
 273         {
 274                 WriteCoord(MSG_ENTITY, self.origin.x);
 275                 WriteCoord(MSG_ENTITY, self.origin.y);
 276                 WriteCoord(MSG_ENTITY, self.origin.z);
 277         }
 278         return true;
 279 }
 280
 281 void W_Tuba_NoteThink(void)
 282 {
 283         float dist_mult;
 284         float vol0, vol1;
 285         vector dir0, dir1;
 286         vector v;
 287         entity e;
 288         if(time > self.teleport_time)
 289         {
 290                 W_Tuba_NoteOff();
 291                 return;
 292         }
 293         self.nextthink = time;
 294         dist_mult = WEP_CVAR(tuba, attenuation) / autocvar_snd_soundradius;
 295         FOR_EACH_REALCLIENT(e)
 296         if(e != self.realowner)
 297         {
 298                 v = self.origin - (e.origin + e.view_ofs);
 299                 vol0 = max(0, 1 - vlen(v) * dist_mult);
 300                 dir0 = normalize(v);
 301                 v = self.realowner.origin - (e.origin + e.view_ofs);
 302                 vol1 = max(0, 1 - vlen(v) * dist_mult);
 303                 dir1 = normalize(v);
 304                 if(fabs(vol0 - vol1) > 0.005) // 0.5 percent change in volume
 305                 {
 306                         setorigin(self, self.realowner.origin);
 307                         self.SendFlags |= 2;
 308                         break;
 309                 }
 310                 if(dir0 * dir1 < 0.9994) // 2 degrees change in angle
 311                 {
 312                         setorigin(self, self.realowner.origin);
 313                         self.SendFlags |= 2;
 314                         break;
 315                 }
 316         }
 317 }
 318
 319 void W_Tuba_NoteOn(float hittype)
 320 {
 321         vector o;
 322         float n;
 323
 324         W_SetupShot(self, false, 2, "", 0, WEP_CVAR(tuba, damage));
 325
 326         n = W_Tuba_GetNote(self, hittype);
 327
 328         hittype = 0;
 329         if(self.tuba_instrument & 1)
 330                 hittype |= HITTYPE_SECONDARY;
 331         if(self.tuba_instrument & 2)
 332                 hittype |= HITTYPE_BOUNCE;
 333
 334         if(self.tuba_note)
 335         {
 336                 if(self.tuba_note.cnt != n || self.tuba_note.tuba_instrument != self.tuba_instrument)
 337                 {
 338                         entity oldself = self;
 339                         self = self.tuba_note;
 340                         W_Tuba_NoteOff();
 341                         self = oldself;
 342                 }
 343         }
 344
 345         if(!self.tuba_note)
 346         {
 347                 self.tuba_note = spawn();
 348                 self.tuba_note.owner = self.tuba_note.realowner = self;
 349                 self.tuba_note.cnt = n;
 350                 self.tuba_note.tuba_instrument = self.tuba_instrument;
 351                 self.tuba_note.think = W_Tuba_NoteThink;
 352                 self.tuba_note.nextthink = time;
 353                 self.tuba_note.spawnshieldtime = time;
 354                 Net_LinkEntity(self.tuba_note, false, 0, W_Tuba_NoteSendEntity);
 355         }
 356
 357         self.tuba_note.teleport_time = time + WEP_CVAR(tuba, refire) * 2 * W_WeaponRateFactor(); // so it can get prolonged safely
 358
 359         //sound(self, c, TUBA_NOTE(n), bound(0, VOL_BASE * cvar("g_balance_tuba_volume"), 1), autocvar_g_balance_tuba_attenuation);
 360         RadiusDamage(self, self, WEP_CVAR(tuba, damage), WEP_CVAR(tuba, edgedamage), WEP_CVAR(tuba, radius), world, world, WEP_CVAR(tuba, force), hittype | WEP_TUBA, world);
 361
 362         o = gettaginfo(self.exteriorweaponentity, 0);
 363         if(time > self.tuba_smoketime)
 364         {
 365                 pointparticles(particleeffectnum("smoke_ring"), o + v_up * 45 + v_right * -6 + v_forward * 8, v_up * 100, 1);
 366                 self.tuba_smoketime = time + 0.25;
 367         }
 368 }
 369
 370 float W_Tuba(float req)
 371 {
 372         switch(req)
 373         {
 374                 case WR_AIM:
 375                 {
 376                         // bots cannot play the Tuba well yet
 377                         // I think they should start with the recorder first
 378                         if(vlen(self.origin - self.enemy.origin) < WEP_CVAR(tuba, radius))
 379                         {
 380                                 if(random() > 0.5)
 381                                         self.BUTTON_ATCK = 1;
 382                                 else
 383                                         self.BUTTON_ATCK2 = 1;
 384                         }
 385
 386                         return true;
 387                 }
 388                 case WR_THINK:
 389                 {
 390                         if(self.BUTTON_ATCK)
 391                         if(weapon_prepareattack(0, WEP_CVAR(tuba, refire)))
 392                         {
 393                                 W_Tuba_NoteOn(0);
 394                                 //weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_tuba_animtime, w_ready);
 395                                 weapon_thinkf(WFRAME_IDLE, WEP_CVAR(tuba, animtime), w_ready);
 396                         }
 397                         if(self.BUTTON_ATCK2)
 398                         if(weapon_prepareattack(1, WEP_CVAR(tuba, refire)))
 399                         {
 400                                 W_Tuba_NoteOn(HITTYPE_SECONDARY);
 401                                 //weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_tuba_animtime, w_ready);
 402                                 weapon_thinkf(WFRAME_IDLE, WEP_CVAR(tuba, animtime), w_ready);
 403                         }
 404                         if(self.tuba_note)
 405                         {
 406                                 if(!self.BUTTON_ATCK && !self.BUTTON_ATCK2)
 407                                 {
 408                                         entity oldself = self;
 409                                         self = self.tuba_note;
 410                                         W_Tuba_NoteOff();
 411                                         self = oldself;
 412                                 }
 413                         }
 414
 415                         return true;
 416                 }
 417                 case WR_INIT:
 418                 {
 419                         precache_model("models/weapons/g_tuba.md3");
 420                         precache_model("models/weapons/v_tuba.md3");
 421                         precache_model("models/weapons/h_tuba.iqm");
 422                         precache_model("models/weapons/v_akordeon.md3");
 423                         precache_model("models/weapons/h_akordeon.iqm");
 424                         precache_model("models/weapons/v_kleinbottle.md3");
 425                         precache_model("models/weapons/h_kleinbottle.iqm");
 426                         TUBA_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 427                         return true;
 428                 }
 429                 case WR_SETUP:
 430                 {
 431                         self.ammo_field = ammo_none;
 432                         self.tuba_instrument = 0;
 433                         return true;
 434                 }
 435                 case WR_RELOAD:
 436                 {
 437                         // switch to alternate instruments :)
 438                         if(self.weaponentity.state == WS_READY)
 439                         {
 440                                 switch(self.tuba_instrument)
 441                                 {
 442                                         case 0:
 443                                                 self.tuba_instrument = 1;
 444                                                 self.weaponname = "akordeon";
 445                                                 break;
 446                                         case 1:
 447                                                 self.tuba_instrument = 2;
 448                                                 self.weaponname = "kleinbottle";
 449                                                 break;
 450                                         case 2:
 451                                                 self.tuba_instrument = 0;
 452                                                 self.weaponname = "tuba";
 453                                                 break;
 454                                 }
 455                                 W_SetupShot(self, false, 0, "", 0, 0);
 456                                 pointparticles(particleeffectnum("teleport"), w_shotorg, '0 0 0', 1);
 457                                 self.weaponentity.state = WS_INUSE;
 458                                 weapon_thinkf(WFRAME_RELOAD, 0.5, w_ready);
 459                         }
 460
 461                         return true;
 462                 }
 463                 case WR_CHECKAMMO1:
 464                 case WR_CHECKAMMO2:
 465                 {
 466                         return true; // tuba has infinite ammo
 467                 }
 468                 case WR_CONFIG:
 469                 {
 470                         TUBA_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 471                         return true;
 472                 }
 473                 case WR_SUICIDEMESSAGE:
 474                 {
 475                         if(w_deathtype & HITTYPE_BOUNCE)
 476                                 return WEAPON_KLEINBOTTLE_SUICIDE;
 477                         else if(w_deathtype & HITTYPE_SECONDARY)
 478                                 return WEAPON_ACCORDEON_SUICIDE;
 479                         else
 480                                 return WEAPON_TUBA_SUICIDE;
 481                 }
 482                 case WR_KILLMESSAGE:
 483                 {
 484                         if(w_deathtype & HITTYPE_BOUNCE)
 485                                 return WEAPON_KLEINBOTTLE_MURDER;
 486                         else if(w_deathtype & HITTYPE_SECONDARY)
 487                                 return WEAPON_ACCORDEON_MURDER;
 488                         else
 489                                 return WEAPON_TUBA_MURDER;
 490                 }
 491         }
 492         return false;
 493 }
 494 #endif
 495 #ifdef CSQC
 496 float W_Tuba(float req)
 497 {
 498         // nothing to do here; particles of tuba are handled differently
 499         // WEAPONTODO
 500
 501         switch(req)
 502         {
 503                 case WR_ZOOMRETICLE:
 504                 {
 505                         // no weapon specific image for this weapon
 506                         return false;
 507                 }
 508         }
 509
 510         return false;
 511 }
 512 #endif
 513 #endif