qcsrc/common/weapons/w_vaporizer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ VAPORIZER,
   4 /* function  */ W_Vaporizer,
   5 /* ammotype  */ ammo_cells,
   6 /* impulse   */ 7,
   7 /* flags     */ WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '0.5 1 1',
  10 /* modelname */ "minstanex",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairminstanex 0.4",
  13 /* wepimg    */ "weaponminstanex",
  14 /* refname   */ "vaporizer",
  15 /* wepname   */ _("Vaporizer")
  16 );
  17
  18 #define VAPORIZER_SETTINGS(w_cvar,w_prop) VAPORIZER_SETTINGS_LIST(w_cvar, w_prop, VAPORIZER, vaporizer)
  19 #define VAPORIZER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, PRI, ammo) \
  21         w_cvar(id, sn, PRI, animtime) \
  22         w_cvar(id, sn, PRI, refire) \
  23         w_cvar(id, sn, SEC, ammo) \
  24         w_cvar(id, sn, SEC, animtime) \
  25         w_cvar(id, sn, SEC, damage) \
  26         w_cvar(id, sn, SEC, delay) \
  27         w_cvar(id, sn, SEC, edgedamage) \
  28         w_cvar(id, sn, SEC, force) \
  29         w_cvar(id, sn, SEC, lifetime) \
  30         w_cvar(id, sn, SEC, radius) \
  31         w_cvar(id, sn, SEC, refire) \
  32         w_cvar(id, sn, SEC, shotangle) \
  33         w_cvar(id, sn, SEC, speed) \
  34         w_cvar(id, sn, SEC, spread) \
  35         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  36         w_prop(id, sn, float,  reloading_time, reload_time) \
  37         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  38         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  39         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  40         w_prop(id, sn, float,  weaponstart, weaponstart) \
  41         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  42         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  43
  44 #ifdef SVQC
  45 VAPORIZER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  46 .float vaporizer_lasthit;
  47 .float jump_interval;
  48 #endif
  49 #else
  50 #ifdef SVQC
  51 void spawnfunc_weapon_vaporizer(void) { weapon_defaultspawnfunc(WEP_VAPORIZER); }
  52 void spawnfunc_weapon_minstanex(void) { spawnfunc_weapon_vaporizer(); }
  53
  54 void W_Vaporizer_Attack(void)
  55 {
  56         float flying;
  57         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  58
  59         W_SetupShot(self, TRUE, 0, "", CH_WEAPON_A, 10000);
  60         // handle sound separately so we can change the volume
  61         // added bonus: no longer plays the strength sound (strength gives no bonus to instakill anyway)
  62         sound (self, CH_WEAPON_A, "weapons/minstanexfire.wav", VOL_BASE * 0.8, ATTEN_NORM);
  63
  64         yoda = 0;
  65         damage_goodhits = 0;
  66         FireRailgunBullet(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, 10000, 800, 0, 0, 0, 0, WEP_VAPORIZER);
  67
  68         if(yoda && flying)
  69                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
  70         if(damage_goodhits && self.vaporizer_lasthit)
  71         {
  72                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
  73                 damage_goodhits = 0; // only every second time
  74         }
  75
  76         self.vaporizer_lasthit = damage_goodhits;
  77
  78         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  79
  80         // teamcolor / hit beam effect
  81         vector v;
  82         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  83         switch(self.team)
  84         {
  85                 case NUM_TEAM_1:   // Red
  86                         if(damage_goodhits)
  87                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED_HIT"), w_shotorg, v);
  88                         else
  89                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED"), w_shotorg, v);
  90                         break;
  91                 case NUM_TEAM_2:   // Blue
  92                         if(damage_goodhits)
  93                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE_HIT"), w_shotorg, v);
  94                         else
  95                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE"), w_shotorg, v);
  96                         break;
  97                 case NUM_TEAM_3:   // Yellow
  98                         if(damage_goodhits)
  99                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW_HIT"), w_shotorg, v);
 100                         else
 101                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW"), w_shotorg, v);
 102                         break;
 103                 case NUM_TEAM_4:   // Pink
 104                         if(damage_goodhits)
 105                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK_HIT"), w_shotorg, v);
 106                         else
 107                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK"), w_shotorg, v);
 108                         break;
 109                 default:
 110                         if(damage_goodhits)
 111                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3_HIT"), w_shotorg, v);
 112                         else
 113                                 WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), w_shotorg, v);
 114                         break;
 115         }
 116
 117         W_DecreaseAmmo(((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)));
 118 }
 119
 120 float W_Vaporizer(float req)
 121 {
 122         float ammo_amount;
 123         float vaporizer_ammo;
 124
 125         // now multiple WR_s use this
 126         vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 127
 128         switch(req)
 129         {
 130                 case WR_AIM:
 131                 {
 132                         if(self.WEP_AMMO(VAPORIZER) > 0)
 133                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 134                         else
 135                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), FALSE); // WEAPONTODO: replace with proper vaporizer cvars
 136
 137                         return TRUE;
 138                 }
 139                 case WR_THINK:
 140                 {
 141                         // if the laser uses load, we also consider its ammo for reloading
 142                         if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && self.clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) // forced reload
 143                                 WEP_ACTION(self.weapon, WR_RELOAD);
 144                         else if(WEP_CVAR(vaporizer, reload_ammo) && self.clip_load < vaporizer_ammo) // forced reload
 145                                 WEP_ACTION(self.weapon, WR_RELOAD);
 146                         else if(self.BUTTON_ATCK)
 147                         {
 148                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(vaporizer, refire)))
 149                                 {
 150                                         W_Vaporizer_Attack();
 151                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 152                                 }
 153                         }
 154                         else if(self.BUTTON_ATCK2)
 155                         {
 156                                 if(self.jump_interval <= time)
 157                                 if(weapon_prepareattack(1, -1))
 158                                 {
 159                                         // handle refire manually, so that primary and secondary can be fired without conflictions (important for instagib)
 160                                         self.jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor();
 161
 162                                         // decrease ammo for the laser?
 163                                         if(WEP_CVAR_SEC(vaporizer, ammo))
 164                                                 W_DecreaseAmmo(WEP_CVAR_SEC(vaporizer, ammo));
 165
 166                                         // ugly instagib hack to reuse the fire mode of the laser
 167                                         W_Blaster_Attack(
 168                                                 WEP_VAPORIZER | HITTYPE_SECONDARY,
 169                                                 WEP_CVAR_SEC(vaporizer, shotangle),
 170                                                 WEP_CVAR_SEC(vaporizer, damage),
 171                                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 172                                                 WEP_CVAR_SEC(vaporizer, radius),
 173                                                 WEP_CVAR_SEC(vaporizer, force),
 174                                                 WEP_CVAR_SEC(vaporizer, speed),
 175                                                 WEP_CVAR_SEC(vaporizer, spread),
 176                                                 WEP_CVAR_SEC(vaporizer, delay),
 177                                                 WEP_CVAR_SEC(vaporizer, lifetime)
 178                                         );
 179
 180                                         // now do normal refire
 181                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 182                                 }
 183                         }
 184
 185                         return TRUE;
 186                 }
 187                 case WR_INIT:
 188                 {
 189                         precache_model("models/nexflash.md3");
 190                         precache_model("models/weapons/g_minstanex.md3");
 191                         precache_model("models/weapons/v_minstanex.md3");
 192                         precache_model("models/weapons/h_minstanex.iqm");
 193                         precache_sound("weapons/minstanexfire.wav");
 194                         precache_sound("weapons/nexwhoosh1.wav");
 195                         precache_sound("weapons/nexwhoosh2.wav");
 196                         precache_sound("weapons/nexwhoosh3.wav");
 197                         //W_Blaster(WR_INIT); // Samual: Is this really the proper thing to do? Didn't we already run this previously?
 198                         VAPORIZER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 199                         return TRUE;
 200                 }
 201                 case WR_SETUP:
 202                 {
 203                         self.ammo_field = WEP_AMMO(VAPORIZER);
 204                         self.vaporizer_lasthit = 0;
 205                         return TRUE;
 206                 }
 207                 case WR_CHECKAMMO1:
 208                 {
 209                         ammo_amount = self.WEP_AMMO(VAPORIZER) >= vaporizer_ammo;
 210                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= vaporizer_ammo;
 211                         return ammo_amount;
 212                 }
 213                 case WR_CHECKAMMO2:
 214                 {
 215                         if(!WEP_CVAR_SEC(vaporizer, ammo))
 216                                 return TRUE;
 217                         ammo_amount = self.WEP_AMMO(VAPORIZER) >= WEP_CVAR_SEC(vaporizer, ammo);
 218                         ammo_amount += self.(weapon_load[WEP_VAPORIZER]) >= WEP_CVAR_SEC(vaporizer, ammo);
 219                         return ammo_amount;
 220                 }
 221                 case WR_CONFIG:
 222                 {
 223                         VAPORIZER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 224                         return TRUE;
 225                 }
 226                 case WR_RESETPLAYER:
 227                 {
 228                         self.vaporizer_lasthit = 0;
 229                         return TRUE;
 230                 }
 231                 case WR_RELOAD:
 232                 {
 233                         float used_ammo;
 234                         if(WEP_CVAR_SEC(vaporizer, ammo))
 235                                 used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 236                         else
 237                                 used_ammo = vaporizer_ammo;
 238
 239                         W_Reload(used_ammo, "weapons/reload.wav");
 240                         return TRUE;
 241                 }
 242                 case WR_SUICIDEMESSAGE:
 243                 {
 244                         return WEAPON_THINKING_WITH_PORTALS;
 245                 }
 246                 case WR_KILLMESSAGE:
 247                 {
 248                         return WEAPON_VAPORIZER_MURDER;
 249                 }
 250         }
 251         return FALSE;
 252 }
 253 #endif
 254 #ifdef CSQC
 255 float W_Vaporizer(float req)
 256 {
 257         switch(req)
 258         {
 259                 case WR_IMPACTEFFECT:
 260                 {
 261                         vector org2;
 262                         org2 = w_org + w_backoff * 6;
 263                         if(w_deathtype & HITTYPE_SECONDARY)
 264                         {
 265                                 pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
 266                                 if(!w_issilent) { sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM); }
 267                         }
 268                         else
 269                         {
 270                                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 271                                 if(!w_issilent) { sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM); }
 272                         }
 273                         return TRUE;
 274                 }
 275                 case WR_INIT:
 276                 {
 277                         precache_sound("weapons/laserimpact.wav");
 278                         precache_sound("weapons/neximpact.wav");
 279                         if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 280                         {
 281                                 precache_pic("gfx/reticle_nex");
 282                         }
 283                         return TRUE;
 284                 }
 285                 case WR_ZOOMRETICLE:
 286                 {
 287                         if(button_zoom || zoomscript_caught)
 288                         {
 289                                 reticle_image = "gfx/reticle_nex";
 290                                 return TRUE;
 291                         }
 292                         else
 293                         {
 294                                 // no weapon specific image for this weapon
 295                                 return FALSE;
 296                         }
 297                 }
 298         }
 299         return FALSE;
 300 }
 301 #endif
 302 #endif