qcsrc/common/weapons/weapon/arc.qc

   1 #include "arc.qh"
   2
   3 #ifdef SVQC
   4 #include <common/gamemodes/gamemode/onslaught/sv_onslaught.qh>
   5 #include <common/gamemodes/gamemode/onslaught/sv_generator.qh>
   6
   7 bool W_Arc_Beam_Send(entity this, entity to, int sf)
   8 {
   9         WriteHeader(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
  10
  11         // Truncate information when this beam is displayed to the owner client
  12         // - The owner client has no use for beam start position or directions,
  13         //    it always figures this information out for itself with csqc code.
  14         // - Spectating the owner also truncates this information.
  15         float drawlocal = ((to == this.owner) || ((to.enemy == this.owner) && IS_SPEC(to)));
  16         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
  17
  18         WriteByte(MSG_ENTITY, sf);
  19         WriteByte(MSG_ENTITY, weaponslot(this.weaponentity_fld));
  20
  21         if(sf & ARC_SF_SETTINGS) // settings information
  22         {
  23                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
  24                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
  25                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
  26                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
  27                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
  28                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
  29
  30                 WriteByte(MSG_ENTITY, drawlocal);
  31                 WriteByte(MSG_ENTITY, etof(this.owner));
  32         }
  33         if(sf & ARC_SF_START) // starting location
  34         {
  35                 WriteVector(MSG_ENTITY, this.beam_start);
  36         }
  37         if(sf & ARC_SF_WANTDIR) // want/aim direction
  38         {
  39                 WriteVector(MSG_ENTITY, this.beam_wantdir);
  40         }
  41         if(sf & ARC_SF_BEAMDIR) // beam direction
  42         {
  43                 WriteAngle(MSG_ENTITY, this.beam_dir.x);
  44                 WriteAngle(MSG_ENTITY, this.beam_dir.y);
  45                 WriteAngle(MSG_ENTITY, this.beam_dir.z);
  46         }
  47         if(sf & ARC_SF_BEAMTYPE) // beam type
  48         {
  49                 WriteByte(MSG_ENTITY, this.beam_type);
  50         }
  51
  52         return true;
  53 }
  54
  55 void Reset_ArcBeam(entity player, vector forward)
  56 {
  57         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  58         {
  59                 .entity weaponentity = weaponentities[slot];
  60                 if(!player.(weaponentity).arc_beam)
  61                         continue;
  62                 player.(weaponentity).arc_beam.beam_dir = forward;
  63                 player.(weaponentity).arc_beam.beam_teleporttime = time;
  64         }
  65 }
  66
  67 float Arc_GetHeat_Percent(entity player, .entity weaponentity)
  68 {
  69         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
  70         {
  71                 player.arc_overheat = 0;
  72                 return 0;
  73         }
  74
  75         if ( player.(weaponentity).arc_beam )
  76                 return player.(weaponentity).arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
  77
  78         if ( player.arc_overheat > time )
  79         {
  80                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
  81                         * player.arc_cooldown;
  82         }
  83
  84         return 0;
  85 }
  86 void Arc_Player_SetHeat(entity player, .entity weaponentity)
  87 {
  88         player.(weaponentity).arc_heat_percent = Arc_GetHeat_Percent(player, weaponentity);
  89         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
  90 }
  91
  92 void W_Arc_Bolt_Explode(entity this, entity directhitentity)
  93 {
  94         this.event_damage = func_null;
  95         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, this.weaponentity_fld, directhitentity);
  96
  97         delete(this);
  98 }
  99
 100 void W_Arc_Bolt_Explode_use(entity this, entity actor, entity trigger)
 101 {
 102         W_Arc_Bolt_Explode(this, trigger);
 103 }
 104
 105 void W_Arc_Bolt_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 106 {
 107         if(GetResourceAmount(this, RESOURCE_HEALTH) <= 0)
 108                 return;
 109
 110         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1))
 111                 return; // g_projectiles_damage says to halt
 112
 113         TakeResource(this, RESOURCE_HEALTH, damage);
 114         this.angles = vectoangles(this.velocity);
 115
 116         if(GetResourceAmount(this, RESOURCE_HEALTH) <= 0)
 117                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 118 }
 119
 120 void W_Arc_Bolt_Touch(entity this, entity toucher)
 121 {
 122         PROJECTILE_TOUCH(this, toucher);
 123         this.use(this, NULL, toucher);
 124 }
 125
 126 void W_Arc_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity)
 127 {
 128         entity missile;
 129
 130         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(arc, bolt_ammo), weaponentity);
 131
 132         W_SetupShot(actor, weaponentity, false, 2, SND_LASERGUN_FIRE, CH_WEAPON_A, WEP_CVAR(arc, bolt_damage), WEP_ARC.m_id | HITTYPE_SECONDARY);
 133
 134         Send_Effect(EFFECT_ARC_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 135
 136         missile = new(missile);
 137         missile.owner = missile.realowner = actor;
 138         missile.bot_dodge = true;
 139         IL_PUSH(g_bot_dodge, missile);
 140         missile.bot_dodgerating = WEP_CVAR(arc, bolt_damage);
 141
 142         missile.takedamage = DAMAGE_YES;
 143         SetResourceAmountExplicit(missile, RESOURCE_HEALTH, WEP_CVAR(arc, bolt_health));
 144         missile.damageforcescale = WEP_CVAR(arc, bolt_damageforcescale);
 145         missile.event_damage = W_Arc_Bolt_Damage;
 146         missile.damagedbycontents = true;
 147         IL_PUSH(g_damagedbycontents, missile);
 148
 149         settouch(missile, W_Arc_Bolt_Touch);
 150         missile.use = W_Arc_Bolt_Explode_use;
 151         setthink(missile, adaptor_think2use_hittype_splash);
 152         missile.nextthink = time + WEP_CVAR(arc, bolt_lifetime);
 153         PROJECTILE_MAKETRIGGER(missile);
 154         missile.projectiledeathtype = WEP_ARC.m_id | HITTYPE_SECONDARY;
 155         missile.weaponentity_fld = weaponentity;
 156         setorigin(missile, w_shotorg);
 157         setsize(missile, '0 0 0', '0 0 0');
 158
 159         set_movetype(missile, MOVETYPE_FLY);
 160         W_SetupProjVelocity_PRE(missile, arc, bolt_);
 161
 162         missile.angles = vectoangles(missile.velocity);
 163         missile.flags = FL_PROJECTILE;
 164         missile.missile_flags = MIF_SPLASH;
 165
 166         CSQCProjectile(missile, true, PROJECTILE_ARC_BOLT, true);
 167
 168         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 169 }
 170
 171 void W_Arc_Beam_Think(entity this)
 172 {
 173         .entity weaponentity = this.weaponentity_fld;
 174         entity own = this.owner;
 175         if(this != own.(weaponentity).arc_beam)
 176         {
 177                 delete(this);
 178                 return;
 179         }
 180
 181         float burst = 0;
 182         if( (PHYS_INPUT_BUTTON_ATCK2(own) && !WEP_CVAR(arc, bolt)) || this.beam_bursting)
 183         {
 184                 if(!this.beam_bursting)
 185                         this.beam_bursting = true;
 186                 burst = ARC_BT_BURSTMASK;
 187         }
 188
 189         Weapon thiswep = WEP_ARC;
 190
 191         if(
 192                 !IS_PLAYER(own)
 193                 ||
 194                 IS_DEAD(own)
 195                 ||
 196                 !weapon_prepareattack_check(thiswep, own, weaponentity, this.beam_bursting, -1)
 197                 ||
 198                 own.(weaponentity).m_switchweapon != WEP_ARC
 199                 ||
 200                 (!PHYS_INPUT_BUTTON_ATCK(own) && !burst )
 201                 ||
 202                 own.vehicle
 203                 ||
 204                 (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max))
 205         )
 206         {
 207                 if ( WEP_CVAR(arc, cooldown) > 0 )
 208                 {
 209                         float cooldown_speed = 0;
 210                         if ( this.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 211                         {
 212                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 213                         }
 214                         else if ( !burst )
 215                         {
 216                                 cooldown_speed = this.beam_heat / WEP_CVAR(arc, beam_refire);
 217                         }
 218
 219                         if ( cooldown_speed )
 220                         {
 221                                 if ( WEP_CVAR(arc, cooldown_release) || (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max)) )
 222                                         own.arc_overheat = time + this.beam_heat / cooldown_speed;
 223                                 own.arc_cooldown = cooldown_speed;
 224                         }
 225
 226                         if ( WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max) )
 227                         {
 228                                 Send_Effect(EFFECT_ARC_OVERHEAT,
 229                                         this.beam_start, this.beam_wantdir, 1 );
 230                                 sound(this, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 231                         }
 232                 }
 233
 234                 if(this == own.(weaponentity).arc_beam) { own.(weaponentity).arc_beam = NULL; }
 235                 if(!thiswep.wr_checkammo1(thiswep, own, weaponentity) && !(own.items & IT_UNLIMITED_WEAPON_AMMO))
 236                 {
 237                         // note: this doesn't force the switch
 238                         W_SwitchToOtherWeapon(own, weaponentity);
 239                         own.(weaponentity).arc_BUTTON_ATCK_prev = false; // hax
 240                 }
 241                 delete(this);
 242                 return;
 243         }
 244
 245         // decrease ammo
 246         float coefficient = frametime;
 247         if(!(own.items & IT_UNLIMITED_WEAPON_AMMO))
 248         {
 249                 float rootammo;
 250                 if(burst)
 251                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 252                 else
 253                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 254
 255                 if(rootammo)
 256                 {
 257                         coefficient = min(coefficient, GetResourceAmount(own, thiswep.ammo_type) / rootammo);
 258                         SetResourceAmount(own, thiswep.ammo_type, max(0, GetResourceAmount(own, thiswep.ammo_type) - (rootammo * frametime)));
 259                 }
 260         }
 261         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 262         this.beam_heat = min( WEP_CVAR(arc, overheat_max), this.beam_heat + heat_speed*frametime );
 263
 264         makevectors(own.v_angle);
 265
 266         W_SetupShot_Range(
 267                 own,
 268                 weaponentity, // TODO
 269                 true,
 270                 0,
 271                 SND_Null,
 272                 0,
 273                 WEP_CVAR(arc, beam_damage) * coefficient,
 274                 WEP_CVAR(arc, beam_range),
 275                 WEP_ARC.m_id
 276         );
 277
 278         // After teleport, "lock" the beam until the teleport is confirmed.
 279         if (time < this.beam_teleporttime + ANTILAG_LATENCY(own)) {
 280                 w_shotdir = this.beam_dir;
 281         }
 282
 283         // network information: shot origin and want/aim direction
 284         if(this.beam_start != w_shotorg)
 285         {
 286                 this.SendFlags |= ARC_SF_START;
 287                 this.beam_start = w_shotorg;
 288         }
 289         if(this.beam_wantdir != w_shotdir)
 290         {
 291                 this.SendFlags |= ARC_SF_WANTDIR;
 292                 this.beam_wantdir = w_shotdir;
 293         }
 294
 295         if(!this.beam_initialized)
 296         {
 297                 this.beam_dir = w_shotdir;
 298                 this.beam_initialized = true;
 299         }
 300
 301         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 302         // idea: blend together this.beam_dir with the inverted direction the player is moving in
 303         // might have to make some special accomodation so that it only uses view_right and view_up
 304
 305         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 306
 307         float segments;
 308         if(this.beam_dir != w_shotdir)
 309         {
 310                 // calculate how much we're going to move the end of the beam to the want position
 311                 // WEAPONTODO (server and client):
 312                 // blendfactor never actually becomes 0 in this situation, which is a problem
 313                 // regarding precision... this means that this.beam_dir and w_shotdir approach
 314                 // eachother, however they never actually become the same value with this method.
 315                 // Perhaps we should do some form of rounding/snapping?
 316                 float angle = vlen(w_shotdir - this.beam_dir) * RAD2DEG;
 317                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 318                 {
 319                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 320                         float blendfactor = bound(
 321                                 0,
 322                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 323                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 324                         );
 325                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 326                 }
 327                 else
 328                 {
 329                         // the radius is not too far yet, no worries :D
 330                         float blendfactor = bound(
 331                                 0,
 332                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 333                                 1
 334                         );
 335                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 336                 }
 337
 338                 // network information: beam direction
 339                 this.SendFlags |= ARC_SF_BEAMDIR;
 340
 341                 // calculate how many segments are needed
 342                 float max_allowed_segments;
 343
 344                 if(WEP_CVAR(arc, beam_distancepersegment))
 345                 {
 346                         max_allowed_segments = min(
 347                                 ARC_MAX_SEGMENTS,
 348                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 349                         );
 350                 }
 351                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 352
 353                 if(WEP_CVAR(arc, beam_degreespersegment))
 354                 {
 355                         segments = bound(
 356                                 1,
 357                                 (
 358                                         min(
 359                                                 angle,
 360                                                 WEP_CVAR(arc, beam_maxangle)
 361                                         )
 362                                         /
 363                                         WEP_CVAR(arc, beam_degreespersegment)
 364                                 ),
 365                                 max_allowed_segments
 366                         );
 367                 }
 368                 else { segments = 1; }
 369         }
 370         else { segments = 1; }
 371
 372         vector beam_endpos = (w_shotorg + (this.beam_dir * WEP_CVAR(arc, beam_range)));
 373         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 374
 375         float i;
 376         float new_beam_type = 0;
 377         vector last_origin = w_shotorg;
 378         for(i = 1; i <= segments; ++i)
 379         {
 380                 // WEAPONTODO (client):
 381                 // In order to do nice fading and pointing on the starting segment, we must always
 382                 // have that drawn as a separate triangle... However, that is difficult to do when
 383                 // keeping in mind the above problems and also optimizing the amount of segments
 384                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 385
 386                 vector new_origin = bezier_quadratic_getpoint(
 387                         w_shotorg,
 388                         beam_controlpoint,
 389                         beam_endpos,
 390                         i / segments);
 391                 vector new_dir = normalize(new_origin - last_origin);
 392
 393                 WarpZone_traceline_antilag(
 394                         own,
 395                         last_origin,
 396                         new_origin,
 397                         MOVE_NORMAL,
 398                         own,
 399                         ANTILAG_LATENCY(own)
 400                 );
 401
 402                 // Do all the transforms for warpzones right now, as we already
 403                 // "are" in the post-trace system (if we hit a player, that's
 404                 // always BEHIND the last passed wz).
 405                 last_origin = trace_endpos;
 406                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 407                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 408                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 409                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 410
 411                 bool is_player = (
 412                         IS_PLAYER(trace_ent)
 413                         ||
 414                         trace_ent.classname == "body"
 415                         ||
 416                         IS_MONSTER(trace_ent)
 417                 );
 418
 419                 if(trace_ent)
 420                 {
 421                         if(SAME_TEAM(own, trace_ent))
 422                         {
 423                                 float roothealth = ((burst) ? WEP_CVAR(arc, burst_healing_hps) : WEP_CVAR(arc, beam_healing_hps));
 424                                 float rootarmor = ((burst) ? WEP_CVAR(arc, burst_healing_aps) : WEP_CVAR(arc, beam_healing_aps));
 425                                 float hplimit = ((IS_PLAYER(trace_ent)) ? WEP_CVAR(arc, beam_healing_hmax) : RESOURCE_LIMIT_NONE);
 426                                 Heal(trace_ent, own, (roothealth * coefficient), hplimit);
 427                                 if(IS_PLAYER(trace_ent) && rootarmor)
 428                                 {
 429                                         if(GetResourceAmount(trace_ent, RESOURCE_ARMOR) <= WEP_CVAR(arc, beam_healing_amax))
 430                                         {
 431                                                 GiveResourceWithLimit(trace_ent, RESOURCE_ARMOR, (rootarmor * coefficient), WEP_CVAR(arc, beam_healing_amax));
 432                                                 trace_ent.pauserotarmor_finished = max(
 433                                                         trace_ent.pauserotarmor_finished,
 434                                                         time + autocvar_g_balance_pause_armor_rot
 435                                                 );
 436                                         }
 437                                 }
 438                                 if(roothealth || rootarmor)
 439                                         new_beam_type = ARC_BT_HEAL;
 440                         }
 441                         else if(trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 442                         {
 443                                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 444                                 // NO. trace_endpos should be just fine. If not,
 445                                 // that's an engine bug that needs proper debugging.
 446                                 vector hitorigin = trace_endpos;
 447
 448                                 float falloff = ExponentialFalloff(
 449                                         WEP_CVAR(arc, beam_falloff_mindist),
 450                                         WEP_CVAR(arc, beam_falloff_maxdist),
 451                                         WEP_CVAR(arc, beam_falloff_halflifedist),
 452                                         vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 453                                 );
 454
 455                                 float rootdamage;
 456                                 if(is_player)
 457                                 {
 458                                         if(burst)
 459                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 460                                         else
 461                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 462                                 }
 463                                 else
 464                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 465
 466                                 if(accuracy_isgooddamage(own, trace_ent))
 467                                 {
 468                                         accuracy_add(
 469                                                 own,
 470                                                 WEP_ARC.m_id,
 471                                                 0,
 472                                                 rootdamage * coefficient * falloff
 473                                         );
 474                                 }
 475
 476                                 Damage(
 477                                         trace_ent,
 478                                         own,
 479                                         own,
 480                                         rootdamage * coefficient * falloff,
 481                                         WEP_ARC.m_id,
 482                                         weaponentity,
 483                                         hitorigin,
 484                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 485                                 );
 486
 487                                 new_beam_type = ARC_BT_HIT;
 488                         }
 489                         break;
 490                 }
 491                 else if(trace_fraction != 1)
 492                 {
 493                         // we collided with geometry
 494                         new_beam_type = ARC_BT_WALL;
 495                         break;
 496                 }
 497         }
 498
 499         // te_explosion(trace_endpos);
 500
 501         // if we're bursting, use burst visual effects
 502         new_beam_type |= burst;
 503
 504         // network information: beam type
 505         if(new_beam_type != this.beam_type)
 506         {
 507                 this.SendFlags |= ARC_SF_BEAMTYPE;
 508                 this.beam_type = new_beam_type;
 509         }
 510
 511         own.(weaponentity).beam_prev = time;
 512         this.nextthink = time;
 513 }
 514
 515 void W_Arc_Beam(float burst, entity actor, .entity weaponentity)
 516 {
 517
 518         // only play fire sound if 1 sec has passed since player let go the fire button
 519         if(time - actor.(weaponentity).beam_prev > 1)
 520                 sound(actor, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 521
 522         entity beam = actor.(weaponentity).arc_beam = new(W_Arc_Beam);
 523         beam.weaponentity_fld = weaponentity;
 524         beam.solid = SOLID_NOT;
 525         setthink(beam, W_Arc_Beam_Think);
 526         beam.owner = actor;
 527         set_movetype(beam, MOVETYPE_NONE);
 528         beam.bot_dodge = true;
 529         IL_PUSH(g_bot_dodge, beam);
 530         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 531         beam.beam_bursting = burst;
 532         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 533
 534         getthink(beam)(beam);
 535 }
 536 void Arc_Smoke(entity actor, .entity weaponentity)
 537 {
 538         makevectors(actor.v_angle);
 539         W_SetupShot_Range(actor,weaponentity,true,0,SND_Null,0,0,0,WEP_ARC.m_id); // TODO: probably doesn't need deathtype, since this is just a prefire effect
 540
 541         vector smoke_origin = w_shotorg + actor.velocity*frametime;
 542         if ( actor.arc_overheat > time )
 543         {
 544                 if ( random() < actor.(weaponentity).arc_heat_percent )
 545                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 546                 if ( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) )
 547                 {
 548                         Send_Effect(EFFECT_ARC_OVERHEAT_FIRE, smoke_origin, w_shotdir, 1 );
 549                         if ( !actor.arc_smoke_sound )
 550                         {
 551                                 actor.arc_smoke_sound = 1;
 552                                 sound(actor, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 553                         }
 554                 }
 555         }
 556         else if ( actor.(weaponentity).arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 557                         actor.(weaponentity).arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 558         {
 559                 if ( random() < (actor.(weaponentity).arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 560                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 561                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 562         }
 563
 564         if (  actor.arc_smoke_sound && ( actor.arc_overheat <= time ||
 565                 !( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) ) ) || actor.(weaponentity).m_switchweapon != WEP_ARC )
 566         {
 567                 actor.arc_smoke_sound = 0;
 568                 sound(actor, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 569         }
 570 }
 571
 572 METHOD(Arc, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 573 {
 574     if(WEP_CVAR(arc, beam_botaimspeed))
 575     {
 576         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 577                 actor,
 578                 weaponentity,
 579             WEP_CVAR(arc, beam_botaimspeed),
 580             0,
 581             WEP_CVAR(arc, beam_botaimlifetime),
 582             false
 583         );
 584     }
 585     else
 586     {
 587         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 588                 actor,
 589                 weaponentity,
 590             1000000,
 591             0,
 592             0.001,
 593             false
 594         );
 595     }
 596 }
 597 METHOD(Arc, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 598 {
 599     Arc_Player_SetHeat(actor, weaponentity);
 600     Arc_Smoke(actor, weaponentity);
 601
 602     bool beam_fire2 = ((fire & 2) && !WEP_CVAR(arc, bolt));
 603
 604     if (time >= actor.arc_overheat)
 605     if ((fire & 1) || beam_fire2 || actor.(weaponentity).arc_beam.beam_bursting)
 606     {
 607
 608         if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 609         {
 610             #if 0
 611             if(actor.animstate_startframe == actor.anim_shoot.x && actor.animstate_numframes == actor.anim_shoot.y)
 612                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 613             else
 614             #endif
 615                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), w_ready);
 616         }
 617
 618         if((!actor.(weaponentity).arc_beam) || wasfreed(actor.(weaponentity).arc_beam))
 619         {
 620             if(weapon_prepareattack(thiswep, actor, weaponentity, boolean(beam_fire2), 0))
 621             {
 622                 W_Arc_Beam(boolean(beam_fire2), actor, weaponentity);
 623
 624                 if(!actor.(weaponentity).arc_BUTTON_ATCK_prev)
 625                 {
 626                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 627                     actor.(weaponentity).arc_BUTTON_ATCK_prev = true;
 628                 }
 629             }
 630         }
 631
 632         return;
 633     }
 634     else if(fire & 2)
 635     {
 636         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR(arc, bolt_refire)))
 637         {
 638             W_Arc_Attack_Bolt(thiswep, actor, weaponentity);
 639             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), w_ready);
 640         }
 641     }
 642
 643     if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 644     {
 645         int slot = weaponslot(weaponentity);
 646         sound(actor, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 647         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 648         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor(actor);
 649     }
 650     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 651
 652     #if 0
 653     if(fire & 2)
 654     if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_arc_secondary_refire))
 655     {
 656         W_Arc_Attack2();
 657         actor.arc_count = autocvar_g_balance_arc_secondary_count;
 658         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 659         actor.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor(actor);
 660     }
 661     #endif
 662 }
 663 METHOD(Arc, wr_init, void(entity thiswep))
 664 {
 665     if(!arc_shotorigin[0])
 666     {
 667         arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 668         arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 669         arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 670         arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 671     }
 672 }
 673 METHOD(Arc, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 674 {
 675     return ((!WEP_CVAR(arc, beam_ammo)) || (GetResourceAmount(actor, thiswep.ammo_type) > 0));
 676 }
 677 METHOD(Arc, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 678 {
 679     if(WEP_CVAR(arc, bolt))
 680     {
 681         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(arc, bolt_ammo);
 682         ammo_amount += actor.(weaponentity).(weapon_load[WEP_ARC.m_id]) >= WEP_CVAR(arc, bolt_ammo);
 683         return ammo_amount;
 684     }
 685     else
 686         return WEP_CVAR(arc, overheat_max) > 0 &&
 687             ((!WEP_CVAR(arc, burst_ammo)) || (GetResourceAmount(actor, thiswep.ammo_type) > 0));
 688 }
 689 METHOD(Arc, wr_killmessage, Notification(entity thiswep))
 690 {
 691     if(w_deathtype & HITTYPE_SECONDARY)
 692         return WEAPON_ARC_MURDER_SPRAY;
 693     else
 694         return WEAPON_ARC_MURDER;
 695 }
 696 METHOD(Arc, wr_drop, void(entity thiswep, entity actor, .entity weaponentity))
 697 {
 698     weapon_dropevent_item.arc_overheat = actor.arc_overheat;
 699     weapon_dropevent_item.arc_cooldown = actor.arc_cooldown;
 700     actor.arc_overheat = 0;
 701     actor.arc_cooldown = 0;
 702     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 703 }
 704 METHOD(Arc, wr_pickup, void(entity thiswep, entity actor, .entity weaponentity))
 705 {
 706     if ( !client_hasweapon(actor, thiswep, weaponentity, false, false) &&
 707         weapon_dropevent_item.arc_overheat > time )
 708     {
 709         actor.arc_overheat = weapon_dropevent_item.arc_overheat;
 710         actor.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 711     }
 712 }
 713 METHOD(Arc, wr_resetplayer, void(entity thiswep, entity actor))
 714 {
 715     actor.arc_overheat = 0;
 716     actor.arc_cooldown = 0;
 717     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 718     {
 719         .entity weaponentity = weaponentities[slot];
 720         actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 721     }
 722 }
 723 METHOD(Arc, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
 724 {
 725     actor.arc_overheat = 0;
 726     actor.arc_cooldown = 0;
 727     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 728 }
 729 #endif
 730 #ifdef CSQC
 731 bool autocvar_cl_arcbeam_teamcolor = true;
 732 bool autocvar_cl_arcbeam_simple = true;
 733
 734 .int beam_slot;
 735
 736 METHOD(Arc, wr_impacteffect, void(entity thiswep, entity actor))
 737 {
 738     if(w_deathtype & HITTYPE_SECONDARY)
 739     {
 740         vector org2;
 741         org2 = w_org + w_backoff * 6;
 742         pointparticles(EFFECT_ARC_BOLT_EXPLODE, org2, w_backoff * 1000, 1);
 743         if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 744     }
 745 }
 746
 747 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 748 {
 749         entity beam = Draw_ArcBeam_callback_entity;
 750         vector transformed_view_org;
 751         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 752
 753         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 754         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 755         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 756
 757         vector hitorigin;
 758
 759         // draw segment
 760         #if 0
 761         if(trace_fraction != 1)
 762         {
 763                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 764                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 765                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 766         }
 767         else
 768         {
 769                 hitorigin = hit;
 770         }
 771         #else
 772         hitorigin = hit;
 773         #endif
 774
 775         // decide upon thickness
 776         float thickness = beam.beam_thickness;
 777
 778         // draw primary beam render
 779         vector top    = hitorigin + (thickdir * thickness);
 780         vector bottom = hitorigin - (thickdir * thickness);
 781
 782         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 783         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 784
 785         if(autocvar_cl_arcbeam_simple)
 786                 Draw_CylindricLine(start, end, thickness, beam.beam_image, 0.25, -time * 3, beam.beam_color, beam.beam_alpha, DRAWFLAG_NORMAL, transformed_view_org);
 787         else
 788         {
 789                 R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 790                 R_PolygonVertex(
 791                         top,
 792                         '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 793                         beam.beam_color,
 794                         beam.beam_alpha
 795                 );
 796                 R_PolygonVertex(
 797                         last_top,
 798                         '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 799                         beam.beam_color,
 800                         beam.beam_alpha
 801                 );
 802                 R_PolygonVertex(
 803                         last_bottom,
 804                         '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 805                         beam.beam_color,
 806                         beam.beam_alpha
 807                 );
 808                 R_PolygonVertex(
 809                         bottom,
 810                         '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 811                         beam.beam_color,
 812                         beam.beam_alpha
 813                 );
 814                 R_EndPolygon();
 815         }
 816
 817         // draw trailing particles
 818         // NOTES:
 819         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 820         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 821         if(beam.beam_traileffect)
 822         {
 823                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 824         }
 825
 826         // set up for the next
 827         Draw_ArcBeam_callback_last_thickness = thickness;
 828         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 829         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 830 }
 831
 832 void Reset_ArcBeam()
 833 {
 834         entity e;
 835         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 836                 e.beam_initialized = false;
 837         }
 838         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 839                 e.beam_initialized = false;
 840         }
 841 }
 842
 843 void Draw_ArcBeam(entity this)
 844 {
 845         float dt = time - this.move_time;
 846         this.move_time = time;
 847         if(dt <= 0) { return; }
 848
 849         if(!this.beam_usevieworigin)
 850         {
 851                 InterpolateOrigin_Do(this);
 852         }
 853
 854         // origin = beam starting origin
 855         // v_angle = wanted/aim direction
 856         // angles = current direction of beam
 857
 858         vector start_pos;
 859         vector wantdir; //= view_forward;
 860         vector beamdir; //= this.beam_dir;
 861
 862         float segments;
 863         if(this.beam_usevieworigin)
 864         {
 865                 // WEAPONTODO:
 866                 // Currently we have to replicate nearly the same method of figuring
 867                 // out the shotdir that the server does... Ideally in the future we
 868                 // should be able to acquire this from a generalized function built
 869                 // into a weapon system for client code.
 870
 871                 // find where we are aiming
 872                 makevectors(((autocvar_chase_active) ? warpzone_save_view_angles : view_angles));
 873                 vector forward = v_forward;
 874                 vector right = v_right;
 875                 vector up = v_up;
 876                 entity wepent = viewmodels[this.beam_slot];
 877
 878                 if(autocvar_chase_active)
 879                         this.beam_usevieworigin = 1;
 880                 else
 881                         this.beam_usevieworigin = 2;
 882
 883                 // decide upon start position
 884                 if(this.beam_usevieworigin == 2)
 885                         { start_pos = warpzone_save_view_origin; }
 886                 else if(csqcplayer)
 887                         { start_pos = csqcplayer.origin + csqcplayer.view_ofs; }
 888                 else
 889                         { start_pos = this.origin; }
 890
 891                 int v_shot_idx;  // used later
 892                 (v_shot_idx = gettagindex(wepent, "shot")) || (v_shot_idx = gettagindex(wepent, "tag_shot"));
 893                 if(v_shot_idx && this.beam_usevieworigin == 2)
 894                         start_pos = gettaginfo(wepent, v_shot_idx) - '0 0 2';
 895
 896                 // trace forward with an estimation
 897                 WarpZone_TraceLine(
 898                         start_pos,
 899                         start_pos + forward * this.beam_range,
 900                         MOVE_NOMONSTERS,
 901                         this
 902                 );
 903
 904                 // untransform in case our trace went through a warpzone
 905                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 906
 907                 // un-adjust trueaim if shotend is too close
 908                 if(vdist(end_pos - start_pos, <, g_trueaim_minrange))
 909                         end_pos = start_pos + (forward * g_trueaim_minrange);
 910
 911                 // move shot origin to the actual gun muzzle origin
 912                 vector origin_offset = '0 0 0';
 913                 if(!v_shot_idx || this.beam_usevieworigin != 2)
 914                 {
 915                         this.beam_shotorigin = wepent.movedir;
 916                         origin_offset =
 917                                  right * -this.beam_shotorigin.y
 918                                 + up * this.beam_shotorigin.z;
 919                 }
 920                 else
 921                         this.beam_shotorigin = '0 0 0';
 922
 923                 start_pos = start_pos + origin_offset;
 924
 925                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 926                 traceline(start_pos, start_pos + forward * this.beam_shotorigin.x, MOVE_NORMAL, this);
 927                 start_pos = trace_endpos;
 928
 929                 // calculate the aim direction now
 930                 wantdir = normalize(end_pos - start_pos);
 931
 932                 if(!this.beam_initialized)
 933                 {
 934                         this.beam_dir = wantdir;
 935                         this.beam_initialized = true;
 936                 }
 937
 938                 if(this.beam_dir != wantdir)
 939                 {
 940                         // calculate how much we're going to move the end of the beam to the want position
 941                         // WEAPONTODO (server and client):
 942                         // blendfactor never actually becomes 0 in this situation, which is a problem
 943                         // regarding precision... this means that this.beam_dir and w_shotdir approach
 944                         // eachother, however they never actually become the same value with this method.
 945                         // Perhaps we should do some form of rounding/snapping?
 946                         float angle = vlen(wantdir - this.beam_dir) * RAD2DEG;
 947                         if(angle && (angle > this.beam_maxangle))
 948                         {
 949                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 950                                 float blendfactor = bound(
 951                                         0,
 952                                         (1 - (this.beam_returnspeed * frametime)),
 953                                         min(this.beam_maxangle / angle, 1)
 954                                 );
 955                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 956                         }
 957                         else
 958                         {
 959                                 // the radius is not too far yet, no worries :D
 960                                 float blendfactor = bound(
 961                                         0,
 962                                         (1 - (this.beam_returnspeed * frametime)),
 963                                         1
 964                                 );
 965                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 966                         }
 967
 968                         // calculate how many segments are needed
 969                         float max_allowed_segments;
 970
 971                         if(this.beam_distancepersegment)
 972                         {
 973                                 max_allowed_segments = min(
 974                                         ARC_MAX_SEGMENTS,
 975                                         1 + (vlen(wantdir / this.beam_distancepersegment))
 976                                 );
 977                         }
 978                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 979
 980                         if(this.beam_degreespersegment)
 981                         {
 982                                 segments = bound(
 983                                         1,
 984                                         (
 985                                                 min(
 986                                                         angle,
 987                                                         this.beam_maxangle
 988                                                 )
 989                                                 /
 990                                                 this.beam_degreespersegment
 991                                         ),
 992                                         max_allowed_segments
 993                                 );
 994                         }
 995                         else { segments = 1; }
 996                 }
 997                 else { segments = 1; }
 998
 999                 // set the beam direction which the rest of the code will refer to
1000                 beamdir = this.beam_dir;
1001
1002                 // finally, set this.angles to the proper direction so that muzzle attachment points in proper direction
1003                 this.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1004         }
1005         else
1006         {
1007                 // set the values from the provided info from the networked entity
1008                 start_pos = this.origin;
1009                 wantdir = this.v_angle;
1010                 beamdir = this.angles;
1011
1012                 if(beamdir != wantdir)
1013                 {
1014                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1015
1016                         // calculate how many segments are needed
1017                         float max_allowed_segments;
1018
1019                         if(this.beam_distancepersegment)
1020                         {
1021                                 max_allowed_segments = min(
1022                                         ARC_MAX_SEGMENTS,
1023                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1024                                 );
1025                         }
1026                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1027
1028                         if(this.beam_degreespersegment)
1029                         {
1030                                 segments = bound(
1031                                         1,
1032                                         (
1033                                                 min(
1034                                                         angle,
1035                                                         this.beam_maxangle
1036                                                 )
1037                                                 /
1038                                                 this.beam_degreespersegment
1039                                         ),
1040                                         max_allowed_segments
1041                                 );
1042                         }
1043                         else { segments = 1; }
1044                 }
1045                 else { segments = 1; }
1046         }
1047
1048         setorigin(this, start_pos);
1049         this.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1050
1051         vector beam_endpos = (start_pos + (beamdir * this.beam_range));
1052         vector beam_controlpoint = start_pos + wantdir * (this.beam_range * (1 - this.beam_tightness));
1053
1054         Draw_ArcBeam_callback_entity = this;
1055         Draw_ArcBeam_callback_last_thickness = 0;
1056         Draw_ArcBeam_callback_last_top = start_pos;
1057         Draw_ArcBeam_callback_last_bottom = start_pos;
1058
1059         vector last_origin = start_pos;
1060         vector original_start_pos = start_pos;
1061
1062         float i;
1063         for(i = 1; i <= segments; ++i)
1064         {
1065                 // WEAPONTODO (client):
1066                 // In order to do nice fading and pointing on the starting segment, we must always
1067                 // have that drawn as a separate triangle... However, that is difficult to do when
1068                 // keeping in mind the above problems and also optimizing the amount of segments
1069                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1070
1071                 vector new_origin = bezier_quadratic_getpoint(
1072                         start_pos,
1073                         beam_controlpoint,
1074                         beam_endpos,
1075                         i / segments);
1076
1077                 WarpZone_TraceBox_ThroughZone(
1078                         last_origin,
1079                         '0 0 0',
1080                         '0 0 0',
1081                         new_origin,
1082                         MOVE_NORMAL,
1083                         NULL,
1084                         NULL,
1085                         Draw_ArcBeam_callback
1086                 );
1087
1088                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1089                 // system (if we hit a player, that's always BEHIND the last passed wz).
1090                 last_origin = trace_endpos;
1091                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1092                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1093                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1094                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1095                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1096                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1097
1098                 if(trace_fraction < 1) { break; }
1099         }
1100
1101         // visual effects for startpoint and endpoint
1102         if(this.beam_hiteffect)
1103         {
1104                 // FIXME we really should do this on the server so it actually
1105                 // matches gameplay. What this client side stuff is doing is no
1106                 // more than guesswork.
1107                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1108                 pointparticles(
1109                         this.beam_hiteffect,
1110                         last_origin,
1111                         beamdir * -1,
1112                         frametime * 2
1113                 );
1114         }
1115         if(this.beam_hitlight[0])
1116         {
1117                 adddynamiclight(
1118                         last_origin,
1119                         this.beam_hitlight[0],
1120                         vec3(
1121                                 this.beam_hitlight[1],
1122                                 this.beam_hitlight[2],
1123                                 this.beam_hitlight[3]
1124                         )
1125                 );
1126         }
1127         if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1128         {
1129                 pointparticles(
1130                         this.beam_muzzleeffect,
1131                         original_start_pos + wantdir * 20,
1132                         wantdir * 1000,
1133                         frametime * 0.1
1134                 );
1135         }
1136         if(this.beam_muzzlelight[0])
1137         {
1138                 adddynamiclight(
1139                         original_start_pos + wantdir * 20,
1140                         this.beam_muzzlelight[0],
1141                         vec3(
1142                                 this.beam_muzzlelight[1],
1143                                 this.beam_muzzlelight[2],
1144                                 this.beam_muzzlelight[3]
1145                         )
1146                 );
1147         }
1148
1149         // cleanup
1150         Draw_ArcBeam_callback_entity = NULL;
1151         Draw_ArcBeam_callback_last_thickness = 0;
1152         Draw_ArcBeam_callback_last_top = '0 0 0';
1153         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1154 }
1155
1156 void Remove_ArcBeam(entity this)
1157 {
1158         delete(this.beam_muzzleentity);
1159         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1160 }
1161
1162 NET_HANDLE(ENT_CLIENT_ARC_BEAM, bool isnew)
1163 {
1164         int sf = ReadByte();
1165         int slot = ReadByte();
1166         entity flash;
1167
1168         this.beam_slot = slot;
1169
1170         if(isnew)
1171         {
1172                 int gunalign = W_GunAlign(viewmodels[slot], STAT(GUNALIGN)) - 1;
1173
1174                 this.beam_shotorigin = arc_shotorigin[gunalign]; // get a starting point
1175
1176                 // set other main attributes of the beam
1177                 this.draw = Draw_ArcBeam;
1178                 IL_PUSH(g_drawables, this);
1179                 this.entremove = Remove_ArcBeam;
1180                 this.move_time = time;
1181                 loopsound(this, CH_SHOTS_SINGLE, SND_ARC_LOOP, VOL_BASE, ATTEN_NORM);
1182
1183                 flash = spawn();
1184                 flash.owner = this;
1185                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1186                 flash.drawmask = MASK_NORMAL;
1187                 flash.solid = SOLID_NOT;
1188                 flash.avelocity_z = 5000;
1189                 setattachment(flash, this, "");
1190                 setorigin(flash, '0 0 0');
1191
1192                 this.beam_muzzleentity = flash;
1193         }
1194         else
1195         {
1196                 flash = this.beam_muzzleentity;
1197         }
1198
1199         if(sf & ARC_SF_SETTINGS) // settings information
1200         {
1201                 this.beam_degreespersegment = ReadShort();
1202                 this.beam_distancepersegment = ReadShort();
1203                 this.beam_maxangle = ReadShort();
1204                 this.beam_range = ReadCoord();
1205                 this.beam_returnspeed = ReadShort();
1206                 this.beam_tightness = (ReadByte() / 10);
1207
1208                 if(ReadByte())
1209                 {
1210                         if(autocvar_chase_active)
1211                                 { this.beam_usevieworigin = 1; }
1212                         else // use view origin
1213                                 { this.beam_usevieworigin = 2; }
1214                 }
1215                 else
1216                 {
1217                         this.beam_usevieworigin = 0;
1218                 }
1219
1220                 this.sv_entnum = ReadByte();
1221         }
1222
1223         if(!this.beam_usevieworigin)
1224         {
1225                 // this.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1226                 this.iflags = IFLAG_ORIGIN;
1227
1228                 InterpolateOrigin_Undo(this);
1229         }
1230
1231         if(sf & ARC_SF_START) // starting location
1232         {
1233                 this.origin = ReadVector();
1234         }
1235         else if(this.beam_usevieworigin) // infer the location from player location
1236         {
1237                 if(this.beam_usevieworigin == 2)
1238                 {
1239                         // use view origin
1240                         this.origin = view_origin;
1241                 }
1242                 else
1243                 {
1244                         // use player origin so that third person display still works
1245                         this.origin = entcs_receiver(player_localnum).origin + ('0 0 1' * STAT(VIEWHEIGHT));
1246                 }
1247         }
1248
1249         setorigin(this, this.origin);
1250
1251         if(sf & ARC_SF_WANTDIR) // want/aim direction
1252         {
1253                 this.v_angle = ReadVector();
1254         }
1255
1256         if(sf & ARC_SF_BEAMDIR) // beam direction
1257         {
1258                 this.angles_x = ReadAngle();
1259                 this.angles_y = ReadAngle();
1260                 this.angles_z = ReadAngle();
1261         }
1262
1263         if(sf & ARC_SF_BEAMTYPE) // beam type
1264         {
1265                 this.beam_type = ReadByte();
1266
1267                 vector beamcolor = ((autocvar_cl_arcbeam_teamcolor) ? colormapPaletteColor(entcs_GetClientColors(this.sv_entnum - 1) & 0x0F, true) : '1 1 1');
1268                 switch(this.beam_type)
1269                 {
1270                         case ARC_BT_MISS:
1271                         {
1272                                 this.beam_color = beamcolor;
1273                                 this.beam_alpha = 0.5;
1274                                 this.beam_thickness = 8;
1275                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1276                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1277                                 this.beam_hitlight[0] = 0;
1278                                 this.beam_hitlight[1] = 1;
1279                                 this.beam_hitlight[2] = 1;
1280                                 this.beam_hitlight[3] = 1;
1281                                 this.beam_muzzleeffect = EFFECT_Null;
1282                                 this.beam_muzzlelight[0] = 0;
1283                                 this.beam_muzzlelight[1] = 1;
1284                                 this.beam_muzzlelight[2] = 1;
1285                                 this.beam_muzzlelight[3] = 1;
1286                                 this.beam_image = "particles/lgbeam";
1287                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1288                                 {
1289                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1290                                         flash.alpha = this.beam_alpha;
1291                                         flash.colormod = this.beam_color;
1292                                         flash.scale = 0.35;
1293                                 }
1294                                 break;
1295                         }
1296                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1297                         {
1298                                 this.beam_color = beamcolor;
1299                                 this.beam_alpha = 0.5;
1300                                 this.beam_thickness = 8;
1301                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1302                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1303                                 this.beam_hitlight[0] = 0;
1304                                 this.beam_hitlight[1] = 1;
1305                                 this.beam_hitlight[2] = 1;
1306                                 this.beam_hitlight[3] = 1;
1307                                 this.beam_muzzleeffect = EFFECT_Null; // (EFFECT_GRENADE_MUZZLEFLASH);
1308                                 this.beam_muzzlelight[0] = 0;
1309                                 this.beam_muzzlelight[1] = 1;
1310                                 this.beam_muzzlelight[2] = 1;
1311                                 this.beam_muzzlelight[3] = 1;
1312                                 this.beam_image = "particles/lgbeam";
1313                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1314                                 {
1315                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1316                                         flash.alpha = this.beam_alpha;
1317                                         flash.colormod = this.beam_color;
1318                                         flash.scale = 0.35;
1319                                 }
1320                                 break;
1321                         }
1322                         case ARC_BT_HEAL:
1323                         {
1324                                 this.beam_color = beamcolor;
1325                                 this.beam_alpha = 0.5;
1326                                 this.beam_thickness = 8;
1327                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1328                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT);
1329                                 this.beam_hitlight[0] = 0;
1330                                 this.beam_hitlight[1] = 1;
1331                                 this.beam_hitlight[2] = 1;
1332                                 this.beam_hitlight[3] = 1;
1333                                 this.beam_muzzleeffect = EFFECT_Null;
1334                                 this.beam_muzzlelight[0] = 0;
1335                                 this.beam_muzzlelight[1] = 1;
1336                                 this.beam_muzzlelight[2] = 1;
1337                                 this.beam_muzzlelight[3] = 1;
1338                                 this.beam_image = "particles/lgbeam";
1339                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1340                                 {
1341                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1342                                         flash.alpha = this.beam_alpha;
1343                                         flash.colormod = this.beam_color;
1344                                         flash.scale = 0.35;
1345                                 }
1346                                 break;
1347                         }
1348                         case ARC_BT_HIT:
1349                         {
1350                                 this.beam_color = beamcolor;
1351                                 this.beam_alpha = 0.5;
1352                                 this.beam_thickness = 8;
1353                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1354                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1355                                 this.beam_hitlight[0] = 20;
1356                                 this.beam_hitlight[1] = 1;
1357                                 this.beam_hitlight[2] = 0;
1358                                 this.beam_hitlight[3] = 0;
1359                                 this.beam_muzzleeffect = EFFECT_Null;
1360                                 this.beam_muzzlelight[0] = 50;
1361                                 this.beam_muzzlelight[1] = 1;
1362                                 this.beam_muzzlelight[2] = 0;
1363                                 this.beam_muzzlelight[3] = 0;
1364                                 this.beam_image = "particles/lgbeam";
1365                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1366                                 {
1367                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1368                                         flash.alpha = this.beam_alpha;
1369                                         flash.colormod = this.beam_color;
1370                                         flash.scale = 0.35;
1371                                 }
1372                                 break;
1373                         }
1374                         case ARC_BT_BURST_MISS:
1375                         {
1376                                 this.beam_color = beamcolor;
1377                                 this.beam_alpha = 0.5;
1378                                 this.beam_thickness = 14;
1379                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1380                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1381                                 this.beam_hitlight[0] = 0;
1382                                 this.beam_hitlight[1] = 1;
1383                                 this.beam_hitlight[2] = 1;
1384                                 this.beam_hitlight[3] = 1;
1385                                 this.beam_muzzleeffect = EFFECT_Null;
1386                                 this.beam_muzzlelight[0] = 0;
1387                                 this.beam_muzzlelight[1] = 1;
1388                                 this.beam_muzzlelight[2] = 1;
1389                                 this.beam_muzzlelight[3] = 1;
1390                                 this.beam_image = "particles/lgbeam";
1391                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1392                                 {
1393                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1394                                         flash.alpha = this.beam_alpha;
1395                                         flash.colormod = this.beam_color;
1396                                         flash.scale = 0.35;
1397                                 }
1398                                 break;
1399                         }
1400                         case ARC_BT_BURST_WALL:
1401                         {
1402                                 this.beam_color = beamcolor;
1403                                 this.beam_alpha = 0.5;
1404                                 this.beam_thickness = 14;
1405                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1406                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1407                                 this.beam_hitlight[0] = 0;
1408                                 this.beam_hitlight[1] = 1;
1409                                 this.beam_hitlight[2] = 1;
1410                                 this.beam_hitlight[3] = 1;
1411                                 this.beam_muzzleeffect = EFFECT_Null;
1412                                 this.beam_muzzlelight[0] = 0;
1413                                 this.beam_muzzlelight[1] = 1;
1414                                 this.beam_muzzlelight[2] = 1;
1415                                 this.beam_muzzlelight[3] = 1;
1416                                 this.beam_image = "particles/lgbeam";
1417                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1418                                 {
1419                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1420                                         flash.alpha = this.beam_alpha;
1421                                         flash.colormod = this.beam_color;
1422                                         flash.scale = 0.35;
1423                                 }
1424                                 break;
1425                         }
1426                         case ARC_BT_BURST_HEAL:
1427                         {
1428                                 this.beam_color = beamcolor;
1429                                 this.beam_alpha = 0.5;
1430                                 this.beam_thickness = 14;
1431                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1432                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT2);
1433                                 this.beam_hitlight[0] = 0;
1434                                 this.beam_hitlight[1] = 1;
1435                                 this.beam_hitlight[2] = 1;
1436                                 this.beam_hitlight[3] = 1;
1437                                 this.beam_muzzleeffect = EFFECT_Null;
1438                                 this.beam_muzzlelight[0] = 0;
1439                                 this.beam_muzzlelight[1] = 1;
1440                                 this.beam_muzzlelight[2] = 1;
1441                                 this.beam_muzzlelight[3] = 1;
1442                                 this.beam_image = "particles/lgbeam";
1443                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1444                                 {
1445                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1446                                         flash.alpha = this.beam_alpha;
1447                                         flash.colormod = this.beam_color;
1448                                         flash.scale = 0.35;
1449                                 }
1450                                 break;
1451                         }
1452                         case ARC_BT_BURST_HIT:
1453                         {
1454                                 this.beam_color = beamcolor;
1455                                 this.beam_alpha = 0.5;
1456                                 this.beam_thickness = 14;
1457                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1458                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1459                                 this.beam_hitlight[0] = 0;
1460                                 this.beam_hitlight[1] = 1;
1461                                 this.beam_hitlight[2] = 1;
1462                                 this.beam_hitlight[3] = 1;
1463                                 this.beam_muzzleeffect = EFFECT_Null;
1464                                 this.beam_muzzlelight[0] = 0;
1465                                 this.beam_muzzlelight[1] = 1;
1466                                 this.beam_muzzlelight[2] = 1;
1467                                 this.beam_muzzlelight[3] = 1;
1468                                 this.beam_image = "particles/lgbeam";
1469                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1470                                 {
1471                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1472                                         flash.alpha = this.beam_alpha;
1473                                         flash.colormod = this.beam_color;
1474                                         flash.scale = 0.35;
1475                                 }
1476                                 break;
1477                         }
1478
1479                         // shouldn't be possible, but lets make it colorful if it does :D
1480                         default:
1481                         {
1482                                 this.beam_color = randomvec();
1483                                 this.beam_alpha = 1;
1484                                 this.beam_thickness = 8;
1485                                 this.beam_traileffect = NULL;
1486                                 this.beam_hiteffect = NULL;
1487                                 this.beam_hitlight[0] = 0;
1488                                 this.beam_hitlight[1] = 1;
1489                                 this.beam_hitlight[2] = 1;
1490                                 this.beam_hitlight[3] = 1;
1491                                 this.beam_muzzleeffect = EFFECT_Null;
1492                                 this.beam_muzzlelight[0] = 0;
1493                                 this.beam_muzzlelight[1] = 1;
1494                                 this.beam_muzzlelight[2] = 1;
1495                                 this.beam_muzzlelight[3] = 1;
1496                                 this.beam_image = "particles/lgbeam";
1497                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1498                                 {
1499                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1500                                         flash.alpha = this.beam_alpha;
1501                                         flash.colormod = this.beam_color;
1502                                         flash.scale = 0.35;
1503                                 }
1504                                 break;
1505                         }
1506                 }
1507         }
1508
1509         if(!this.beam_usevieworigin)
1510         {
1511                 InterpolateOrigin_Note(this);
1512         }
1513         return true;
1514 }
1515
1516 #endif