qcsrc/common/weapons/weapon/arc.qc

   1 #include "arc.qh"
   2
   3 #ifdef SVQC
   4 #include <common/gamemodes/gamemode/onslaught/sv_onslaught.qh>
   5 #include <common/gamemodes/gamemode/onslaught/sv_generator.qh>
   6
   7 bool W_Arc_Beam_Send(entity this, entity to, int sf)
   8 {
   9         WriteHeader(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
  10
  11         // Truncate information when this beam is displayed to the owner client
  12         // - The owner client has no use for beam start position or directions,
  13         //    it always figures this information out for itself with csqc code.
  14         // - Spectating the owner also truncates this information.
  15         float drawlocal = ((to == this.owner) || ((to.enemy == this.owner) && IS_SPEC(to)));
  16         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
  17
  18         WriteByte(MSG_ENTITY, sf);
  19         WriteByte(MSG_ENTITY, weaponslot(this.weaponentity_fld));
  20
  21         if(sf & ARC_SF_SETTINGS) // settings information
  22         {
  23                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
  24                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
  25                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
  26                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
  27                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
  28                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
  29
  30                 WriteByte(MSG_ENTITY, drawlocal);
  31                 WriteByte(MSG_ENTITY, etof(this.owner));
  32         }
  33         if(sf & ARC_SF_START) // starting location
  34         {
  35                 WriteVector(MSG_ENTITY, this.beam_start);
  36         }
  37         if(sf & ARC_SF_WANTDIR) // want/aim direction
  38         {
  39                 WriteVector(MSG_ENTITY, this.beam_wantdir);
  40         }
  41         if(sf & ARC_SF_BEAMDIR) // beam direction
  42         {
  43                 WriteAngle(MSG_ENTITY, this.beam_dir.x);
  44                 WriteAngle(MSG_ENTITY, this.beam_dir.y);
  45                 WriteAngle(MSG_ENTITY, this.beam_dir.z);
  46         }
  47         if(sf & ARC_SF_BEAMTYPE) // beam type
  48         {
  49                 WriteByte(MSG_ENTITY, this.beam_type);
  50         }
  51
  52         return true;
  53 }
  54
  55 void Reset_ArcBeam(entity player, vector forward)
  56 {
  57         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  58         {
  59                 .entity weaponentity = weaponentities[slot];
  60                 if(!player.(weaponentity).arc_beam)
  61                         continue;
  62                 player.(weaponentity).arc_beam.beam_dir = forward;
  63                 player.(weaponentity).arc_beam.beam_teleporttime = time;
  64         }
  65 }
  66
  67 float Arc_GetHeat_Percent(entity player, .entity weaponentity)
  68 {
  69         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
  70         {
  71                 player.arc_overheat = 0;
  72                 return 0;
  73         }
  74
  75         if ( player.(weaponentity).arc_beam )
  76                 return player.(weaponentity).arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
  77
  78         if ( player.arc_overheat > time )
  79         {
  80                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
  81                         * player.arc_cooldown;
  82         }
  83
  84         return 0;
  85 }
  86 void Arc_Player_SetHeat(entity player, .entity weaponentity)
  87 {
  88         player.(weaponentity).arc_heat_percent = Arc_GetHeat_Percent(player, weaponentity);
  89         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
  90 }
  91
  92 void W_Arc_Bolt_Explode(entity this, entity directhitentity)
  93 {
  94         this.event_damage = func_null;
  95         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, this.weaponentity_fld, directhitentity);
  96
  97         delete(this);
  98 }
  99
 100 void W_Arc_Bolt_Explode_use(entity this, entity actor, entity trigger)
 101 {
 102         W_Arc_Bolt_Explode(this, trigger);
 103 }
 104
 105 void W_Arc_Bolt_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 106 {
 107         if(GetResourceAmount(this, RESOURCE_HEALTH) <= 0)
 108                 return;
 109
 110         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1))
 111                 return; // g_projectiles_damage says to halt
 112
 113         TakeResource(this, RESOURCE_HEALTH, damage);
 114         this.angles = vectoangles(this.velocity);
 115
 116         if(GetResourceAmount(this, RESOURCE_HEALTH) <= 0)
 117                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 118 }
 119
 120 void W_Arc_Bolt_Touch(entity this, entity toucher)
 121 {
 122         PROJECTILE_TOUCH(this, toucher);
 123         this.use(this, NULL, toucher);
 124 }
 125
 126 void W_Arc_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity)
 127 {
 128         entity missile;
 129
 130         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(arc, bolt_ammo), weaponentity);
 131
 132         W_SetupShot(actor, weaponentity, false, 2, SND_LASERGUN_FIRE, CH_WEAPON_A, WEP_CVAR(arc, bolt_damage), WEP_ARC.m_id | HITTYPE_SECONDARY);
 133
 134         Send_Effect(EFFECT_ARC_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 135
 136         missile = new(missile);
 137         missile.owner = missile.realowner = actor;
 138         missile.bot_dodge = true;
 139         IL_PUSH(g_bot_dodge, missile);
 140         missile.bot_dodgerating = WEP_CVAR(arc, bolt_damage);
 141
 142         missile.takedamage = DAMAGE_YES;
 143         SetResourceAmountExplicit(missile, RESOURCE_HEALTH, WEP_CVAR(arc, bolt_health));
 144         missile.damageforcescale = WEP_CVAR(arc, bolt_damageforcescale);
 145         missile.event_damage = W_Arc_Bolt_Damage;
 146         missile.damagedbycontents = true;
 147         IL_PUSH(g_damagedbycontents, missile);
 148
 149         settouch(missile, W_Arc_Bolt_Touch);
 150         missile.use = W_Arc_Bolt_Explode_use;
 151         setthink(missile, adaptor_think2use_hittype_splash);
 152         missile.nextthink = time + WEP_CVAR(arc, bolt_lifetime);
 153         PROJECTILE_MAKETRIGGER(missile);
 154         missile.projectiledeathtype = WEP_ARC.m_id | HITTYPE_SECONDARY;
 155         missile.weaponentity_fld = weaponentity;
 156         setorigin(missile, w_shotorg);
 157         setsize(missile, '0 0 0', '0 0 0');
 158
 159         set_movetype(missile, MOVETYPE_FLY);
 160         W_SetupProjVelocity_PRE(missile, arc, bolt_);
 161
 162         missile.angles = vectoangles(missile.velocity);
 163         missile.flags = FL_PROJECTILE;
 164         missile.missile_flags = MIF_SPLASH;
 165
 166         CSQCProjectile(missile, true, PROJECTILE_ARC_BOLT, true);
 167
 168         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 169 }
 170
 171 void W_Arc_Beam_Think(entity this)
 172 {
 173         .entity weaponentity = this.weaponentity_fld;
 174         entity own = this.owner;
 175         if(this != own.(weaponentity).arc_beam)
 176         {
 177                 delete(this);
 178                 return;
 179         }
 180
 181         float burst = 0;
 182         if( (PHYS_INPUT_BUTTON_ATCK2(own) && !WEP_CVAR(arc, bolt)) || this.beam_bursting)
 183         {
 184                 if(!this.beam_bursting)
 185                         this.beam_bursting = true;
 186                 burst = ARC_BT_BURSTMASK;
 187         }
 188
 189         Weapon thiswep = WEP_ARC;
 190
 191         if(
 192                 !IS_PLAYER(own)
 193                 ||
 194                 IS_DEAD(own)
 195                 ||
 196                 !weapon_prepareattack_check(thiswep, own, weaponentity, this.beam_bursting, -1)
 197                 ||
 198                 own.(weaponentity).m_switchweapon != WEP_ARC
 199                 ||
 200                 (!PHYS_INPUT_BUTTON_ATCK(own) && !burst )
 201                 ||
 202                 own.vehicle
 203                 ||
 204                 (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max))
 205         )
 206         {
 207                 if ( WEP_CVAR(arc, cooldown) > 0 )
 208                 {
 209                         float cooldown_speed = 0;
 210                         if ( this.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 211                         {
 212                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 213                         }
 214                         else if ( !burst )
 215                         {
 216                                 cooldown_speed = this.beam_heat / WEP_CVAR(arc, beam_refire);
 217                         }
 218
 219                         if ( cooldown_speed )
 220                         {
 221                                 if ( WEP_CVAR(arc, cooldown_release) || (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max)) )
 222                                         own.arc_overheat = time + this.beam_heat / cooldown_speed;
 223                                 own.arc_cooldown = cooldown_speed;
 224                         }
 225
 226                         if ( WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max) )
 227                         {
 228                                 Send_Effect(EFFECT_ARC_OVERHEAT,
 229                                         this.beam_start, this.beam_wantdir, 1 );
 230                                 sound(this, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 231                         }
 232                 }
 233
 234                 if(this == own.(weaponentity).arc_beam) { own.(weaponentity).arc_beam = NULL; }
 235                 if(!thiswep.wr_checkammo1(thiswep, own, weaponentity) && !(own.items & IT_UNLIMITED_WEAPON_AMMO))
 236                 {
 237                         // note: this doesn't force the switch
 238                         W_SwitchToOtherWeapon(own, weaponentity);
 239                 }
 240                 own.(weaponentity).arc_BUTTON_ATCK_prev = false; // allow switching weapons
 241                 delete(this);
 242                 return;
 243         }
 244
 245         // decrease ammo
 246         float coefficient = frametime;
 247         if(!(own.items & IT_UNLIMITED_WEAPON_AMMO))
 248         {
 249                 float rootammo;
 250                 if(burst)
 251                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 252                 else
 253                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 254
 255                 if(rootammo)
 256                 {
 257                         coefficient = min(coefficient, GetResourceAmount(own, thiswep.ammo_type) / rootammo);
 258                         SetResourceAmount(own, thiswep.ammo_type, max(0, GetResourceAmount(own, thiswep.ammo_type) - (rootammo * frametime)));
 259                 }
 260         }
 261         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 262         this.beam_heat = min( WEP_CVAR(arc, overheat_max), this.beam_heat + heat_speed*frametime );
 263
 264         makevectors(own.v_angle);
 265
 266         W_SetupShot_Range(
 267                 own,
 268                 weaponentity,
 269                 true,
 270                 0,
 271                 SND_Null,
 272                 0,
 273                 WEP_CVAR(arc, beam_damage) * coefficient,
 274                 WEP_CVAR(arc, beam_range),
 275                 thiswep.m_id
 276         );
 277
 278         // After teleport, "lock" the beam until the teleport is confirmed.
 279         if (time < this.beam_teleporttime + ANTILAG_LATENCY(own)) {
 280                 w_shotdir = this.beam_dir;
 281         }
 282
 283         // network information: shot origin and want/aim direction
 284         if(this.beam_start != w_shotorg)
 285         {
 286                 this.SendFlags |= ARC_SF_START;
 287                 this.beam_start = w_shotorg;
 288         }
 289         if(this.beam_wantdir != w_shotdir)
 290         {
 291                 this.SendFlags |= ARC_SF_WANTDIR;
 292                 this.beam_wantdir = w_shotdir;
 293         }
 294
 295         if(!this.beam_initialized)
 296         {
 297                 this.beam_dir = w_shotdir;
 298                 this.beam_initialized = true;
 299         }
 300
 301         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 302         // idea: blend together this.beam_dir with the inverted direction the player is moving in
 303         // might have to make some special accomodation so that it only uses view_right and view_up
 304
 305         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 306
 307         float segments;
 308         if(this.beam_dir != w_shotdir)
 309         {
 310                 // calculate how much we're going to move the end of the beam to the want position
 311                 // WEAPONTODO (server and client):
 312                 // blendfactor never actually becomes 0 in this situation, which is a problem
 313                 // regarding precision... this means that this.beam_dir and w_shotdir approach
 314                 // eachother, however they never actually become the same value with this method.
 315                 // Perhaps we should do some form of rounding/snapping?
 316                 float angle = vlen(w_shotdir - this.beam_dir) * RAD2DEG;
 317                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 318                 {
 319                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 320                         float blendfactor = bound(
 321                                 0,
 322                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 323                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 324                         );
 325                         if(vdist(this.beam_dir - w_shotdir, <, 0.01))
 326                                 this.beam_dir = w_shotdir;
 327                         else
 328                                 this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 329                 }
 330                 else
 331                 {
 332                         // the radius is not too far yet, no worries :D
 333                         float blendfactor = bound(
 334                                 0,
 335                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 336                                 1
 337                         );
 338                         if(vdist(this.beam_dir - w_shotdir, <, 0.01))
 339                                 this.beam_dir = w_shotdir;
 340                         else
 341                                 this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 342                 }
 343
 344                 // network information: beam direction
 345                 this.SendFlags |= ARC_SF_BEAMDIR;
 346
 347                 // calculate how many segments are needed
 348                 float max_allowed_segments;
 349
 350                 if(WEP_CVAR(arc, beam_distancepersegment))
 351                 {
 352                         max_allowed_segments = min(
 353                                 ARC_MAX_SEGMENTS,
 354                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 355                         );
 356                 }
 357                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 358
 359                 if(WEP_CVAR(arc, beam_degreespersegment))
 360                 {
 361                         segments = bound(
 362                                 1,
 363                                 (
 364                                         min(
 365                                                 angle,
 366                                                 WEP_CVAR(arc, beam_maxangle)
 367                                         )
 368                                         /
 369                                         WEP_CVAR(arc, beam_degreespersegment)
 370                                 ),
 371                                 max_allowed_segments
 372                         );
 373                 }
 374                 else { segments = 1; }
 375         }
 376         else { segments = 1; }
 377
 378         vector beam_endpos = (w_shotorg + (this.beam_dir * WEP_CVAR(arc, beam_range)));
 379         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 380
 381         float i;
 382         float new_beam_type = 0;
 383         vector last_origin = w_shotorg;
 384         for(i = 1; i <= segments; ++i)
 385         {
 386                 // WEAPONTODO (client):
 387                 // In order to do nice fading and pointing on the starting segment, we must always
 388                 // have that drawn as a separate triangle... However, that is difficult to do when
 389                 // keeping in mind the above problems and also optimizing the amount of segments
 390                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 391
 392                 vector new_origin = bezier_quadratic_getpoint(
 393                         w_shotorg,
 394                         beam_controlpoint,
 395                         beam_endpos,
 396                         i / segments);
 397                 vector new_dir = normalize(new_origin - last_origin);
 398
 399                 WarpZone_traceline_antilag(
 400                         own,
 401                         last_origin,
 402                         new_origin,
 403                         MOVE_NORMAL,
 404                         own,
 405                         ANTILAG_LATENCY(own)
 406                 );
 407
 408                 // Do all the transforms for warpzones right now, as we already
 409                 // "are" in the post-trace system (if we hit a player, that's
 410                 // always BEHIND the last passed wz).
 411                 last_origin = trace_endpos;
 412                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 413                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 414                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 415                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 416
 417                 bool is_player = (
 418                         IS_PLAYER(trace_ent)
 419                         ||
 420                         trace_ent.classname == "body"
 421                         ||
 422                         IS_MONSTER(trace_ent)
 423                 );
 424
 425                 if(trace_ent)
 426                 {
 427                         if(SAME_TEAM(own, trace_ent))
 428                         {
 429                                 float roothealth = ((burst) ? WEP_CVAR(arc, burst_healing_hps) : WEP_CVAR(arc, beam_healing_hps));
 430                                 float rootarmor = ((burst) ? WEP_CVAR(arc, burst_healing_aps) : WEP_CVAR(arc, beam_healing_aps));
 431                                 float hplimit = ((IS_PLAYER(trace_ent)) ? WEP_CVAR(arc, beam_healing_hmax) : RESOURCE_LIMIT_NONE);
 432                                 Heal(trace_ent, own, (roothealth * coefficient), hplimit);
 433                                 if(IS_PLAYER(trace_ent) && rootarmor)
 434                                 {
 435                                         if(GetResourceAmount(trace_ent, RESOURCE_ARMOR) <= WEP_CVAR(arc, beam_healing_amax))
 436                                         {
 437                                                 GiveResourceWithLimit(trace_ent, RESOURCE_ARMOR, (rootarmor * coefficient), WEP_CVAR(arc, beam_healing_amax));
 438                                                 trace_ent.pauserotarmor_finished = max(
 439                                                         trace_ent.pauserotarmor_finished,
 440                                                         time + autocvar_g_balance_pause_armor_rot
 441                                                 );
 442                                         }
 443                                 }
 444                                 if(roothealth || rootarmor)
 445                                         new_beam_type = ARC_BT_HEAL;
 446                         }
 447                         else if(trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 448                         {
 449                                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 450                                 // NO. trace_endpos should be just fine. If not,
 451                                 // that's an engine bug that needs proper debugging.
 452                                 vector hitorigin = trace_endpos;
 453
 454                                 float falloff = ExponentialFalloff(
 455                                         WEP_CVAR(arc, beam_falloff_mindist),
 456                                         WEP_CVAR(arc, beam_falloff_maxdist),
 457                                         WEP_CVAR(arc, beam_falloff_halflifedist),
 458                                         vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 459                                 );
 460
 461                                 float rootdamage;
 462                                 if(is_player)
 463                                 {
 464                                         if(burst)
 465                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 466                                         else
 467                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 468                                 }
 469                                 else
 470                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 471
 472                                 if(accuracy_isgooddamage(own, trace_ent))
 473                                 {
 474                                         accuracy_add(
 475                                                 own,
 476                                                 WEP_ARC.m_id,
 477                                                 0,
 478                                                 rootdamage * coefficient * falloff
 479                                         );
 480                                 }
 481
 482                                 Damage(
 483                                         trace_ent,
 484                                         own,
 485                                         own,
 486                                         rootdamage * coefficient * falloff,
 487                                         WEP_ARC.m_id,
 488                                         weaponentity,
 489                                         hitorigin,
 490                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 491                                 );
 492
 493                                 new_beam_type = ARC_BT_HIT;
 494                         }
 495                         break;
 496                 }
 497                 else if(trace_fraction != 1)
 498                 {
 499                         // we collided with geometry
 500                         new_beam_type = ARC_BT_WALL;
 501                         break;
 502                 }
 503         }
 504
 505         // te_explosion(trace_endpos);
 506
 507         // if we're bursting, use burst visual effects
 508         new_beam_type |= burst;
 509
 510         // network information: beam type
 511         if(new_beam_type != this.beam_type)
 512         {
 513                 this.SendFlags |= ARC_SF_BEAMTYPE;
 514                 this.beam_type = new_beam_type;
 515         }
 516
 517         own.(weaponentity).beam_prev = time;
 518         this.nextthink = time;
 519 }
 520
 521 void W_Arc_Beam(float burst, entity actor, .entity weaponentity)
 522 {
 523
 524         // only play fire sound if 1 sec has passed since player let go the fire button
 525         if(time - actor.(weaponentity).beam_prev > 1)
 526                 sound(actor, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 527
 528         entity beam = actor.(weaponentity).arc_beam = new(W_Arc_Beam);
 529         beam.weaponentity_fld = weaponentity;
 530         beam.solid = SOLID_NOT;
 531         setthink(beam, W_Arc_Beam_Think);
 532         beam.owner = actor;
 533         set_movetype(beam, MOVETYPE_NONE);
 534         beam.bot_dodge = true;
 535         IL_PUSH(g_bot_dodge, beam);
 536         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 537         beam.beam_bursting = burst;
 538         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 539
 540         getthink(beam)(beam);
 541 }
 542 void Arc_Smoke(entity actor, .entity weaponentity)
 543 {
 544         makevectors(actor.v_angle);
 545         W_SetupShot_Range(actor,weaponentity,false,0,SND_Null,0,0,0,WEP_ARC.m_id); // TODO: probably doesn't need deathtype, since this is just a prefire effect
 546
 547         vector smoke_origin = w_shotorg + actor.velocity*frametime;
 548         if ( actor.arc_overheat > time )
 549         {
 550                 if ( random() < actor.(weaponentity).arc_heat_percent )
 551                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 552                 if ( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) )
 553                 {
 554                         Send_Effect(EFFECT_ARC_OVERHEAT_FIRE, smoke_origin, w_shotdir, 1 );
 555                         if ( !actor.arc_smoke_sound )
 556                         {
 557                                 actor.arc_smoke_sound = 1;
 558                                 sound(actor, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 559                         }
 560                 }
 561         }
 562         else if ( actor.(weaponentity).arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 563                         actor.(weaponentity).arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 564         {
 565                 if ( random() < (actor.(weaponentity).arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 566                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 567                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 568         }
 569
 570         if (  actor.arc_smoke_sound && ( actor.arc_overheat <= time ||
 571                 !( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) ) ) || actor.(weaponentity).m_switchweapon != WEP_ARC )
 572         {
 573                 actor.arc_smoke_sound = 0;
 574                 sound(actor, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 575         }
 576 }
 577
 578 METHOD(Arc, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 579 {
 580     if(WEP_CVAR(arc, beam_botaimspeed))
 581     {
 582         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 583                 actor,
 584                 weaponentity,
 585             WEP_CVAR(arc, beam_botaimspeed),
 586             0,
 587             WEP_CVAR(arc, beam_botaimlifetime),
 588             false
 589         );
 590     }
 591     else
 592     {
 593         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 594                 actor,
 595                 weaponentity,
 596             1000000,
 597             0,
 598             0.001,
 599             false
 600         );
 601     }
 602 }
 603 METHOD(Arc, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 604 {
 605     Arc_Player_SetHeat(actor, weaponentity);
 606     Arc_Smoke(actor, weaponentity);
 607
 608     bool beam_fire2 = ((fire & 2) && !WEP_CVAR(arc, bolt));
 609
 610     if (time >= actor.arc_overheat)
 611     if ((fire & 1) || beam_fire2 || actor.(weaponentity).arc_beam.beam_bursting)
 612     {
 613
 614         if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 615         {
 616             #if 0
 617             if(actor.animstate_startframe == actor.anim_shoot.x && actor.animstate_numframes == actor.anim_shoot.y)
 618                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 619             else
 620             #endif
 621                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), w_ready);
 622         }
 623
 624         if((!actor.(weaponentity).arc_beam) || wasfreed(actor.(weaponentity).arc_beam))
 625         {
 626             if(weapon_prepareattack(thiswep, actor, weaponentity, boolean(beam_fire2), 0))
 627             {
 628                 W_Arc_Beam(boolean(beam_fire2), actor, weaponentity);
 629
 630                 if(!actor.(weaponentity).arc_BUTTON_ATCK_prev)
 631                 {
 632                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 633                     actor.(weaponentity).arc_BUTTON_ATCK_prev = true;
 634                 }
 635             }
 636         }
 637
 638         return;
 639     }
 640     else if(fire & 2)
 641     {
 642         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR(arc, bolt_refire)))
 643         {
 644             W_Arc_Attack_Bolt(thiswep, actor, weaponentity);
 645             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), w_ready);
 646         }
 647     }
 648
 649     if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 650     {
 651         int slot = weaponslot(weaponentity);
 652         sound(actor, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 653         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 654         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor(actor);
 655     }
 656     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 657
 658     #if 0
 659     if(fire & 2)
 660     if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_arc_secondary_refire))
 661     {
 662         W_Arc_Attack2();
 663         actor.arc_count = autocvar_g_balance_arc_secondary_count;
 664         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 665         actor.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor(actor);
 666     }
 667     #endif
 668 }
 669 METHOD(Arc, wr_init, void(entity thiswep))
 670 {
 671     if(!arc_shotorigin[0])
 672     {
 673         arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 674         arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 675         arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 676         arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 677     }
 678 }
 679 METHOD(Arc, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 680 {
 681     return ((!WEP_CVAR(arc, beam_ammo)) || (GetResourceAmount(actor, thiswep.ammo_type) > 0));
 682 }
 683 METHOD(Arc, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 684 {
 685     if(WEP_CVAR(arc, bolt))
 686     {
 687         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(arc, bolt_ammo);
 688         ammo_amount += actor.(weaponentity).(weapon_load[WEP_ARC.m_id]) >= WEP_CVAR(arc, bolt_ammo);
 689         return ammo_amount;
 690     }
 691     else
 692         return WEP_CVAR(arc, overheat_max) > 0 &&
 693             ((!WEP_CVAR(arc, burst_ammo)) || (GetResourceAmount(actor, thiswep.ammo_type) > 0));
 694 }
 695 METHOD(Arc, wr_killmessage, Notification(entity thiswep))
 696 {
 697     if(w_deathtype & HITTYPE_SECONDARY)
 698         return WEAPON_ARC_MURDER_SPRAY;
 699     else
 700         return WEAPON_ARC_MURDER;
 701 }
 702 METHOD(Arc, wr_drop, void(entity thiswep, entity actor, .entity weaponentity))
 703 {
 704     weapon_dropevent_item.arc_overheat = actor.arc_overheat;
 705     weapon_dropevent_item.arc_cooldown = actor.arc_cooldown;
 706     actor.arc_overheat = 0;
 707     actor.arc_cooldown = 0;
 708     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 709 }
 710 METHOD(Arc, wr_pickup, void(entity thiswep, entity actor, .entity weaponentity))
 711 {
 712     if ( !client_hasweapon(actor, thiswep, weaponentity, false, false) &&
 713         weapon_dropevent_item.arc_overheat > time )
 714     {
 715         actor.arc_overheat = weapon_dropevent_item.arc_overheat;
 716         actor.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 717     }
 718 }
 719 METHOD(Arc, wr_resetplayer, void(entity thiswep, entity actor))
 720 {
 721     actor.arc_overheat = 0;
 722     actor.arc_cooldown = 0;
 723     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 724     {
 725         .entity weaponentity = weaponentities[slot];
 726         actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 727     }
 728 }
 729 METHOD(Arc, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
 730 {
 731     actor.arc_overheat = 0;
 732     actor.arc_cooldown = 0;
 733     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 734 }
 735 #endif
 736 #ifdef CSQC
 737 bool autocvar_cl_arcbeam_teamcolor = true;
 738 bool autocvar_cl_arcbeam_simple = true;
 739
 740 .int beam_slot;
 741
 742 METHOD(Arc, wr_impacteffect, void(entity thiswep, entity actor))
 743 {
 744     if(w_deathtype & HITTYPE_SECONDARY)
 745     {
 746         vector org2;
 747         org2 = w_org + w_backoff * 6;
 748         pointparticles(EFFECT_ARC_BOLT_EXPLODE, org2, w_backoff * 1000, 1);
 749         if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 750     }
 751 }
 752
 753 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 754 {
 755         entity beam = Draw_ArcBeam_callback_entity;
 756         vector transformed_view_org;
 757         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 758
 759         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 760         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 761         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 762
 763         vector hitorigin;
 764
 765         // draw segment
 766         #if 0
 767         if(trace_fraction != 1)
 768         {
 769                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 770                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 771                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 772         }
 773         else
 774         {
 775                 hitorigin = hit;
 776         }
 777         #else
 778         hitorigin = hit;
 779         #endif
 780
 781         // decide upon thickness
 782         float thickness = beam.beam_thickness;
 783
 784         // draw primary beam render
 785         vector top    = hitorigin + (thickdir * thickness);
 786         vector bottom = hitorigin - (thickdir * thickness);
 787
 788         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 789         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 790
 791         if(autocvar_cl_arcbeam_simple)
 792                 Draw_CylindricLine(start, end, thickness, beam.beam_image, 0.25, -time * 3, beam.beam_color, beam.beam_alpha, DRAWFLAG_NORMAL, transformed_view_org);
 793         else
 794         {
 795                 R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 796                 R_PolygonVertex(
 797                         top,
 798                         '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 799                         beam.beam_color,
 800                         beam.beam_alpha
 801                 );
 802                 R_PolygonVertex(
 803                         last_top,
 804                         '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 805                         beam.beam_color,
 806                         beam.beam_alpha
 807                 );
 808                 R_PolygonVertex(
 809                         last_bottom,
 810                         '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 811                         beam.beam_color,
 812                         beam.beam_alpha
 813                 );
 814                 R_PolygonVertex(
 815                         bottom,
 816                         '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 817                         beam.beam_color,
 818                         beam.beam_alpha
 819                 );
 820                 R_EndPolygon();
 821         }
 822
 823         // draw trailing particles
 824         // NOTES:
 825         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 826         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 827         if(beam.beam_traileffect)
 828         {
 829                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 830         }
 831
 832         // set up for the next
 833         Draw_ArcBeam_callback_last_thickness = thickness;
 834         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 835         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 836 }
 837
 838 void Reset_ArcBeam()
 839 {
 840         entity e;
 841         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 842                 e.beam_initialized = false;
 843         }
 844         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 845                 e.beam_initialized = false;
 846         }
 847 }
 848
 849 void Draw_ArcBeam(entity this)
 850 {
 851         float dt = time - this.move_time;
 852         this.move_time = time;
 853         if(dt <= 0) { return; }
 854
 855         if(!this.beam_usevieworigin)
 856         {
 857                 InterpolateOrigin_Do(this);
 858         }
 859
 860         // origin = beam starting origin
 861         // v_angle = wanted/aim direction
 862         // angles = current direction of beam
 863
 864         vector start_pos;
 865         vector wantdir; //= view_forward;
 866         vector beamdir; //= this.beam_dir;
 867
 868         float segments;
 869         if(this.beam_usevieworigin)
 870         {
 871                 // WEAPONTODO:
 872                 // Currently we have to replicate nearly the same method of figuring
 873                 // out the shotdir that the server does... Ideally in the future we
 874                 // should be able to acquire this from a generalized function built
 875                 // into a weapon system for client code.
 876
 877                 // find where we are aiming
 878                 makevectors(((autocvar_chase_active) ? warpzone_save_view_angles : view_angles));
 879                 vector forward = v_forward;
 880                 vector right = v_right;
 881                 vector up = v_up;
 882                 entity wepent = viewmodels[this.beam_slot];
 883
 884                 if(autocvar_chase_active)
 885                         this.beam_usevieworigin = 1;
 886                 else
 887                         this.beam_usevieworigin = 2;
 888
 889                 // decide upon start position
 890                 if(this.beam_usevieworigin == 2)
 891                         { start_pos = warpzone_save_view_origin; }
 892                 else if(csqcplayer)
 893                         { start_pos = csqcplayer.origin + csqcplayer.view_ofs; }
 894                 else
 895                         { start_pos = this.origin; }
 896
 897                 int v_shot_idx;  // used later
 898                 (v_shot_idx = gettagindex(wepent, "shot")) || (v_shot_idx = gettagindex(wepent, "tag_shot"));
 899                 if(v_shot_idx && this.beam_usevieworigin == 2)
 900                         start_pos = gettaginfo(wepent, v_shot_idx) - '0 0 2';
 901
 902                 // trace forward with an estimation
 903                 WarpZone_TraceLine(
 904                         start_pos,
 905                         start_pos + forward * this.beam_range,
 906                         MOVE_NOMONSTERS,
 907                         this
 908                 );
 909
 910                 // untransform in case our trace went through a warpzone
 911                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 912
 913                 // un-adjust trueaim if shotend is too close
 914                 if(vdist(end_pos - start_pos, <, g_trueaim_minrange))
 915                         end_pos = start_pos + (forward * g_trueaim_minrange);
 916
 917                 // move shot origin to the actual gun muzzle origin
 918                 vector origin_offset = '0 0 0';
 919                 if(!v_shot_idx || this.beam_usevieworigin != 2)
 920                 {
 921                         this.beam_shotorigin = wepent.movedir;
 922                         origin_offset =
 923                                  right * -this.beam_shotorigin.y
 924                                 + up * this.beam_shotorigin.z;
 925                 }
 926                 else
 927                         this.beam_shotorigin = '0 0 0';
 928
 929                 start_pos = start_pos + origin_offset;
 930
 931                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 932                 traceline(start_pos, start_pos + forward * this.beam_shotorigin.x, MOVE_NORMAL, this);
 933                 start_pos = trace_endpos;
 934
 935                 // calculate the aim direction now
 936                 wantdir = normalize(end_pos - start_pos);
 937
 938                 if(!this.beam_initialized)
 939                 {
 940                         this.beam_dir = wantdir;
 941                         this.beam_initialized = true;
 942                 }
 943
 944                 if(this.beam_dir != wantdir)
 945                 {
 946                         // calculate how much we're going to move the end of the beam to the want position
 947                         // WEAPONTODO (server and client):
 948                         // blendfactor never actually becomes 0 in this situation, which is a problem
 949                         // regarding precision... this means that this.beam_dir and w_shotdir approach
 950                         // eachother, however they never actually become the same value with this method.
 951                         // Perhaps we should do some form of rounding/snapping?
 952                         float angle = vlen(wantdir - this.beam_dir) * RAD2DEG;
 953                         if(angle && (angle > this.beam_maxangle))
 954                         {
 955                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 956                                 float blendfactor = bound(
 957                                         0,
 958                                         (1 - (this.beam_returnspeed * frametime)),
 959                                         min(this.beam_maxangle / angle, 1)
 960                                 );
 961                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 962                         }
 963                         else
 964                         {
 965                                 // the radius is not too far yet, no worries :D
 966                                 float blendfactor = bound(
 967                                         0,
 968                                         (1 - (this.beam_returnspeed * frametime)),
 969                                         1
 970                                 );
 971                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 972                         }
 973
 974                         // calculate how many segments are needed
 975                         float max_allowed_segments;
 976
 977                         if(this.beam_distancepersegment)
 978                         {
 979                                 max_allowed_segments = min(
 980                                         ARC_MAX_SEGMENTS,
 981                                         1 + (vlen(wantdir / this.beam_distancepersegment))
 982                                 );
 983                         }
 984                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 985
 986                         if(this.beam_degreespersegment)
 987                         {
 988                                 segments = bound(
 989                                         1,
 990                                         (
 991                                                 min(
 992                                                         angle,
 993                                                         this.beam_maxangle
 994                                                 )
 995                                                 /
 996                                                 this.beam_degreespersegment
 997                                         ),
 998                                         max_allowed_segments
 999                                 );
1000                         }
1001                         else { segments = 1; }
1002                 }
1003                 else { segments = 1; }
1004
1005                 // set the beam direction which the rest of the code will refer to
1006                 beamdir = this.beam_dir;
1007
1008                 // finally, set this.angles to the proper direction so that muzzle attachment points in proper direction
1009                 this.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1010         }
1011         else
1012         {
1013                 // set the values from the provided info from the networked entity
1014                 start_pos = this.origin;
1015                 wantdir = this.v_angle;
1016                 beamdir = this.angles;
1017
1018                 if(beamdir != wantdir)
1019                 {
1020                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1021
1022                         // calculate how many segments are needed
1023                         float max_allowed_segments;
1024
1025                         if(this.beam_distancepersegment)
1026                         {
1027                                 max_allowed_segments = min(
1028                                         ARC_MAX_SEGMENTS,
1029                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1030                                 );
1031                         }
1032                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1033
1034                         if(this.beam_degreespersegment)
1035                         {
1036                                 segments = bound(
1037                                         1,
1038                                         (
1039                                                 min(
1040                                                         angle,
1041                                                         this.beam_maxangle
1042                                                 )
1043                                                 /
1044                                                 this.beam_degreespersegment
1045                                         ),
1046                                         max_allowed_segments
1047                                 );
1048                         }
1049                         else { segments = 1; }
1050                 }
1051                 else { segments = 1; }
1052         }
1053
1054         setorigin(this, start_pos);
1055         this.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1056
1057         vector beam_endpos = (start_pos + (beamdir * this.beam_range));
1058         vector beam_controlpoint = start_pos + wantdir * (this.beam_range * (1 - this.beam_tightness));
1059
1060         Draw_ArcBeam_callback_entity = this;
1061         Draw_ArcBeam_callback_last_thickness = 0;
1062         Draw_ArcBeam_callback_last_top = start_pos;
1063         Draw_ArcBeam_callback_last_bottom = start_pos;
1064
1065         vector last_origin = start_pos;
1066         vector original_start_pos = start_pos;
1067
1068         float i;
1069         for(i = 1; i <= segments; ++i)
1070         {
1071                 // WEAPONTODO (client):
1072                 // In order to do nice fading and pointing on the starting segment, we must always
1073                 // have that drawn as a separate triangle... However, that is difficult to do when
1074                 // keeping in mind the above problems and also optimizing the amount of segments
1075                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1076
1077                 vector new_origin = bezier_quadratic_getpoint(
1078                         start_pos,
1079                         beam_controlpoint,
1080                         beam_endpos,
1081                         i / segments);
1082
1083                 WarpZone_TraceBox_ThroughZone(
1084                         last_origin,
1085                         '0 0 0',
1086                         '0 0 0',
1087                         new_origin,
1088                         MOVE_NORMAL,
1089                         NULL,
1090                         NULL,
1091                         Draw_ArcBeam_callback
1092                 );
1093
1094                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1095                 // system (if we hit a player, that's always BEHIND the last passed wz).
1096                 last_origin = trace_endpos;
1097                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1098                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1099                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1100                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1101                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1102                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1103
1104                 if(trace_fraction < 1) { break; }
1105         }
1106
1107         // visual effects for startpoint and endpoint
1108         if(this.beam_hiteffect)
1109         {
1110                 // FIXME we really should do this on the server so it actually
1111                 // matches gameplay. What this client side stuff is doing is no
1112                 // more than guesswork.
1113                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1114                 pointparticles(
1115                         this.beam_hiteffect,
1116                         last_origin,
1117                         beamdir * -1,
1118                         frametime * 2
1119                 );
1120         }
1121         if(this.beam_hitlight[0])
1122         {
1123                 adddynamiclight(
1124                         last_origin,
1125                         this.beam_hitlight[0],
1126                         vec3(
1127                                 this.beam_hitlight[1],
1128                                 this.beam_hitlight[2],
1129                                 this.beam_hitlight[3]
1130                         )
1131                 );
1132         }
1133         if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1134         {
1135                 pointparticles(
1136                         this.beam_muzzleeffect,
1137                         original_start_pos + wantdir * 20,
1138                         wantdir * 1000,
1139                         frametime * 0.1
1140                 );
1141         }
1142         if(this.beam_muzzlelight[0])
1143         {
1144                 adddynamiclight(
1145                         original_start_pos + wantdir * 20,
1146                         this.beam_muzzlelight[0],
1147                         vec3(
1148                                 this.beam_muzzlelight[1],
1149                                 this.beam_muzzlelight[2],
1150                                 this.beam_muzzlelight[3]
1151                         )
1152                 );
1153         }
1154
1155         // cleanup
1156         Draw_ArcBeam_callback_entity = NULL;
1157         Draw_ArcBeam_callback_last_thickness = 0;
1158         Draw_ArcBeam_callback_last_top = '0 0 0';
1159         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1160 }
1161
1162 void Remove_ArcBeam(entity this)
1163 {
1164         delete(this.beam_muzzleentity);
1165         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1166 }
1167
1168 NET_HANDLE(ENT_CLIENT_ARC_BEAM, bool isnew)
1169 {
1170         int sf = ReadByte();
1171         int slot = ReadByte();
1172         entity flash;
1173
1174         this.beam_slot = slot;
1175
1176         if(isnew)
1177         {
1178                 int gunalign = W_GunAlign(viewmodels[slot], STAT(GUNALIGN)) - 1;
1179
1180                 this.beam_shotorigin = arc_shotorigin[gunalign]; // get a starting point
1181
1182                 // set other main attributes of the beam
1183                 this.draw = Draw_ArcBeam;
1184                 IL_PUSH(g_drawables, this);
1185                 this.entremove = Remove_ArcBeam;
1186                 this.move_time = time;
1187                 loopsound(this, CH_SHOTS_SINGLE, SND_ARC_LOOP, VOL_BASE, ATTEN_NORM);
1188
1189                 flash = spawn();
1190                 flash.owner = this;
1191                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1192                 flash.drawmask = MASK_NORMAL;
1193                 flash.solid = SOLID_NOT;
1194                 flash.avelocity_z = 5000;
1195                 setattachment(flash, this, "");
1196                 setorigin(flash, '0 0 0');
1197
1198                 this.beam_muzzleentity = flash;
1199         }
1200         else
1201         {
1202                 flash = this.beam_muzzleentity;
1203         }
1204
1205         if(sf & ARC_SF_SETTINGS) // settings information
1206         {
1207                 this.beam_degreespersegment = ReadShort();
1208                 this.beam_distancepersegment = ReadShort();
1209                 this.beam_maxangle = ReadShort();
1210                 this.beam_range = ReadCoord();
1211                 this.beam_returnspeed = ReadShort();
1212                 this.beam_tightness = (ReadByte() / 10);
1213
1214                 if(ReadByte())
1215                 {
1216                         if(autocvar_chase_active)
1217                                 { this.beam_usevieworigin = 1; }
1218                         else // use view origin
1219                                 { this.beam_usevieworigin = 2; }
1220                 }
1221                 else
1222                 {
1223                         this.beam_usevieworigin = 0;
1224                 }
1225
1226                 this.sv_entnum = ReadByte();
1227         }
1228
1229         if(!this.beam_usevieworigin)
1230         {
1231                 // this.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1232                 this.iflags = IFLAG_ORIGIN;
1233
1234                 InterpolateOrigin_Undo(this);
1235         }
1236
1237         if(sf & ARC_SF_START) // starting location
1238         {
1239                 this.origin = ReadVector();
1240         }
1241         else if(this.beam_usevieworigin) // infer the location from player location
1242         {
1243                 if(this.beam_usevieworigin == 2)
1244                 {
1245                         // use view origin
1246                         this.origin = view_origin;
1247                 }
1248                 else
1249                 {
1250                         // use player origin so that third person display still works
1251                         this.origin = entcs_receiver(player_localnum).origin + ('0 0 1' * STAT(VIEWHEIGHT));
1252                 }
1253         }
1254
1255         setorigin(this, this.origin);
1256
1257         if(sf & ARC_SF_WANTDIR) // want/aim direction
1258         {
1259                 this.v_angle = ReadVector();
1260         }
1261
1262         if(sf & ARC_SF_BEAMDIR) // beam direction
1263         {
1264                 this.angles_x = ReadAngle();
1265                 this.angles_y = ReadAngle();
1266                 this.angles_z = ReadAngle();
1267         }
1268
1269         if(sf & ARC_SF_BEAMTYPE) // beam type
1270         {
1271                 this.beam_type = ReadByte();
1272
1273                 vector beamcolor = ((autocvar_cl_arcbeam_teamcolor) ? colormapPaletteColor(entcs_GetClientColors(this.sv_entnum - 1) & 0x0F, true) : '1 1 1');
1274                 switch(this.beam_type)
1275                 {
1276                         case ARC_BT_MISS:
1277                         {
1278                                 this.beam_color = beamcolor;
1279                                 this.beam_alpha = 0.5;
1280                                 this.beam_thickness = 8;
1281                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1282                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1283                                 this.beam_hitlight[0] = 0;
1284                                 this.beam_hitlight[1] = 1;
1285                                 this.beam_hitlight[2] = 1;
1286                                 this.beam_hitlight[3] = 1;
1287                                 this.beam_muzzleeffect = EFFECT_Null;
1288                                 this.beam_muzzlelight[0] = 0;
1289                                 this.beam_muzzlelight[1] = 1;
1290                                 this.beam_muzzlelight[2] = 1;
1291                                 this.beam_muzzlelight[3] = 1;
1292                                 this.beam_image = "particles/lgbeam";
1293                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1294                                 {
1295                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1296                                         flash.alpha = this.beam_alpha;
1297                                         flash.colormod = this.beam_color;
1298                                         flash.scale = 0.35;
1299                                 }
1300                                 break;
1301                         }
1302                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1303                         {
1304                                 this.beam_color = beamcolor;
1305                                 this.beam_alpha = 0.5;
1306                                 this.beam_thickness = 8;
1307                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1308                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1309                                 this.beam_hitlight[0] = 0;
1310                                 this.beam_hitlight[1] = 1;
1311                                 this.beam_hitlight[2] = 1;
1312                                 this.beam_hitlight[3] = 1;
1313                                 this.beam_muzzleeffect = EFFECT_Null; // (EFFECT_GRENADE_MUZZLEFLASH);
1314                                 this.beam_muzzlelight[0] = 0;
1315                                 this.beam_muzzlelight[1] = 1;
1316                                 this.beam_muzzlelight[2] = 1;
1317                                 this.beam_muzzlelight[3] = 1;
1318                                 this.beam_image = "particles/lgbeam";
1319                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1320                                 {
1321                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1322                                         flash.alpha = this.beam_alpha;
1323                                         flash.colormod = this.beam_color;
1324                                         flash.scale = 0.35;
1325                                 }
1326                                 break;
1327                         }
1328                         case ARC_BT_HEAL:
1329                         {
1330                                 this.beam_color = beamcolor;
1331                                 this.beam_alpha = 0.5;
1332                                 this.beam_thickness = 8;
1333                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1334                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT);
1335                                 this.beam_hitlight[0] = 0;
1336                                 this.beam_hitlight[1] = 1;
1337                                 this.beam_hitlight[2] = 1;
1338                                 this.beam_hitlight[3] = 1;
1339                                 this.beam_muzzleeffect = EFFECT_Null;
1340                                 this.beam_muzzlelight[0] = 0;
1341                                 this.beam_muzzlelight[1] = 1;
1342                                 this.beam_muzzlelight[2] = 1;
1343                                 this.beam_muzzlelight[3] = 1;
1344                                 this.beam_image = "particles/lgbeam";
1345                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1346                                 {
1347                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1348                                         flash.alpha = this.beam_alpha;
1349                                         flash.colormod = this.beam_color;
1350                                         flash.scale = 0.35;
1351                                 }
1352                                 break;
1353                         }
1354                         case ARC_BT_HIT:
1355                         {
1356                                 this.beam_color = beamcolor;
1357                                 this.beam_alpha = 0.5;
1358                                 this.beam_thickness = 8;
1359                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1360                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1361                                 this.beam_hitlight[0] = 20;
1362                                 this.beam_hitlight[1] = 1;
1363                                 this.beam_hitlight[2] = 0;
1364                                 this.beam_hitlight[3] = 0;
1365                                 this.beam_muzzleeffect = EFFECT_Null;
1366                                 this.beam_muzzlelight[0] = 50;
1367                                 this.beam_muzzlelight[1] = 1;
1368                                 this.beam_muzzlelight[2] = 0;
1369                                 this.beam_muzzlelight[3] = 0;
1370                                 this.beam_image = "particles/lgbeam";
1371                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1372                                 {
1373                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1374                                         flash.alpha = this.beam_alpha;
1375                                         flash.colormod = this.beam_color;
1376                                         flash.scale = 0.35;
1377                                 }
1378                                 break;
1379                         }
1380                         case ARC_BT_BURST_MISS:
1381                         {
1382                                 this.beam_color = beamcolor;
1383                                 this.beam_alpha = 0.5;
1384                                 this.beam_thickness = 14;
1385                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1386                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1387                                 this.beam_hitlight[0] = 0;
1388                                 this.beam_hitlight[1] = 1;
1389                                 this.beam_hitlight[2] = 1;
1390                                 this.beam_hitlight[3] = 1;
1391                                 this.beam_muzzleeffect = EFFECT_Null;
1392                                 this.beam_muzzlelight[0] = 0;
1393                                 this.beam_muzzlelight[1] = 1;
1394                                 this.beam_muzzlelight[2] = 1;
1395                                 this.beam_muzzlelight[3] = 1;
1396                                 this.beam_image = "particles/lgbeam";
1397                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1398                                 {
1399                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1400                                         flash.alpha = this.beam_alpha;
1401                                         flash.colormod = this.beam_color;
1402                                         flash.scale = 0.35;
1403                                 }
1404                                 break;
1405                         }
1406                         case ARC_BT_BURST_WALL:
1407                         {
1408                                 this.beam_color = beamcolor;
1409                                 this.beam_alpha = 0.5;
1410                                 this.beam_thickness = 14;
1411                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1412                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1413                                 this.beam_hitlight[0] = 0;
1414                                 this.beam_hitlight[1] = 1;
1415                                 this.beam_hitlight[2] = 1;
1416                                 this.beam_hitlight[3] = 1;
1417                                 this.beam_muzzleeffect = EFFECT_Null;
1418                                 this.beam_muzzlelight[0] = 0;
1419                                 this.beam_muzzlelight[1] = 1;
1420                                 this.beam_muzzlelight[2] = 1;
1421                                 this.beam_muzzlelight[3] = 1;
1422                                 this.beam_image = "particles/lgbeam";
1423                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1424                                 {
1425                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1426                                         flash.alpha = this.beam_alpha;
1427                                         flash.colormod = this.beam_color;
1428                                         flash.scale = 0.35;
1429                                 }
1430                                 break;
1431                         }
1432                         case ARC_BT_BURST_HEAL:
1433                         {
1434                                 this.beam_color = beamcolor;
1435                                 this.beam_alpha = 0.5;
1436                                 this.beam_thickness = 14;
1437                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1438                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT2);
1439                                 this.beam_hitlight[0] = 0;
1440                                 this.beam_hitlight[1] = 1;
1441                                 this.beam_hitlight[2] = 1;
1442                                 this.beam_hitlight[3] = 1;
1443                                 this.beam_muzzleeffect = EFFECT_Null;
1444                                 this.beam_muzzlelight[0] = 0;
1445                                 this.beam_muzzlelight[1] = 1;
1446                                 this.beam_muzzlelight[2] = 1;
1447                                 this.beam_muzzlelight[3] = 1;
1448                                 this.beam_image = "particles/lgbeam";
1449                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1450                                 {
1451                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1452                                         flash.alpha = this.beam_alpha;
1453                                         flash.colormod = this.beam_color;
1454                                         flash.scale = 0.35;
1455                                 }
1456                                 break;
1457                         }
1458                         case ARC_BT_BURST_HIT:
1459                         {
1460                                 this.beam_color = beamcolor;
1461                                 this.beam_alpha = 0.5;
1462                                 this.beam_thickness = 14;
1463                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1464                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1465                                 this.beam_hitlight[0] = 0;
1466                                 this.beam_hitlight[1] = 1;
1467                                 this.beam_hitlight[2] = 1;
1468                                 this.beam_hitlight[3] = 1;
1469                                 this.beam_muzzleeffect = EFFECT_Null;
1470                                 this.beam_muzzlelight[0] = 0;
1471                                 this.beam_muzzlelight[1] = 1;
1472                                 this.beam_muzzlelight[2] = 1;
1473                                 this.beam_muzzlelight[3] = 1;
1474                                 this.beam_image = "particles/lgbeam";
1475                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1476                                 {
1477                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1478                                         flash.alpha = this.beam_alpha;
1479                                         flash.colormod = this.beam_color;
1480                                         flash.scale = 0.35;
1481                                 }
1482                                 break;
1483                         }
1484
1485                         // shouldn't be possible, but lets make it colorful if it does :D
1486                         default:
1487                         {
1488                                 this.beam_color = randomvec();
1489                                 this.beam_alpha = 1;
1490                                 this.beam_thickness = 8;
1491                                 this.beam_traileffect = NULL;
1492                                 this.beam_hiteffect = NULL;
1493                                 this.beam_hitlight[0] = 0;
1494                                 this.beam_hitlight[1] = 1;
1495                                 this.beam_hitlight[2] = 1;
1496                                 this.beam_hitlight[3] = 1;
1497                                 this.beam_muzzleeffect = EFFECT_Null;
1498                                 this.beam_muzzlelight[0] = 0;
1499                                 this.beam_muzzlelight[1] = 1;
1500                                 this.beam_muzzlelight[2] = 1;
1501                                 this.beam_muzzlelight[3] = 1;
1502                                 this.beam_image = "particles/lgbeam";
1503                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1504                                 {
1505                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1506                                         flash.alpha = this.beam_alpha;
1507                                         flash.colormod = this.beam_color;
1508                                         flash.scale = 0.35;
1509                                 }
1510                                 break;
1511                         }
1512                 }
1513         }
1514
1515         if(!this.beam_usevieworigin)
1516         {
1517                 InterpolateOrigin_Note(this);
1518         }
1519         return true;
1520 }
1521
1522 #endif