qcsrc/common/weapons/weapon/arc.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ ARC,
   4 /* function  */ W_Arc,
   5 /* ammotype  */ ammo_cells,
   6 /* impulse   */ 3,
   7 /* flags     */ WEP_FLAG_NORMAL,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '1 1 1',
  10 /* modelname */ "arc",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairhlac 0.7",
  13 /* wepimg    */ "weaponarc",
  14 /* refname   */ "arc",
  15 /* wepname   */ _("Arc")
  16 );
  17
  18 #define ARC_SETTINGS(w_cvar,w_prop) ARC_SETTINGS_LIST(w_cvar, w_prop, ARC, arc)
  19 #define ARC_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, beam_ammo) \
  21         w_cvar(id, sn, NONE, beam_animtime) \
  22         w_cvar(id, sn, NONE, beam_botaimspeed) \
  23         w_cvar(id, sn, NONE, beam_botaimlifetime) \
  24         w_cvar(id, sn, NONE, beam_damage) \
  25         w_cvar(id, sn, NONE, beam_degreespersegment) \
  26         w_cvar(id, sn, NONE, beam_distancepersegment) \
  27         w_cvar(id, sn, NONE, beam_falloff_halflifedist) \
  28         w_cvar(id, sn, NONE, beam_falloff_maxdist) \
  29         w_cvar(id, sn, NONE, beam_falloff_mindist) \
  30         w_cvar(id, sn, NONE, beam_force) \
  31         w_cvar(id, sn, NONE, beam_healing_amax) \
  32         w_cvar(id, sn, NONE, beam_healing_aps) \
  33         w_cvar(id, sn, NONE, beam_healing_hmax) \
  34         w_cvar(id, sn, NONE, beam_healing_hps) \
  35         w_cvar(id, sn, NONE, beam_maxangle) \
  36         w_cvar(id, sn, NONE, beam_nonplayerdamage) \
  37         w_cvar(id, sn, NONE, beam_range) \
  38         w_cvar(id, sn, NONE, beam_refire) \
  39         w_cvar(id, sn, NONE, beam_returnspeed) \
  40         w_cvar(id, sn, NONE, beam_tightness) \
  41         w_cvar(id, sn, NONE, burst_ammo) \
  42         w_cvar(id, sn, NONE, burst_damage) \
  43         w_cvar(id, sn, NONE, burst_healing_aps) \
  44         w_cvar(id, sn, NONE, burst_healing_hps) \
  45         w_cvar(id, sn, NONE, overheat_max)/* maximum heat before jamming */ \
  46         w_cvar(id, sn, NONE, overheat_min)/* minimum heat to wait for cooldown */ \
  47         w_cvar(id, sn, NONE, beam_heat)   /* heat increase per second (primary) */ \
  48         w_cvar(id, sn, NONE, burst_heat)  /* heat increase per second (secondary) */ \
  49         w_cvar(id, sn, NONE, cooldown)    /* heat decrease per second when resting */ \
  50         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  51         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  52         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  53         w_prop(id, sn, float,  weaponstart, weaponstart) \
  54         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  55         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  56
  57 #ifndef MENUQC
  58 const float ARC_MAX_SEGMENTS = 20;
  59 vector arc_shotorigin[4];
  60 .vector beam_start;
  61 .vector beam_dir;
  62 .vector beam_wantdir;
  63 .int beam_type;
  64
  65 const int ARC_BT_MISS =        0x00;
  66 const int ARC_BT_WALL =        0x01;
  67 const int ARC_BT_HEAL =        0x02;
  68 const int ARC_BT_HIT =         0x03;
  69 const int ARC_BT_BURST_MISS =  0x10;
  70 const int ARC_BT_BURST_WALL =  0x11;
  71 const int ARC_BT_BURST_HEAL =  0x12;
  72 const int ARC_BT_BURST_HIT =   0x13;
  73 const int ARC_BT_BURSTMASK =   0x10;
  74
  75 const int ARC_SF_SETTINGS =    1;
  76 const int ARC_SF_START =       2;
  77 const int ARC_SF_WANTDIR =     4;
  78 const int ARC_SF_BEAMDIR =     8;
  79 const int ARC_SF_BEAMTYPE =    16;
  80 const int ARC_SF_LOCALMASK =   14;
  81 #endif
  82 #ifdef SVQC
  83 ARC_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  84 .entity arc_beam;
  85 .float arc_BUTTON_ATCK_prev; // for better animation control
  86 .float beam_prev;
  87 .float beam_initialized;
  88 .float beam_bursting;
  89 .float beam_teleporttime;
  90 .float beam_heat; // (beam) amount of heat produced
  91 .float arc_overheat; // (dropped arc/player) time during which it's too hot
  92 .float arc_cooldown; // (dropped arc/player) cooling speed
  93 .float arc_heat_percent; // (player) arc heat in [0,1] (stat)
  94 .float arc_smoke_sound;
  95 #endif
  96 #ifdef CSQC
  97 void Ent_ReadArcBeam(float isnew);
  98
  99 .vector beam_color;
 100 .float beam_alpha;
 101 .float beam_thickness;
 102 .float beam_traileffect;
 103 .float beam_hiteffect;
 104 .float beam_hitlight[4]; // 0: radius, 123: rgb
 105 .float beam_muzzleeffect;
 106 .float beam_muzzlelight[4]; // 0: radius, 123: rgb
 107 .string beam_image;
 108
 109 .entity beam_muzzleentity;
 110
 111 .float beam_degreespersegment;
 112 .float beam_distancepersegment;
 113 .float beam_usevieworigin;
 114 .float beam_initialized;
 115 .float beam_maxangle;
 116 .float beam_range;
 117 .float beam_returnspeed;
 118 .float beam_tightness;
 119 .vector beam_shotorigin;
 120
 121 entity Draw_ArcBeam_callback_entity;
 122 float Draw_ArcBeam_callback_last_thickness;
 123 vector Draw_ArcBeam_callback_last_top; // NOTE: in same coordinate system as player.
 124 vector Draw_ArcBeam_callback_last_bottom; // NOTE: in same coordinate system as player.
 125 #endif
 126 #endif
 127 #ifdef IMPLEMENTATION
 128 #ifdef SVQC
 129 void spawnfunc_weapon_arc(void) { weapon_defaultspawnfunc(WEP_ARC.m_id); }
 130
 131 float W_Arc_Beam_Send(entity to, int sf)
 132 {SELFPARAM();
 133         WriteByte(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
 134
 135         // Truncate information when this beam is displayed to the owner client
 136         // - The owner client has no use for beam start position or directions,
 137         //    it always figures this information out for itself with csqc code.
 138         // - Spectating the owner also truncates this information.
 139         float drawlocal = ((to == self.owner) || ((to.enemy == self.owner) && IS_SPEC(to)));
 140         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
 141
 142         WriteByte(MSG_ENTITY, sf);
 143
 144         if(sf & ARC_SF_SETTINGS) // settings information
 145         {
 146                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
 147                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
 148                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
 149                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
 150                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
 151                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
 152
 153                 WriteByte(MSG_ENTITY, drawlocal);
 154         }
 155         if(sf & ARC_SF_START) // starting location
 156         {
 157                 WriteCoord(MSG_ENTITY, self.beam_start.x);
 158                 WriteCoord(MSG_ENTITY, self.beam_start.y);
 159                 WriteCoord(MSG_ENTITY, self.beam_start.z);
 160         }
 161         if(sf & ARC_SF_WANTDIR) // want/aim direction
 162         {
 163                 WriteCoord(MSG_ENTITY, self.beam_wantdir.x);
 164                 WriteCoord(MSG_ENTITY, self.beam_wantdir.y);
 165                 WriteCoord(MSG_ENTITY, self.beam_wantdir.z);
 166         }
 167         if(sf & ARC_SF_BEAMDIR) // beam direction
 168         {
 169                 WriteCoord(MSG_ENTITY, self.beam_dir.x);
 170                 WriteCoord(MSG_ENTITY, self.beam_dir.y);
 171                 WriteCoord(MSG_ENTITY, self.beam_dir.z);
 172         }
 173         if(sf & ARC_SF_BEAMTYPE) // beam type
 174         {
 175                 WriteByte(MSG_ENTITY, self.beam_type);
 176         }
 177
 178         return true;
 179 }
 180
 181 void Reset_ArcBeam(entity player, vector forward)
 182 {
 183         if (!player.arc_beam) {
 184                 return;
 185         }
 186         player.arc_beam.beam_dir = forward;
 187         player.arc_beam.beam_teleporttime = time;
 188 }
 189
 190 float Arc_GetHeat_Percent(entity player)
 191 {
 192         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
 193         {
 194                 player.arc_overheat = 0;
 195                 return 0;
 196         }
 197
 198         if ( player.arc_beam )
 199                 return player.arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
 200
 201         if ( player.arc_overheat > time )
 202         {
 203                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
 204                         * player.arc_cooldown;
 205         }
 206
 207         return 0;
 208 }
 209 void Arc_Player_SetHeat(entity player)
 210 {
 211         player.arc_heat_percent = Arc_GetHeat_Percent(player);
 212         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
 213 }
 214
 215 void W_Arc_Beam_Think(void)
 216 {SELFPARAM();
 217         if(self != self.owner.arc_beam)
 218         {
 219                 remove(self);
 220                 return;
 221         }
 222
 223
 224         float burst = 0;
 225         if( self.owner.BUTTON_ATCK2 || self.beam_bursting)
 226         {
 227                 if(!self.beam_bursting)
 228                         self.beam_bursting = true;
 229                 burst = ARC_BT_BURSTMASK;
 230         }
 231
 232         if(
 233                 !IS_PLAYER(self.owner)
 234                 ||
 235                 (self.owner.WEP_AMMO(ARC) <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 236                 ||
 237                 self.owner.deadflag != DEAD_NO
 238                 ||
 239                 (!self.owner.BUTTON_ATCK && !burst )
 240                 ||
 241                 self.owner.frozen
 242                 ||
 243                 self.owner.vehicle
 244                 ||
 245                 (WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max))
 246         )
 247         {
 248                 if ( WEP_CVAR(arc, cooldown) > 0 )
 249                 {
 250                         float cooldown_speed = 0;
 251                         if ( self.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 252                         {
 253                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 254                         }
 255                         else if ( !burst )
 256                         {
 257                                 cooldown_speed = self.beam_heat / WEP_CVAR(arc, beam_refire);
 258                         }
 259
 260                         if ( cooldown_speed )
 261                         {
 262                                 self.owner.arc_overheat = time + self.beam_heat / cooldown_speed;
 263                                 self.owner.arc_cooldown = cooldown_speed;
 264                         }
 265
 266                         if ( WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max) )
 267                         {
 268                                 Send_Effect_("arc_overheat",
 269                                         self.beam_start, self.beam_wantdir, 1 );
 270                                 sound(self, CH_WEAPON_A, W_Sound("arc_stop"), VOL_BASE, ATTN_NORM);
 271                         }
 272                 }
 273
 274                 if(self == self.owner.arc_beam) { self.owner.arc_beam = world; }
 275                 setself(self.owner);
 276                 if(!WEP_ACTION(WEP_ARC.m_id, WR_CHECKAMMO1) && !WEP_ACTION(WEP_ARC.m_id, WR_CHECKAMMO2))
 277                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 278                 {
 279                         // note: this doesn't force the switch
 280                         W_SwitchToOtherWeapon(self);
 281                 }
 282                 setself(this);
 283                 remove(self);
 284                 return;
 285         }
 286
 287         // decrease ammo
 288         float coefficient = frametime;
 289         if(!(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 290         {
 291                 float rootammo;
 292                 if(burst)
 293                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 294                 else
 295                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 296
 297                 if(rootammo)
 298                 {
 299                         coefficient = min(coefficient, self.owner.WEP_AMMO(ARC) / rootammo);
 300                         self.owner.WEP_AMMO(ARC) = max(0, self.owner.WEP_AMMO(ARC) - (rootammo * frametime));
 301                 }
 302         }
 303         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 304         self.beam_heat = min( WEP_CVAR(arc, overheat_max), self.beam_heat + heat_speed*frametime );
 305
 306         makevectors(self.owner.v_angle);
 307
 308         W_SetupShot_Range(
 309                 self.owner,
 310                 true,
 311                 0,
 312                 "",
 313                 0,
 314                 WEP_CVAR(arc, beam_damage) * coefficient,
 315                 WEP_CVAR(arc, beam_range)
 316         );
 317
 318         // After teleport, "lock" the beam until the teleport is confirmed.
 319         if (time < self.beam_teleporttime + ANTILAG_LATENCY(self.owner)) {
 320                 w_shotdir = self.beam_dir;
 321         }
 322
 323         // network information: shot origin and want/aim direction
 324         if(self.beam_start != w_shotorg)
 325         {
 326                 self.SendFlags |= ARC_SF_START;
 327                 self.beam_start = w_shotorg;
 328         }
 329         if(self.beam_wantdir != w_shotdir)
 330         {
 331                 self.SendFlags |= ARC_SF_WANTDIR;
 332                 self.beam_wantdir = w_shotdir;
 333         }
 334
 335         if(!self.beam_initialized)
 336         {
 337                 self.beam_dir = w_shotdir;
 338                 self.beam_initialized = true;
 339         }
 340
 341         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 342         // idea: blend together self.beam_dir with the inverted direction the player is moving in
 343         // might have to make some special accomodation so that it only uses view_right and view_up
 344
 345         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 346
 347         float segments;
 348         if(self.beam_dir != w_shotdir)
 349         {
 350                 // calculate how much we're going to move the end of the beam to the want position
 351                 // WEAPONTODO (server and client):
 352                 // blendfactor never actually becomes 0 in this situation, which is a problem
 353                 // regarding precision... this means that self.beam_dir and w_shotdir approach
 354                 // eachother, however they never actually become the same value with this method.
 355                 // Perhaps we should do some form of rounding/snapping?
 356                 float angle = vlen(w_shotdir - self.beam_dir) * RAD2DEG;
 357                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 358                 {
 359                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 360                         float blendfactor = bound(
 361                                 0,
 362                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 363                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 364                         );
 365                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 366                 }
 367                 else
 368                 {
 369                         // the radius is not too far yet, no worries :D
 370                         float blendfactor = bound(
 371                                 0,
 372                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 373                                 1
 374                         );
 375                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 376                 }
 377
 378                 // network information: beam direction
 379                 self.SendFlags |= ARC_SF_BEAMDIR;
 380
 381                 // calculate how many segments are needed
 382                 float max_allowed_segments;
 383
 384                 if(WEP_CVAR(arc, beam_distancepersegment))
 385                 {
 386                         max_allowed_segments = min(
 387                                 ARC_MAX_SEGMENTS,
 388                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 389                         );
 390                 }
 391                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 392
 393                 if(WEP_CVAR(arc, beam_degreespersegment))
 394                 {
 395                         segments = bound(
 396                                 1,
 397                                 (
 398                                         min(
 399                                                 angle,
 400                                                 WEP_CVAR(arc, beam_maxangle)
 401                                         )
 402                                         /
 403                                         WEP_CVAR(arc, beam_degreespersegment)
 404                                 ),
 405                                 max_allowed_segments
 406                         );
 407                 }
 408                 else { segments = 1; }
 409         }
 410         else { segments = 1; }
 411
 412         vector beam_endpos = (w_shotorg + (self.beam_dir * WEP_CVAR(arc, beam_range)));
 413         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 414
 415         float i;
 416         float new_beam_type = 0;
 417         vector last_origin = w_shotorg;
 418         for(i = 1; i <= segments; ++i)
 419         {
 420                 // WEAPONTODO (client):
 421                 // In order to do nice fading and pointing on the starting segment, we must always
 422                 // have that drawn as a separate triangle... However, that is difficult to do when
 423                 // keeping in mind the above problems and also optimizing the amount of segments
 424                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 425
 426                 vector new_origin = bezier_quadratic_getpoint(
 427                         w_shotorg,
 428                         beam_controlpoint,
 429                         beam_endpos,
 430                         i / segments);
 431                 vector new_dir = normalize(new_origin - last_origin);
 432
 433                 WarpZone_traceline_antilag(
 434                         self.owner,
 435                         last_origin,
 436                         new_origin,
 437                         MOVE_NORMAL,
 438                         self.owner,
 439                         ANTILAG_LATENCY(self.owner)
 440                 );
 441
 442                 // Do all the transforms for warpzones right now, as we already
 443                 // "are" in the post-trace system (if we hit a player, that's
 444                 // always BEHIND the last passed wz).
 445                 last_origin = trace_endpos;
 446                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 447                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 448                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 449                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 450
 451                 float is_player = (
 452                         IS_PLAYER(trace_ent)
 453                         ||
 454                         trace_ent.classname == "body"
 455                         ||
 456                         IS_MONSTER(trace_ent)
 457                 );
 458
 459                 if(trace_ent && trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 460                 {
 461                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 462                         // NO. trace_endpos should be just fine. If not,
 463                         // that's an engine bug that needs proper debugging.
 464                         vector hitorigin = trace_endpos;
 465
 466                         float falloff = ExponentialFalloff(
 467                                 WEP_CVAR(arc, beam_falloff_mindist),
 468                                 WEP_CVAR(arc, beam_falloff_maxdist),
 469                                 WEP_CVAR(arc, beam_falloff_halflifedist),
 470                                 vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 471                         );
 472
 473                         if(is_player && SAME_TEAM(self.owner, trace_ent))
 474                         {
 475                                 float roothealth, rootarmor;
 476                                 if(burst)
 477                                 {
 478                                         roothealth = WEP_CVAR(arc, burst_healing_hps);
 479                                         rootarmor = WEP_CVAR(arc, burst_healing_aps);
 480                                 }
 481                                 else
 482                                 {
 483                                         roothealth = WEP_CVAR(arc, beam_healing_hps);
 484                                         rootarmor = WEP_CVAR(arc, beam_healing_aps);
 485                                 }
 486
 487                                 if(trace_ent.health <= WEP_CVAR(arc, beam_healing_hmax) && roothealth)
 488                                 {
 489                                         trace_ent.health = min(
 490                                                 trace_ent.health + (roothealth * coefficient),
 491                                                 WEP_CVAR(arc, beam_healing_hmax)
 492                                         );
 493                                 }
 494                                 if(trace_ent.armorvalue <= WEP_CVAR(arc, beam_healing_amax) && rootarmor)
 495                                 {
 496                                         trace_ent.armorvalue = min(
 497                                                 trace_ent.armorvalue + (rootarmor * coefficient),
 498                                                 WEP_CVAR(arc, beam_healing_amax)
 499                                         );
 500                                 }
 501
 502                                 // stop rot, set visual effect
 503                                 if(roothealth || rootarmor)
 504                                 {
 505                                         trace_ent.pauserothealth_finished = max(
 506                                                 trace_ent.pauserothealth_finished,
 507                                                 time + autocvar_g_balance_pause_health_rot
 508                                         );
 509                                         trace_ent.pauserotarmor_finished = max(
 510                                                 trace_ent.pauserotarmor_finished,
 511                                                 time + autocvar_g_balance_pause_armor_rot
 512                                         );
 513                                         new_beam_type = ARC_BT_HEAL;
 514                                 }
 515                         }
 516                         else
 517                         {
 518                                 float rootdamage;
 519                                 if(is_player)
 520                                 {
 521                                         if(burst)
 522                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 523                                         else
 524                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 525                                 }
 526                                 else
 527                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 528
 529                                 if(accuracy_isgooddamage(self.owner, trace_ent))
 530                                 {
 531                                         accuracy_add(
 532                                                 self.owner,
 533                                                 WEP_ARC.m_id,
 534                                                 0,
 535                                                 rootdamage * coefficient * falloff
 536                                         );
 537                                 }
 538
 539                                 Damage(
 540                                         trace_ent,
 541                                         self.owner,
 542                                         self.owner,
 543                                         rootdamage * coefficient * falloff,
 544                                         WEP_ARC.m_id,
 545                                         hitorigin,
 546                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 547                                 );
 548
 549                                 new_beam_type = ARC_BT_HIT;
 550                         }
 551                         break;
 552                 }
 553                 else if(trace_fraction != 1)
 554                 {
 555                         // we collided with geometry
 556                         new_beam_type = ARC_BT_WALL;
 557                         break;
 558                 }
 559         }
 560
 561         // te_explosion(trace_endpos);
 562
 563         // if we're bursting, use burst visual effects
 564         new_beam_type |= burst;
 565
 566         // network information: beam type
 567         if(new_beam_type != self.beam_type)
 568         {
 569                 self.SendFlags |= ARC_SF_BEAMTYPE;
 570                 self.beam_type = new_beam_type;
 571         }
 572
 573         self.owner.beam_prev = time;
 574         self.nextthink = time;
 575 }
 576
 577 void W_Arc_Beam(float burst)
 578 {SELFPARAM();
 579
 580         // only play fire sound if 1 sec has passed since player let go the fire button
 581         if(time - self.beam_prev > 1)
 582                 sound(self, CH_WEAPON_A, W_Sound("arc_fire"), VOL_BASE, ATTN_NORM);
 583
 584         entity beam = self.arc_beam = spawn();
 585         beam.classname = "W_Arc_Beam";
 586         beam.solid = SOLID_NOT;
 587         beam.think = W_Arc_Beam_Think;
 588         beam.owner = self;
 589         beam.movetype = MOVETYPE_NONE;
 590         beam.bot_dodge = true;
 591         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 592         beam.beam_bursting = burst;
 593         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 594
 595         WITH(entity, self, beam, beam.think());
 596 }
 597
 598 void Arc_Smoke()
 599 {SELFPARAM();
 600         makevectors(self.v_angle);
 601         W_SetupShot_Range(self,true,0,"",0,0,0);
 602
 603         vector smoke_origin = w_shotorg + self.velocity*frametime;
 604         if ( self.arc_overheat > time )
 605         {
 606                 if ( random() < self.arc_heat_percent )
 607                         Send_Effect_("arc_smoke", smoke_origin, '0 0 0', 1 );
 608                 if ( self.BUTTON_ATCK || self.BUTTON_ATCK2 )
 609                 {
 610                         Send_Effect_("arc_overheat_fire", smoke_origin, w_shotdir, 1 );
 611                         if ( !self.arc_smoke_sound )
 612                         {
 613                                 self.arc_smoke_sound = 1;
 614                                 sound(self, CH_SHOTS_SINGLE, W_Sound("arc_loop_overheat"), VOL_BASE, ATTN_NORM);
 615                         }
 616                 }
 617         }
 618         else if ( self.arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 619                         self.arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 620         {
 621                 if ( random() < (self.arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 622                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 623                         Send_Effect_("arc_smoke", smoke_origin, '0 0 0', 1 );
 624         }
 625
 626         if (  self.arc_smoke_sound && ( self.arc_overheat <= time ||
 627                 !( self.BUTTON_ATCK || self.BUTTON_ATCK2 ) ) || self.switchweapon != WEP_ARC.m_id )
 628         {
 629                 self.arc_smoke_sound = 0;
 630                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
 631         }
 632 }
 633
 634 bool W_Arc(int req)
 635 {SELFPARAM();
 636         switch(req)
 637         {
 638                 case WR_AIM:
 639                 {
 640                         if(WEP_CVAR(arc, beam_botaimspeed))
 641                         {
 642                                 self.BUTTON_ATCK = bot_aim(
 643                                         WEP_CVAR(arc, beam_botaimspeed),
 644                                         0,
 645                                         WEP_CVAR(arc, beam_botaimlifetime),
 646                                         false
 647                                 );
 648                         }
 649                         else
 650                         {
 651                                 self.BUTTON_ATCK = bot_aim(
 652                                         1000000,
 653                                         0,
 654                                         0.001,
 655                                         false
 656                                 );
 657                         }
 658                         return true;
 659                 }
 660                 case WR_THINK:
 661                 {
 662                         Arc_Player_SetHeat(self);
 663                         Arc_Smoke();
 664
 665                         if ( self.arc_overheat <= time )
 666                         if(self.BUTTON_ATCK || self.BUTTON_ATCK2 || self.arc_beam.beam_bursting )
 667                         {
 668
 669                                 if(self.arc_BUTTON_ATCK_prev)
 670                                 {
 671                                         #if 0
 672                                         if(self.animstate_startframe == self.anim_shoot.x && self.animstate_numframes == self.anim_shoot.y)
 673                                                 weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 674                                         else
 675                                         #endif
 676                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 677                                 }
 678
 679                                 if((!self.arc_beam) || wasfreed(self.arc_beam))
 680                                 {
 681                                         if(weapon_prepareattack(!!self.BUTTON_ATCK2, 0))
 682                                         {
 683                                                 W_Arc_Beam(!!self.BUTTON_ATCK2);
 684
 685                                                 if(!self.arc_BUTTON_ATCK_prev)
 686                                                 {
 687                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 688                                                         self.arc_BUTTON_ATCK_prev = 1;
 689                                                 }
 690                                         }
 691                                 }
 692
 693                                 return true;
 694                         }
 695
 696                         if(self.arc_BUTTON_ATCK_prev != 0)
 697                         {
 698                                 sound(self, CH_WEAPON_A, W_Sound("arc_stop"), VOL_BASE, ATTN_NORM);
 699                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 700                                 ATTACK_FINISHED(self) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor();
 701                         }
 702                         self.arc_BUTTON_ATCK_prev = 0;
 703
 704                         #if 0
 705                         if(self.BUTTON_ATCK2)
 706                         if(weapon_prepareattack(1, autocvar_g_balance_arc_secondary_refire))
 707                         {
 708                                 W_Arc_Attack2();
 709                                 self.arc_count = autocvar_g_balance_arc_secondary_count;
 710                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 711                                 self.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor();
 712                         }
 713                         #endif
 714
 715                         return true;
 716                 }
 717                 case WR_INIT:
 718                 {
 719                         precache_sound(W_Sound("arc_fire"));
 720                         precache_sound(W_Sound("arc_loop"));
 721                         precache_sound(W_Sound("arc_stop"));
 722                         precache_sound(W_Sound("arc_loop_overheat"));
 723                         if(!arc_shotorigin[0])
 724                         {
 725                                 arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 726                                 arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 727                                 arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 728                                 arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 729                         }
 730                         ARC_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 731                         return true;
 732                 }
 733                 case WR_CHECKAMMO1:
 734                 {
 735                         return ((!WEP_CVAR(arc, beam_ammo)) || (self.WEP_AMMO(ARC) > 0));
 736                 }
 737                 case WR_CHECKAMMO2:
 738                 {
 739                         return WEP_CVAR(arc, overheat_max) > 0 &&
 740                                 ((!WEP_CVAR(arc, burst_ammo)) || (self.WEP_AMMO(ARC) > 0));
 741                 }
 742                 case WR_CONFIG:
 743                 {
 744                         ARC_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 745                         return true;
 746                 }
 747                 case WR_KILLMESSAGE:
 748                 {
 749                         return WEAPON_ARC_MURDER;
 750                 }
 751                 case WR_DROP:
 752                 {
 753                         weapon_dropevent_item.arc_overheat = self.arc_overheat;
 754                         weapon_dropevent_item.arc_cooldown = self.arc_cooldown;
 755                         self.arc_overheat = 0;
 756                         self.arc_cooldown = 0;
 757                         return true;
 758                 }
 759                 case WR_PICKUP:
 760                 {
 761                         if ( !client_hasweapon(self, WEP_ARC.m_id, false, false) &&
 762                                 weapon_dropevent_item.arc_overheat > time )
 763                         {
 764                                 self.arc_overheat = weapon_dropevent_item.arc_overheat;
 765                                 self.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 766                         }
 767                         return true;
 768                 }
 769         }
 770         return false;
 771 }
 772 #endif
 773 #ifdef CSQC
 774 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 775 {
 776         entity beam = Draw_ArcBeam_callback_entity;
 777         vector transformed_view_org;
 778         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 779
 780         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 781         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 782         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 783
 784         vector hitorigin;
 785
 786         // draw segment
 787         #if 0
 788         if(trace_fraction != 1)
 789         {
 790                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 791                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 792                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 793         }
 794         else
 795         {
 796                 hitorigin = hit;
 797         }
 798         #else
 799         hitorigin = hit;
 800         #endif
 801
 802         // decide upon thickness
 803         float thickness = beam.beam_thickness;
 804
 805         // draw primary beam render
 806         vector top    = hitorigin + (thickdir * thickness);
 807         vector bottom = hitorigin - (thickdir * thickness);
 808
 809         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 810         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 811
 812         R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 813         R_PolygonVertex(
 814                 top,
 815                 '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 816                 beam.beam_color,
 817                 beam.beam_alpha
 818         );
 819         R_PolygonVertex(
 820                 last_top,
 821                 '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 822                 beam.beam_color,
 823                 beam.beam_alpha
 824         );
 825         R_PolygonVertex(
 826                 last_bottom,
 827                 '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 828                 beam.beam_color,
 829                 beam.beam_alpha
 830         );
 831         R_PolygonVertex(
 832                 bottom,
 833                 '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 834                 beam.beam_color,
 835                 beam.beam_alpha
 836         );
 837         R_EndPolygon();
 838
 839         // draw trailing particles
 840         // NOTES:
 841         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 842         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 843         if(beam.beam_traileffect)
 844         {
 845                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 846         }
 847
 848         // set up for the next
 849         Draw_ArcBeam_callback_last_thickness = thickness;
 850         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 851         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 852 }
 853
 854 void Reset_ArcBeam(void)
 855 {
 856         entity e;
 857         for (e = world; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 858                 e.beam_initialized = false;
 859         }
 860         for (e = world; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 861                 e.beam_initialized = false;
 862         }
 863 }
 864
 865 void Draw_ArcBeam(void)
 866 {SELFPARAM();
 867         float dt = time - self.move_time;
 868         self.move_time = time;
 869         if(dt <= 0) { return; }
 870
 871         if(!self.beam_usevieworigin)
 872         {
 873                 InterpolateOrigin_Do();
 874         }
 875
 876         // origin = beam starting origin
 877         // v_angle = wanted/aim direction
 878         // angles = current direction of beam
 879
 880         vector start_pos;
 881         vector wantdir; //= view_forward;
 882         vector beamdir; //= self.beam_dir;
 883
 884         float segments;
 885         if(self.beam_usevieworigin)
 886         {
 887                 // WEAPONTODO:
 888                 // Currently we have to replicate nearly the same method of figuring
 889                 // out the shotdir that the server does... Ideally in the future we
 890                 // should be able to acquire this from a generalized function built
 891                 // into a weapon system for client code.
 892
 893                 // find where we are aiming
 894                 makevectors(warpzone_save_view_angles);
 895                 vector forward = v_forward;
 896                 vector right = v_right;
 897                 vector up = v_up;
 898
 899                 // decide upon start position
 900                 if(self.beam_usevieworigin == 2)
 901                         { start_pos = warpzone_save_view_origin; }
 902                 else
 903                         { start_pos = self.origin; }
 904
 905                 // trace forward with an estimation
 906                 WarpZone_TraceLine(
 907                         start_pos,
 908                         start_pos + forward * self.beam_range,
 909                         MOVE_NOMONSTERS,
 910                         self
 911                 );
 912
 913                 // untransform in case our trace went through a warpzone
 914                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 915
 916                 // un-adjust trueaim if shotend is too close
 917                 if(vlen(end_pos - start_pos) < g_trueaim_minrange)
 918                         end_pos = start_pos + (forward * g_trueaim_minrange);
 919
 920                 // move shot origin to the actual gun muzzle origin
 921                 vector origin_offset =
 922                           right * -self.beam_shotorigin.y
 923                         + up * self.beam_shotorigin.z;
 924
 925                 start_pos = start_pos + origin_offset;
 926
 927                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 928                 traceline(start_pos, start_pos + forward * self.beam_shotorigin.x, MOVE_NORMAL, self);
 929                 start_pos = trace_endpos;
 930
 931                 // calculate the aim direction now
 932                 wantdir = normalize(end_pos - start_pos);
 933
 934                 if(!self.beam_initialized)
 935                 {
 936                         self.beam_dir = wantdir;
 937                         self.beam_initialized = true;
 938                 }
 939
 940                 if(self.beam_dir != wantdir)
 941                 {
 942                         // calculate how much we're going to move the end of the beam to the want position
 943                         // WEAPONTODO (server and client):
 944                         // blendfactor never actually becomes 0 in this situation, which is a problem
 945                         // regarding precision... this means that self.beam_dir and w_shotdir approach
 946                         // eachother, however they never actually become the same value with this method.
 947                         // Perhaps we should do some form of rounding/snapping?
 948                         float angle = vlen(wantdir - self.beam_dir) * RAD2DEG;
 949                         if(angle && (angle > self.beam_maxangle))
 950                         {
 951                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 952                                 float blendfactor = bound(
 953                                         0,
 954                                         (1 - (self.beam_returnspeed * frametime)),
 955                                         min(self.beam_maxangle / angle, 1)
 956                                 );
 957                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 958                         }
 959                         else
 960                         {
 961                                 // the radius is not too far yet, no worries :D
 962                                 float blendfactor = bound(
 963                                         0,
 964                                         (1 - (self.beam_returnspeed * frametime)),
 965                                         1
 966                                 );
 967                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 968                         }
 969
 970                         // calculate how many segments are needed
 971                         float max_allowed_segments;
 972
 973                         if(self.beam_distancepersegment)
 974                         {
 975                                 max_allowed_segments = min(
 976                                         ARC_MAX_SEGMENTS,
 977                                         1 + (vlen(wantdir / self.beam_distancepersegment))
 978                                 );
 979                         }
 980                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 981
 982                         if(self.beam_degreespersegment)
 983                         {
 984                                 segments = bound(
 985                                         1,
 986                                         (
 987                                                 min(
 988                                                         angle,
 989                                                         self.beam_maxangle
 990                                                 )
 991                                                 /
 992                                                 self.beam_degreespersegment
 993                                         ),
 994                                         max_allowed_segments
 995                                 );
 996                         }
 997                         else { segments = 1; }
 998                 }
 999                 else { segments = 1; }
1000
1001                 // set the beam direction which the rest of the code will refer to
1002                 beamdir = self.beam_dir;
1003
1004                 // finally, set self.angles to the proper direction so that muzzle attachment points in proper direction
1005                 self.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1006         }
1007         else
1008         {
1009                 // set the values from the provided info from the networked entity
1010                 start_pos = self.origin;
1011                 wantdir = self.v_angle;
1012                 beamdir = self.angles;
1013
1014                 if(beamdir != wantdir)
1015                 {
1016                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1017
1018                         // calculate how many segments are needed
1019                         float max_allowed_segments;
1020
1021                         if(self.beam_distancepersegment)
1022                         {
1023                                 max_allowed_segments = min(
1024                                         ARC_MAX_SEGMENTS,
1025                                         1 + (vlen(wantdir / self.beam_distancepersegment))
1026                                 );
1027                         }
1028                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1029
1030                         if(self.beam_degreespersegment)
1031                         {
1032                                 segments = bound(
1033                                         1,
1034                                         (
1035                                                 min(
1036                                                         angle,
1037                                                         self.beam_maxangle
1038                                                 )
1039                                                 /
1040                                                 self.beam_degreespersegment
1041                                         ),
1042                                         max_allowed_segments
1043                                 );
1044                         }
1045                         else { segments = 1; }
1046                 }
1047                 else { segments = 1; }
1048         }
1049
1050         setorigin(self, start_pos);
1051         self.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1052
1053         vector beam_endpos = (start_pos + (beamdir * self.beam_range));
1054         vector beam_controlpoint = start_pos + wantdir * (self.beam_range * (1 - self.beam_tightness));
1055
1056         Draw_ArcBeam_callback_entity = self;
1057         Draw_ArcBeam_callback_last_thickness = 0;
1058         Draw_ArcBeam_callback_last_top = start_pos;
1059         Draw_ArcBeam_callback_last_bottom = start_pos;
1060
1061         vector last_origin = start_pos;
1062         vector original_start_pos = start_pos;
1063
1064         float i;
1065         for(i = 1; i <= segments; ++i)
1066         {
1067                 // WEAPONTODO (client):
1068                 // In order to do nice fading and pointing on the starting segment, we must always
1069                 // have that drawn as a separate triangle... However, that is difficult to do when
1070                 // keeping in mind the above problems and also optimizing the amount of segments
1071                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1072
1073                 vector new_origin = bezier_quadratic_getpoint(
1074                         start_pos,
1075                         beam_controlpoint,
1076                         beam_endpos,
1077                         i / segments);
1078
1079                 WarpZone_TraceBox_ThroughZone(
1080                         last_origin,
1081                         '0 0 0',
1082                         '0 0 0',
1083                         new_origin,
1084                         MOVE_NORMAL,
1085                         world,
1086                         world,
1087                         Draw_ArcBeam_callback
1088                 );
1089
1090                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1091                 // system (if we hit a player, that's always BEHIND the last passed wz).
1092                 last_origin = trace_endpos;
1093                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1094                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1095                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1096                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1097                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1098                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1099
1100                 if(trace_fraction < 1) { break; }
1101         }
1102
1103         // visual effects for startpoint and endpoint
1104         if(self.beam_hiteffect)
1105         {
1106                 // FIXME we really should do this on the server so it actually
1107                 // matches gameplay. What this client side stuff is doing is no
1108                 // more than guesswork.
1109                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1110                 pointparticles(
1111                         self.beam_hiteffect,
1112                         last_origin,
1113                         beamdir * -1,
1114                         frametime * 2
1115                 );
1116         }
1117         if(self.beam_hitlight[0])
1118         {
1119                 adddynamiclight(
1120                         last_origin,
1121                         self.beam_hitlight[0],
1122                         vec3(
1123                                 self.beam_hitlight[1],
1124                                 self.beam_hitlight[2],
1125                                 self.beam_hitlight[3]
1126                         )
1127                 );
1128         }
1129         if(self.beam_muzzleeffect)
1130         {
1131                 pointparticles(
1132                         self.beam_muzzleeffect,
1133                         original_start_pos + wantdir * 20,
1134                         wantdir * 1000,
1135                         frametime * 0.1
1136                 );
1137         }
1138         if(self.beam_muzzlelight[0])
1139         {
1140                 adddynamiclight(
1141                         original_start_pos + wantdir * 20,
1142                         self.beam_muzzlelight[0],
1143                         vec3(
1144                                 self.beam_muzzlelight[1],
1145                                 self.beam_muzzlelight[2],
1146                                 self.beam_muzzlelight[3]
1147                         )
1148                 );
1149         }
1150
1151         // cleanup
1152         Draw_ArcBeam_callback_entity = world;
1153         Draw_ArcBeam_callback_last_thickness = 0;
1154         Draw_ArcBeam_callback_last_top = '0 0 0';
1155         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1156 }
1157
1158 void Remove_ArcBeam(void)
1159 {SELFPARAM();
1160         remove(self.beam_muzzleentity);
1161         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
1162 }
1163
1164 void Ent_ReadArcBeam(float isnew)
1165 {SELFPARAM();
1166         int sf = ReadByte();
1167         entity flash;
1168
1169         if(isnew)
1170         {
1171                 // calculate shot origin offset from gun alignment
1172                 int gunalign = autocvar_cl_gunalign;
1173                 if(gunalign != 1 && gunalign != 2 && gunalign != 4)
1174                         gunalign = 3; // default value
1175                 --gunalign;
1176
1177                 self.beam_shotorigin = arc_shotorigin[gunalign];
1178
1179                 // set other main attributes of the beam
1180                 self.draw = Draw_ArcBeam;
1181                 self.entremove = Remove_ArcBeam;
1182                 self.move_time = time;
1183                 loopsound(self, CH_SHOTS_SINGLE, W_Sound("arc_loop"), VOL_BASE, ATTEN_NORM);
1184
1185                 flash = spawn();
1186                 flash.owner = self;
1187                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1188                 flash.drawmask = MASK_NORMAL;
1189                 flash.solid = SOLID_NOT;
1190                 flash.avelocity_z = 5000;
1191                 setattachment(flash, self, "");
1192                 setorigin(flash, '0 0 0');
1193
1194                 self.beam_muzzleentity = flash;
1195         }
1196         else
1197         {
1198                 flash = self.beam_muzzleentity;
1199         }
1200
1201         if(sf & ARC_SF_SETTINGS) // settings information
1202         {
1203                 self.beam_degreespersegment = ReadShort();
1204                 self.beam_distancepersegment = ReadShort();
1205                 self.beam_maxangle = ReadShort();
1206                 self.beam_range = ReadCoord();
1207                 self.beam_returnspeed = ReadShort();
1208                 self.beam_tightness = (ReadByte() / 10);
1209
1210                 if(ReadByte())
1211                 {
1212                         if(autocvar_chase_active)
1213                                 { self.beam_usevieworigin = 1; }
1214                         else // use view origin
1215                                 { self.beam_usevieworigin = 2; }
1216                 }
1217                 else
1218                 {
1219                         self.beam_usevieworigin = 0;
1220                 }
1221         }
1222
1223         if(!self.beam_usevieworigin)
1224         {
1225                 // self.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1226                 self.iflags = IFLAG_ORIGIN;
1227
1228                 InterpolateOrigin_Undo();
1229         }
1230
1231         if(sf & ARC_SF_START) // starting location
1232         {
1233                 self.origin_x = ReadCoord();
1234                 self.origin_y = ReadCoord();
1235                 self.origin_z = ReadCoord();
1236         }
1237         else if(self.beam_usevieworigin) // infer the location from player location
1238         {
1239                 if(self.beam_usevieworigin == 2)
1240                 {
1241                         // use view origin
1242                         self.origin = view_origin;
1243                 }
1244                 else
1245                 {
1246                         // use player origin so that third person display still works
1247                         self.origin = getplayerorigin(player_localnum) + ('0 0 1' * getstati(STAT_VIEWHEIGHT));
1248                 }
1249         }
1250
1251         setorigin(self, self.origin);
1252
1253         if(sf & ARC_SF_WANTDIR) // want/aim direction
1254         {
1255                 self.v_angle_x = ReadCoord();
1256                 self.v_angle_y = ReadCoord();
1257                 self.v_angle_z = ReadCoord();
1258         }
1259
1260         if(sf & ARC_SF_BEAMDIR) // beam direction
1261         {
1262                 self.angles_x = ReadCoord();
1263                 self.angles_y = ReadCoord();
1264                 self.angles_z = ReadCoord();
1265         }
1266
1267         if(sf & ARC_SF_BEAMTYPE) // beam type
1268         {
1269                 self.beam_type = ReadByte();
1270                 switch(self.beam_type)
1271                 {
1272                         case ARC_BT_MISS:
1273                         {
1274                                 self.beam_color = '1 1 1';
1275                                 self.beam_alpha = 0.5;
1276                                 self.beam_thickness = 8;
1277                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1278                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1279                                 self.beam_hitlight[0] = 0;
1280                                 self.beam_hitlight[1] = 1;
1281                                 self.beam_hitlight[2] = 1;
1282                                 self.beam_hitlight[3] = 1;
1283                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1284                                 self.beam_muzzlelight[0] = 0;
1285                                 self.beam_muzzlelight[1] = 1;
1286                                 self.beam_muzzlelight[2] = 1;
1287                                 self.beam_muzzlelight[3] = 1;
1288                                 if(self.beam_muzzleeffect >= 0)
1289                                 {
1290                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1291                                         flash.alpha = self.beam_alpha;
1292                                         flash.colormod = self.beam_color;
1293                                         flash.scale = 0.5;
1294                                 }
1295                                 break;
1296                         }
1297                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1298                         {
1299                                 self.beam_color = '1 1 1';
1300                                 self.beam_alpha = 0.5;
1301                                 self.beam_thickness = 8;
1302                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1303                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1304                                 self.beam_hitlight[0] = 0;
1305                                 self.beam_hitlight[1] = 1;
1306                                 self.beam_hitlight[2] = 1;
1307                                 self.beam_hitlight[3] = 1;
1308                                 self.beam_muzzleeffect = -1; // particleeffectnum(EFFECT_GRENADE_MUZZLEFLASH);
1309                                 self.beam_muzzlelight[0] = 0;
1310                                 self.beam_muzzlelight[1] = 1;
1311                                 self.beam_muzzlelight[2] = 1;
1312                                 self.beam_muzzlelight[3] = 1;
1313                                 self.beam_image = "particles/lgbeam";
1314                                 if(self.beam_muzzleeffect >= 0)
1315                                 {
1316                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1317                                         flash.alpha = self.beam_alpha;
1318                                         flash.colormod = self.beam_color;
1319                                         flash.scale = 0.5;
1320                                 }
1321                                 break;
1322                         }
1323                         case ARC_BT_HEAL:
1324                         {
1325                                 self.beam_color = '1 1 1';
1326                                 self.beam_alpha = 0.5;
1327                                 self.beam_thickness = 8;
1328                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL);
1329                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL_IMPACT);
1330                                 self.beam_hitlight[0] = 0;
1331                                 self.beam_hitlight[1] = 1;
1332                                 self.beam_hitlight[2] = 1;
1333                                 self.beam_hitlight[3] = 1;
1334                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1335                                 self.beam_muzzlelight[0] = 0;
1336                                 self.beam_muzzlelight[1] = 1;
1337                                 self.beam_muzzlelight[2] = 1;
1338                                 self.beam_muzzlelight[3] = 1;
1339                                 self.beam_image = "particles/lgbeam";
1340                                 if(self.beam_muzzleeffect >= 0)
1341                                 {
1342                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1343                                         flash.alpha = self.beam_alpha;
1344                                         flash.colormod = self.beam_color;
1345                                         flash.scale = 0.5;
1346                                 }
1347                                 break;
1348                         }
1349                         case ARC_BT_HIT:
1350                         {
1351                                 self.beam_color = '1 1 1';
1352                                 self.beam_alpha = 0.5;
1353                                 self.beam_thickness = 8;
1354                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1355                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1356                                 self.beam_hitlight[0] = 20;
1357                                 self.beam_hitlight[1] = 1;
1358                                 self.beam_hitlight[2] = 0;
1359                                 self.beam_hitlight[3] = 0;
1360                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1361                                 self.beam_muzzlelight[0] = 50;
1362                                 self.beam_muzzlelight[1] = 1;
1363                                 self.beam_muzzlelight[2] = 0;
1364                                 self.beam_muzzlelight[3] = 0;
1365                                 self.beam_image = "particles/lgbeam";
1366                                 if(self.beam_muzzleeffect >= 0)
1367                                 {
1368                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1369                                         flash.alpha = self.beam_alpha;
1370                                         flash.colormod = self.beam_color;
1371                                         flash.scale = 0.5;
1372                                 }
1373                                 break;
1374                         }
1375                         case ARC_BT_BURST_MISS:
1376                         {
1377                                 self.beam_color = '1 1 1';
1378                                 self.beam_alpha = 0.5;
1379                                 self.beam_thickness = 14;
1380                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1381                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1382                                 self.beam_hitlight[0] = 0;
1383                                 self.beam_hitlight[1] = 1;
1384                                 self.beam_hitlight[2] = 1;
1385                                 self.beam_hitlight[3] = 1;
1386                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1387                                 self.beam_muzzlelight[0] = 0;
1388                                 self.beam_muzzlelight[1] = 1;
1389                                 self.beam_muzzlelight[2] = 1;
1390                                 self.beam_muzzlelight[3] = 1;
1391                                 self.beam_image = "particles/lgbeam";
1392                                 if(self.beam_muzzleeffect >= 0)
1393                                 {
1394                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1395                                         flash.alpha = self.beam_alpha;
1396                                         flash.colormod = self.beam_color;
1397                                         flash.scale = 0.5;
1398                                 }
1399                                 break;
1400                         }
1401                         case ARC_BT_BURST_WALL:
1402                         {
1403                                 self.beam_color = '1 1 1';
1404                                 self.beam_alpha = 0.5;
1405                                 self.beam_thickness = 14;
1406                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1407                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1408                                 self.beam_hitlight[0] = 0;
1409                                 self.beam_hitlight[1] = 1;
1410                                 self.beam_hitlight[2] = 1;
1411                                 self.beam_hitlight[3] = 1;
1412                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1413                                 self.beam_muzzlelight[0] = 0;
1414                                 self.beam_muzzlelight[1] = 1;
1415                                 self.beam_muzzlelight[2] = 1;
1416                                 self.beam_muzzlelight[3] = 1;
1417                                 self.beam_image = "particles/lgbeam";
1418                                 if(self.beam_muzzleeffect >= 0)
1419                                 {
1420                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1421                                         flash.alpha = self.beam_alpha;
1422                                         flash.colormod = self.beam_color;
1423                                         flash.scale = 0.5;
1424                                 }
1425                                 break;
1426                         }
1427                         case ARC_BT_BURST_HEAL:
1428                         {
1429                                 self.beam_color = '1 1 1';
1430                                 self.beam_alpha = 0.5;
1431                                 self.beam_thickness = 14;
1432                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL);
1433                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_BEAM_HEAL_IMPACT2);
1434                                 self.beam_hitlight[0] = 0;
1435                                 self.beam_hitlight[1] = 1;
1436                                 self.beam_hitlight[2] = 1;
1437                                 self.beam_hitlight[3] = 1;
1438                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1439                                 self.beam_muzzlelight[0] = 0;
1440                                 self.beam_muzzlelight[1] = 1;
1441                                 self.beam_muzzlelight[2] = 1;
1442                                 self.beam_muzzlelight[3] = 1;
1443                                 self.beam_image = "particles/lgbeam";
1444                                 if(self.beam_muzzleeffect >= 0)
1445                                 {
1446                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1447                                         flash.alpha = self.beam_alpha;
1448                                         flash.colormod = self.beam_color;
1449                                         flash.scale = 0.5;
1450                                 }
1451                                 break;
1452                         }
1453                         case ARC_BT_BURST_HIT:
1454                         {
1455                                 self.beam_color = '1 1 1';
1456                                 self.beam_alpha = 0.5;
1457                                 self.beam_thickness = 14;
1458                                 self.beam_traileffect = particleeffectnum(EFFECT_ARC_BEAM);
1459                                 self.beam_hiteffect = particleeffectnum(EFFECT_ARC_LIGHTNING);
1460                                 self.beam_hitlight[0] = 0;
1461                                 self.beam_hitlight[1] = 1;
1462                                 self.beam_hitlight[2] = 1;
1463                                 self.beam_hitlight[3] = 1;
1464                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1465                                 self.beam_muzzlelight[0] = 0;
1466                                 self.beam_muzzlelight[1] = 1;
1467                                 self.beam_muzzlelight[2] = 1;
1468                                 self.beam_muzzlelight[3] = 1;
1469                                 self.beam_image = "particles/lgbeam";
1470                                 if(self.beam_muzzleeffect >= 0)
1471                                 {
1472                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1473                                         flash.alpha = self.beam_alpha;
1474                                         flash.colormod = self.beam_color;
1475                                         flash.scale = 0.5;
1476                                 }
1477                                 break;
1478                         }
1479
1480                         // shouldn't be possible, but lets make it colorful if it does :D
1481                         default:
1482                         {
1483                                 self.beam_color = randomvec();
1484                                 self.beam_alpha = 1;
1485                                 self.beam_thickness = 8;
1486                                 self.beam_traileffect = false;
1487                                 self.beam_hiteffect = false;
1488                                 self.beam_hitlight[0] = 0;
1489                                 self.beam_hitlight[1] = 1;
1490                                 self.beam_hitlight[2] = 1;
1491                                 self.beam_hitlight[3] = 1;
1492                                 self.beam_muzzleeffect = -1; //particleeffectnum(EFFECT_VORTEX_MUZZLEFLASH);
1493                                 self.beam_muzzlelight[0] = 0;
1494                                 self.beam_muzzlelight[1] = 1;
1495                                 self.beam_muzzlelight[2] = 1;
1496                                 self.beam_muzzlelight[3] = 1;
1497                                 self.beam_image = "particles/lgbeam";
1498                                 if(self.beam_muzzleeffect >= 0)
1499                                 {
1500                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1501                                         flash.alpha = self.beam_alpha;
1502                                         flash.colormod = self.beam_color;
1503                                         flash.scale = 0.5;
1504                                 }
1505                                 break;
1506                         }
1507                 }
1508         }
1509
1510         if(!self.beam_usevieworigin)
1511         {
1512                 InterpolateOrigin_Note();
1513         }
1514 }
1515
1516 bool W_Arc(int req)
1517 {SELFPARAM();
1518         switch(req)
1519         {
1520                 case WR_IMPACTEFFECT:
1521                 {
1522                         // todo
1523                         return true;
1524                 }
1525                 case WR_INIT:
1526                 {
1527                         precache_sound(W_Sound("arc_loop"));
1528                         return true;
1529                 }
1530                 case WR_ZOOMRETICLE:
1531                 {
1532                         // no weapon specific image for this weapon
1533                         return false;
1534                 }
1535         }
1536         return false;
1537 }
1538 #endif
1539 #endif