qcsrc/common/weapons/weapon/arc.qc

   1 #include "arc.qh"
   2
   3 #ifdef SVQC
   4
   5 bool W_Arc_Beam_Send(entity this, entity to, int sf)
   6 {
   7         WriteHeader(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
   8
   9         // Truncate information when this beam is displayed to the owner client
  10         // - The owner client has no use for beam start position or directions,
  11         //    it always figures this information out for itself with csqc code.
  12         // - Spectating the owner also truncates this information.
  13         float drawlocal = ((to == this.owner) || ((to.enemy == this.owner) && IS_SPEC(to)));
  14         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
  15
  16         WriteByte(MSG_ENTITY, sf);
  17         WriteByte(MSG_ENTITY, weaponslot(this.weaponentity_fld));
  18
  19         if(sf & ARC_SF_SETTINGS) // settings information
  20         {
  21                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
  22                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
  23                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
  24                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
  25                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
  26                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
  27
  28                 WriteByte(MSG_ENTITY, drawlocal);
  29                 WriteByte(MSG_ENTITY, etof(this.owner));
  30         }
  31         if(sf & ARC_SF_START) // starting location
  32         {
  33                 WriteCoord(MSG_ENTITY, this.beam_start.x);
  34                 WriteCoord(MSG_ENTITY, this.beam_start.y);
  35                 WriteCoord(MSG_ENTITY, this.beam_start.z);
  36         }
  37         if(sf & ARC_SF_WANTDIR) // want/aim direction
  38         {
  39                 WriteCoord(MSG_ENTITY, this.beam_wantdir.x);
  40                 WriteCoord(MSG_ENTITY, this.beam_wantdir.y);
  41                 WriteCoord(MSG_ENTITY, this.beam_wantdir.z);
  42         }
  43         if(sf & ARC_SF_BEAMDIR) // beam direction
  44         {
  45                 WriteCoord(MSG_ENTITY, this.beam_dir.x);
  46                 WriteCoord(MSG_ENTITY, this.beam_dir.y);
  47                 WriteCoord(MSG_ENTITY, this.beam_dir.z);
  48         }
  49         if(sf & ARC_SF_BEAMTYPE) // beam type
  50         {
  51                 WriteByte(MSG_ENTITY, this.beam_type);
  52         }
  53
  54         return true;
  55 }
  56
  57 void Reset_ArcBeam(entity player, vector forward)
  58 {
  59         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  60         {
  61                 .entity weaponentity = weaponentities[slot];
  62                 if(!player.(weaponentity).arc_beam)
  63                         continue;
  64                 player.(weaponentity).arc_beam.beam_dir = forward;
  65                 player.(weaponentity).arc_beam.beam_teleporttime = time;
  66         }
  67 }
  68
  69 float Arc_GetHeat_Percent(entity player, .entity weaponentity)
  70 {
  71         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
  72         {
  73                 player.arc_overheat = 0;
  74                 return 0;
  75         }
  76
  77         if ( player.(weaponentity).arc_beam )
  78                 return player.(weaponentity).arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
  79
  80         if ( player.arc_overheat > time )
  81         {
  82                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
  83                         * player.arc_cooldown;
  84         }
  85
  86         return 0;
  87 }
  88 void Arc_Player_SetHeat(entity player, .entity weaponentity)
  89 {
  90         player.(weaponentity).arc_heat_percent = Arc_GetHeat_Percent(player, weaponentity);
  91         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
  92 }
  93
  94 void W_Arc_Bolt_Explode(entity this, entity directhitentity)
  95 {
  96         this.event_damage = func_null;
  97         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, this.weaponentity_fld, directhitentity);
  98
  99         delete(this);
 100 }
 101
 102 void W_Arc_Bolt_Explode_use(entity this, entity actor, entity trigger)
 103 {
 104         W_Arc_Bolt_Explode(this, trigger);
 105 }
 106
 107 void W_Arc_Bolt_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 108 {
 109         if(this.health <= 0)
 110                 return;
 111
 112         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1))
 113                 return; // g_projectiles_damage says to halt
 114
 115         this.health = this.health - damage;
 116         this.angles = vectoangles(this.velocity);
 117
 118         if(this.health <= 0)
 119                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 120 }
 121
 122 void W_Arc_Bolt_Touch(entity this, entity toucher)
 123 {
 124         PROJECTILE_TOUCH(this, toucher);
 125         this.use(this, NULL, toucher);
 126 }
 127
 128 void W_Arc_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity)
 129 {
 130         entity missile;
 131
 132         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(arc, bolt_ammo), weaponentity);
 133
 134         W_SetupShot(actor, weaponentity, false, 2, SND_LASERGUN_FIRE, CH_WEAPON_A, WEP_CVAR(arc, bolt_damage));
 135
 136         Send_Effect(EFFECT_ARC_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 137
 138         missile = new(missile);
 139         missile.owner = missile.realowner = actor;
 140         missile.bot_dodge = true;
 141         IL_PUSH(g_bot_dodge, missile);
 142         missile.bot_dodgerating = WEP_CVAR(arc, bolt_damage);
 143
 144         missile.takedamage = DAMAGE_YES;
 145         missile.health = WEP_CVAR(arc, bolt_health);
 146         missile.damageforcescale = WEP_CVAR(arc, bolt_damageforcescale);
 147         missile.event_damage = W_Arc_Bolt_Damage;
 148         missile.damagedbycontents = true;
 149         IL_PUSH(g_damagedbycontents, missile);
 150
 151         settouch(missile, W_Arc_Bolt_Touch);
 152         missile.use = W_Arc_Bolt_Explode_use;
 153         setthink(missile, adaptor_think2use_hittype_splash);
 154         missile.nextthink = time + WEP_CVAR(arc, bolt_lifetime);
 155         PROJECTILE_MAKETRIGGER(missile);
 156         missile.projectiledeathtype = WEP_ARC.m_id | HITTYPE_SECONDARY;
 157         missile.weaponentity_fld = weaponentity;
 158         setorigin(missile, w_shotorg);
 159         setsize(missile, '0 0 0', '0 0 0');
 160
 161         set_movetype(missile, MOVETYPE_FLY);
 162         W_SetupProjVelocity_PRE(missile, arc, bolt_);
 163
 164         missile.angles = vectoangles(missile.velocity);
 165         missile.flags = FL_PROJECTILE;
 166         missile.missile_flags = MIF_SPLASH;
 167
 168         CSQCProjectile(missile, true, PROJECTILE_ARC_BOLT, true);
 169
 170         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 171 }
 172
 173 void W_Arc_Beam_Think(entity this)
 174 {
 175         .entity weaponentity = this.weaponentity_fld;
 176         entity own = this.owner;
 177         if(this != own.(weaponentity).arc_beam)
 178         {
 179                 delete(this);
 180                 return;
 181         }
 182
 183         float burst = 0;
 184         if( (PHYS_INPUT_BUTTON_ATCK2(own) && !WEP_CVAR(arc, bolt)) || this.beam_bursting)
 185         {
 186                 if(!this.beam_bursting)
 187                         this.beam_bursting = true;
 188                 burst = ARC_BT_BURSTMASK;
 189         }
 190
 191         Weapon thiswep = WEP_ARC;
 192
 193         if(
 194                 !IS_PLAYER(own)
 195                 ||
 196                 (!thiswep.wr_checkammo1(thiswep, own, weaponentity) && !(own.items & IT_UNLIMITED_WEAPON_AMMO))
 197                 ||
 198                 IS_DEAD(own)
 199                 ||
 200                 forbidWeaponUse(own)
 201                 ||
 202                 own.(weaponentity).m_switchweapon != WEP_ARC
 203                 ||
 204                 (!PHYS_INPUT_BUTTON_ATCK(own) && !burst )
 205                 ||
 206                 own.vehicle
 207                 ||
 208                 (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max))
 209         )
 210         {
 211                 if ( WEP_CVAR(arc, cooldown) > 0 )
 212                 {
 213                         float cooldown_speed = 0;
 214                         if ( this.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 215                         {
 216                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 217                         }
 218                         else if ( !burst )
 219                         {
 220                                 cooldown_speed = this.beam_heat / WEP_CVAR(arc, beam_refire);
 221                         }
 222
 223                         if ( cooldown_speed )
 224                         {
 225                                 if ( WEP_CVAR(arc, cooldown_release) || (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max)) )
 226                                         own.arc_overheat = time + this.beam_heat / cooldown_speed;
 227                                 own.arc_cooldown = cooldown_speed;
 228                         }
 229
 230                         if ( WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max) )
 231                         {
 232                                 Send_Effect(EFFECT_ARC_OVERHEAT,
 233                                         this.beam_start, this.beam_wantdir, 1 );
 234                                 sound(this, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 235                         }
 236                 }
 237
 238                 if(this == own.(weaponentity).arc_beam) { own.(weaponentity).arc_beam = NULL; }
 239                 if(!thiswep.wr_checkammo1(thiswep, own, weaponentity) && !(own.items & IT_UNLIMITED_WEAPON_AMMO))
 240                 {
 241                         // note: this doesn't force the switch
 242                         W_SwitchToOtherWeapon(own, weaponentity);
 243                         own.(weaponentity).arc_BUTTON_ATCK_prev = false; // hax
 244                 }
 245                 delete(this);
 246                 return;
 247         }
 248
 249         // decrease ammo
 250         float coefficient = frametime;
 251         if(!(own.items & IT_UNLIMITED_WEAPON_AMMO))
 252         {
 253                 float rootammo;
 254                 if(burst)
 255                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 256                 else
 257                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 258
 259                 if(rootammo)
 260                 {
 261                         coefficient = min(coefficient, GetResourceAmount(own, thiswep.ammo_type) / rootammo);
 262                         SetResourceAmount(own, thiswep.ammo_type, max(0, GetResourceAmount(own, thiswep.ammo_type) - (rootammo * frametime)));
 263                 }
 264         }
 265         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 266         this.beam_heat = min( WEP_CVAR(arc, overheat_max), this.beam_heat + heat_speed*frametime );
 267
 268         makevectors(own.v_angle);
 269
 270         W_SetupShot_Range(
 271                 own,
 272                 weaponentity, // TODO
 273                 true,
 274                 0,
 275                 SND_Null,
 276                 0,
 277                 WEP_CVAR(arc, beam_damage) * coefficient,
 278                 WEP_CVAR(arc, beam_range)
 279         );
 280
 281         // After teleport, "lock" the beam until the teleport is confirmed.
 282         if (time < this.beam_teleporttime + ANTILAG_LATENCY(own)) {
 283                 w_shotdir = this.beam_dir;
 284         }
 285
 286         // network information: shot origin and want/aim direction
 287         if(this.beam_start != w_shotorg)
 288         {
 289                 this.SendFlags |= ARC_SF_START;
 290                 this.beam_start = w_shotorg;
 291         }
 292         if(this.beam_wantdir != w_shotdir)
 293         {
 294                 this.SendFlags |= ARC_SF_WANTDIR;
 295                 this.beam_wantdir = w_shotdir;
 296         }
 297
 298         if(!this.beam_initialized)
 299         {
 300                 this.beam_dir = w_shotdir;
 301                 this.beam_initialized = true;
 302         }
 303
 304         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 305         // idea: blend together this.beam_dir with the inverted direction the player is moving in
 306         // might have to make some special accomodation so that it only uses view_right and view_up
 307
 308         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 309
 310         float segments;
 311         if(this.beam_dir != w_shotdir)
 312         {
 313                 // calculate how much we're going to move the end of the beam to the want position
 314                 // WEAPONTODO (server and client):
 315                 // blendfactor never actually becomes 0 in this situation, which is a problem
 316                 // regarding precision... this means that this.beam_dir and w_shotdir approach
 317                 // eachother, however they never actually become the same value with this method.
 318                 // Perhaps we should do some form of rounding/snapping?
 319                 float angle = vlen(w_shotdir - this.beam_dir) * RAD2DEG;
 320                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 321                 {
 322                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 323                         float blendfactor = bound(
 324                                 0,
 325                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 326                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 327                         );
 328                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 329                 }
 330                 else
 331                 {
 332                         // the radius is not too far yet, no worries :D
 333                         float blendfactor = bound(
 334                                 0,
 335                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 336                                 1
 337                         );
 338                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 339                 }
 340
 341                 // network information: beam direction
 342                 this.SendFlags |= ARC_SF_BEAMDIR;
 343
 344                 // calculate how many segments are needed
 345                 float max_allowed_segments;
 346
 347                 if(WEP_CVAR(arc, beam_distancepersegment))
 348                 {
 349                         max_allowed_segments = min(
 350                                 ARC_MAX_SEGMENTS,
 351                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 352                         );
 353                 }
 354                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 355
 356                 if(WEP_CVAR(arc, beam_degreespersegment))
 357                 {
 358                         segments = bound(
 359                                 1,
 360                                 (
 361                                         min(
 362                                                 angle,
 363                                                 WEP_CVAR(arc, beam_maxangle)
 364                                         )
 365                                         /
 366                                         WEP_CVAR(arc, beam_degreespersegment)
 367                                 ),
 368                                 max_allowed_segments
 369                         );
 370                 }
 371                 else { segments = 1; }
 372         }
 373         else { segments = 1; }
 374
 375         vector beam_endpos = (w_shotorg + (this.beam_dir * WEP_CVAR(arc, beam_range)));
 376         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 377
 378         float i;
 379         float new_beam_type = 0;
 380         vector last_origin = w_shotorg;
 381         for(i = 1; i <= segments; ++i)
 382         {
 383                 // WEAPONTODO (client):
 384                 // In order to do nice fading and pointing on the starting segment, we must always
 385                 // have that drawn as a separate triangle... However, that is difficult to do when
 386                 // keeping in mind the above problems and also optimizing the amount of segments
 387                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 388
 389                 vector new_origin = bezier_quadratic_getpoint(
 390                         w_shotorg,
 391                         beam_controlpoint,
 392                         beam_endpos,
 393                         i / segments);
 394                 vector new_dir = normalize(new_origin - last_origin);
 395
 396                 WarpZone_traceline_antilag(
 397                         own,
 398                         last_origin,
 399                         new_origin,
 400                         MOVE_NORMAL,
 401                         own,
 402                         ANTILAG_LATENCY(own)
 403                 );
 404
 405                 // Do all the transforms for warpzones right now, as we already
 406                 // "are" in the post-trace system (if we hit a player, that's
 407                 // always BEHIND the last passed wz).
 408                 last_origin = trace_endpos;
 409                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 410                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 411                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 412                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 413
 414                 float is_player = (
 415                         IS_PLAYER(trace_ent)
 416                         ||
 417                         trace_ent.classname == "body"
 418                         ||
 419                         IS_MONSTER(trace_ent)
 420                 );
 421
 422                 if(trace_ent && trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 423                 {
 424                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 425                         // NO. trace_endpos should be just fine. If not,
 426                         // that's an engine bug that needs proper debugging.
 427                         vector hitorigin = trace_endpos;
 428
 429                         float falloff = ExponentialFalloff(
 430                                 WEP_CVAR(arc, beam_falloff_mindist),
 431                                 WEP_CVAR(arc, beam_falloff_maxdist),
 432                                 WEP_CVAR(arc, beam_falloff_halflifedist),
 433                                 vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 434                         );
 435
 436                         if(is_player && SAME_TEAM(own, trace_ent))
 437                         {
 438                                 float roothealth, rootarmor;
 439                                 if(burst)
 440                                 {
 441                                         roothealth = WEP_CVAR(arc, burst_healing_hps);
 442                                         rootarmor = WEP_CVAR(arc, burst_healing_aps);
 443                                 }
 444                                 else
 445                                 {
 446                                         roothealth = WEP_CVAR(arc, beam_healing_hps);
 447                                         rootarmor = WEP_CVAR(arc, beam_healing_aps);
 448                                 }
 449
 450                                 if(trace_ent.health <= WEP_CVAR(arc, beam_healing_hmax) && roothealth)
 451                                 {
 452                                         trace_ent.health = min(
 453                                                 trace_ent.health + (roothealth * coefficient),
 454                                                 WEP_CVAR(arc, beam_healing_hmax)
 455                                         );
 456                                 }
 457                                 if(trace_ent.armorvalue <= WEP_CVAR(arc, beam_healing_amax) && rootarmor)
 458                                 {
 459                                         trace_ent.armorvalue = min(
 460                                                 trace_ent.armorvalue + (rootarmor * coefficient),
 461                                                 WEP_CVAR(arc, beam_healing_amax)
 462                                         );
 463                                 }
 464
 465                                 // stop rot, set visual effect
 466                                 if(roothealth || rootarmor)
 467                                 {
 468                                         trace_ent.pauserothealth_finished = max(
 469                                                 trace_ent.pauserothealth_finished,
 470                                                 time + autocvar_g_balance_pause_health_rot
 471                                         );
 472                                         trace_ent.pauserotarmor_finished = max(
 473                                                 trace_ent.pauserotarmor_finished,
 474                                                 time + autocvar_g_balance_pause_armor_rot
 475                                         );
 476                                         new_beam_type = ARC_BT_HEAL;
 477                                 }
 478                         }
 479                         else
 480                         {
 481                                 float rootdamage;
 482                                 if(is_player)
 483                                 {
 484                                         if(burst)
 485                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 486                                         else
 487                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 488                                 }
 489                                 else
 490                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 491
 492                                 if(accuracy_isgooddamage(own, trace_ent))
 493                                 {
 494                                         accuracy_add(
 495                                                 own,
 496                                                 WEP_ARC.m_id,
 497                                                 0,
 498                                                 rootdamage * coefficient * falloff
 499                                         );
 500                                 }
 501
 502                                 Damage(
 503                                         trace_ent,
 504                                         own,
 505                                         own,
 506                                         rootdamage * coefficient * falloff,
 507                                         WEP_ARC.m_id,
 508                                         weaponentity,
 509                                         hitorigin,
 510                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 511                                 );
 512
 513                                 new_beam_type = ARC_BT_HIT;
 514                         }
 515                         break;
 516                 }
 517                 else if(trace_fraction != 1)
 518                 {
 519                         // we collided with geometry
 520                         new_beam_type = ARC_BT_WALL;
 521                         break;
 522                 }
 523         }
 524
 525         // te_explosion(trace_endpos);
 526
 527         // if we're bursting, use burst visual effects
 528         new_beam_type |= burst;
 529
 530         // network information: beam type
 531         if(new_beam_type != this.beam_type)
 532         {
 533                 this.SendFlags |= ARC_SF_BEAMTYPE;
 534                 this.beam_type = new_beam_type;
 535         }
 536
 537         own.(weaponentity).beam_prev = time;
 538         this.nextthink = time;
 539 }
 540
 541 void W_Arc_Beam(float burst, entity actor, .entity weaponentity)
 542 {
 543
 544         // only play fire sound if 1 sec has passed since player let go the fire button
 545         if(time - actor.(weaponentity).beam_prev > 1)
 546                 sound(actor, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 547
 548         entity beam = actor.(weaponentity).arc_beam = new(W_Arc_Beam);
 549         beam.weaponentity_fld = weaponentity;
 550         beam.solid = SOLID_NOT;
 551         setthink(beam, W_Arc_Beam_Think);
 552         beam.owner = actor;
 553         set_movetype(beam, MOVETYPE_NONE);
 554         beam.bot_dodge = true;
 555         IL_PUSH(g_bot_dodge, beam);
 556         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 557         beam.beam_bursting = burst;
 558         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 559
 560         getthink(beam)(beam);
 561 }
 562 void Arc_Smoke(entity actor, .entity weaponentity)
 563 {
 564         makevectors(actor.v_angle);
 565         W_SetupShot_Range(actor,weaponentity,true,0,SND_Null,0,0,0);
 566
 567         vector smoke_origin = w_shotorg + actor.velocity*frametime;
 568         if ( actor.arc_overheat > time )
 569         {
 570                 if ( random() < actor.(weaponentity).arc_heat_percent )
 571                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 572                 if ( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) )
 573                 {
 574                         Send_Effect(EFFECT_ARC_OVERHEAT_FIRE, smoke_origin, w_shotdir, 1 );
 575                         if ( !actor.arc_smoke_sound )
 576                         {
 577                                 actor.arc_smoke_sound = 1;
 578                                 sound(actor, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 579                         }
 580                 }
 581         }
 582         else if ( actor.(weaponentity).arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 583                         actor.(weaponentity).arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 584         {
 585                 if ( random() < (actor.(weaponentity).arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 586                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 587                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 588         }
 589
 590         if (  actor.arc_smoke_sound && ( actor.arc_overheat <= time ||
 591                 !( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) ) ) || actor.(weaponentity).m_switchweapon != WEP_ARC )
 592         {
 593                 actor.arc_smoke_sound = 0;
 594                 sound(actor, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 595         }
 596 }
 597
 598 METHOD(Arc, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 599 {
 600     if(WEP_CVAR(arc, beam_botaimspeed))
 601     {
 602         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 603                 actor,
 604                 weaponentity,
 605             WEP_CVAR(arc, beam_botaimspeed),
 606             0,
 607             WEP_CVAR(arc, beam_botaimlifetime),
 608             false
 609         );
 610     }
 611     else
 612     {
 613         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 614                 actor,
 615                 weaponentity,
 616             1000000,
 617             0,
 618             0.001,
 619             false
 620         );
 621     }
 622 }
 623 METHOD(Arc, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 624 {
 625     Arc_Player_SetHeat(actor, weaponentity);
 626     Arc_Smoke(actor, weaponentity);
 627
 628     bool beam_fire2 = ((fire & 2) && !WEP_CVAR(arc, bolt));
 629
 630     if (time >= actor.arc_overheat)
 631     if ((fire & 1) || beam_fire2 || actor.(weaponentity).arc_beam.beam_bursting)
 632     {
 633
 634         if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 635         {
 636             #if 0
 637             if(actor.animstate_startframe == actor.anim_shoot.x && actor.animstate_numframes == actor.anim_shoot.y)
 638                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 639             else
 640             #endif
 641                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), w_ready);
 642         }
 643
 644         if((!actor.(weaponentity).arc_beam) || wasfreed(actor.(weaponentity).arc_beam))
 645         {
 646             if(weapon_prepareattack(thiswep, actor, weaponentity, boolean(beam_fire2), 0))
 647             {
 648                 W_Arc_Beam(boolean(beam_fire2), actor, weaponentity);
 649
 650                 if(!actor.(weaponentity).arc_BUTTON_ATCK_prev)
 651                 {
 652                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 653                     actor.(weaponentity).arc_BUTTON_ATCK_prev = true;
 654                 }
 655             }
 656         }
 657
 658         return;
 659     }
 660     else if(fire & 2)
 661     {
 662         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(arc, bolt_refire)))
 663         {
 664             W_Arc_Attack_Bolt(thiswep, actor, weaponentity);
 665             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), w_ready);
 666         }
 667     }
 668
 669     if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 670     {
 671         int slot = weaponslot(weaponentity);
 672         sound(actor, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 673         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 674         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor(actor);
 675     }
 676     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 677
 678     #if 0
 679     if(fire & 2)
 680     if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_arc_secondary_refire))
 681     {
 682         W_Arc_Attack2();
 683         actor.arc_count = autocvar_g_balance_arc_secondary_count;
 684         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 685         actor.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor(actor);
 686     }
 687     #endif
 688 }
 689 METHOD(Arc, wr_init, void(entity thiswep))
 690 {
 691     if(!arc_shotorigin[0])
 692     {
 693         arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 694         arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 695         arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 696         arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 697     }
 698 }
 699 METHOD(Arc, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 700 {
 701     return ((!WEP_CVAR(arc, beam_ammo)) || (GetResourceAmount(actor, thiswep.ammo_type) > 0));
 702 }
 703 METHOD(Arc, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 704 {
 705     if(WEP_CVAR(arc, bolt))
 706     {
 707         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(arc, bolt_ammo);
 708         ammo_amount += actor.(weaponentity).(weapon_load[WEP_ARC.m_id]) >= WEP_CVAR(arc, bolt_ammo);
 709         return ammo_amount;
 710     }
 711     else
 712         return WEP_CVAR(arc, overheat_max) > 0 &&
 713             ((!WEP_CVAR(arc, burst_ammo)) || (GetResourceAmount(actor, thiswep.ammo_type) > 0));
 714 }
 715 METHOD(Arc, wr_killmessage, Notification(entity thiswep))
 716 {
 717     if(w_deathtype & HITTYPE_SECONDARY)
 718         return WEAPON_ARC_MURDER_SPRAY;
 719     else
 720         return WEAPON_ARC_MURDER;
 721 }
 722 METHOD(Arc, wr_drop, void(entity thiswep, entity actor, .entity weaponentity))
 723 {
 724     weapon_dropevent_item.arc_overheat = actor.arc_overheat;
 725     weapon_dropevent_item.arc_cooldown = actor.arc_cooldown;
 726     actor.arc_overheat = 0;
 727     actor.arc_cooldown = 0;
 728     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 729 }
 730 METHOD(Arc, wr_pickup, void(entity thiswep, entity actor, .entity weaponentity))
 731 {
 732     if ( !client_hasweapon(actor, thiswep, weaponentity, false, false) &&
 733         weapon_dropevent_item.arc_overheat > time )
 734     {
 735         actor.arc_overheat = weapon_dropevent_item.arc_overheat;
 736         actor.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 737     }
 738 }
 739 METHOD(Arc, wr_resetplayer, void(entity thiswep, entity actor))
 740 {
 741     actor.arc_overheat = 0;
 742     actor.arc_cooldown = 0;
 743     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744     {
 745         .entity weaponentity = weaponentities[slot];
 746         actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 747     }
 748 }
 749 METHOD(Arc, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
 750 {
 751     actor.arc_overheat = 0;
 752     actor.arc_cooldown = 0;
 753     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 754 }
 755 #endif
 756 #ifdef CSQC
 757 bool autocvar_cl_arcbeam_teamcolor = true;
 758
 759 METHOD(Arc, wr_impacteffect, void(entity thiswep, entity actor))
 760 {
 761     if(w_deathtype & HITTYPE_SECONDARY)
 762     {
 763         vector org2;
 764         org2 = w_org + w_backoff * 6;
 765         pointparticles(EFFECT_ARC_BOLT_EXPLODE, org2, w_backoff * 1000, 1);
 766         if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 767     }
 768 }
 769
 770 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 771 {
 772         entity beam = Draw_ArcBeam_callback_entity;
 773         vector transformed_view_org;
 774         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 775
 776         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 777         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 778         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 779
 780         vector hitorigin;
 781
 782         // draw segment
 783         #if 0
 784         if(trace_fraction != 1)
 785         {
 786                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 787                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 788                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 789         }
 790         else
 791         {
 792                 hitorigin = hit;
 793         }
 794         #else
 795         hitorigin = hit;
 796         #endif
 797
 798         // decide upon thickness
 799         float thickness = beam.beam_thickness;
 800
 801         // draw primary beam render
 802         vector top    = hitorigin + (thickdir * thickness);
 803         vector bottom = hitorigin - (thickdir * thickness);
 804
 805         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 806         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 807
 808         R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 809         R_PolygonVertex(
 810                 top,
 811                 '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 812                 beam.beam_color,
 813                 beam.beam_alpha
 814         );
 815         R_PolygonVertex(
 816                 last_top,
 817                 '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 818                 beam.beam_color,
 819                 beam.beam_alpha
 820         );
 821         R_PolygonVertex(
 822                 last_bottom,
 823                 '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 824                 beam.beam_color,
 825                 beam.beam_alpha
 826         );
 827         R_PolygonVertex(
 828                 bottom,
 829                 '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 830                 beam.beam_color,
 831                 beam.beam_alpha
 832         );
 833         R_EndPolygon();
 834
 835         // draw trailing particles
 836         // NOTES:
 837         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 838         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 839         if(beam.beam_traileffect)
 840         {
 841                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 842         }
 843
 844         // set up for the next
 845         Draw_ArcBeam_callback_last_thickness = thickness;
 846         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 847         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 848 }
 849
 850 void Reset_ArcBeam()
 851 {
 852         entity e;
 853         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 854                 e.beam_initialized = false;
 855         }
 856         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 857                 e.beam_initialized = false;
 858         }
 859 }
 860
 861 void Draw_ArcBeam(entity this)
 862 {
 863         float dt = time - this.move_time;
 864         this.move_time = time;
 865         if(dt <= 0) { return; }
 866
 867         if(!this.beam_usevieworigin)
 868         {
 869                 InterpolateOrigin_Do(this);
 870         }
 871
 872         // origin = beam starting origin
 873         // v_angle = wanted/aim direction
 874         // angles = current direction of beam
 875
 876         vector start_pos;
 877         vector wantdir; //= view_forward;
 878         vector beamdir; //= this.beam_dir;
 879
 880         float segments;
 881         if(this.beam_usevieworigin)
 882         {
 883                 // WEAPONTODO:
 884                 // Currently we have to replicate nearly the same method of figuring
 885                 // out the shotdir that the server does... Ideally in the future we
 886                 // should be able to acquire this from a generalized function built
 887                 // into a weapon system for client code.
 888
 889                 // find where we are aiming
 890                 makevectors(warpzone_save_view_angles);
 891                 vector forward = v_forward;
 892                 vector right = v_right;
 893                 vector up = v_up;
 894
 895                 // decide upon start position
 896                 if(this.beam_usevieworigin == 2)
 897                         { start_pos = warpzone_save_view_origin; }
 898                 else
 899                         { start_pos = this.origin; }
 900
 901                 // trace forward with an estimation
 902                 WarpZone_TraceLine(
 903                         start_pos,
 904                         start_pos + forward * this.beam_range,
 905                         MOVE_NOMONSTERS,
 906                         this
 907                 );
 908
 909                 // untransform in case our trace went through a warpzone
 910                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 911
 912                 // un-adjust trueaim if shotend is too close
 913                 if(vdist(end_pos - start_pos, <, g_trueaim_minrange))
 914                         end_pos = start_pos + (forward * g_trueaim_minrange);
 915
 916                 // move shot origin to the actual gun muzzle origin
 917                 vector origin_offset =
 918                           right * -this.beam_shotorigin.y
 919                         + up * this.beam_shotorigin.z;
 920
 921                 start_pos = start_pos + origin_offset;
 922
 923                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 924                 traceline(start_pos, start_pos + forward * this.beam_shotorigin.x, MOVE_NORMAL, this);
 925                 start_pos = trace_endpos;
 926
 927                 // calculate the aim direction now
 928                 wantdir = normalize(end_pos - start_pos);
 929
 930                 if(!this.beam_initialized)
 931                 {
 932                         this.beam_dir = wantdir;
 933                         this.beam_initialized = true;
 934                 }
 935
 936                 if(this.beam_dir != wantdir)
 937                 {
 938                         // calculate how much we're going to move the end of the beam to the want position
 939                         // WEAPONTODO (server and client):
 940                         // blendfactor never actually becomes 0 in this situation, which is a problem
 941                         // regarding precision... this means that this.beam_dir and w_shotdir approach
 942                         // eachother, however they never actually become the same value with this method.
 943                         // Perhaps we should do some form of rounding/snapping?
 944                         float angle = vlen(wantdir - this.beam_dir) * RAD2DEG;
 945                         if(angle && (angle > this.beam_maxangle))
 946                         {
 947                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 948                                 float blendfactor = bound(
 949                                         0,
 950                                         (1 - (this.beam_returnspeed * frametime)),
 951                                         min(this.beam_maxangle / angle, 1)
 952                                 );
 953                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 954                         }
 955                         else
 956                         {
 957                                 // the radius is not too far yet, no worries :D
 958                                 float blendfactor = bound(
 959                                         0,
 960                                         (1 - (this.beam_returnspeed * frametime)),
 961                                         1
 962                                 );
 963                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 964                         }
 965
 966                         // calculate how many segments are needed
 967                         float max_allowed_segments;
 968
 969                         if(this.beam_distancepersegment)
 970                         {
 971                                 max_allowed_segments = min(
 972                                         ARC_MAX_SEGMENTS,
 973                                         1 + (vlen(wantdir / this.beam_distancepersegment))
 974                                 );
 975                         }
 976                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 977
 978                         if(this.beam_degreespersegment)
 979                         {
 980                                 segments = bound(
 981                                         1,
 982                                         (
 983                                                 min(
 984                                                         angle,
 985                                                         this.beam_maxangle
 986                                                 )
 987                                                 /
 988                                                 this.beam_degreespersegment
 989                                         ),
 990                                         max_allowed_segments
 991                                 );
 992                         }
 993                         else { segments = 1; }
 994                 }
 995                 else { segments = 1; }
 996
 997                 // set the beam direction which the rest of the code will refer to
 998                 beamdir = this.beam_dir;
 999
1000                 // finally, set this.angles to the proper direction so that muzzle attachment points in proper direction
1001                 this.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1002         }
1003         else
1004         {
1005                 // set the values from the provided info from the networked entity
1006                 start_pos = this.origin;
1007                 wantdir = this.v_angle;
1008                 beamdir = this.angles;
1009
1010                 if(beamdir != wantdir)
1011                 {
1012                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1013
1014                         // calculate how many segments are needed
1015                         float max_allowed_segments;
1016
1017                         if(this.beam_distancepersegment)
1018                         {
1019                                 max_allowed_segments = min(
1020                                         ARC_MAX_SEGMENTS,
1021                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1022                                 );
1023                         }
1024                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1025
1026                         if(this.beam_degreespersegment)
1027                         {
1028                                 segments = bound(
1029                                         1,
1030                                         (
1031                                                 min(
1032                                                         angle,
1033                                                         this.beam_maxangle
1034                                                 )
1035                                                 /
1036                                                 this.beam_degreespersegment
1037                                         ),
1038                                         max_allowed_segments
1039                                 );
1040                         }
1041                         else { segments = 1; }
1042                 }
1043                 else { segments = 1; }
1044         }
1045
1046         setorigin(this, start_pos);
1047         this.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1048
1049         vector beam_endpos = (start_pos + (beamdir * this.beam_range));
1050         vector beam_controlpoint = start_pos + wantdir * (this.beam_range * (1 - this.beam_tightness));
1051
1052         Draw_ArcBeam_callback_entity = this;
1053         Draw_ArcBeam_callback_last_thickness = 0;
1054         Draw_ArcBeam_callback_last_top = start_pos;
1055         Draw_ArcBeam_callback_last_bottom = start_pos;
1056
1057         vector last_origin = start_pos;
1058         vector original_start_pos = start_pos;
1059
1060         float i;
1061         for(i = 1; i <= segments; ++i)
1062         {
1063                 // WEAPONTODO (client):
1064                 // In order to do nice fading and pointing on the starting segment, we must always
1065                 // have that drawn as a separate triangle... However, that is difficult to do when
1066                 // keeping in mind the above problems and also optimizing the amount of segments
1067                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1068
1069                 vector new_origin = bezier_quadratic_getpoint(
1070                         start_pos,
1071                         beam_controlpoint,
1072                         beam_endpos,
1073                         i / segments);
1074
1075                 WarpZone_TraceBox_ThroughZone(
1076                         last_origin,
1077                         '0 0 0',
1078                         '0 0 0',
1079                         new_origin,
1080                         MOVE_NORMAL,
1081                         NULL,
1082                         NULL,
1083                         Draw_ArcBeam_callback
1084                 );
1085
1086                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1087                 // system (if we hit a player, that's always BEHIND the last passed wz).
1088                 last_origin = trace_endpos;
1089                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1090                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1091                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1092                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1093                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1094                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1095
1096                 if(trace_fraction < 1) { break; }
1097         }
1098
1099         // visual effects for startpoint and endpoint
1100         if(this.beam_hiteffect)
1101         {
1102                 // FIXME we really should do this on the server so it actually
1103                 // matches gameplay. What this client side stuff is doing is no
1104                 // more than guesswork.
1105                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1106                 pointparticles(
1107                         this.beam_hiteffect,
1108                         last_origin,
1109                         beamdir * -1,
1110                         frametime * 2
1111                 );
1112         }
1113         if(this.beam_hitlight[0])
1114         {
1115                 adddynamiclight(
1116                         last_origin,
1117                         this.beam_hitlight[0],
1118                         vec3(
1119                                 this.beam_hitlight[1],
1120                                 this.beam_hitlight[2],
1121                                 this.beam_hitlight[3]
1122                         )
1123                 );
1124         }
1125         if(this.beam_muzzleeffect)
1126         {
1127                 pointparticles(
1128                         this.beam_muzzleeffect,
1129                         original_start_pos + wantdir * 20,
1130                         wantdir * 1000,
1131                         frametime * 0.1
1132                 );
1133         }
1134         if(this.beam_muzzlelight[0])
1135         {
1136                 adddynamiclight(
1137                         original_start_pos + wantdir * 20,
1138                         this.beam_muzzlelight[0],
1139                         vec3(
1140                                 this.beam_muzzlelight[1],
1141                                 this.beam_muzzlelight[2],
1142                                 this.beam_muzzlelight[3]
1143                         )
1144                 );
1145         }
1146
1147         // cleanup
1148         Draw_ArcBeam_callback_entity = NULL;
1149         Draw_ArcBeam_callback_last_thickness = 0;
1150         Draw_ArcBeam_callback_last_top = '0 0 0';
1151         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1152 }
1153
1154 void Remove_ArcBeam(entity this)
1155 {
1156         delete(this.beam_muzzleentity);
1157         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1158 }
1159
1160 NET_HANDLE(ENT_CLIENT_ARC_BEAM, bool isnew)
1161 {
1162         int sf = ReadByte();
1163         int slot = ReadByte();
1164         entity flash;
1165
1166         if(isnew)
1167         {
1168                 int gunalign = W_GunAlign(viewmodels[slot], STAT(GUNALIGN)) - 1;
1169
1170                 this.beam_shotorigin = arc_shotorigin[gunalign];
1171
1172                 // set other main attributes of the beam
1173                 this.draw = Draw_ArcBeam;
1174                 IL_PUSH(g_drawables, this);
1175                 this.entremove = Remove_ArcBeam;
1176                 this.move_time = time;
1177                 loopsound(this, CH_SHOTS_SINGLE, SND_ARC_LOOP, VOL_BASE, ATTEN_NORM);
1178
1179                 flash = spawn();
1180                 flash.owner = this;
1181                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1182                 flash.drawmask = MASK_NORMAL;
1183                 flash.solid = SOLID_NOT;
1184                 flash.avelocity_z = 5000;
1185                 setattachment(flash, this, "");
1186                 setorigin(flash, '0 0 0');
1187
1188                 this.beam_muzzleentity = flash;
1189         }
1190         else
1191         {
1192                 flash = this.beam_muzzleentity;
1193         }
1194
1195         if(sf & ARC_SF_SETTINGS) // settings information
1196         {
1197                 this.beam_degreespersegment = ReadShort();
1198                 this.beam_distancepersegment = ReadShort();
1199                 this.beam_maxangle = ReadShort();
1200                 this.beam_range = ReadCoord();
1201                 this.beam_returnspeed = ReadShort();
1202                 this.beam_tightness = (ReadByte() / 10);
1203
1204                 if(ReadByte())
1205                 {
1206                         if(autocvar_chase_active)
1207                                 { this.beam_usevieworigin = 1; }
1208                         else // use view origin
1209                                 { this.beam_usevieworigin = 2; }
1210                 }
1211                 else
1212                 {
1213                         this.beam_usevieworigin = 0;
1214                 }
1215
1216                 this.sv_entnum = ReadByte();
1217         }
1218
1219         if(!this.beam_usevieworigin)
1220         {
1221                 // this.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1222                 this.iflags = IFLAG_ORIGIN;
1223
1224                 InterpolateOrigin_Undo(this);
1225         }
1226
1227         if(sf & ARC_SF_START) // starting location
1228         {
1229                 this.origin_x = ReadCoord();
1230                 this.origin_y = ReadCoord();
1231                 this.origin_z = ReadCoord();
1232         }
1233         else if(this.beam_usevieworigin) // infer the location from player location
1234         {
1235                 if(this.beam_usevieworigin == 2)
1236                 {
1237                         // use view origin
1238                         this.origin = view_origin;
1239                 }
1240                 else
1241                 {
1242                         // use player origin so that third person display still works
1243                         this.origin = entcs_receiver(player_localnum).origin + ('0 0 1' * STAT(VIEWHEIGHT));
1244                 }
1245         }
1246
1247         setorigin(this, this.origin);
1248
1249         if(sf & ARC_SF_WANTDIR) // want/aim direction
1250         {
1251                 this.v_angle_x = ReadCoord();
1252                 this.v_angle_y = ReadCoord();
1253                 this.v_angle_z = ReadCoord();
1254         }
1255
1256         if(sf & ARC_SF_BEAMDIR) // beam direction
1257         {
1258                 this.angles_x = ReadCoord();
1259                 this.angles_y = ReadCoord();
1260                 this.angles_z = ReadCoord();
1261         }
1262
1263         if(sf & ARC_SF_BEAMTYPE) // beam type
1264         {
1265                 this.beam_type = ReadByte();
1266
1267                 vector beamcolor = ((autocvar_cl_arcbeam_teamcolor) ? colormapPaletteColor(entcs_GetClientColors(this.sv_entnum - 1) & 0x0F, true) : '1 1 1');
1268                 switch(this.beam_type)
1269                 {
1270                         case ARC_BT_MISS:
1271                         {
1272                                 this.beam_color = beamcolor;
1273                                 this.beam_alpha = 0.5;
1274                                 this.beam_thickness = 8;
1275                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1276                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1277                                 this.beam_hitlight[0] = 0;
1278                                 this.beam_hitlight[1] = 1;
1279                                 this.beam_hitlight[2] = 1;
1280                                 this.beam_hitlight[3] = 1;
1281                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1282                                 this.beam_muzzlelight[0] = 0;
1283                                 this.beam_muzzlelight[1] = 1;
1284                                 this.beam_muzzlelight[2] = 1;
1285                                 this.beam_muzzlelight[3] = 1;
1286                                 if(this.beam_muzzleeffect)
1287                                 {
1288                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1289                                         flash.alpha = this.beam_alpha;
1290                                         flash.colormod = this.beam_color;
1291                                         flash.scale = 0.5;
1292                                 }
1293                                 break;
1294                         }
1295                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1296                         {
1297                                 this.beam_color = beamcolor;
1298                                 this.beam_alpha = 0.5;
1299                                 this.beam_thickness = 8;
1300                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1301                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1302                                 this.beam_hitlight[0] = 0;
1303                                 this.beam_hitlight[1] = 1;
1304                                 this.beam_hitlight[2] = 1;
1305                                 this.beam_hitlight[3] = 1;
1306                                 this.beam_muzzleeffect = NULL; // (EFFECT_GRENADE_MUZZLEFLASH);
1307                                 this.beam_muzzlelight[0] = 0;
1308                                 this.beam_muzzlelight[1] = 1;
1309                                 this.beam_muzzlelight[2] = 1;
1310                                 this.beam_muzzlelight[3] = 1;
1311                                 this.beam_image = "particles/lgbeam";
1312                                 if(this.beam_muzzleeffect)
1313                                 {
1314                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1315                                         flash.alpha = this.beam_alpha;
1316                                         flash.colormod = this.beam_color;
1317                                         flash.scale = 0.5;
1318                                 }
1319                                 break;
1320                         }
1321                         case ARC_BT_HEAL:
1322                         {
1323                                 this.beam_color = beamcolor;
1324                                 this.beam_alpha = 0.5;
1325                                 this.beam_thickness = 8;
1326                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1327                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT);
1328                                 this.beam_hitlight[0] = 0;
1329                                 this.beam_hitlight[1] = 1;
1330                                 this.beam_hitlight[2] = 1;
1331                                 this.beam_hitlight[3] = 1;
1332                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1333                                 this.beam_muzzlelight[0] = 0;
1334                                 this.beam_muzzlelight[1] = 1;
1335                                 this.beam_muzzlelight[2] = 1;
1336                                 this.beam_muzzlelight[3] = 1;
1337                                 this.beam_image = "particles/lgbeam";
1338                                 if(this.beam_muzzleeffect)
1339                                 {
1340                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1341                                         flash.alpha = this.beam_alpha;
1342                                         flash.colormod = this.beam_color;
1343                                         flash.scale = 0.5;
1344                                 }
1345                                 break;
1346                         }
1347                         case ARC_BT_HIT:
1348                         {
1349                                 this.beam_color = beamcolor;
1350                                 this.beam_alpha = 0.5;
1351                                 this.beam_thickness = 8;
1352                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1353                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1354                                 this.beam_hitlight[0] = 20;
1355                                 this.beam_hitlight[1] = 1;
1356                                 this.beam_hitlight[2] = 0;
1357                                 this.beam_hitlight[3] = 0;
1358                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1359                                 this.beam_muzzlelight[0] = 50;
1360                                 this.beam_muzzlelight[1] = 1;
1361                                 this.beam_muzzlelight[2] = 0;
1362                                 this.beam_muzzlelight[3] = 0;
1363                                 this.beam_image = "particles/lgbeam";
1364                                 if(this.beam_muzzleeffect)
1365                                 {
1366                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1367                                         flash.alpha = this.beam_alpha;
1368                                         flash.colormod = this.beam_color;
1369                                         flash.scale = 0.5;
1370                                 }
1371                                 break;
1372                         }
1373                         case ARC_BT_BURST_MISS:
1374                         {
1375                                 this.beam_color = beamcolor;
1376                                 this.beam_alpha = 0.5;
1377                                 this.beam_thickness = 14;
1378                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1379                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1380                                 this.beam_hitlight[0] = 0;
1381                                 this.beam_hitlight[1] = 1;
1382                                 this.beam_hitlight[2] = 1;
1383                                 this.beam_hitlight[3] = 1;
1384                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1385                                 this.beam_muzzlelight[0] = 0;
1386                                 this.beam_muzzlelight[1] = 1;
1387                                 this.beam_muzzlelight[2] = 1;
1388                                 this.beam_muzzlelight[3] = 1;
1389                                 this.beam_image = "particles/lgbeam";
1390                                 if(this.beam_muzzleeffect)
1391                                 {
1392                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1393                                         flash.alpha = this.beam_alpha;
1394                                         flash.colormod = this.beam_color;
1395                                         flash.scale = 0.5;
1396                                 }
1397                                 break;
1398                         }
1399                         case ARC_BT_BURST_WALL:
1400                         {
1401                                 this.beam_color = beamcolor;
1402                                 this.beam_alpha = 0.5;
1403                                 this.beam_thickness = 14;
1404                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1405                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1406                                 this.beam_hitlight[0] = 0;
1407                                 this.beam_hitlight[1] = 1;
1408                                 this.beam_hitlight[2] = 1;
1409                                 this.beam_hitlight[3] = 1;
1410                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1411                                 this.beam_muzzlelight[0] = 0;
1412                                 this.beam_muzzlelight[1] = 1;
1413                                 this.beam_muzzlelight[2] = 1;
1414                                 this.beam_muzzlelight[3] = 1;
1415                                 this.beam_image = "particles/lgbeam";
1416                                 if(this.beam_muzzleeffect)
1417                                 {
1418                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1419                                         flash.alpha = this.beam_alpha;
1420                                         flash.colormod = this.beam_color;
1421                                         flash.scale = 0.5;
1422                                 }
1423                                 break;
1424                         }
1425                         case ARC_BT_BURST_HEAL:
1426                         {
1427                                 this.beam_color = beamcolor;
1428                                 this.beam_alpha = 0.5;
1429                                 this.beam_thickness = 14;
1430                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1431                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT2);
1432                                 this.beam_hitlight[0] = 0;
1433                                 this.beam_hitlight[1] = 1;
1434                                 this.beam_hitlight[2] = 1;
1435                                 this.beam_hitlight[3] = 1;
1436                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1437                                 this.beam_muzzlelight[0] = 0;
1438                                 this.beam_muzzlelight[1] = 1;
1439                                 this.beam_muzzlelight[2] = 1;
1440                                 this.beam_muzzlelight[3] = 1;
1441                                 this.beam_image = "particles/lgbeam";
1442                                 if(this.beam_muzzleeffect)
1443                                 {
1444                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1445                                         flash.alpha = this.beam_alpha;
1446                                         flash.colormod = this.beam_color;
1447                                         flash.scale = 0.5;
1448                                 }
1449                                 break;
1450                         }
1451                         case ARC_BT_BURST_HIT:
1452                         {
1453                                 this.beam_color = beamcolor;
1454                                 this.beam_alpha = 0.5;
1455                                 this.beam_thickness = 14;
1456                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1457                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1458                                 this.beam_hitlight[0] = 0;
1459                                 this.beam_hitlight[1] = 1;
1460                                 this.beam_hitlight[2] = 1;
1461                                 this.beam_hitlight[3] = 1;
1462                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1463                                 this.beam_muzzlelight[0] = 0;
1464                                 this.beam_muzzlelight[1] = 1;
1465                                 this.beam_muzzlelight[2] = 1;
1466                                 this.beam_muzzlelight[3] = 1;
1467                                 this.beam_image = "particles/lgbeam";
1468                                 if(this.beam_muzzleeffect)
1469                                 {
1470                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1471                                         flash.alpha = this.beam_alpha;
1472                                         flash.colormod = this.beam_color;
1473                                         flash.scale = 0.5;
1474                                 }
1475                                 break;
1476                         }
1477
1478                         // shouldn't be possible, but lets make it colorful if it does :D
1479                         default:
1480                         {
1481                                 this.beam_color = randomvec();
1482                                 this.beam_alpha = 1;
1483                                 this.beam_thickness = 8;
1484                                 this.beam_traileffect = NULL;
1485                                 this.beam_hiteffect = NULL;
1486                                 this.beam_hitlight[0] = 0;
1487                                 this.beam_hitlight[1] = 1;
1488                                 this.beam_hitlight[2] = 1;
1489                                 this.beam_hitlight[3] = 1;
1490                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1491                                 this.beam_muzzlelight[0] = 0;
1492                                 this.beam_muzzlelight[1] = 1;
1493                                 this.beam_muzzlelight[2] = 1;
1494                                 this.beam_muzzlelight[3] = 1;
1495                                 this.beam_image = "particles/lgbeam";
1496                                 if(this.beam_muzzleeffect)
1497                                 {
1498                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1499                                         flash.alpha = this.beam_alpha;
1500                                         flash.colormod = this.beam_color;
1501                                         flash.scale = 0.5;
1502                                 }
1503                                 break;
1504                         }
1505                 }
1506         }
1507
1508         if(!this.beam_usevieworigin)
1509         {
1510                 InterpolateOrigin_Note(this);
1511         }
1512         return true;
1513 }
1514
1515 #endif