qcsrc/common/weapons/weapon/arc.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ ARC,
   4 /* function  */ W_Arc,
   5 /* ammotype  */ ammo_cells,
   6 /* impulse   */ 3,
   7 /* flags     */ WEP_FLAG_NORMAL,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '1 1 1',
  10 /* modelname */ "arc",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairhlac 0.7",
  13 /* wepimg    */ "weaponarc",
  14 /* refname   */ "arc",
  15 /* wepname   */ _("Arc")
  16 );
  17
  18 #define ARC_SETTINGS(w_cvar,w_prop) ARC_SETTINGS_LIST(w_cvar, w_prop, ARC, arc)
  19 #define ARC_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, beam_ammo) \
  21         w_cvar(id, sn, NONE, beam_animtime) \
  22         w_cvar(id, sn, NONE, beam_botaimspeed) \
  23         w_cvar(id, sn, NONE, beam_botaimlifetime) \
  24         w_cvar(id, sn, NONE, beam_damage) \
  25         w_cvar(id, sn, NONE, beam_degreespersegment) \
  26         w_cvar(id, sn, NONE, beam_distancepersegment) \
  27         w_cvar(id, sn, NONE, beam_falloff_halflifedist) \
  28         w_cvar(id, sn, NONE, beam_falloff_maxdist) \
  29         w_cvar(id, sn, NONE, beam_falloff_mindist) \
  30         w_cvar(id, sn, NONE, beam_force) \
  31         w_cvar(id, sn, NONE, beam_healing_amax) \
  32         w_cvar(id, sn, NONE, beam_healing_aps) \
  33         w_cvar(id, sn, NONE, beam_healing_hmax) \
  34         w_cvar(id, sn, NONE, beam_healing_hps) \
  35         w_cvar(id, sn, NONE, beam_maxangle) \
  36         w_cvar(id, sn, NONE, beam_nonplayerdamage) \
  37         w_cvar(id, sn, NONE, beam_range) \
  38         w_cvar(id, sn, NONE, beam_refire) \
  39         w_cvar(id, sn, NONE, beam_returnspeed) \
  40         w_cvar(id, sn, NONE, beam_tightness) \
  41         w_cvar(id, sn, NONE, burst_ammo) \
  42         w_cvar(id, sn, NONE, burst_damage) \
  43         w_cvar(id, sn, NONE, burst_healing_aps) \
  44         w_cvar(id, sn, NONE, burst_healing_hps) \
  45         w_cvar(id, sn, NONE, overheat_max)/* maximum heat before jamming */ \
  46         w_cvar(id, sn, NONE, overheat_min)/* minimum heat to wait for cooldown */ \
  47         w_cvar(id, sn, NONE, beam_heat)   /* heat increase per second (primary) */ \
  48         w_cvar(id, sn, NONE, burst_heat)  /* heat increase per second (secondary) */ \
  49         w_cvar(id, sn, NONE, cooldown)    /* heat decrease per second when resting */ \
  50         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  51         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  52         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  53         w_prop(id, sn, float,  weaponstart, weaponstart) \
  54         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  55         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  56
  57 #ifndef MENUQC
  58 const float ARC_MAX_SEGMENTS = 20;
  59 vector arc_shotorigin[4];
  60 .vector beam_start;
  61 .vector beam_dir;
  62 .vector beam_wantdir;
  63 .int beam_type;
  64
  65 const int ARC_BT_MISS =        0x00;
  66 const int ARC_BT_WALL =        0x01;
  67 const int ARC_BT_HEAL =        0x02;
  68 const int ARC_BT_HIT =         0x03;
  69 const int ARC_BT_BURST_MISS =  0x10;
  70 const int ARC_BT_BURST_WALL =  0x11;
  71 const int ARC_BT_BURST_HEAL =  0x12;
  72 const int ARC_BT_BURST_HIT =   0x13;
  73 const int ARC_BT_BURSTMASK =   0x10;
  74
  75 const int ARC_SF_SETTINGS =    1;
  76 const int ARC_SF_START =       2;
  77 const int ARC_SF_WANTDIR =     4;
  78 const int ARC_SF_BEAMDIR =     8;
  79 const int ARC_SF_BEAMTYPE =    16;
  80 const int ARC_SF_LOCALMASK =   14;
  81 #endif
  82 #ifdef SVQC
  83 ARC_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  84 .entity arc_beam;
  85 .float arc_BUTTON_ATCK_prev; // for better animation control
  86 .float beam_prev;
  87 .float beam_initialized;
  88 .float beam_bursting;
  89 .float beam_teleporttime;
  90 .float beam_heat; // (beam) amount of heat produced
  91 .float arc_overheat; // (dropped arc/player) time during which it's too hot
  92 .float arc_cooldown; // (dropped arc/player) cooling speed
  93 .float arc_heat_percent; // (player) arc heat in [0,1] (stat)
  94 .float arc_smoke_sound;
  95 #endif
  96 #ifdef CSQC
  97 void Ent_ReadArcBeam(float isnew);
  98
  99 .vector beam_color;
 100 .float beam_alpha;
 101 .float beam_thickness;
 102 .float beam_traileffect;
 103 .float beam_hiteffect;
 104 .float beam_hitlight[4]; // 0: radius, 123: rgb
 105 .float beam_muzzleeffect;
 106 .float beam_muzzlelight[4]; // 0: radius, 123: rgb
 107 .string beam_image;
 108
 109 .entity beam_muzzleentity;
 110
 111 .float beam_degreespersegment;
 112 .float beam_distancepersegment;
 113 .float beam_usevieworigin;
 114 .float beam_initialized;
 115 .float beam_maxangle;
 116 .float beam_range;
 117 .float beam_returnspeed;
 118 .float beam_tightness;
 119 .vector beam_shotorigin;
 120
 121 entity Draw_ArcBeam_callback_entity;
 122 float Draw_ArcBeam_callback_last_thickness;
 123 vector Draw_ArcBeam_callback_last_top; // NOTE: in same coordinate system as player.
 124 vector Draw_ArcBeam_callback_last_bottom; // NOTE: in same coordinate system as player.
 125 #endif
 126 #endif
 127 #ifdef IMPLEMENTATION
 128 #ifdef SVQC
 129 void spawnfunc_weapon_arc(void) { weapon_defaultspawnfunc(WEP_ARC.m_id); }
 130
 131 float W_Arc_Beam_Send(entity to, int sf)
 132 {SELFPARAM();
 133         WriteByte(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
 134
 135         // Truncate information when this beam is displayed to the owner client
 136         // - The owner client has no use for beam start position or directions,
 137         //    it always figures this information out for itself with csqc code.
 138         // - Spectating the owner also truncates this information.
 139         float drawlocal = ((to == self.owner) || ((to.enemy == self.owner) && IS_SPEC(to)));
 140         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
 141
 142         WriteByte(MSG_ENTITY, sf);
 143
 144         if(sf & ARC_SF_SETTINGS) // settings information
 145         {
 146                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
 147                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
 148                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
 149                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
 150                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
 151                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
 152
 153                 WriteByte(MSG_ENTITY, drawlocal);
 154         }
 155         if(sf & ARC_SF_START) // starting location
 156         {
 157                 WriteCoord(MSG_ENTITY, self.beam_start.x);
 158                 WriteCoord(MSG_ENTITY, self.beam_start.y);
 159                 WriteCoord(MSG_ENTITY, self.beam_start.z);
 160         }
 161         if(sf & ARC_SF_WANTDIR) // want/aim direction
 162         {
 163                 WriteCoord(MSG_ENTITY, self.beam_wantdir.x);
 164                 WriteCoord(MSG_ENTITY, self.beam_wantdir.y);
 165                 WriteCoord(MSG_ENTITY, self.beam_wantdir.z);
 166         }
 167         if(sf & ARC_SF_BEAMDIR) // beam direction
 168         {
 169                 WriteCoord(MSG_ENTITY, self.beam_dir.x);
 170                 WriteCoord(MSG_ENTITY, self.beam_dir.y);
 171                 WriteCoord(MSG_ENTITY, self.beam_dir.z);
 172         }
 173         if(sf & ARC_SF_BEAMTYPE) // beam type
 174         {
 175                 WriteByte(MSG_ENTITY, self.beam_type);
 176         }
 177
 178         return true;
 179 }
 180
 181 void Reset_ArcBeam(entity player, vector forward)
 182 {
 183         if (!player.arc_beam) {
 184                 return;
 185         }
 186         player.arc_beam.beam_dir = forward;
 187         player.arc_beam.beam_teleporttime = time;
 188 }
 189
 190 float Arc_GetHeat_Percent(entity player)
 191 {
 192         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
 193         {
 194                 player.arc_overheat = 0;
 195                 return 0;
 196         }
 197
 198         if ( player.arc_beam )
 199                 return player.arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
 200
 201         if ( player.arc_overheat > time )
 202         {
 203                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
 204                         * player.arc_cooldown;
 205         }
 206
 207         return 0;
 208 }
 209 void Arc_Player_SetHeat(entity player)
 210 {
 211         player.arc_heat_percent = Arc_GetHeat_Percent(player);
 212         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
 213 }
 214
 215 void W_Arc_Beam_Think(void)
 216 {SELFPARAM();
 217         if(self != self.owner.arc_beam)
 218         {
 219                 remove(self);
 220                 return;
 221         }
 222
 223
 224         float burst = 0;
 225         if( self.owner.BUTTON_ATCK2 || self.beam_bursting)
 226         {
 227                 if(!self.beam_bursting)
 228                         self.beam_bursting = true;
 229                 burst = ARC_BT_BURSTMASK;
 230         }
 231
 232         if(
 233                 !IS_PLAYER(self.owner)
 234                 ||
 235                 (self.owner.WEP_AMMO(ARC) <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 236                 ||
 237                 self.owner.deadflag != DEAD_NO
 238                 ||
 239                 (!self.owner.BUTTON_ATCK && !burst )
 240                 ||
 241                 self.owner.frozen
 242                 ||
 243                 self.owner.vehicle
 244                 ||
 245                 (WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max))
 246         )
 247         {
 248                 if ( WEP_CVAR(arc, cooldown) > 0 )
 249                 {
 250                         float cooldown_speed = 0;
 251                         if ( self.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 252                         {
 253                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 254                         }
 255                         else if ( !burst )
 256                         {
 257                                 cooldown_speed = self.beam_heat / WEP_CVAR(arc, beam_refire);
 258                         }
 259
 260                         if ( cooldown_speed )
 261                         {
 262                                 self.owner.arc_overheat = time + self.beam_heat / cooldown_speed;
 263                                 self.owner.arc_cooldown = cooldown_speed;
 264                         }
 265
 266                         if ( WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max) )
 267                         {
 268                                 Send_Effect_("arc_overheat",
 269                                         self.beam_start, self.beam_wantdir, 1 );
 270                                 sound(self, CH_WEAPON_A, W_Sound("arc_stop"), VOL_BASE, ATTN_NORM);
 271                         }
 272                 }
 273
 274                 if(self == self.owner.arc_beam) { self.owner.arc_beam = world; }
 275                 setself(self.owner);
 276                 if(!WEP_ACTION(WEP_ARC.m_id, WR_CHECKAMMO1) && !WEP_ACTION(WEP_ARC.m_id, WR_CHECKAMMO2))
 277                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 278                 {
 279                         // note: this doesn't force the switch
 280                         W_SwitchToOtherWeapon(self);
 281                 }
 282                 setself(this);
 283                 remove(self);
 284                 return;
 285         }
 286
 287         // decrease ammo
 288         float coefficient = frametime;
 289         if(!(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 290         {
 291                 float rootammo;
 292                 if(burst)
 293                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 294                 else
 295                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 296
 297                 if(rootammo)
 298                 {
 299                         coefficient = min(coefficient, self.owner.WEP_AMMO(ARC) / rootammo);
 300                         self.owner.WEP_AMMO(ARC) = max(0, self.owner.WEP_AMMO(ARC) - (rootammo * frametime));
 301                 }
 302         }
 303         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 304         self.beam_heat = min( WEP_CVAR(arc, overheat_max), self.beam_heat + heat_speed*frametime );
 305
 306         makevectors(self.owner.v_angle);
 307
 308         W_SetupShot_Range(
 309                 self.owner,
 310                 true,
 311                 0,
 312                 "",
 313                 0,
 314                 WEP_CVAR(arc, beam_damage) * coefficient,
 315                 WEP_CVAR(arc, beam_range)
 316         );
 317
 318         // After teleport, "lock" the beam until the teleport is confirmed.
 319         if (time < self.beam_teleporttime + ANTILAG_LATENCY(self.owner)) {
 320                 w_shotdir = self.beam_dir;
 321         }
 322
 323         // network information: shot origin and want/aim direction
 324         if(self.beam_start != w_shotorg)
 325         {
 326                 self.SendFlags |= ARC_SF_START;
 327                 self.beam_start = w_shotorg;
 328         }
 329         if(self.beam_wantdir != w_shotdir)
 330         {
 331                 self.SendFlags |= ARC_SF_WANTDIR;
 332                 self.beam_wantdir = w_shotdir;
 333         }
 334
 335         if(!self.beam_initialized)
 336         {
 337                 self.beam_dir = w_shotdir;
 338                 self.beam_initialized = true;
 339         }
 340
 341         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 342         // idea: blend together self.beam_dir with the inverted direction the player is moving in
 343         // might have to make some special accomodation so that it only uses view_right and view_up
 344
 345         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 346
 347         float segments;
 348         if(self.beam_dir != w_shotdir)
 349         {
 350                 // calculate how much we're going to move the end of the beam to the want position
 351                 // WEAPONTODO (server and client):
 352                 // blendfactor never actually becomes 0 in this situation, which is a problem
 353                 // regarding precision... this means that self.beam_dir and w_shotdir approach
 354                 // eachother, however they never actually become the same value with this method.
 355                 // Perhaps we should do some form of rounding/snapping?
 356                 float angle = vlen(w_shotdir - self.beam_dir) * RAD2DEG;
 357                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 358                 {
 359                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 360                         float blendfactor = bound(
 361                                 0,
 362                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 363                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 364                         );
 365                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 366                 }
 367                 else
 368                 {
 369                         // the radius is not too far yet, no worries :D
 370                         float blendfactor = bound(
 371                                 0,
 372                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 373                                 1
 374                         );
 375                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 376                 }
 377
 378                 // network information: beam direction
 379                 self.SendFlags |= ARC_SF_BEAMDIR;
 380
 381                 // calculate how many segments are needed
 382                 float max_allowed_segments;
 383
 384                 if(WEP_CVAR(arc, beam_distancepersegment))
 385                 {
 386                         max_allowed_segments = min(
 387                                 ARC_MAX_SEGMENTS,
 388                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 389                         );
 390                 }
 391                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 392
 393                 if(WEP_CVAR(arc, beam_degreespersegment))
 394                 {
 395                         segments = bound(
 396                                 1,
 397                                 (
 398                                         min(
 399                                                 angle,
 400                                                 WEP_CVAR(arc, beam_maxangle)
 401                                         )
 402                                         /
 403                                         WEP_CVAR(arc, beam_degreespersegment)
 404                                 ),
 405                                 max_allowed_segments
 406                         );
 407                 }
 408                 else { segments = 1; }
 409         }
 410         else { segments = 1; }
 411
 412         vector beam_endpos = (w_shotorg + (self.beam_dir * WEP_CVAR(arc, beam_range)));
 413         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 414
 415         float i;
 416         float new_beam_type = 0;
 417         vector last_origin = w_shotorg;
 418         for(i = 1; i <= segments; ++i)
 419         {
 420                 // WEAPONTODO (client):
 421                 // In order to do nice fading and pointing on the starting segment, we must always
 422                 // have that drawn as a separate triangle... However, that is difficult to do when
 423                 // keeping in mind the above problems and also optimizing the amount of segments
 424                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 425
 426                 vector new_origin = bezier_quadratic_getpoint(
 427                         w_shotorg,
 428                         beam_controlpoint,
 429                         beam_endpos,
 430                         i / segments);
 431                 vector new_dir = normalize(new_origin - last_origin);
 432
 433                 WarpZone_traceline_antilag(
 434                         self.owner,
 435                         last_origin,
 436                         new_origin,
 437                         MOVE_NORMAL,
 438                         self.owner,
 439                         ANTILAG_LATENCY(self.owner)
 440                 );
 441
 442                 // Do all the transforms for warpzones right now, as we already
 443                 // "are" in the post-trace system (if we hit a player, that's
 444                 // always BEHIND the last passed wz).
 445                 last_origin = trace_endpos;
 446                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 447                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 448                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 449                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 450
 451                 float is_player = (
 452                         IS_PLAYER(trace_ent)
 453                         ||
 454                         trace_ent.classname == "body"
 455                         ||
 456                         IS_MONSTER(trace_ent)
 457                 );
 458
 459                 if(trace_ent && trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 460                 {
 461                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 462                         // NO. trace_endpos should be just fine. If not,
 463                         // that's an engine bug that needs proper debugging.
 464                         vector hitorigin = trace_endpos;
 465
 466                         float falloff = ExponentialFalloff(
 467                                 WEP_CVAR(arc, beam_falloff_mindist),
 468                                 WEP_CVAR(arc, beam_falloff_maxdist),
 469                                 WEP_CVAR(arc, beam_falloff_halflifedist),
 470                                 vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 471                         );
 472
 473                         if(is_player && SAME_TEAM(self.owner, trace_ent))
 474                         {
 475                                 float roothealth, rootarmor;
 476                                 if(burst)
 477                                 {
 478                                         roothealth = WEP_CVAR(arc, burst_healing_hps);
 479                                         rootarmor = WEP_CVAR(arc, burst_healing_aps);
 480                                 }
 481                                 else
 482                                 {
 483                                         roothealth = WEP_CVAR(arc, beam_healing_hps);
 484                                         rootarmor = WEP_CVAR(arc, beam_healing_aps);
 485                                 }
 486
 487                                 if(trace_ent.health <= WEP_CVAR(arc, beam_healing_hmax) && roothealth)
 488                                 {
 489                                         trace_ent.health = min(
 490                                                 trace_ent.health + (roothealth * coefficient),
 491                                                 WEP_CVAR(arc, beam_healing_hmax)
 492                                         );
 493                                 }
 494                                 if(trace_ent.armorvalue <= WEP_CVAR(arc, beam_healing_amax) && rootarmor)
 495                                 {
 496                                         trace_ent.armorvalue = min(
 497                                                 trace_ent.armorvalue + (rootarmor * coefficient),
 498                                                 WEP_CVAR(arc, beam_healing_amax)
 499                                         );
 500                                 }
 501
 502                                 // stop rot, set visual effect
 503                                 if(roothealth || rootarmor)
 504                                 {
 505                                         trace_ent.pauserothealth_finished = max(
 506                                                 trace_ent.pauserothealth_finished,
 507                                                 time + autocvar_g_balance_pause_health_rot
 508                                         );
 509                                         trace_ent.pauserotarmor_finished = max(
 510                                                 trace_ent.pauserotarmor_finished,
 511                                                 time + autocvar_g_balance_pause_armor_rot
 512                                         );
 513                                         new_beam_type = ARC_BT_HEAL;
 514                                 }
 515                         }
 516                         else
 517                         {
 518                                 float rootdamage;
 519                                 if(is_player)
 520                                 {
 521                                         if(burst)
 522                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 523                                         else
 524                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 525                                 }
 526                                 else
 527                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 528
 529                                 if(accuracy_isgooddamage(self.owner, trace_ent))
 530                                 {
 531                                         accuracy_add(
 532                                                 self.owner,
 533                                                 WEP_ARC.m_id,
 534                                                 0,
 535                                                 rootdamage * coefficient * falloff
 536                                         );
 537                                 }
 538
 539                                 Damage(
 540                                         trace_ent,
 541                                         self.owner,
 542                                         self.owner,
 543                                         rootdamage * coefficient * falloff,
 544                                         WEP_ARC.m_id,
 545                                         hitorigin,
 546                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 547                                 );
 548
 549                                 new_beam_type = ARC_BT_HIT;
 550                         }
 551                         break;
 552                 }
 553                 else if(trace_fraction != 1)
 554                 {
 555                         // we collided with geometry
 556                         new_beam_type = ARC_BT_WALL;
 557                         break;
 558                 }
 559         }
 560
 561         // te_explosion(trace_endpos);
 562
 563         // if we're bursting, use burst visual effects
 564         new_beam_type |= burst;
 565
 566         // network information: beam type
 567         if(new_beam_type != self.beam_type)
 568         {
 569                 self.SendFlags |= ARC_SF_BEAMTYPE;
 570                 self.beam_type = new_beam_type;
 571         }
 572
 573         self.owner.beam_prev = time;
 574         self.nextthink = time;
 575 }
 576
 577 void W_Arc_Beam(float burst)
 578 {SELFPARAM();
 579
 580         // only play fire sound if 1 sec has passed since player let go the fire button
 581         if(time - self.beam_prev > 1)
 582                 sound(self, CH_WEAPON_A, W_Sound("arc_fire"), VOL_BASE, ATTN_NORM);
 583
 584         entity beam = self.arc_beam = spawn();
 585         beam.classname = "W_Arc_Beam";
 586         beam.solid = SOLID_NOT;
 587         beam.think = W_Arc_Beam_Think;
 588         beam.owner = self;
 589         beam.movetype = MOVETYPE_NONE;
 590         beam.bot_dodge = true;
 591         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 592         beam.beam_bursting = burst;
 593         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 594
 595         SELFCALL(beam, beam.think());
 596         SELFCALL_DONE();
 597 }
 598
 599 void Arc_Smoke()
 600 {SELFPARAM();
 601         makevectors(self.v_angle);
 602         W_SetupShot_Range(self,true,0,"",0,0,0);
 603
 604         vector smoke_origin = w_shotorg + self.velocity*frametime;
 605         if ( self.arc_overheat > time )
 606         {
 607                 if ( random() < self.arc_heat_percent )
 608                         Send_Effect_("arc_smoke", smoke_origin, '0 0 0', 1 );
 609                 if ( self.BUTTON_ATCK || self.BUTTON_ATCK2 )
 610                 {
 611                         Send_Effect_("arc_overheat_fire", smoke_origin, w_shotdir, 1 );
 612                         if ( !self.arc_smoke_sound )
 613                         {
 614                                 self.arc_smoke_sound = 1;
 615                                 sound(self, CH_SHOTS_SINGLE, W_Sound("arc_loop_overheat"), VOL_BASE, ATTN_NORM);
 616                         }
 617                 }
 618         }
 619         else if ( self.arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 620                         self.arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 621         {
 622                 if ( random() < (self.arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 623                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 624                         Send_Effect_("arc_smoke", smoke_origin, '0 0 0', 1 );
 625         }
 626
 627         if (  self.arc_smoke_sound && ( self.arc_overheat <= time ||
 628                 !( self.BUTTON_ATCK || self.BUTTON_ATCK2 ) ) || self.switchweapon != WEP_ARC.m_id )
 629         {
 630                 self.arc_smoke_sound = 0;
 631                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
 632         }
 633 }
 634
 635 bool W_Arc(int req)
 636 {SELFPARAM();
 637         switch(req)
 638         {
 639                 case WR_AIM:
 640                 {
 641                         if(WEP_CVAR(arc, beam_botaimspeed))
 642                         {
 643                                 self.BUTTON_ATCK = bot_aim(
 644                                         WEP_CVAR(arc, beam_botaimspeed),
 645                                         0,
 646                                         WEP_CVAR(arc, beam_botaimlifetime),
 647                                         false
 648                                 );
 649                         }
 650                         else
 651                         {
 652                                 self.BUTTON_ATCK = bot_aim(
 653                                         1000000,
 654                                         0,
 655                                         0.001,
 656                                         false
 657                                 );
 658                         }
 659                         return true;
 660                 }
 661                 case WR_THINK:
 662                 {
 663                         Arc_Player_SetHeat(self);
 664                         Arc_Smoke();
 665
 666                         if ( self.arc_overheat <= time )
 667                         if(self.BUTTON_ATCK || self.BUTTON_ATCK2 || self.arc_beam.beam_bursting )
 668                         {
 669
 670                                 if(self.arc_BUTTON_ATCK_prev)
 671                                 {
 672                                         #if 0
 673                                         if(self.animstate_startframe == self.anim_shoot.x && self.animstate_numframes == self.anim_shoot.y)
 674                                                 weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 675                                         else
 676                                         #endif
 677                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 678                                 }
 679
 680                                 if((!self.arc_beam) || wasfreed(self.arc_beam))
 681                                 {
 682                                         if(weapon_prepareattack(!!self.BUTTON_ATCK2, 0))
 683                                         {
 684                                                 W_Arc_Beam(!!self.BUTTON_ATCK2);
 685
 686                                                 if(!self.arc_BUTTON_ATCK_prev)
 687                                                 {
 688                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 689                                                         self.arc_BUTTON_ATCK_prev = 1;
 690                                                 }
 691                                         }
 692                                 }
 693
 694                                 return true;
 695                         }
 696
 697                         if(self.arc_BUTTON_ATCK_prev != 0)
 698                         {
 699                                 sound(self, CH_WEAPON_A, W_Sound("arc_stop"), VOL_BASE, ATTN_NORM);
 700                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 701                                 ATTACK_FINISHED(self) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor();
 702                         }
 703                         self.arc_BUTTON_ATCK_prev = 0;
 704
 705                         #if 0
 706                         if(self.BUTTON_ATCK2)
 707                         if(weapon_prepareattack(1, autocvar_g_balance_arc_secondary_refire))
 708                         {
 709                                 W_Arc_Attack2();
 710                                 self.arc_count = autocvar_g_balance_arc_secondary_count;
 711                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 712                                 self.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor();
 713                         }
 714                         #endif
 715
 716                         return true;
 717                 }
 718                 case WR_INIT:
 719                 {
 720                         precache_model(W_Model("g_arc.md3"));
 721                         precache_model(W_Model("v_arc.md3"));
 722                         precache_model(W_Model("h_arc.iqm"));
 723                         precache_sound(W_Sound("arc_fire"));
 724                         precache_sound(W_Sound("arc_loop"));
 725                         precache_sound(W_Sound("arc_stop"));
 726                         precache_sound(W_Sound("arc_loop_overheat"));
 727                         if(!arc_shotorigin[0])
 728                         {
 729                                 arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 730                                 arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 731                                 arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 732                                 arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 733                         }
 734                         ARC_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 735                         return true;
 736                 }
 737                 case WR_CHECKAMMO1:
 738                 {
 739                         return ((!WEP_CVAR(arc, beam_ammo)) || (self.WEP_AMMO(ARC) > 0));
 740                 }
 741                 case WR_CHECKAMMO2:
 742                 {
 743                         return WEP_CVAR(arc, overheat_max) > 0 &&
 744                                 ((!WEP_CVAR(arc, burst_ammo)) || (self.WEP_AMMO(ARC) > 0));
 745                 }
 746                 case WR_CONFIG:
 747                 {
 748                         ARC_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 749                         return true;
 750                 }
 751                 case WR_KILLMESSAGE:
 752                 {
 753                         return WEAPON_ARC_MURDER;
 754                 }
 755                 case WR_DROP:
 756                 {
 757                         weapon_dropevent_item.arc_overheat = self.arc_overheat;
 758                         weapon_dropevent_item.arc_cooldown = self.arc_cooldown;
 759                         self.arc_overheat = 0;
 760                         self.arc_cooldown = 0;
 761                         return true;
 762                 }
 763                 case WR_PICKUP:
 764                 {
 765                         if ( !client_hasweapon(self, WEP_ARC.m_id, false, false) &&
 766                                 weapon_dropevent_item.arc_overheat > time )
 767                         {
 768                                 self.arc_overheat = weapon_dropevent_item.arc_overheat;
 769                                 self.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 770                         }
 771                         return true;
 772                 }
 773         }
 774         return false;
 775 }
 776 #endif
 777 #ifdef CSQC
 778 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 779 {
 780         entity beam = Draw_ArcBeam_callback_entity;
 781         vector transformed_view_org;
 782         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 783
 784         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 785         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 786         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 787
 788         vector hitorigin;
 789
 790         // draw segment
 791         #if 0
 792         if(trace_fraction != 1)
 793         {
 794                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 795                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 796                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 797         }
 798         else
 799         {
 800                 hitorigin = hit;
 801         }
 802         #else
 803         hitorigin = hit;
 804         #endif
 805
 806         // decide upon thickness
 807         float thickness = beam.beam_thickness;
 808
 809         // draw primary beam render
 810         vector top    = hitorigin + (thickdir * thickness);
 811         vector bottom = hitorigin - (thickdir * thickness);
 812
 813         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 814         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 815
 816         R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 817         R_PolygonVertex(
 818                 top,
 819                 '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 820                 beam.beam_color,
 821                 beam.beam_alpha
 822         );
 823         R_PolygonVertex(
 824                 last_top,
 825                 '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 826                 beam.beam_color,
 827                 beam.beam_alpha
 828         );
 829         R_PolygonVertex(
 830                 last_bottom,
 831                 '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 832                 beam.beam_color,
 833                 beam.beam_alpha
 834         );
 835         R_PolygonVertex(
 836                 bottom,
 837                 '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 838                 beam.beam_color,
 839                 beam.beam_alpha
 840         );
 841         R_EndPolygon();
 842
 843         // draw trailing particles
 844         // NOTES:
 845         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 846         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 847         if(beam.beam_traileffect)
 848         {
 849                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 850         }
 851
 852         // set up for the next
 853         Draw_ArcBeam_callback_last_thickness = thickness;
 854         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 855         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 856 }
 857
 858 void Reset_ArcBeam(void)
 859 {
 860         entity e;
 861         for (e = world; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 862                 e.beam_initialized = false;
 863         }
 864         for (e = world; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 865                 e.beam_initialized = false;
 866         }
 867 }
 868
 869 void Draw_ArcBeam(void)
 870 {SELFPARAM();
 871         float dt = time - self.move_time;
 872         self.move_time = time;
 873         if(dt <= 0) { return; }
 874
 875         if(!self.beam_usevieworigin)
 876         {
 877                 InterpolateOrigin_Do();
 878         }
 879
 880         // origin = beam starting origin
 881         // v_angle = wanted/aim direction
 882         // angles = current direction of beam
 883
 884         vector start_pos;
 885         vector wantdir; //= view_forward;
 886         vector beamdir; //= self.beam_dir;
 887
 888         float segments;
 889         if(self.beam_usevieworigin)
 890         {
 891                 // WEAPONTODO:
 892                 // Currently we have to replicate nearly the same method of figuring
 893                 // out the shotdir that the server does... Ideally in the future we
 894                 // should be able to acquire this from a generalized function built
 895                 // into a weapon system for client code.
 896
 897                 // find where we are aiming
 898                 makevectors(warpzone_save_view_angles);
 899                 vector forward = v_forward;
 900                 vector right = v_right;
 901                 vector up = v_up;
 902
 903                 // decide upon start position
 904                 if(self.beam_usevieworigin == 2)
 905                         { start_pos = warpzone_save_view_origin; }
 906                 else
 907                         { start_pos = self.origin; }
 908
 909                 // trace forward with an estimation
 910                 WarpZone_TraceLine(
 911                         start_pos,
 912                         start_pos + forward * self.beam_range,
 913                         MOVE_NOMONSTERS,
 914                         self
 915                 );
 916
 917                 // untransform in case our trace went through a warpzone
 918                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 919
 920                 // un-adjust trueaim if shotend is too close
 921                 if(vlen(end_pos - start_pos) < g_trueaim_minrange)
 922                         end_pos = start_pos + (forward * g_trueaim_minrange);
 923
 924                 // move shot origin to the actual gun muzzle origin
 925                 vector origin_offset =
 926                           right * -self.beam_shotorigin.y
 927                         + up * self.beam_shotorigin.z;
 928
 929                 start_pos = start_pos + origin_offset;
 930
 931                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 932                 traceline(start_pos, start_pos + forward * self.beam_shotorigin.x, MOVE_NORMAL, self);
 933                 start_pos = trace_endpos;
 934
 935                 // calculate the aim direction now
 936                 wantdir = normalize(end_pos - start_pos);
 937
 938                 if(!self.beam_initialized)
 939                 {
 940                         self.beam_dir = wantdir;
 941                         self.beam_initialized = true;
 942                 }
 943
 944                 if(self.beam_dir != wantdir)
 945                 {
 946                         // calculate how much we're going to move the end of the beam to the want position
 947                         // WEAPONTODO (server and client):
 948                         // blendfactor never actually becomes 0 in this situation, which is a problem
 949                         // regarding precision... this means that self.beam_dir and w_shotdir approach
 950                         // eachother, however they never actually become the same value with this method.
 951                         // Perhaps we should do some form of rounding/snapping?
 952                         float angle = vlen(wantdir - self.beam_dir) * RAD2DEG;
 953                         if(angle && (angle > self.beam_maxangle))
 954                         {
 955                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 956                                 float blendfactor = bound(
 957                                         0,
 958                                         (1 - (self.beam_returnspeed * frametime)),
 959                                         min(self.beam_maxangle / angle, 1)
 960                                 );
 961                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 962                         }
 963                         else
 964                         {
 965                                 // the radius is not too far yet, no worries :D
 966                                 float blendfactor = bound(
 967                                         0,
 968                                         (1 - (self.beam_returnspeed * frametime)),
 969                                         1
 970                                 );
 971                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 972                         }
 973
 974                         // calculate how many segments are needed
 975                         float max_allowed_segments;
 976
 977                         if(self.beam_distancepersegment)
 978                         {
 979                                 max_allowed_segments = min(
 980                                         ARC_MAX_SEGMENTS,
 981                                         1 + (vlen(wantdir / self.beam_distancepersegment))
 982                                 );
 983                         }
 984                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 985
 986                         if(self.beam_degreespersegment)
 987                         {
 988                                 segments = bound(
 989                                         1,
 990                                         (
 991                                                 min(
 992                                                         angle,
 993                                                         self.beam_maxangle
 994                                                 )
 995                                                 /
 996                                                 self.beam_degreespersegment
 997                                         ),
 998                                         max_allowed_segments
 999                                 );
1000                         }
1001                         else { segments = 1; }
1002                 }
1003                 else { segments = 1; }
1004
1005                 // set the beam direction which the rest of the code will refer to
1006                 beamdir = self.beam_dir;
1007
1008                 // finally, set self.angles to the proper direction so that muzzle attachment points in proper direction
1009                 self.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1010         }
1011         else
1012         {
1013                 // set the values from the provided info from the networked entity
1014                 start_pos = self.origin;
1015                 wantdir = self.v_angle;
1016                 beamdir = self.angles;
1017
1018                 if(beamdir != wantdir)
1019                 {
1020                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1021
1022                         // calculate how many segments are needed
1023                         float max_allowed_segments;
1024
1025                         if(self.beam_distancepersegment)
1026                         {
1027                                 max_allowed_segments = min(
1028                                         ARC_MAX_SEGMENTS,
1029                                         1 + (vlen(wantdir / self.beam_distancepersegment))
1030                                 );
1031                         }
1032                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1033
1034                         if(self.beam_degreespersegment)
1035                         {
1036                                 segments = bound(
1037                                         1,
1038                                         (
1039                                                 min(
1040                                                         angle,
1041                                                         self.beam_maxangle
1042                                                 )
1043                                                 /
1044                                                 self.beam_degreespersegment
1045                                         ),
1046                                         max_allowed_segments
1047                                 );
1048                         }
1049                         else { segments = 1; }
1050                 }
1051                 else { segments = 1; }
1052         }
1053
1054         setorigin(self, start_pos);
1055         self.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1056
1057         vector beam_endpos = (start_pos + (beamdir * self.beam_range));
1058         vector beam_controlpoint = start_pos + wantdir * (self.beam_range * (1 - self.beam_tightness));
1059
1060         Draw_ArcBeam_callback_entity = self;
1061         Draw_ArcBeam_callback_last_thickness = 0;
1062         Draw_ArcBeam_callback_last_top = start_pos;
1063         Draw_ArcBeam_callback_last_bottom = start_pos;
1064
1065         vector last_origin = start_pos;
1066         vector original_start_pos = start_pos;
1067
1068         float i;
1069         for(i = 1; i <= segments; ++i)
1070         {
1071                 // WEAPONTODO (client):
1072                 // In order to do nice fading and pointing on the starting segment, we must always
1073                 // have that drawn as a separate triangle... However, that is difficult to do when
1074                 // keeping in mind the above problems and also optimizing the amount of segments
1075                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1076
1077                 vector new_origin = bezier_quadratic_getpoint(
1078                         start_pos,
1079                         beam_controlpoint,
1080                         beam_endpos,
1081                         i / segments);
1082
1083                 WarpZone_TraceBox_ThroughZone(
1084                         last_origin,
1085                         '0 0 0',
1086                         '0 0 0',
1087                         new_origin,
1088                         MOVE_NORMAL,
1089                         world,
1090                         world,
1091                         Draw_ArcBeam_callback
1092                 );
1093
1094                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1095                 // system (if we hit a player, that's always BEHIND the last passed wz).
1096                 last_origin = trace_endpos;
1097                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1098                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1099                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1100                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1101                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1102                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1103
1104                 if(trace_fraction < 1) { break; }
1105         }
1106
1107         // visual effects for startpoint and endpoint
1108         if(self.beam_hiteffect)
1109         {
1110                 // FIXME we really should do this on the server so it actually
1111                 // matches gameplay. What this client side stuff is doing is no
1112                 // more than guesswork.
1113                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1114                 pointparticles(
1115                         self.beam_hiteffect,
1116                         last_origin,
1117                         beamdir * -1,
1118                         frametime * 2
1119                 );
1120         }
1121         if(self.beam_hitlight[0])
1122         {
1123                 adddynamiclight(
1124                         last_origin,
1125                         self.beam_hitlight[0],
1126                         vec3(
1127                                 self.beam_hitlight[1],
1128                                 self.beam_hitlight[2],
1129                                 self.beam_hitlight[3]
1130                         )
1131                 );
1132         }
1133         if(self.beam_muzzleeffect)
1134         {
1135                 pointparticles(
1136                         self.beam_muzzleeffect,
1137                         original_start_pos + wantdir * 20,
1138                         wantdir * 1000,
1139                         frametime * 0.1
1140                 );
1141         }
1142         if(self.beam_muzzlelight[0])
1143         {
1144                 adddynamiclight(
1145                         original_start_pos + wantdir * 20,
1146                         self.beam_muzzlelight[0],
1147                         vec3(
1148                                 self.beam_muzzlelight[1],
1149                                 self.beam_muzzlelight[2],
1150                                 self.beam_muzzlelight[3]
1151                         )
1152                 );
1153         }
1154
1155         // cleanup
1156         Draw_ArcBeam_callback_entity = world;
1157         Draw_ArcBeam_callback_last_thickness = 0;
1158         Draw_ArcBeam_callback_last_top = '0 0 0';
1159         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1160 }
1161
1162 void Remove_ArcBeam(void)
1163 {SELFPARAM();
1164         remove(self.beam_muzzleentity);
1165         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
1166 }
1167
1168 void Ent_ReadArcBeam(float isnew)
1169 {SELFPARAM();
1170         int sf = ReadByte();
1171         entity flash;
1172
1173         if(isnew)
1174         {
1175                 // calculate shot origin offset from gun alignment
1176                 int gunalign = autocvar_cl_gunalign;
1177                 if(gunalign != 1 && gunalign != 2 && gunalign != 4)
1178                         gunalign = 3; // default value
1179                 --gunalign;
1180
1181                 self.beam_shotorigin = arc_shotorigin[gunalign];
1182
1183                 // set other main attributes of the beam
1184                 self.draw = Draw_ArcBeam;
1185                 self.entremove = Remove_ArcBeam;
1186                 self.move_time = time;
1187                 loopsound(self, CH_SHOTS_SINGLE, W_Sound("arc_loop"), VOL_BASE, ATTEN_NORM);
1188
1189                 flash = spawn();
1190                 flash.owner = self;
1191                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1192                 flash.drawmask = MASK_NORMAL;
1193                 flash.solid = SOLID_NOT;
1194                 flash.avelocity_z = 5000;
1195                 setattachment(flash, self, "");
1196                 setorigin(flash, '0 0 0');
1197
1198                 self.beam_muzzleentity = flash;
1199         }
1200         else
1201         {
1202                 flash = self.beam_muzzleentity;
1203         }
1204
1205         if(sf & ARC_SF_SETTINGS) // settings information
1206         {
1207                 self.beam_degreespersegment = ReadShort();
1208                 self.beam_distancepersegment = ReadShort();
1209                 self.beam_maxangle = ReadShort();
1210                 self.beam_range = ReadCoord();
1211                 self.beam_returnspeed = ReadShort();
1212                 self.beam_tightness = (ReadByte() / 10);
1213
1214                 if(ReadByte())
1215                 {
1216                         if(autocvar_chase_active)
1217                                 { self.beam_usevieworigin = 1; }
1218                         else // use view origin
1219                                 { self.beam_usevieworigin = 2; }
1220                 }
1221                 else
1222                 {
1223                         self.beam_usevieworigin = 0;
1224                 }
1225         }
1226
1227         if(!self.beam_usevieworigin)
1228         {
1229                 // self.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1230                 self.iflags = IFLAG_ORIGIN;
1231
1232                 InterpolateOrigin_Undo();
1233         }
1234
1235         if(sf & ARC_SF_START) // starting location
1236         {
1237                 self.origin_x = ReadCoord();
1238                 self.origin_y = ReadCoord();
1239                 self.origin_z = ReadCoord();
1240         }
1241         else if(self.beam_usevieworigin) // infer the location from player location
1242         {
1243                 if(self.beam_usevieworigin == 2)
1244                 {
1245                         // use view origin
1246                         self.origin = view_origin;
1247                 }
1248                 else
1249                 {
1250                         // use player origin so that third person display still works
1251                         self.origin = getplayerorigin(player_localnum) + ('0 0 1' * getstati(STAT_VIEWHEIGHT));
1252                 }
1253         }
1254
1255         setorigin(self, self.origin);
1256
1257         if(sf & ARC_SF_WANTDIR) // want/aim direction
1258         {
1259                 self.v_angle_x = ReadCoord();
1260                 self.v_angle_y = ReadCoord();
1261                 self.v_angle_z = ReadCoord();
1262         }
1263
1264         if(sf & ARC_SF_BEAMDIR) // beam direction
1265         {
1266                 self.angles_x = ReadCoord();
1267                 self.angles_y = ReadCoord();
1268                 self.angles_z = ReadCoord();
1269         }
1270
1271         if(sf & ARC_SF_BEAMTYPE) // beam type
1272         {
1273                 self.beam_type = ReadByte();
1274                 switch(self.beam_type)
1275                 {
1276                         case ARC_BT_MISS:
1277                         {
1278                                 self.beam_color = '1 1 1';
1279                                 self.beam_alpha = 0.5;
1280                                 self.beam_thickness = 8;
1281                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1282                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1283                                 self.beam_hitlight[0] = 0;
1284                                 self.beam_hitlight[1] = 1;
1285                                 self.beam_hitlight[2] = 1;
1286                                 self.beam_hitlight[3] = 1;
1287                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1288                                 self.beam_muzzlelight[0] = 0;
1289                                 self.beam_muzzlelight[1] = 1;
1290                                 self.beam_muzzlelight[2] = 1;
1291                                 self.beam_muzzlelight[3] = 1;
1292                                 if(self.beam_muzzleeffect >= 0)
1293                                 {
1294                                         setmodel(flash, "models/flash.md3");
1295                                         flash.alpha = self.beam_alpha;
1296                                         flash.colormod = self.beam_color;
1297                                         flash.scale = 0.5;
1298                                 }
1299                                 break;
1300                         }
1301                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1302                         {
1303                                 self.beam_color = '1 1 1';
1304                                 self.beam_alpha = 0.5;
1305                                 self.beam_thickness = 8;
1306                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1307                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1308                                 self.beam_hitlight[0] = 0;
1309                                 self.beam_hitlight[1] = 1;
1310                                 self.beam_hitlight[2] = 1;
1311                                 self.beam_hitlight[3] = 1;
1312                                 self.beam_muzzleeffect = -1; // particleeffectnum(EFFECT_GRENADE_MUZZLEFLASH);
1313                                 self.beam_muzzlelight[0] = 0;
1314                                 self.beam_muzzlelight[1] = 1;
1315                                 self.beam_muzzlelight[2] = 1;
1316                                 self.beam_muzzlelight[3] = 1;
1317                                 self.beam_image = "particles/lgbeam";
1318                                 if(self.beam_muzzleeffect >= 0)
1319                                 {
1320                                         setmodel(flash, "models/flash.md3");
1321                                         flash.alpha = self.beam_alpha;
1322                                         flash.colormod = self.beam_color;
1323                                         flash.scale = 0.5;
1324                                 }
1325                                 break;
1326                         }
1327                         case ARC_BT_HEAL:
1328                         {
1329                                 self.beam_color = '1 1 1';
1330                                 self.beam_alpha = 0.5;
1331                                 self.beam_thickness = 8;
1332                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL);
1333                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL_IMPACT);
1334                                 self.beam_hitlight[0] = 0;
1335                                 self.beam_hitlight[1] = 1;
1336                                 self.beam_hitlight[2] = 1;
1337                                 self.beam_hitlight[3] = 1;
1338                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1339                                 self.beam_muzzlelight[0] = 0;
1340                                 self.beam_muzzlelight[1] = 1;
1341                                 self.beam_muzzlelight[2] = 1;
1342                                 self.beam_muzzlelight[3] = 1;
1343                                 self.beam_image = "particles/lgbeam";
1344                                 if(self.beam_muzzleeffect >= 0)
1345                                 {
1346                                         setmodel(flash, "models/flash.md3");
1347                                         flash.alpha = self.beam_alpha;
1348                                         flash.colormod = self.beam_color;
1349                                         flash.scale = 0.5;
1350                                 }
1351                                 break;
1352                         }
1353                         case ARC_BT_HIT:
1354                         {
1355                                 self.beam_color = '1 1 1';
1356                                 self.beam_alpha = 0.5;
1357                                 self.beam_thickness = 8;
1358                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1359                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1360                                 self.beam_hitlight[0] = 20;
1361                                 self.beam_hitlight[1] = 1;
1362                                 self.beam_hitlight[2] = 0;
1363                                 self.beam_hitlight[3] = 0;
1364                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1365                                 self.beam_muzzlelight[0] = 50;
1366                                 self.beam_muzzlelight[1] = 1;
1367                                 self.beam_muzzlelight[2] = 0;
1368                                 self.beam_muzzlelight[3] = 0;
1369                                 self.beam_image = "particles/lgbeam";
1370                                 if(self.beam_muzzleeffect >= 0)
1371                                 {
1372                                         setmodel(flash, "models/flash.md3");
1373                                         flash.alpha = self.beam_alpha;
1374                                         flash.colormod = self.beam_color;
1375                                         flash.scale = 0.5;
1376                                 }
1377                                 break;
1378                         }
1379                         case ARC_BT_BURST_MISS:
1380                         {
1381                                 self.beam_color = '1 1 1';
1382                                 self.beam_alpha = 0.5;
1383                                 self.beam_thickness = 14;
1384                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1385                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1386                                 self.beam_hitlight[0] = 0;
1387                                 self.beam_hitlight[1] = 1;
1388                                 self.beam_hitlight[2] = 1;
1389                                 self.beam_hitlight[3] = 1;
1390                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1391                                 self.beam_muzzlelight[0] = 0;
1392                                 self.beam_muzzlelight[1] = 1;
1393                                 self.beam_muzzlelight[2] = 1;
1394                                 self.beam_muzzlelight[3] = 1;
1395                                 self.beam_image = "particles/lgbeam";
1396                                 if(self.beam_muzzleeffect >= 0)
1397                                 {
1398                                         setmodel(flash, "models/flash.md3");
1399                                         flash.alpha = self.beam_alpha;
1400                                         flash.colormod = self.beam_color;
1401                                         flash.scale = 0.5;
1402                                 }
1403                                 break;
1404                         }
1405                         case ARC_BT_BURST_WALL:
1406                         {
1407                                 self.beam_color = '1 1 1';
1408                                 self.beam_alpha = 0.5;
1409                                 self.beam_thickness = 14;
1410                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1411                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1412                                 self.beam_hitlight[0] = 0;
1413                                 self.beam_hitlight[1] = 1;
1414                                 self.beam_hitlight[2] = 1;
1415                                 self.beam_hitlight[3] = 1;
1416                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1417                                 self.beam_muzzlelight[0] = 0;
1418                                 self.beam_muzzlelight[1] = 1;
1419                                 self.beam_muzzlelight[2] = 1;
1420                                 self.beam_muzzlelight[3] = 1;
1421                                 self.beam_image = "particles/lgbeam";
1422                                 if(self.beam_muzzleeffect >= 0)
1423                                 {
1424                                         setmodel(flash, "models/flash.md3");
1425                                         flash.alpha = self.beam_alpha;
1426                                         flash.colormod = self.beam_color;
1427                                         flash.scale = 0.5;
1428                                 }
1429                                 break;
1430                         }
1431                         case ARC_BT_BURST_HEAL:
1432                         {
1433                                 self.beam_color = '1 1 1';
1434                                 self.beam_alpha = 0.5;
1435                                 self.beam_thickness = 14;
1436                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL);
1437                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL_IMPACT2);
1438                                 self.beam_hitlight[0] = 0;
1439                                 self.beam_hitlight[1] = 1;
1440                                 self.beam_hitlight[2] = 1;
1441                                 self.beam_hitlight[3] = 1;
1442                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1443                                 self.beam_muzzlelight[0] = 0;
1444                                 self.beam_muzzlelight[1] = 1;
1445                                 self.beam_muzzlelight[2] = 1;
1446                                 self.beam_muzzlelight[3] = 1;
1447                                 self.beam_image = "particles/lgbeam";
1448                                 if(self.beam_muzzleeffect >= 0)
1449                                 {
1450                                         setmodel(flash, "models/flash.md3");
1451                                         flash.alpha = self.beam_alpha;
1452                                         flash.colormod = self.beam_color;
1453                                         flash.scale = 0.5;
1454                                 }
1455                                 break;
1456                         }
1457                         case ARC_BT_BURST_HIT:
1458                         {
1459                                 self.beam_color = '1 1 1';
1460                                 self.beam_alpha = 0.5;
1461                                 self.beam_thickness = 14;
1462                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1463                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1464                                 self.beam_hitlight[0] = 0;
1465                                 self.beam_hitlight[1] = 1;
1466                                 self.beam_hitlight[2] = 1;
1467                                 self.beam_hitlight[3] = 1;
1468                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1469                                 self.beam_muzzlelight[0] = 0;
1470                                 self.beam_muzzlelight[1] = 1;
1471                                 self.beam_muzzlelight[2] = 1;
1472                                 self.beam_muzzlelight[3] = 1;
1473                                 self.beam_image = "particles/lgbeam";
1474                                 if(self.beam_muzzleeffect >= 0)
1475                                 {
1476                                         setmodel(flash, "models/flash.md3");
1477                                         flash.alpha = self.beam_alpha;
1478                                         flash.colormod = self.beam_color;
1479                                         flash.scale = 0.5;
1480                                 }
1481                                 break;
1482                         }
1483
1484                         // shouldn't be possible, but lets make it colorful if it does :D
1485                         default:
1486                         {
1487                                 self.beam_color = randomvec();
1488                                 self.beam_alpha = 1;
1489                                 self.beam_thickness = 8;
1490                                 self.beam_traileffect = false;
1491                                 self.beam_hiteffect = false;
1492                                 self.beam_hitlight[0] = 0;
1493                                 self.beam_hitlight[1] = 1;
1494                                 self.beam_hitlight[2] = 1;
1495                                 self.beam_hitlight[3] = 1;
1496                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1497                                 self.beam_muzzlelight[0] = 0;
1498                                 self.beam_muzzlelight[1] = 1;
1499                                 self.beam_muzzlelight[2] = 1;
1500                                 self.beam_muzzlelight[3] = 1;
1501                                 self.beam_image = "particles/lgbeam";
1502                                 if(self.beam_muzzleeffect >= 0)
1503                                 {
1504                                         setmodel(flash, "models/flash.md3");
1505                                         flash.alpha = self.beam_alpha;
1506                                         flash.colormod = self.beam_color;
1507                                         flash.scale = 0.5;
1508                                 }
1509                                 break;
1510                         }
1511                 }
1512         }
1513
1514         if(!self.beam_usevieworigin)
1515         {
1516                 InterpolateOrigin_Note();
1517         }
1518 }
1519
1520 bool W_Arc(int req)
1521 {SELFPARAM();
1522         switch(req)
1523         {
1524                 case WR_IMPACTEFFECT:
1525                 {
1526                         // todo
1527                         return true;
1528                 }
1529                 case WR_INIT:
1530                 {
1531                         precache_sound(W_Sound("arc_loop"));
1532                         return true;
1533                 }
1534                 case WR_ZOOMRETICLE:
1535                 {
1536                         // no weapon specific image for this weapon
1537                         return false;
1538                 }
1539         }
1540         return false;
1541 }
1542 #endif
1543 #endif