qcsrc/common/weapons/weapon/arc.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ ARC,
   4 /* function  */ W_Arc,
   5 /* ammotype  */ ammo_cells,
   6 /* impulse   */ 3,
   7 /* flags     */ WEP_FLAG_NORMAL,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '1 1 1',
  10 /* modelname */ "arc",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairhlac 0.7",
  13 /* wepimg    */ "weaponarc",
  14 /* refname   */ "arc",
  15 /* wepname   */ _("Arc")
  16 );
  17
  18 #define ARC_SETTINGS(w_cvar,w_prop) ARC_SETTINGS_LIST(w_cvar, w_prop, ARC, arc)
  19 #define ARC_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, beam_ammo) \
  21         w_cvar(id, sn, NONE, beam_animtime) \
  22         w_cvar(id, sn, NONE, beam_botaimspeed) \
  23         w_cvar(id, sn, NONE, beam_botaimlifetime) \
  24         w_cvar(id, sn, NONE, beam_damage) \
  25         w_cvar(id, sn, NONE, beam_degreespersegment) \
  26         w_cvar(id, sn, NONE, beam_distancepersegment) \
  27         w_cvar(id, sn, NONE, beam_falloff_halflifedist) \
  28         w_cvar(id, sn, NONE, beam_falloff_maxdist) \
  29         w_cvar(id, sn, NONE, beam_falloff_mindist) \
  30         w_cvar(id, sn, NONE, beam_force) \
  31         w_cvar(id, sn, NONE, beam_healing_amax) \
  32         w_cvar(id, sn, NONE, beam_healing_aps) \
  33         w_cvar(id, sn, NONE, beam_healing_hmax) \
  34         w_cvar(id, sn, NONE, beam_healing_hps) \
  35         w_cvar(id, sn, NONE, beam_maxangle) \
  36         w_cvar(id, sn, NONE, beam_nonplayerdamage) \
  37         w_cvar(id, sn, NONE, beam_range) \
  38         w_cvar(id, sn, NONE, beam_refire) \
  39         w_cvar(id, sn, NONE, beam_returnspeed) \
  40         w_cvar(id, sn, NONE, beam_tightness) \
  41         w_cvar(id, sn, NONE, burst_ammo) \
  42         w_cvar(id, sn, NONE, burst_damage) \
  43         w_cvar(id, sn, NONE, burst_healing_aps) \
  44         w_cvar(id, sn, NONE, burst_healing_hps) \
  45         w_cvar(id, sn, NONE, overheat_max)/* maximum heat before jamming */ \
  46         w_cvar(id, sn, NONE, overheat_min)/* minimum heat to wait for cooldown */ \
  47         w_cvar(id, sn, NONE, beam_heat)   /* heat increase per second (primary) */ \
  48         w_cvar(id, sn, NONE, burst_heat)  /* heat increase per second (secondary) */ \
  49         w_cvar(id, sn, NONE, cooldown)    /* heat decrease per second when resting */ \
  50         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  51         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  52         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  53         w_prop(id, sn, float,  weaponstart, weaponstart) \
  54         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  55         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  56
  57 #ifndef MENUQC
  58 const float ARC_MAX_SEGMENTS = 20;
  59 vector arc_shotorigin[4];
  60 .vector beam_start;
  61 .vector beam_dir;
  62 .vector beam_wantdir;
  63 .int beam_type;
  64
  65 const int ARC_BT_MISS =        0x00;
  66 const int ARC_BT_WALL =        0x01;
  67 const int ARC_BT_HEAL =        0x02;
  68 const int ARC_BT_HIT =         0x03;
  69 const int ARC_BT_BURST_MISS =  0x10;
  70 const int ARC_BT_BURST_WALL =  0x11;
  71 const int ARC_BT_BURST_HEAL =  0x12;
  72 const int ARC_BT_BURST_HIT =   0x13;
  73 const int ARC_BT_BURSTMASK =   0x10;
  74
  75 const int ARC_SF_SETTINGS =    1;
  76 const int ARC_SF_START =       2;
  77 const int ARC_SF_WANTDIR =     4;
  78 const int ARC_SF_BEAMDIR =     8;
  79 const int ARC_SF_BEAMTYPE =    16;
  80 const int ARC_SF_LOCALMASK =   14;
  81 #endif
  82 #ifdef SVQC
  83 ARC_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  84 .entity arc_beam;
  85 .float arc_BUTTON_ATCK_prev; // for better animation control
  86 .float beam_prev;
  87 .float beam_initialized;
  88 .float beam_bursting;
  89 .float beam_teleporttime;
  90 .float beam_heat; // (beam) amount of heat produced
  91 .float arc_overheat; // (dropped arc/player) time during which it's too hot
  92 .float arc_cooldown; // (dropped arc/player) cooling speed
  93 .float arc_heat_percent; // (player) arc heat in [0,1] (stat)
  94 .float arc_smoke_sound;
  95 #endif
  96 #ifdef CSQC
  97 void Ent_ReadArcBeam(float isnew);
  98
  99 .vector beam_color;
 100 .float beam_alpha;
 101 .float beam_thickness;
 102 .float beam_traileffect;
 103 .float beam_hiteffect;
 104 .float beam_hitlight[4]; // 0: radius, 123: rgb
 105 .float beam_muzzleeffect;
 106 .float beam_muzzlelight[4]; // 0: radius, 123: rgb
 107 .string beam_image;
 108
 109 .entity beam_muzzleentity;
 110
 111 .float beam_degreespersegment;
 112 .float beam_distancepersegment;
 113 .float beam_usevieworigin;
 114 .float beam_initialized;
 115 .float beam_maxangle;
 116 .float beam_range;
 117 .float beam_returnspeed;
 118 .float beam_tightness;
 119 .vector beam_shotorigin;
 120
 121 entity Draw_ArcBeam_callback_entity;
 122 float Draw_ArcBeam_callback_last_thickness;
 123 vector Draw_ArcBeam_callback_last_top; // NOTE: in same coordinate system as player.
 124 vector Draw_ArcBeam_callback_last_bottom; // NOTE: in same coordinate system as player.
 125 #endif
 126 #endif
 127 #ifdef IMPLEMENTATION
 128 #ifdef SVQC
 129 void spawnfunc_weapon_arc(void) { weapon_defaultspawnfunc(WEP_ARC.m_id); }
 130
 131 float W_Arc_Beam_Send(entity to, int sf)
 132 {SELFPARAM();
 133         WriteByte(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
 134
 135         // Truncate information when this beam is displayed to the owner client
 136         // - The owner client has no use for beam start position or directions,
 137         //    it always figures this information out for itself with csqc code.
 138         // - Spectating the owner also truncates this information.
 139         float drawlocal = ((to == self.owner) || ((to.enemy == self.owner) && IS_SPEC(to)));
 140         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
 141
 142         WriteByte(MSG_ENTITY, sf);
 143
 144         if(sf & ARC_SF_SETTINGS) // settings information
 145         {
 146                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
 147                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
 148                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
 149                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
 150                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
 151                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
 152
 153                 WriteByte(MSG_ENTITY, drawlocal);
 154         }
 155         if(sf & ARC_SF_START) // starting location
 156         {
 157                 WriteCoord(MSG_ENTITY, self.beam_start.x);
 158                 WriteCoord(MSG_ENTITY, self.beam_start.y);
 159                 WriteCoord(MSG_ENTITY, self.beam_start.z);
 160         }
 161         if(sf & ARC_SF_WANTDIR) // want/aim direction
 162         {
 163                 WriteCoord(MSG_ENTITY, self.beam_wantdir.x);
 164                 WriteCoord(MSG_ENTITY, self.beam_wantdir.y);
 165                 WriteCoord(MSG_ENTITY, self.beam_wantdir.z);
 166         }
 167         if(sf & ARC_SF_BEAMDIR) // beam direction
 168         {
 169                 WriteCoord(MSG_ENTITY, self.beam_dir.x);
 170                 WriteCoord(MSG_ENTITY, self.beam_dir.y);
 171                 WriteCoord(MSG_ENTITY, self.beam_dir.z);
 172         }
 173         if(sf & ARC_SF_BEAMTYPE) // beam type
 174         {
 175                 WriteByte(MSG_ENTITY, self.beam_type);
 176         }
 177
 178         return true;
 179 }
 180
 181 void Reset_ArcBeam(entity player, vector forward)
 182 {
 183         if (!player.arc_beam) {
 184                 return;
 185         }
 186         player.arc_beam.beam_dir = forward;
 187         player.arc_beam.beam_teleporttime = time;
 188 }
 189
 190 float Arc_GetHeat_Percent(entity player)
 191 {
 192         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
 193         {
 194                 player.arc_overheat = 0;
 195                 return 0;
 196         }
 197
 198         if ( player.arc_beam )
 199                 return player.arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
 200
 201         if ( player.arc_overheat > time )
 202         {
 203                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
 204                         * player.arc_cooldown;
 205         }
 206
 207         return 0;
 208 }
 209 void Arc_Player_SetHeat(entity player)
 210 {
 211         player.arc_heat_percent = Arc_GetHeat_Percent(player);
 212         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
 213 }
 214
 215 void W_Arc_Beam_Think(void)
 216 {SELFPARAM();
 217         if(self != self.owner.arc_beam)
 218         {
 219                 remove(self);
 220                 return;
 221         }
 222
 223
 224         float burst = 0;
 225         if( self.owner.BUTTON_ATCK2 || self.beam_bursting)
 226         {
 227                 if(!self.beam_bursting)
 228                         self.beam_bursting = true;
 229                 burst = ARC_BT_BURSTMASK;
 230         }
 231
 232         if(
 233                 !IS_PLAYER(self.owner)
 234                 ||
 235                 (self.owner.WEP_AMMO(ARC) <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 236                 ||
 237                 self.owner.deadflag != DEAD_NO
 238                 ||
 239                 (!self.owner.BUTTON_ATCK && !burst )
 240                 ||
 241                 self.owner.frozen
 242                 ||
 243                 self.owner.vehicle
 244                 ||
 245                 (WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max))
 246         )
 247         {
 248                 if ( WEP_CVAR(arc, cooldown) > 0 )
 249                 {
 250                         float cooldown_speed = 0;
 251                         if ( self.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 252                         {
 253                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 254                         }
 255                         else if ( !burst )
 256                         {
 257                                 cooldown_speed = self.beam_heat / WEP_CVAR(arc, beam_refire);
 258                         }
 259
 260                         if ( cooldown_speed )
 261                         {
 262                                 self.owner.arc_overheat = time + self.beam_heat / cooldown_speed;
 263                                 self.owner.arc_cooldown = cooldown_speed;
 264                         }
 265
 266                         if ( WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max) )
 267                         {
 268                                 Send_Effect_("arc_overheat",
 269                                         self.beam_start, self.beam_wantdir, 1 );
 270                                 sound(self, CH_WEAPON_A, W_Sound("arc_stop"), VOL_BASE, ATTN_NORM);
 271                         }
 272                 }
 273
 274                 if(self == self.owner.arc_beam) { self.owner.arc_beam = world; }
 275                 setself(self.owner);
 276                 if(!WEP_ACTION(WEP_ARC.m_id, WR_CHECKAMMO1) && !WEP_ACTION(WEP_ARC.m_id, WR_CHECKAMMO2))
 277                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 278                 {
 279                         // note: this doesn't force the switch
 280                         W_SwitchToOtherWeapon(self);
 281                 }
 282                 setself(this);
 283                 remove(self);
 284                 return;
 285         }
 286
 287         // decrease ammo
 288         float coefficient = frametime;
 289         if(!(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 290         {
 291                 float rootammo;
 292                 if(burst)
 293                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 294                 else
 295                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 296
 297                 if(rootammo)
 298                 {
 299                         coefficient = min(coefficient, self.owner.WEP_AMMO(ARC) / rootammo);
 300                         self.owner.WEP_AMMO(ARC) = max(0, self.owner.WEP_AMMO(ARC) - (rootammo * frametime));
 301                 }
 302         }
 303         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 304         self.beam_heat = min( WEP_CVAR(arc, overheat_max), self.beam_heat + heat_speed*frametime );
 305
 306         makevectors(self.owner.v_angle);
 307
 308         W_SetupShot_Range(
 309                 self.owner,
 310                 true,
 311                 0,
 312                 "",
 313                 0,
 314                 WEP_CVAR(arc, beam_damage) * coefficient,
 315                 WEP_CVAR(arc, beam_range)
 316         );
 317
 318         // After teleport, "lock" the beam until the teleport is confirmed.
 319         if (time < self.beam_teleporttime + ANTILAG_LATENCY(self.owner)) {
 320                 w_shotdir = self.beam_dir;
 321         }
 322
 323         // network information: shot origin and want/aim direction
 324         if(self.beam_start != w_shotorg)
 325         {
 326                 self.SendFlags |= ARC_SF_START;
 327                 self.beam_start = w_shotorg;
 328         }
 329         if(self.beam_wantdir != w_shotdir)
 330         {
 331                 self.SendFlags |= ARC_SF_WANTDIR;
 332                 self.beam_wantdir = w_shotdir;
 333         }
 334
 335         if(!self.beam_initialized)
 336         {
 337                 self.beam_dir = w_shotdir;
 338                 self.beam_initialized = true;
 339         }
 340
 341         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 342         // idea: blend together self.beam_dir with the inverted direction the player is moving in
 343         // might have to make some special accomodation so that it only uses view_right and view_up
 344
 345         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 346
 347         float segments;
 348         if(self.beam_dir != w_shotdir)
 349         {
 350                 // calculate how much we're going to move the end of the beam to the want position
 351                 // WEAPONTODO (server and client):
 352                 // blendfactor never actually becomes 0 in this situation, which is a problem
 353                 // regarding precision... this means that self.beam_dir and w_shotdir approach
 354                 // eachother, however they never actually become the same value with this method.
 355                 // Perhaps we should do some form of rounding/snapping?
 356                 float angle = vlen(w_shotdir - self.beam_dir) * RAD2DEG;
 357                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 358                 {
 359                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 360                         float blendfactor = bound(
 361                                 0,
 362                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 363                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 364                         );
 365                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 366                 }
 367                 else
 368                 {
 369                         // the radius is not too far yet, no worries :D
 370                         float blendfactor = bound(
 371                                 0,
 372                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 373                                 1
 374                         );
 375                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 376                 }
 377
 378                 // network information: beam direction
 379                 self.SendFlags |= ARC_SF_BEAMDIR;
 380
 381                 // calculate how many segments are needed
 382                 float max_allowed_segments;
 383
 384                 if(WEP_CVAR(arc, beam_distancepersegment))
 385                 {
 386                         max_allowed_segments = min(
 387                                 ARC_MAX_SEGMENTS,
 388                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 389                         );
 390                 }
 391                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 392
 393                 if(WEP_CVAR(arc, beam_degreespersegment))
 394                 {
 395                         segments = bound(
 396                                 1,
 397                                 (
 398                                         min(
 399                                                 angle,
 400                                                 WEP_CVAR(arc, beam_maxangle)
 401                                         )
 402                                         /
 403                                         WEP_CVAR(arc, beam_degreespersegment)
 404                                 ),
 405                                 max_allowed_segments
 406                         );
 407                 }
 408                 else { segments = 1; }
 409         }
 410         else { segments = 1; }
 411
 412         vector beam_endpos = (w_shotorg + (self.beam_dir * WEP_CVAR(arc, beam_range)));
 413         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 414
 415         float i;
 416         float new_beam_type = 0;
 417         vector last_origin = w_shotorg;
 418         for(i = 1; i <= segments; ++i)
 419         {
 420                 // WEAPONTODO (client):
 421                 // In order to do nice fading and pointing on the starting segment, we must always
 422                 // have that drawn as a separate triangle... However, that is difficult to do when
 423                 // keeping in mind the above problems and also optimizing the amount of segments
 424                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 425
 426                 vector new_origin = bezier_quadratic_getpoint(
 427                         w_shotorg,
 428                         beam_controlpoint,
 429                         beam_endpos,
 430                         i / segments);
 431                 vector new_dir = normalize(new_origin - last_origin);
 432
 433                 WarpZone_traceline_antilag(
 434                         self.owner,
 435                         last_origin,
 436                         new_origin,
 437                         MOVE_NORMAL,
 438                         self.owner,
 439                         ANTILAG_LATENCY(self.owner)
 440                 );
 441
 442                 // Do all the transforms for warpzones right now, as we already
 443                 // "are" in the post-trace system (if we hit a player, that's
 444                 // always BEHIND the last passed wz).
 445                 last_origin = trace_endpos;
 446                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 447                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 448                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 449                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 450
 451                 float is_player = (
 452                         IS_PLAYER(trace_ent)
 453                         ||
 454                         trace_ent.classname == "body"
 455                         ||
 456                         IS_MONSTER(trace_ent)
 457                 );
 458
 459                 if(trace_ent && trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 460                 {
 461                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 462                         // NO. trace_endpos should be just fine. If not,
 463                         // that's an engine bug that needs proper debugging.
 464                         vector hitorigin = trace_endpos;
 465
 466                         float falloff = ExponentialFalloff(
 467                                 WEP_CVAR(arc, beam_falloff_mindist),
 468                                 WEP_CVAR(arc, beam_falloff_maxdist),
 469                                 WEP_CVAR(arc, beam_falloff_halflifedist),
 470                                 vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 471                         );
 472
 473                         if(is_player && SAME_TEAM(self.owner, trace_ent))
 474                         {
 475                                 float roothealth, rootarmor;
 476                                 if(burst)
 477                                 {
 478                                         roothealth = WEP_CVAR(arc, burst_healing_hps);
 479                                         rootarmor = WEP_CVAR(arc, burst_healing_aps);
 480                                 }
 481                                 else
 482                                 {
 483                                         roothealth = WEP_CVAR(arc, beam_healing_hps);
 484                                         rootarmor = WEP_CVAR(arc, beam_healing_aps);
 485                                 }
 486
 487                                 if(trace_ent.health <= WEP_CVAR(arc, beam_healing_hmax) && roothealth)
 488                                 {
 489                                         trace_ent.health = min(
 490                                                 trace_ent.health + (roothealth * coefficient),
 491                                                 WEP_CVAR(arc, beam_healing_hmax)
 492                                         );
 493                                 }
 494                                 if(trace_ent.armorvalue <= WEP_CVAR(arc, beam_healing_amax) && rootarmor)
 495                                 {
 496                                         trace_ent.armorvalue = min(
 497                                                 trace_ent.armorvalue + (rootarmor * coefficient),
 498                                                 WEP_CVAR(arc, beam_healing_amax)
 499                                         );
 500                                 }
 501
 502                                 // stop rot, set visual effect
 503                                 if(roothealth || rootarmor)
 504                                 {
 505                                         trace_ent.pauserothealth_finished = max(
 506                                                 trace_ent.pauserothealth_finished,
 507                                                 time + autocvar_g_balance_pause_health_rot
 508                                         );
 509                                         trace_ent.pauserotarmor_finished = max(
 510                                                 trace_ent.pauserotarmor_finished,
 511                                                 time + autocvar_g_balance_pause_armor_rot
 512                                         );
 513                                         new_beam_type = ARC_BT_HEAL;
 514                                 }
 515                         }
 516                         else
 517                         {
 518                                 float rootdamage;
 519                                 if(is_player)
 520                                 {
 521                                         if(burst)
 522                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 523                                         else
 524                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 525                                 }
 526                                 else
 527                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 528
 529                                 if(accuracy_isgooddamage(self.owner, trace_ent))
 530                                 {
 531                                         accuracy_add(
 532                                                 self.owner,
 533                                                 WEP_ARC.m_id,
 534                                                 0,
 535                                                 rootdamage * coefficient * falloff
 536                                         );
 537                                 }
 538
 539                                 Damage(
 540                                         trace_ent,
 541                                         self.owner,
 542                                         self.owner,
 543                                         rootdamage * coefficient * falloff,
 544                                         WEP_ARC.m_id,
 545                                         hitorigin,
 546                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 547                                 );
 548
 549                                 new_beam_type = ARC_BT_HIT;
 550                         }
 551                         break;
 552                 }
 553                 else if(trace_fraction != 1)
 554                 {
 555                         // we collided with geometry
 556                         new_beam_type = ARC_BT_WALL;
 557                         break;
 558                 }
 559         }
 560
 561         // te_explosion(trace_endpos);
 562
 563         // if we're bursting, use burst visual effects
 564         new_beam_type |= burst;
 565
 566         // network information: beam type
 567         if(new_beam_type != self.beam_type)
 568         {
 569                 self.SendFlags |= ARC_SF_BEAMTYPE;
 570                 self.beam_type = new_beam_type;
 571         }
 572
 573         self.owner.beam_prev = time;
 574         self.nextthink = time;
 575 }
 576
 577 void W_Arc_Beam(float burst)
 578 {SELFPARAM();
 579
 580         // only play fire sound if 1 sec has passed since player let go the fire button
 581         if(time - self.beam_prev > 1)
 582                 sound(self, CH_WEAPON_A, W_Sound("arc_fire"), VOL_BASE, ATTN_NORM);
 583
 584         entity beam = self.arc_beam = spawn();
 585         beam.classname = "W_Arc_Beam";
 586         beam.solid = SOLID_NOT;
 587         beam.think = W_Arc_Beam_Think;
 588         beam.owner = self;
 589         beam.movetype = MOVETYPE_NONE;
 590         beam.bot_dodge = true;
 591         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 592         beam.beam_bursting = burst;
 593         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 594
 595         WITH(entity, self, beam, beam.think());
 596 }
 597
 598 void Arc_Smoke()
 599 {SELFPARAM();
 600         makevectors(self.v_angle);
 601         W_SetupShot_Range(self,true,0,"",0,0,0);
 602
 603         vector smoke_origin = w_shotorg + self.velocity*frametime;
 604         if ( self.arc_overheat > time )
 605         {
 606                 if ( random() < self.arc_heat_percent )
 607                         Send_Effect_("arc_smoke", smoke_origin, '0 0 0', 1 );
 608                 if ( self.BUTTON_ATCK || self.BUTTON_ATCK2 )
 609                 {
 610                         Send_Effect_("arc_overheat_fire", smoke_origin, w_shotdir, 1 );
 611                         if ( !self.arc_smoke_sound )
 612                         {
 613                                 self.arc_smoke_sound = 1;
 614                                 sound(self, CH_SHOTS_SINGLE, W_Sound("arc_loop_overheat"), VOL_BASE, ATTN_NORM);
 615                         }
 616                 }
 617         }
 618         else if ( self.arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 619                         self.arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 620         {
 621                 if ( random() < (self.arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 622                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 623                         Send_Effect_("arc_smoke", smoke_origin, '0 0 0', 1 );
 624         }
 625
 626         if (  self.arc_smoke_sound && ( self.arc_overheat <= time ||
 627                 !( self.BUTTON_ATCK || self.BUTTON_ATCK2 ) ) || self.switchweapon != WEP_ARC.m_id )
 628         {
 629                 self.arc_smoke_sound = 0;
 630                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
 631         }
 632 }
 633
 634 bool W_Arc(int req)
 635 {SELFPARAM();
 636         switch(req)
 637         {
 638                 case WR_AIM:
 639                 {
 640                         if(WEP_CVAR(arc, beam_botaimspeed))
 641                         {
 642                                 self.BUTTON_ATCK = bot_aim(
 643                                         WEP_CVAR(arc, beam_botaimspeed),
 644                                         0,
 645                                         WEP_CVAR(arc, beam_botaimlifetime),
 646                                         false
 647                                 );
 648                         }
 649                         else
 650                         {
 651                                 self.BUTTON_ATCK = bot_aim(
 652                                         1000000,
 653                                         0,
 654                                         0.001,
 655                                         false
 656                                 );
 657                         }
 658                         return true;
 659                 }
 660                 case WR_THINK:
 661                 {
 662                         Arc_Player_SetHeat(self);
 663                         Arc_Smoke();
 664
 665                         if ( self.arc_overheat <= time )
 666                         if(self.BUTTON_ATCK || self.BUTTON_ATCK2 || self.arc_beam.beam_bursting )
 667                         {
 668
 669                                 if(self.arc_BUTTON_ATCK_prev)
 670                                 {
 671                                         #if 0
 672                                         if(self.animstate_startframe == self.anim_shoot.x && self.animstate_numframes == self.anim_shoot.y)
 673                                                 weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 674                                         else
 675                                         #endif
 676                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 677                                 }
 678
 679                                 if((!self.arc_beam) || wasfreed(self.arc_beam))
 680                                 {
 681                                         if(weapon_prepareattack(!!self.BUTTON_ATCK2, 0))
 682                                         {
 683                                                 W_Arc_Beam(!!self.BUTTON_ATCK2);
 684
 685                                                 if(!self.arc_BUTTON_ATCK_prev)
 686                                                 {
 687                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 688                                                         self.arc_BUTTON_ATCK_prev = 1;
 689                                                 }
 690                                         }
 691                                 }
 692
 693                                 return true;
 694                         }
 695
 696                         if(self.arc_BUTTON_ATCK_prev != 0)
 697                         {
 698                                 sound(self, CH_WEAPON_A, W_Sound("arc_stop"), VOL_BASE, ATTN_NORM);
 699                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 700                                 ATTACK_FINISHED(self) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor();
 701                         }
 702                         self.arc_BUTTON_ATCK_prev = 0;
 703
 704                         #if 0
 705                         if(self.BUTTON_ATCK2)
 706                         if(weapon_prepareattack(1, autocvar_g_balance_arc_secondary_refire))
 707                         {
 708                                 W_Arc_Attack2();
 709                                 self.arc_count = autocvar_g_balance_arc_secondary_count;
 710                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 711                                 self.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor();
 712                         }
 713                         #endif
 714
 715                         return true;
 716                 }
 717                 case WR_INIT:
 718                 {
 719                         precache_model(W_Model("g_arc.md3"));
 720                         precache_model(W_Model("v_arc.md3"));
 721                         precache_model(W_Model("h_arc.iqm"));
 722                         precache_sound(W_Sound("arc_fire"));
 723                         precache_sound(W_Sound("arc_loop"));
 724                         precache_sound(W_Sound("arc_stop"));
 725                         precache_sound(W_Sound("arc_loop_overheat"));
 726                         if(!arc_shotorigin[0])
 727                         {
 728                                 arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 729                                 arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 730                                 arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 731                                 arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 732                         }
 733                         ARC_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 734                         return true;
 735                 }
 736                 case WR_CHECKAMMO1:
 737                 {
 738                         return ((!WEP_CVAR(arc, beam_ammo)) || (self.WEP_AMMO(ARC) > 0));
 739                 }
 740                 case WR_CHECKAMMO2:
 741                 {
 742                         return WEP_CVAR(arc, overheat_max) > 0 &&
 743                                 ((!WEP_CVAR(arc, burst_ammo)) || (self.WEP_AMMO(ARC) > 0));
 744                 }
 745                 case WR_CONFIG:
 746                 {
 747                         ARC_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 748                         return true;
 749                 }
 750                 case WR_KILLMESSAGE:
 751                 {
 752                         return WEAPON_ARC_MURDER;
 753                 }
 754                 case WR_DROP:
 755                 {
 756                         weapon_dropevent_item.arc_overheat = self.arc_overheat;
 757                         weapon_dropevent_item.arc_cooldown = self.arc_cooldown;
 758                         self.arc_overheat = 0;
 759                         self.arc_cooldown = 0;
 760                         return true;
 761                 }
 762                 case WR_PICKUP:
 763                 {
 764                         if ( !client_hasweapon(self, WEP_ARC.m_id, false, false) &&
 765                                 weapon_dropevent_item.arc_overheat > time )
 766                         {
 767                                 self.arc_overheat = weapon_dropevent_item.arc_overheat;
 768                                 self.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 769                         }
 770                         return true;
 771                 }
 772         }
 773         return false;
 774 }
 775 #endif
 776 #ifdef CSQC
 777 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 778 {
 779         entity beam = Draw_ArcBeam_callback_entity;
 780         vector transformed_view_org;
 781         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 782
 783         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 784         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 785         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 786
 787         vector hitorigin;
 788
 789         // draw segment
 790         #if 0
 791         if(trace_fraction != 1)
 792         {
 793                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 794                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 795                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 796         }
 797         else
 798         {
 799                 hitorigin = hit;
 800         }
 801         #else
 802         hitorigin = hit;
 803         #endif
 804
 805         // decide upon thickness
 806         float thickness = beam.beam_thickness;
 807
 808         // draw primary beam render
 809         vector top    = hitorigin + (thickdir * thickness);
 810         vector bottom = hitorigin - (thickdir * thickness);
 811
 812         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 813         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 814
 815         R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 816         R_PolygonVertex(
 817                 top,
 818                 '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 819                 beam.beam_color,
 820                 beam.beam_alpha
 821         );
 822         R_PolygonVertex(
 823                 last_top,
 824                 '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 825                 beam.beam_color,
 826                 beam.beam_alpha
 827         );
 828         R_PolygonVertex(
 829                 last_bottom,
 830                 '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 831                 beam.beam_color,
 832                 beam.beam_alpha
 833         );
 834         R_PolygonVertex(
 835                 bottom,
 836                 '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 837                 beam.beam_color,
 838                 beam.beam_alpha
 839         );
 840         R_EndPolygon();
 841
 842         // draw trailing particles
 843         // NOTES:
 844         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 845         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 846         if(beam.beam_traileffect)
 847         {
 848                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 849         }
 850
 851         // set up for the next
 852         Draw_ArcBeam_callback_last_thickness = thickness;
 853         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 854         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 855 }
 856
 857 void Reset_ArcBeam(void)
 858 {
 859         entity e;
 860         for (e = world; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 861                 e.beam_initialized = false;
 862         }
 863         for (e = world; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 864                 e.beam_initialized = false;
 865         }
 866 }
 867
 868 void Draw_ArcBeam(void)
 869 {SELFPARAM();
 870         float dt = time - self.move_time;
 871         self.move_time = time;
 872         if(dt <= 0) { return; }
 873
 874         if(!self.beam_usevieworigin)
 875         {
 876                 InterpolateOrigin_Do();
 877         }
 878
 879         // origin = beam starting origin
 880         // v_angle = wanted/aim direction
 881         // angles = current direction of beam
 882
 883         vector start_pos;
 884         vector wantdir; //= view_forward;
 885         vector beamdir; //= self.beam_dir;
 886
 887         float segments;
 888         if(self.beam_usevieworigin)
 889         {
 890                 // WEAPONTODO:
 891                 // Currently we have to replicate nearly the same method of figuring
 892                 // out the shotdir that the server does... Ideally in the future we
 893                 // should be able to acquire this from a generalized function built
 894                 // into a weapon system for client code.
 895
 896                 // find where we are aiming
 897                 makevectors(warpzone_save_view_angles);
 898                 vector forward = v_forward;
 899                 vector right = v_right;
 900                 vector up = v_up;
 901
 902                 // decide upon start position
 903                 if(self.beam_usevieworigin == 2)
 904                         { start_pos = warpzone_save_view_origin; }
 905                 else
 906                         { start_pos = self.origin; }
 907
 908                 // trace forward with an estimation
 909                 WarpZone_TraceLine(
 910                         start_pos,
 911                         start_pos + forward * self.beam_range,
 912                         MOVE_NOMONSTERS,
 913                         self
 914                 );
 915
 916                 // untransform in case our trace went through a warpzone
 917                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 918
 919                 // un-adjust trueaim if shotend is too close
 920                 if(vlen(end_pos - start_pos) < g_trueaim_minrange)
 921                         end_pos = start_pos + (forward * g_trueaim_minrange);
 922
 923                 // move shot origin to the actual gun muzzle origin
 924                 vector origin_offset =
 925                           right * -self.beam_shotorigin.y
 926                         + up * self.beam_shotorigin.z;
 927
 928                 start_pos = start_pos + origin_offset;
 929
 930                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 931                 traceline(start_pos, start_pos + forward * self.beam_shotorigin.x, MOVE_NORMAL, self);
 932                 start_pos = trace_endpos;
 933
 934                 // calculate the aim direction now
 935                 wantdir = normalize(end_pos - start_pos);
 936
 937                 if(!self.beam_initialized)
 938                 {
 939                         self.beam_dir = wantdir;
 940                         self.beam_initialized = true;
 941                 }
 942
 943                 if(self.beam_dir != wantdir)
 944                 {
 945                         // calculate how much we're going to move the end of the beam to the want position
 946                         // WEAPONTODO (server and client):
 947                         // blendfactor never actually becomes 0 in this situation, which is a problem
 948                         // regarding precision... this means that self.beam_dir and w_shotdir approach
 949                         // eachother, however they never actually become the same value with this method.
 950                         // Perhaps we should do some form of rounding/snapping?
 951                         float angle = vlen(wantdir - self.beam_dir) * RAD2DEG;
 952                         if(angle && (angle > self.beam_maxangle))
 953                         {
 954                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 955                                 float blendfactor = bound(
 956                                         0,
 957                                         (1 - (self.beam_returnspeed * frametime)),
 958                                         min(self.beam_maxangle / angle, 1)
 959                                 );
 960                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 961                         }
 962                         else
 963                         {
 964                                 // the radius is not too far yet, no worries :D
 965                                 float blendfactor = bound(
 966                                         0,
 967                                         (1 - (self.beam_returnspeed * frametime)),
 968                                         1
 969                                 );
 970                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 971                         }
 972
 973                         // calculate how many segments are needed
 974                         float max_allowed_segments;
 975
 976                         if(self.beam_distancepersegment)
 977                         {
 978                                 max_allowed_segments = min(
 979                                         ARC_MAX_SEGMENTS,
 980                                         1 + (vlen(wantdir / self.beam_distancepersegment))
 981                                 );
 982                         }
 983                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 984
 985                         if(self.beam_degreespersegment)
 986                         {
 987                                 segments = bound(
 988                                         1,
 989                                         (
 990                                                 min(
 991                                                         angle,
 992                                                         self.beam_maxangle
 993                                                 )
 994                                                 /
 995                                                 self.beam_degreespersegment
 996                                         ),
 997                                         max_allowed_segments
 998                                 );
 999                         }
1000                         else { segments = 1; }
1001                 }
1002                 else { segments = 1; }
1003
1004                 // set the beam direction which the rest of the code will refer to
1005                 beamdir = self.beam_dir;
1006
1007                 // finally, set self.angles to the proper direction so that muzzle attachment points in proper direction
1008                 self.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1009         }
1010         else
1011         {
1012                 // set the values from the provided info from the networked entity
1013                 start_pos = self.origin;
1014                 wantdir = self.v_angle;
1015                 beamdir = self.angles;
1016
1017                 if(beamdir != wantdir)
1018                 {
1019                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1020
1021                         // calculate how many segments are needed
1022                         float max_allowed_segments;
1023
1024                         if(self.beam_distancepersegment)
1025                         {
1026                                 max_allowed_segments = min(
1027                                         ARC_MAX_SEGMENTS,
1028                                         1 + (vlen(wantdir / self.beam_distancepersegment))
1029                                 );
1030                         }
1031                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1032
1033                         if(self.beam_degreespersegment)
1034                         {
1035                                 segments = bound(
1036                                         1,
1037                                         (
1038                                                 min(
1039                                                         angle,
1040                                                         self.beam_maxangle
1041                                                 )
1042                                                 /
1043                                                 self.beam_degreespersegment
1044                                         ),
1045                                         max_allowed_segments
1046                                 );
1047                         }
1048                         else { segments = 1; }
1049                 }
1050                 else { segments = 1; }
1051         }
1052
1053         setorigin(self, start_pos);
1054         self.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1055
1056         vector beam_endpos = (start_pos + (beamdir * self.beam_range));
1057         vector beam_controlpoint = start_pos + wantdir * (self.beam_range * (1 - self.beam_tightness));
1058
1059         Draw_ArcBeam_callback_entity = self;
1060         Draw_ArcBeam_callback_last_thickness = 0;
1061         Draw_ArcBeam_callback_last_top = start_pos;
1062         Draw_ArcBeam_callback_last_bottom = start_pos;
1063
1064         vector last_origin = start_pos;
1065         vector original_start_pos = start_pos;
1066
1067         float i;
1068         for(i = 1; i <= segments; ++i)
1069         {
1070                 // WEAPONTODO (client):
1071                 // In order to do nice fading and pointing on the starting segment, we must always
1072                 // have that drawn as a separate triangle... However, that is difficult to do when
1073                 // keeping in mind the above problems and also optimizing the amount of segments
1074                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1075
1076                 vector new_origin = bezier_quadratic_getpoint(
1077                         start_pos,
1078                         beam_controlpoint,
1079                         beam_endpos,
1080                         i / segments);
1081
1082                 WarpZone_TraceBox_ThroughZone(
1083                         last_origin,
1084                         '0 0 0',
1085                         '0 0 0',
1086                         new_origin,
1087                         MOVE_NORMAL,
1088                         world,
1089                         world,
1090                         Draw_ArcBeam_callback
1091                 );
1092
1093                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1094                 // system (if we hit a player, that's always BEHIND the last passed wz).
1095                 last_origin = trace_endpos;
1096                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1097                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1098                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1099                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1100                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1101                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1102
1103                 if(trace_fraction < 1) { break; }
1104         }
1105
1106         // visual effects for startpoint and endpoint
1107         if(self.beam_hiteffect)
1108         {
1109                 // FIXME we really should do this on the server so it actually
1110                 // matches gameplay. What this client side stuff is doing is no
1111                 // more than guesswork.
1112                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1113                 pointparticles(
1114                         self.beam_hiteffect,
1115                         last_origin,
1116                         beamdir * -1,
1117                         frametime * 2
1118                 );
1119         }
1120         if(self.beam_hitlight[0])
1121         {
1122                 adddynamiclight(
1123                         last_origin,
1124                         self.beam_hitlight[0],
1125                         vec3(
1126                                 self.beam_hitlight[1],
1127                                 self.beam_hitlight[2],
1128                                 self.beam_hitlight[3]
1129                         )
1130                 );
1131         }
1132         if(self.beam_muzzleeffect)
1133         {
1134                 pointparticles(
1135                         self.beam_muzzleeffect,
1136                         original_start_pos + wantdir * 20,
1137                         wantdir * 1000,
1138                         frametime * 0.1
1139                 );
1140         }
1141         if(self.beam_muzzlelight[0])
1142         {
1143                 adddynamiclight(
1144                         original_start_pos + wantdir * 20,
1145                         self.beam_muzzlelight[0],
1146                         vec3(
1147                                 self.beam_muzzlelight[1],
1148                                 self.beam_muzzlelight[2],
1149                                 self.beam_muzzlelight[3]
1150                         )
1151                 );
1152         }
1153
1154         // cleanup
1155         Draw_ArcBeam_callback_entity = world;
1156         Draw_ArcBeam_callback_last_thickness = 0;
1157         Draw_ArcBeam_callback_last_top = '0 0 0';
1158         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1159 }
1160
1161 void Remove_ArcBeam(void)
1162 {SELFPARAM();
1163         remove(self.beam_muzzleentity);
1164         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
1165 }
1166
1167 void Ent_ReadArcBeam(float isnew)
1168 {SELFPARAM();
1169         int sf = ReadByte();
1170         entity flash;
1171
1172         if(isnew)
1173         {
1174                 // calculate shot origin offset from gun alignment
1175                 int gunalign = autocvar_cl_gunalign;
1176                 if(gunalign != 1 && gunalign != 2 && gunalign != 4)
1177                         gunalign = 3; // default value
1178                 --gunalign;
1179
1180                 self.beam_shotorigin = arc_shotorigin[gunalign];
1181
1182                 // set other main attributes of the beam
1183                 self.draw = Draw_ArcBeam;
1184                 self.entremove = Remove_ArcBeam;
1185                 self.move_time = time;
1186                 loopsound(self, CH_SHOTS_SINGLE, W_Sound("arc_loop"), VOL_BASE, ATTEN_NORM);
1187
1188                 flash = spawn();
1189                 flash.owner = self;
1190                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1191                 flash.drawmask = MASK_NORMAL;
1192                 flash.solid = SOLID_NOT;
1193                 flash.avelocity_z = 5000;
1194                 setattachment(flash, self, "");
1195                 setorigin(flash, '0 0 0');
1196
1197                 self.beam_muzzleentity = flash;
1198         }
1199         else
1200         {
1201                 flash = self.beam_muzzleentity;
1202         }
1203
1204         if(sf & ARC_SF_SETTINGS) // settings information
1205         {
1206                 self.beam_degreespersegment = ReadShort();
1207                 self.beam_distancepersegment = ReadShort();
1208                 self.beam_maxangle = ReadShort();
1209                 self.beam_range = ReadCoord();
1210                 self.beam_returnspeed = ReadShort();
1211                 self.beam_tightness = (ReadByte() / 10);
1212
1213                 if(ReadByte())
1214                 {
1215                         if(autocvar_chase_active)
1216                                 { self.beam_usevieworigin = 1; }
1217                         else // use view origin
1218                                 { self.beam_usevieworigin = 2; }
1219                 }
1220                 else
1221                 {
1222                         self.beam_usevieworigin = 0;
1223                 }
1224         }
1225
1226         if(!self.beam_usevieworigin)
1227         {
1228                 // self.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1229                 self.iflags = IFLAG_ORIGIN;
1230
1231                 InterpolateOrigin_Undo();
1232         }
1233
1234         if(sf & ARC_SF_START) // starting location
1235         {
1236                 self.origin_x = ReadCoord();
1237                 self.origin_y = ReadCoord();
1238                 self.origin_z = ReadCoord();
1239         }
1240         else if(self.beam_usevieworigin) // infer the location from player location
1241         {
1242                 if(self.beam_usevieworigin == 2)
1243                 {
1244                         // use view origin
1245                         self.origin = view_origin;
1246                 }
1247                 else
1248                 {
1249                         // use player origin so that third person display still works
1250                         self.origin = getplayerorigin(player_localnum) + ('0 0 1' * getstati(STAT_VIEWHEIGHT));
1251                 }
1252         }
1253
1254         setorigin(self, self.origin);
1255
1256         if(sf & ARC_SF_WANTDIR) // want/aim direction
1257         {
1258                 self.v_angle_x = ReadCoord();
1259                 self.v_angle_y = ReadCoord();
1260                 self.v_angle_z = ReadCoord();
1261         }
1262
1263         if(sf & ARC_SF_BEAMDIR) // beam direction
1264         {
1265                 self.angles_x = ReadCoord();
1266                 self.angles_y = ReadCoord();
1267                 self.angles_z = ReadCoord();
1268         }
1269
1270         if(sf & ARC_SF_BEAMTYPE) // beam type
1271         {
1272                 self.beam_type = ReadByte();
1273                 switch(self.beam_type)
1274                 {
1275                         case ARC_BT_MISS:
1276                         {
1277                                 self.beam_color = '1 1 1';
1278                                 self.beam_alpha = 0.5;
1279                                 self.beam_thickness = 8;
1280                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1281                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1282                                 self.beam_hitlight[0] = 0;
1283                                 self.beam_hitlight[1] = 1;
1284                                 self.beam_hitlight[2] = 1;
1285                                 self.beam_hitlight[3] = 1;
1286                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1287                                 self.beam_muzzlelight[0] = 0;
1288                                 self.beam_muzzlelight[1] = 1;
1289                                 self.beam_muzzlelight[2] = 1;
1290                                 self.beam_muzzlelight[3] = 1;
1291                                 if(self.beam_muzzleeffect >= 0)
1292                                 {
1293                                         setmodel(flash, "models/flash.md3");
1294                                         flash.alpha = self.beam_alpha;
1295                                         flash.colormod = self.beam_color;
1296                                         flash.scale = 0.5;
1297                                 }
1298                                 break;
1299                         }
1300                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1301                         {
1302                                 self.beam_color = '1 1 1';
1303                                 self.beam_alpha = 0.5;
1304                                 self.beam_thickness = 8;
1305                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1306                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1307                                 self.beam_hitlight[0] = 0;
1308                                 self.beam_hitlight[1] = 1;
1309                                 self.beam_hitlight[2] = 1;
1310                                 self.beam_hitlight[3] = 1;
1311                                 self.beam_muzzleeffect = -1; // particleeffectnum(EFFECT_GRENADE_MUZZLEFLASH);
1312                                 self.beam_muzzlelight[0] = 0;
1313                                 self.beam_muzzlelight[1] = 1;
1314                                 self.beam_muzzlelight[2] = 1;
1315                                 self.beam_muzzlelight[3] = 1;
1316                                 self.beam_image = "particles/lgbeam";
1317                                 if(self.beam_muzzleeffect >= 0)
1318                                 {
1319                                         setmodel(flash, "models/flash.md3");
1320                                         flash.alpha = self.beam_alpha;
1321                                         flash.colormod = self.beam_color;
1322                                         flash.scale = 0.5;
1323                                 }
1324                                 break;
1325                         }
1326                         case ARC_BT_HEAL:
1327                         {
1328                                 self.beam_color = '1 1 1';
1329                                 self.beam_alpha = 0.5;
1330                                 self.beam_thickness = 8;
1331                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL);
1332                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL_IMPACT);
1333                                 self.beam_hitlight[0] = 0;
1334                                 self.beam_hitlight[1] = 1;
1335                                 self.beam_hitlight[2] = 1;
1336                                 self.beam_hitlight[3] = 1;
1337                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1338                                 self.beam_muzzlelight[0] = 0;
1339                                 self.beam_muzzlelight[1] = 1;
1340                                 self.beam_muzzlelight[2] = 1;
1341                                 self.beam_muzzlelight[3] = 1;
1342                                 self.beam_image = "particles/lgbeam";
1343                                 if(self.beam_muzzleeffect >= 0)
1344                                 {
1345                                         setmodel(flash, "models/flash.md3");
1346                                         flash.alpha = self.beam_alpha;
1347                                         flash.colormod = self.beam_color;
1348                                         flash.scale = 0.5;
1349                                 }
1350                                 break;
1351                         }
1352                         case ARC_BT_HIT:
1353                         {
1354                                 self.beam_color = '1 1 1';
1355                                 self.beam_alpha = 0.5;
1356                                 self.beam_thickness = 8;
1357                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1358                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1359                                 self.beam_hitlight[0] = 20;
1360                                 self.beam_hitlight[1] = 1;
1361                                 self.beam_hitlight[2] = 0;
1362                                 self.beam_hitlight[3] = 0;
1363                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1364                                 self.beam_muzzlelight[0] = 50;
1365                                 self.beam_muzzlelight[1] = 1;
1366                                 self.beam_muzzlelight[2] = 0;
1367                                 self.beam_muzzlelight[3] = 0;
1368                                 self.beam_image = "particles/lgbeam";
1369                                 if(self.beam_muzzleeffect >= 0)
1370                                 {
1371                                         setmodel(flash, "models/flash.md3");
1372                                         flash.alpha = self.beam_alpha;
1373                                         flash.colormod = self.beam_color;
1374                                         flash.scale = 0.5;
1375                                 }
1376                                 break;
1377                         }
1378                         case ARC_BT_BURST_MISS:
1379                         {
1380                                 self.beam_color = '1 1 1';
1381                                 self.beam_alpha = 0.5;
1382                                 self.beam_thickness = 14;
1383                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1384                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1385                                 self.beam_hitlight[0] = 0;
1386                                 self.beam_hitlight[1] = 1;
1387                                 self.beam_hitlight[2] = 1;
1388                                 self.beam_hitlight[3] = 1;
1389                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1390                                 self.beam_muzzlelight[0] = 0;
1391                                 self.beam_muzzlelight[1] = 1;
1392                                 self.beam_muzzlelight[2] = 1;
1393                                 self.beam_muzzlelight[3] = 1;
1394                                 self.beam_image = "particles/lgbeam";
1395                                 if(self.beam_muzzleeffect >= 0)
1396                                 {
1397                                         setmodel(flash, "models/flash.md3");
1398                                         flash.alpha = self.beam_alpha;
1399                                         flash.colormod = self.beam_color;
1400                                         flash.scale = 0.5;
1401                                 }
1402                                 break;
1403                         }
1404                         case ARC_BT_BURST_WALL:
1405                         {
1406                                 self.beam_color = '1 1 1';
1407                                 self.beam_alpha = 0.5;
1408                                 self.beam_thickness = 14;
1409                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1410                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1411                                 self.beam_hitlight[0] = 0;
1412                                 self.beam_hitlight[1] = 1;
1413                                 self.beam_hitlight[2] = 1;
1414                                 self.beam_hitlight[3] = 1;
1415                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1416                                 self.beam_muzzlelight[0] = 0;
1417                                 self.beam_muzzlelight[1] = 1;
1418                                 self.beam_muzzlelight[2] = 1;
1419                                 self.beam_muzzlelight[3] = 1;
1420                                 self.beam_image = "particles/lgbeam";
1421                                 if(self.beam_muzzleeffect >= 0)
1422                                 {
1423                                         setmodel(flash, "models/flash.md3");
1424                                         flash.alpha = self.beam_alpha;
1425                                         flash.colormod = self.beam_color;
1426                                         flash.scale = 0.5;
1427                                 }
1428                                 break;
1429                         }
1430                         case ARC_BT_BURST_HEAL:
1431                         {
1432                                 self.beam_color = '1 1 1';
1433                                 self.beam_alpha = 0.5;
1434                                 self.beam_thickness = 14;
1435                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL);
1436                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL_IMPACT2);
1437                                 self.beam_hitlight[0] = 0;
1438                                 self.beam_hitlight[1] = 1;
1439                                 self.beam_hitlight[2] = 1;
1440                                 self.beam_hitlight[3] = 1;
1441                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1442                                 self.beam_muzzlelight[0] = 0;
1443                                 self.beam_muzzlelight[1] = 1;
1444                                 self.beam_muzzlelight[2] = 1;
1445                                 self.beam_muzzlelight[3] = 1;
1446                                 self.beam_image = "particles/lgbeam";
1447                                 if(self.beam_muzzleeffect >= 0)
1448                                 {
1449                                         setmodel(flash, "models/flash.md3");
1450                                         flash.alpha = self.beam_alpha;
1451                                         flash.colormod = self.beam_color;
1452                                         flash.scale = 0.5;
1453                                 }
1454                                 break;
1455                         }
1456                         case ARC_BT_BURST_HIT:
1457                         {
1458                                 self.beam_color = '1 1 1';
1459                                 self.beam_alpha = 0.5;
1460                                 self.beam_thickness = 14;
1461                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1462                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1463                                 self.beam_hitlight[0] = 0;
1464                                 self.beam_hitlight[1] = 1;
1465                                 self.beam_hitlight[2] = 1;
1466                                 self.beam_hitlight[3] = 1;
1467                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1468                                 self.beam_muzzlelight[0] = 0;
1469                                 self.beam_muzzlelight[1] = 1;
1470                                 self.beam_muzzlelight[2] = 1;
1471                                 self.beam_muzzlelight[3] = 1;
1472                                 self.beam_image = "particles/lgbeam";
1473                                 if(self.beam_muzzleeffect >= 0)
1474                                 {
1475                                         setmodel(flash, "models/flash.md3");
1476                                         flash.alpha = self.beam_alpha;
1477                                         flash.colormod = self.beam_color;
1478                                         flash.scale = 0.5;
1479                                 }
1480                                 break;
1481                         }
1482
1483                         // shouldn't be possible, but lets make it colorful if it does :D
1484                         default:
1485                         {
1486                                 self.beam_color = randomvec();
1487                                 self.beam_alpha = 1;
1488                                 self.beam_thickness = 8;
1489                                 self.beam_traileffect = false;
1490                                 self.beam_hiteffect = false;
1491                                 self.beam_hitlight[0] = 0;
1492                                 self.beam_hitlight[1] = 1;
1493                                 self.beam_hitlight[2] = 1;
1494                                 self.beam_hitlight[3] = 1;
1495                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1496                                 self.beam_muzzlelight[0] = 0;
1497                                 self.beam_muzzlelight[1] = 1;
1498                                 self.beam_muzzlelight[2] = 1;
1499                                 self.beam_muzzlelight[3] = 1;
1500                                 self.beam_image = "particles/lgbeam";
1501                                 if(self.beam_muzzleeffect >= 0)
1502                                 {
1503                                         setmodel(flash, "models/flash.md3");
1504                                         flash.alpha = self.beam_alpha;
1505                                         flash.colormod = self.beam_color;
1506                                         flash.scale = 0.5;
1507                                 }
1508                                 break;
1509                         }
1510                 }
1511         }
1512
1513         if(!self.beam_usevieworigin)
1514         {
1515                 InterpolateOrigin_Note();
1516         }
1517 }
1518
1519 bool W_Arc(int req)
1520 {SELFPARAM();
1521         switch(req)
1522         {
1523                 case WR_IMPACTEFFECT:
1524                 {
1525                         // todo
1526                         return true;
1527                 }
1528                 case WR_INIT:
1529                 {
1530                         precache_sound(W_Sound("arc_loop"));
1531                         return true;
1532                 }
1533                 case WR_ZOOMRETICLE:
1534                 {
1535                         // no weapon specific image for this weapon
1536                         return false;
1537                 }
1538         }
1539         return false;
1540 }
1541 #endif
1542 #endif