qcsrc/common/weapons/weapon/arc.qc

   1 #include "arc.qh"
   2
   3 #ifdef SVQC
   4
   5 bool W_Arc_Beam_Send(entity this, entity to, int sf)
   6 {
   7         WriteHeader(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
   8
   9         // Truncate information when this beam is displayed to the owner client
  10         // - The owner client has no use for beam start position or directions,
  11         //    it always figures this information out for itself with csqc code.
  12         // - Spectating the owner also truncates this information.
  13         float drawlocal = ((to == this.owner) || ((to.enemy == this.owner) && IS_SPEC(to)));
  14         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
  15
  16         WriteByte(MSG_ENTITY, sf);
  17         WriteByte(MSG_ENTITY, weaponslot(this.weaponentity_fld));
  18
  19         if(sf & ARC_SF_SETTINGS) // settings information
  20         {
  21                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
  22                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
  23                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
  24                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
  25                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
  26                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
  27
  28                 WriteByte(MSG_ENTITY, drawlocal);
  29                 WriteByte(MSG_ENTITY, etof(this.owner));
  30         }
  31         if(sf & ARC_SF_START) // starting location
  32         {
  33                 WriteCoord(MSG_ENTITY, this.beam_start.x);
  34                 WriteCoord(MSG_ENTITY, this.beam_start.y);
  35                 WriteCoord(MSG_ENTITY, this.beam_start.z);
  36         }
  37         if(sf & ARC_SF_WANTDIR) // want/aim direction
  38         {
  39                 WriteCoord(MSG_ENTITY, this.beam_wantdir.x);
  40                 WriteCoord(MSG_ENTITY, this.beam_wantdir.y);
  41                 WriteCoord(MSG_ENTITY, this.beam_wantdir.z);
  42         }
  43         if(sf & ARC_SF_BEAMDIR) // beam direction
  44         {
  45                 WriteCoord(MSG_ENTITY, this.beam_dir.x);
  46                 WriteCoord(MSG_ENTITY, this.beam_dir.y);
  47                 WriteCoord(MSG_ENTITY, this.beam_dir.z);
  48         }
  49         if(sf & ARC_SF_BEAMTYPE) // beam type
  50         {
  51                 WriteByte(MSG_ENTITY, this.beam_type);
  52         }
  53
  54         return true;
  55 }
  56
  57 void Reset_ArcBeam(entity player, vector forward)
  58 {
  59         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  60         {
  61                 .entity weaponentity = weaponentities[slot];
  62                 if(!player.(weaponentity).arc_beam)
  63                         continue;
  64                 player.(weaponentity).arc_beam.beam_dir = forward;
  65                 player.(weaponentity).arc_beam.beam_teleporttime = time;
  66         }
  67 }
  68
  69 float Arc_GetHeat_Percent(entity player, .entity weaponentity)
  70 {
  71         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
  72         {
  73                 player.arc_overheat = 0;
  74                 return 0;
  75         }
  76
  77         if ( player.(weaponentity).arc_beam )
  78                 return player.(weaponentity).arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
  79
  80         if ( player.arc_overheat > time )
  81         {
  82                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
  83                         * player.arc_cooldown;
  84         }
  85
  86         return 0;
  87 }
  88 void Arc_Player_SetHeat(entity player, .entity weaponentity)
  89 {
  90         player.arc_heat_percent = Arc_GetHeat_Percent(player, weaponentity);
  91         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
  92 }
  93
  94 void W_Arc_Bolt_Explode(entity this, entity directhitentity)
  95 {
  96         this.event_damage = func_null;
  97         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, directhitentity);
  98
  99         delete(this);
 100 }
 101
 102 void W_Arc_Bolt_Explode_use(entity this, entity actor, entity trigger)
 103 {
 104         W_Arc_Bolt_Explode(this, trigger);
 105 }
 106
 107 void W_Arc_Bolt_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 108 {
 109         if(this.health <= 0)
 110                 return;
 111
 112         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1))
 113                 return; // g_projectiles_damage says to halt
 114
 115         this.health = this.health - damage;
 116         this.angles = vectoangles(this.velocity);
 117
 118         if(this.health <= 0)
 119                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 120 }
 121
 122 void W_Arc_Bolt_Touch(entity this, entity toucher)
 123 {
 124         PROJECTILE_TOUCH(this, toucher);
 125         this.use(this, NULL, toucher);
 126 }
 127
 128 void W_Arc_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity)
 129 {
 130         entity missile;
 131
 132         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(arc, bolt_ammo), weaponentity);
 133
 134         W_SetupShot(actor, weaponentity, false, 2, SND_LASERGUN_FIRE, CH_WEAPON_A, WEP_CVAR(arc, bolt_damage));
 135
 136         Send_Effect(EFFECT_ARC_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 137
 138         missile = new(missile);
 139         missile.owner = missile.realowner = actor;
 140         missile.bot_dodge = true;
 141         IL_PUSH(g_bot_dodge, missile);
 142         missile.bot_dodgerating = WEP_CVAR(arc, bolt_damage);
 143
 144         missile.takedamage = DAMAGE_YES;
 145         missile.health = WEP_CVAR(arc, bolt_health);
 146         missile.damageforcescale = WEP_CVAR(arc, bolt_damageforcescale);
 147         missile.event_damage = W_Arc_Bolt_Damage;
 148         missile.damagedbycontents = true;
 149         IL_PUSH(g_damagedbycontents, missile);
 150
 151         settouch(missile, W_Arc_Bolt_Touch);
 152         missile.use = W_Arc_Bolt_Explode_use;
 153         setthink(missile, adaptor_think2use_hittype_splash);
 154         missile.nextthink = time + WEP_CVAR(arc, bolt_lifetime);
 155         PROJECTILE_MAKETRIGGER(missile);
 156         missile.projectiledeathtype = WEP_ARC.m_id | HITTYPE_SECONDARY;
 157         setorigin(missile, w_shotorg);
 158         setsize(missile, '0 0 0', '0 0 0');
 159
 160         set_movetype(missile, MOVETYPE_FLY);
 161         W_SetupProjVelocity_PRE(missile, arc, bolt_);
 162
 163         missile.angles = vectoangles(missile.velocity);
 164         missile.flags = FL_PROJECTILE;
 165         missile.missile_flags = MIF_SPLASH;
 166
 167         CSQCProjectile(missile, true, PROJECTILE_ARC_BOLT, true);
 168
 169         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 170 }
 171
 172 void W_Arc_Beam_Think(entity this)
 173 {
 174         .entity weaponentity = this.weaponentity_fld;
 175         entity own = this.owner;
 176         if(this != own.(weaponentity).arc_beam)
 177         {
 178                 delete(this);
 179                 return;
 180         }
 181
 182         float burst = 0;
 183         if( (PHYS_INPUT_BUTTON_ATCK2(own) && !WEP_CVAR(arc, bolt)) || this.beam_bursting)
 184         {
 185                 if(!this.beam_bursting)
 186                         this.beam_bursting = true;
 187                 burst = ARC_BT_BURSTMASK;
 188         }
 189
 190         Weapon thiswep = WEP_ARC;
 191
 192         if(
 193                 !IS_PLAYER(own)
 194                 ||
 195                 (!thiswep.wr_checkammo1(thiswep, own, weaponentity) && !(own.items & IT_UNLIMITED_WEAPON_AMMO))
 196                 ||
 197                 IS_DEAD(own)
 198                 ||
 199                 forbidWeaponUse(own)
 200                 ||
 201                 own.(weaponentity).m_switchweapon != WEP_ARC
 202                 ||
 203                 (!PHYS_INPUT_BUTTON_ATCK(own) && !burst )
 204                 ||
 205                 own.vehicle
 206                 ||
 207                 (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max))
 208         )
 209         {
 210                 if ( WEP_CVAR(arc, cooldown) > 0 )
 211                 {
 212                         float cooldown_speed = 0;
 213                         if ( this.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 214                         {
 215                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 216                         }
 217                         else if ( !burst )
 218                         {
 219                                 cooldown_speed = this.beam_heat / WEP_CVAR(arc, beam_refire);
 220                         }
 221
 222                         if ( cooldown_speed )
 223                         {
 224                                 if ( WEP_CVAR(arc, cooldown_release) || (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max)) )
 225                                         own.arc_overheat = time + this.beam_heat / cooldown_speed;
 226                                 own.arc_cooldown = cooldown_speed;
 227                         }
 228
 229                         if ( WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max) )
 230                         {
 231                                 Send_Effect(EFFECT_ARC_OVERHEAT,
 232                                         this.beam_start, this.beam_wantdir, 1 );
 233                                 sound(this, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 234                         }
 235                 }
 236
 237                 if(this == own.(weaponentity).arc_beam) { own.(weaponentity).arc_beam = NULL; }
 238                 if(!thiswep.wr_checkammo1(thiswep, own, weaponentity) && !(own.items & IT_UNLIMITED_WEAPON_AMMO))
 239                 {
 240                         // note: this doesn't force the switch
 241                         W_SwitchToOtherWeapon(own, weaponentity);
 242                         own.(weaponentity).arc_BUTTON_ATCK_prev = false; // hax
 243                 }
 244                 delete(this);
 245                 return;
 246         }
 247
 248         // decrease ammo
 249         float coefficient = frametime;
 250         if(!(own.items & IT_UNLIMITED_WEAPON_AMMO))
 251         {
 252                 float rootammo;
 253                 if(burst)
 254                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 255                 else
 256                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 257
 258                 if(rootammo)
 259                 {
 260                         coefficient = min(coefficient, GetResourceAmount(own, thiswep.ammo_type) / rootammo);
 261                         SetResourceAmount(own, thiswep.ammo_type, max(0, GetResourceAmount(own, thiswep.ammo_type) - (rootammo * frametime)));
 262                 }
 263         }
 264         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 265         this.beam_heat = min( WEP_CVAR(arc, overheat_max), this.beam_heat + heat_speed*frametime );
 266
 267         makevectors(own.v_angle);
 268
 269         W_SetupShot_Range(
 270                 own,
 271                 weaponentity, // TODO
 272                 true,
 273                 0,
 274                 SND_Null,
 275                 0,
 276                 WEP_CVAR(arc, beam_damage) * coefficient,
 277                 WEP_CVAR(arc, beam_range)
 278         );
 279
 280         // After teleport, "lock" the beam until the teleport is confirmed.
 281         if (time < this.beam_teleporttime + ANTILAG_LATENCY(own)) {
 282                 w_shotdir = this.beam_dir;
 283         }
 284
 285         // network information: shot origin and want/aim direction
 286         if(this.beam_start != w_shotorg)
 287         {
 288                 this.SendFlags |= ARC_SF_START;
 289                 this.beam_start = w_shotorg;
 290         }
 291         if(this.beam_wantdir != w_shotdir)
 292         {
 293                 this.SendFlags |= ARC_SF_WANTDIR;
 294                 this.beam_wantdir = w_shotdir;
 295         }
 296
 297         if(!this.beam_initialized)
 298         {
 299                 this.beam_dir = w_shotdir;
 300                 this.beam_initialized = true;
 301         }
 302
 303         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 304         // idea: blend together this.beam_dir with the inverted direction the player is moving in
 305         // might have to make some special accomodation so that it only uses view_right and view_up
 306
 307         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 308
 309         float segments;
 310         if(this.beam_dir != w_shotdir)
 311         {
 312                 // calculate how much we're going to move the end of the beam to the want position
 313                 // WEAPONTODO (server and client):
 314                 // blendfactor never actually becomes 0 in this situation, which is a problem
 315                 // regarding precision... this means that this.beam_dir and w_shotdir approach
 316                 // eachother, however they never actually become the same value with this method.
 317                 // Perhaps we should do some form of rounding/snapping?
 318                 float angle = vlen(w_shotdir - this.beam_dir) * RAD2DEG;
 319                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 320                 {
 321                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 322                         float blendfactor = bound(
 323                                 0,
 324                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 325                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 326                         );
 327                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 328                 }
 329                 else
 330                 {
 331                         // the radius is not too far yet, no worries :D
 332                         float blendfactor = bound(
 333                                 0,
 334                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 335                                 1
 336                         );
 337                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 338                 }
 339
 340                 // network information: beam direction
 341                 this.SendFlags |= ARC_SF_BEAMDIR;
 342
 343                 // calculate how many segments are needed
 344                 float max_allowed_segments;
 345
 346                 if(WEP_CVAR(arc, beam_distancepersegment))
 347                 {
 348                         max_allowed_segments = min(
 349                                 ARC_MAX_SEGMENTS,
 350                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 351                         );
 352                 }
 353                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 354
 355                 if(WEP_CVAR(arc, beam_degreespersegment))
 356                 {
 357                         segments = bound(
 358                                 1,
 359                                 (
 360                                         min(
 361                                                 angle,
 362                                                 WEP_CVAR(arc, beam_maxangle)
 363                                         )
 364                                         /
 365                                         WEP_CVAR(arc, beam_degreespersegment)
 366                                 ),
 367                                 max_allowed_segments
 368                         );
 369                 }
 370                 else { segments = 1; }
 371         }
 372         else { segments = 1; }
 373
 374         vector beam_endpos = (w_shotorg + (this.beam_dir * WEP_CVAR(arc, beam_range)));
 375         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 376
 377         float i;
 378         float new_beam_type = 0;
 379         vector last_origin = w_shotorg;
 380         for(i = 1; i <= segments; ++i)
 381         {
 382                 // WEAPONTODO (client):
 383                 // In order to do nice fading and pointing on the starting segment, we must always
 384                 // have that drawn as a separate triangle... However, that is difficult to do when
 385                 // keeping in mind the above problems and also optimizing the amount of segments
 386                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 387
 388                 vector new_origin = bezier_quadratic_getpoint(
 389                         w_shotorg,
 390                         beam_controlpoint,
 391                         beam_endpos,
 392                         i / segments);
 393                 vector new_dir = normalize(new_origin - last_origin);
 394
 395                 WarpZone_traceline_antilag(
 396                         own,
 397                         last_origin,
 398                         new_origin,
 399                         MOVE_NORMAL,
 400                         own,
 401                         ANTILAG_LATENCY(own)
 402                 );
 403
 404                 // Do all the transforms for warpzones right now, as we already
 405                 // "are" in the post-trace system (if we hit a player, that's
 406                 // always BEHIND the last passed wz).
 407                 last_origin = trace_endpos;
 408                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 409                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 410                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 411                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 412
 413                 float is_player = (
 414                         IS_PLAYER(trace_ent)
 415                         ||
 416                         trace_ent.classname == "body"
 417                         ||
 418                         IS_MONSTER(trace_ent)
 419                 );
 420
 421                 if(trace_ent && trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 422                 {
 423                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 424                         // NO. trace_endpos should be just fine. If not,
 425                         // that's an engine bug that needs proper debugging.
 426                         vector hitorigin = trace_endpos;
 427
 428                         float falloff = ExponentialFalloff(
 429                                 WEP_CVAR(arc, beam_falloff_mindist),
 430                                 WEP_CVAR(arc, beam_falloff_maxdist),
 431                                 WEP_CVAR(arc, beam_falloff_halflifedist),
 432                                 vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 433                         );
 434
 435                         if(is_player && SAME_TEAM(own, trace_ent))
 436                         {
 437                                 float roothealth, rootarmor;
 438                                 if(burst)
 439                                 {
 440                                         roothealth = WEP_CVAR(arc, burst_healing_hps);
 441                                         rootarmor = WEP_CVAR(arc, burst_healing_aps);
 442                                 }
 443                                 else
 444                                 {
 445                                         roothealth = WEP_CVAR(arc, beam_healing_hps);
 446                                         rootarmor = WEP_CVAR(arc, beam_healing_aps);
 447                                 }
 448
 449                                 if(trace_ent.health <= WEP_CVAR(arc, beam_healing_hmax) && roothealth)
 450                                 {
 451                                         trace_ent.health = min(
 452                                                 trace_ent.health + (roothealth * coefficient),
 453                                                 WEP_CVAR(arc, beam_healing_hmax)
 454                                         );
 455                                 }
 456                                 if(trace_ent.armorvalue <= WEP_CVAR(arc, beam_healing_amax) && rootarmor)
 457                                 {
 458                                         trace_ent.armorvalue = min(
 459                                                 trace_ent.armorvalue + (rootarmor * coefficient),
 460                                                 WEP_CVAR(arc, beam_healing_amax)
 461                                         );
 462                                 }
 463
 464                                 // stop rot, set visual effect
 465                                 if(roothealth || rootarmor)
 466                                 {
 467                                         trace_ent.pauserothealth_finished = max(
 468                                                 trace_ent.pauserothealth_finished,
 469                                                 time + autocvar_g_balance_pause_health_rot
 470                                         );
 471                                         trace_ent.pauserotarmor_finished = max(
 472                                                 trace_ent.pauserotarmor_finished,
 473                                                 time + autocvar_g_balance_pause_armor_rot
 474                                         );
 475                                         new_beam_type = ARC_BT_HEAL;
 476                                 }
 477                         }
 478                         else
 479                         {
 480                                 float rootdamage;
 481                                 if(is_player)
 482                                 {
 483                                         if(burst)
 484                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 485                                         else
 486                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 487                                 }
 488                                 else
 489                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 490
 491                                 if(accuracy_isgooddamage(own, trace_ent))
 492                                 {
 493                                         accuracy_add(
 494                                                 own,
 495                                                 WEP_ARC.m_id,
 496                                                 0,
 497                                                 rootdamage * coefficient * falloff
 498                                         );
 499                                 }
 500
 501                                 Damage(
 502                                         trace_ent,
 503                                         own,
 504                                         own,
 505                                         rootdamage * coefficient * falloff,
 506                                         WEP_ARC.m_id,
 507                                         hitorigin,
 508                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 509                                 );
 510
 511                                 new_beam_type = ARC_BT_HIT;
 512                         }
 513                         break;
 514                 }
 515                 else if(trace_fraction != 1)
 516                 {
 517                         // we collided with geometry
 518                         new_beam_type = ARC_BT_WALL;
 519                         break;
 520                 }
 521         }
 522
 523         // te_explosion(trace_endpos);
 524
 525         // if we're bursting, use burst visual effects
 526         new_beam_type |= burst;
 527
 528         // network information: beam type
 529         if(new_beam_type != this.beam_type)
 530         {
 531                 this.SendFlags |= ARC_SF_BEAMTYPE;
 532                 this.beam_type = new_beam_type;
 533         }
 534
 535         own.(weaponentity).beam_prev = time;
 536         this.nextthink = time;
 537 }
 538
 539 void W_Arc_Beam(float burst, entity actor, .entity weaponentity)
 540 {
 541
 542         // only play fire sound if 1 sec has passed since player let go the fire button
 543         if(time - actor.(weaponentity).beam_prev > 1)
 544                 sound(actor, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 545
 546         entity beam = actor.(weaponentity).arc_beam = new(W_Arc_Beam);
 547         beam.weaponentity_fld = weaponentity;
 548         beam.solid = SOLID_NOT;
 549         setthink(beam, W_Arc_Beam_Think);
 550         beam.owner = actor;
 551         set_movetype(beam, MOVETYPE_NONE);
 552         beam.bot_dodge = true;
 553         IL_PUSH(g_bot_dodge, beam);
 554         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 555         beam.beam_bursting = burst;
 556         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 557
 558         getthink(beam)(beam);
 559 }
 560 void Arc_Smoke(entity actor, .entity weaponentity)
 561 {
 562         makevectors(actor.v_angle);
 563         W_SetupShot_Range(actor,weaponentity,true,0,SND_Null,0,0,0);
 564
 565         vector smoke_origin = w_shotorg + actor.velocity*frametime;
 566         if ( actor.arc_overheat > time )
 567         {
 568                 if ( random() < actor.arc_heat_percent )
 569                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 570                 if ( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) )
 571                 {
 572                         Send_Effect(EFFECT_ARC_OVERHEAT_FIRE, smoke_origin, w_shotdir, 1 );
 573                         if ( !actor.arc_smoke_sound )
 574                         {
 575                                 actor.arc_smoke_sound = 1;
 576                                 sound(actor, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 577                         }
 578                 }
 579         }
 580         else if ( actor.(weaponentity).arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 581                         actor.(weaponentity).arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 582         {
 583                 if ( random() < (actor.(weaponentity).arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 584                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 585                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 586         }
 587
 588         if (  actor.arc_smoke_sound && ( actor.arc_overheat <= time ||
 589                 !( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) ) ) || actor.(weaponentity).m_switchweapon != WEP_ARC )
 590         {
 591                 actor.arc_smoke_sound = 0;
 592                 sound(actor, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 593         }
 594 }
 595
 596 METHOD(Arc, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 597 {
 598     if(WEP_CVAR(arc, beam_botaimspeed))
 599     {
 600         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 601                 actor,
 602                 weaponentity,
 603             WEP_CVAR(arc, beam_botaimspeed),
 604             0,
 605             WEP_CVAR(arc, beam_botaimlifetime),
 606             false
 607         );
 608     }
 609     else
 610     {
 611         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 612                 actor,
 613                 weaponentity,
 614             1000000,
 615             0,
 616             0.001,
 617             false
 618         );
 619     }
 620 }
 621 METHOD(Arc, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 622 {
 623     Arc_Player_SetHeat(actor, weaponentity);
 624     Arc_Smoke(actor, weaponentity);
 625
 626     bool beam_fire2 = ((fire & 2) && !WEP_CVAR(arc, bolt));
 627
 628     if (time >= actor.arc_overheat)
 629     if ((fire & 1) || beam_fire2 || actor.(weaponentity).arc_beam.beam_bursting)
 630     {
 631
 632         if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 633         {
 634             #if 0
 635             if(actor.animstate_startframe == actor.anim_shoot.x && actor.animstate_numframes == actor.anim_shoot.y)
 636                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 637             else
 638             #endif
 639                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), w_ready);
 640         }
 641
 642         if((!actor.(weaponentity).arc_beam) || wasfreed(actor.(weaponentity).arc_beam))
 643         {
 644             if(weapon_prepareattack(thiswep, actor, weaponentity, boolean(beam_fire2), 0))
 645             {
 646                 W_Arc_Beam(boolean(beam_fire2), actor, weaponentity);
 647
 648                 if(!actor.(weaponentity).arc_BUTTON_ATCK_prev)
 649                 {
 650                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 651                     actor.(weaponentity).arc_BUTTON_ATCK_prev = true;
 652                 }
 653             }
 654         }
 655
 656         return;
 657     }
 658     else if(fire & 2)
 659     {
 660         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(arc, bolt_refire)))
 661         {
 662             W_Arc_Attack_Bolt(thiswep, actor, weaponentity);
 663             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), w_ready);
 664         }
 665     }
 666
 667     if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 668     {
 669         int slot = weaponslot(weaponentity);
 670         sound(actor, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 671         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 672         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor(actor);
 673     }
 674     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 675
 676     #if 0
 677     if(fire & 2)
 678     if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_arc_secondary_refire))
 679     {
 680         W_Arc_Attack2();
 681         actor.arc_count = autocvar_g_balance_arc_secondary_count;
 682         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 683         actor.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor(actor);
 684     }
 685     #endif
 686 }
 687 METHOD(Arc, wr_init, void(entity thiswep))
 688 {
 689     if(!arc_shotorigin[0])
 690     {
 691         arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 692         arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 693         arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 694         arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 695     }
 696 }
 697 METHOD(Arc, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 698 {
 699     return ((!WEP_CVAR(arc, beam_ammo)) || (GetResourceAmount(actor, thiswep.ammo_type) > 0));
 700 }
 701 METHOD(Arc, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 702 {
 703     if(WEP_CVAR(arc, bolt))
 704     {
 705         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(arc, bolt_ammo);
 706         ammo_amount += actor.(weaponentity).(weapon_load[WEP_ARC.m_id]) >= WEP_CVAR(arc, bolt_ammo);
 707         return ammo_amount;
 708     }
 709     else
 710         return WEP_CVAR(arc, overheat_max) > 0 &&
 711             ((!WEP_CVAR(arc, burst_ammo)) || (GetResourceAmount(actor, thiswep.ammo_type) > 0));
 712 }
 713 METHOD(Arc, wr_killmessage, Notification(entity thiswep))
 714 {
 715     if(w_deathtype & HITTYPE_SECONDARY)
 716         return WEAPON_ARC_MURDER_SPRAY;
 717     else
 718         return WEAPON_ARC_MURDER;
 719 }
 720 METHOD(Arc, wr_drop, void(entity thiswep, entity actor, .entity weaponentity))
 721 {
 722     weapon_dropevent_item.arc_overheat = actor.arc_overheat;
 723     weapon_dropevent_item.arc_cooldown = actor.arc_cooldown;
 724     actor.arc_overheat = 0;
 725     actor.arc_cooldown = 0;
 726     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 727 }
 728 METHOD(Arc, wr_pickup, void(entity thiswep, entity actor, .entity weaponentity))
 729 {
 730     if ( !client_hasweapon(actor, thiswep, weaponentity, false, false) &&
 731         weapon_dropevent_item.arc_overheat > time )
 732     {
 733         actor.arc_overheat = weapon_dropevent_item.arc_overheat;
 734         actor.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 735     }
 736 }
 737 METHOD(Arc, wr_resetplayer, void(entity thiswep, entity actor))
 738 {
 739     actor.arc_overheat = 0;
 740     actor.arc_cooldown = 0;
 741     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 742     {
 743         .entity weaponentity = weaponentities[slot];
 744         actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 745     }
 746 }
 747 METHOD(Arc, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
 748 {
 749     actor.arc_overheat = 0;
 750     actor.arc_cooldown = 0;
 751     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 752 }
 753 #endif
 754 #ifdef CSQC
 755 bool autocvar_cl_arcbeam_teamcolor = true;
 756
 757 METHOD(Arc, wr_impacteffect, void(entity thiswep, entity actor))
 758 {
 759     if(w_deathtype & HITTYPE_SECONDARY)
 760     {
 761         vector org2;
 762         org2 = w_org + w_backoff * 6;
 763         pointparticles(EFFECT_ARC_BOLT_EXPLODE, org2, w_backoff * 1000, 1);
 764         if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 765     }
 766 }
 767
 768 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 769 {
 770         entity beam = Draw_ArcBeam_callback_entity;
 771         vector transformed_view_org;
 772         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 773
 774         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 775         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 776         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 777
 778         vector hitorigin;
 779
 780         // draw segment
 781         #if 0
 782         if(trace_fraction != 1)
 783         {
 784                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 785                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 786                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 787         }
 788         else
 789         {
 790                 hitorigin = hit;
 791         }
 792         #else
 793         hitorigin = hit;
 794         #endif
 795
 796         // decide upon thickness
 797         float thickness = beam.beam_thickness;
 798
 799         // draw primary beam render
 800         vector top    = hitorigin + (thickdir * thickness);
 801         vector bottom = hitorigin - (thickdir * thickness);
 802
 803         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 804         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 805
 806         R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 807         R_PolygonVertex(
 808                 top,
 809                 '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 810                 beam.beam_color,
 811                 beam.beam_alpha
 812         );
 813         R_PolygonVertex(
 814                 last_top,
 815                 '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 816                 beam.beam_color,
 817                 beam.beam_alpha
 818         );
 819         R_PolygonVertex(
 820                 last_bottom,
 821                 '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 822                 beam.beam_color,
 823                 beam.beam_alpha
 824         );
 825         R_PolygonVertex(
 826                 bottom,
 827                 '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 828                 beam.beam_color,
 829                 beam.beam_alpha
 830         );
 831         R_EndPolygon();
 832
 833         // draw trailing particles
 834         // NOTES:
 835         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 836         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 837         if(beam.beam_traileffect)
 838         {
 839                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 840         }
 841
 842         // set up for the next
 843         Draw_ArcBeam_callback_last_thickness = thickness;
 844         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 845         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 846 }
 847
 848 void Reset_ArcBeam()
 849 {
 850         entity e;
 851         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 852                 e.beam_initialized = false;
 853         }
 854         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 855                 e.beam_initialized = false;
 856         }
 857 }
 858
 859 void Draw_ArcBeam(entity this)
 860 {
 861         float dt = time - this.move_time;
 862         this.move_time = time;
 863         if(dt <= 0) { return; }
 864
 865         if(!this.beam_usevieworigin)
 866         {
 867                 InterpolateOrigin_Do(this);
 868         }
 869
 870         // origin = beam starting origin
 871         // v_angle = wanted/aim direction
 872         // angles = current direction of beam
 873
 874         vector start_pos;
 875         vector wantdir; //= view_forward;
 876         vector beamdir; //= this.beam_dir;
 877
 878         float segments;
 879         if(this.beam_usevieworigin)
 880         {
 881                 // WEAPONTODO:
 882                 // Currently we have to replicate nearly the same method of figuring
 883                 // out the shotdir that the server does... Ideally in the future we
 884                 // should be able to acquire this from a generalized function built
 885                 // into a weapon system for client code.
 886
 887                 // find where we are aiming
 888                 makevectors(warpzone_save_view_angles);
 889                 vector forward = v_forward;
 890                 vector right = v_right;
 891                 vector up = v_up;
 892
 893                 // decide upon start position
 894                 if(this.beam_usevieworigin == 2)
 895                         { start_pos = warpzone_save_view_origin; }
 896                 else
 897                         { start_pos = this.origin; }
 898
 899                 // trace forward with an estimation
 900                 WarpZone_TraceLine(
 901                         start_pos,
 902                         start_pos + forward * this.beam_range,
 903                         MOVE_NOMONSTERS,
 904                         this
 905                 );
 906
 907                 // untransform in case our trace went through a warpzone
 908                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 909
 910                 // un-adjust trueaim if shotend is too close
 911                 if(vdist(end_pos - start_pos, <, g_trueaim_minrange))
 912                         end_pos = start_pos + (forward * g_trueaim_minrange);
 913
 914                 // move shot origin to the actual gun muzzle origin
 915                 vector origin_offset =
 916                           right * -this.beam_shotorigin.y
 917                         + up * this.beam_shotorigin.z;
 918
 919                 start_pos = start_pos + origin_offset;
 920
 921                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 922                 traceline(start_pos, start_pos + forward * this.beam_shotorigin.x, MOVE_NORMAL, this);
 923                 start_pos = trace_endpos;
 924
 925                 // calculate the aim direction now
 926                 wantdir = normalize(end_pos - start_pos);
 927
 928                 if(!this.beam_initialized)
 929                 {
 930                         this.beam_dir = wantdir;
 931                         this.beam_initialized = true;
 932                 }
 933
 934                 if(this.beam_dir != wantdir)
 935                 {
 936                         // calculate how much we're going to move the end of the beam to the want position
 937                         // WEAPONTODO (server and client):
 938                         // blendfactor never actually becomes 0 in this situation, which is a problem
 939                         // regarding precision... this means that this.beam_dir and w_shotdir approach
 940                         // eachother, however they never actually become the same value with this method.
 941                         // Perhaps we should do some form of rounding/snapping?
 942                         float angle = vlen(wantdir - this.beam_dir) * RAD2DEG;
 943                         if(angle && (angle > this.beam_maxangle))
 944                         {
 945                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 946                                 float blendfactor = bound(
 947                                         0,
 948                                         (1 - (this.beam_returnspeed * frametime)),
 949                                         min(this.beam_maxangle / angle, 1)
 950                                 );
 951                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 952                         }
 953                         else
 954                         {
 955                                 // the radius is not too far yet, no worries :D
 956                                 float blendfactor = bound(
 957                                         0,
 958                                         (1 - (this.beam_returnspeed * frametime)),
 959                                         1
 960                                 );
 961                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 962                         }
 963
 964                         // calculate how many segments are needed
 965                         float max_allowed_segments;
 966
 967                         if(this.beam_distancepersegment)
 968                         {
 969                                 max_allowed_segments = min(
 970                                         ARC_MAX_SEGMENTS,
 971                                         1 + (vlen(wantdir / this.beam_distancepersegment))
 972                                 );
 973                         }
 974                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 975
 976                         if(this.beam_degreespersegment)
 977                         {
 978                                 segments = bound(
 979                                         1,
 980                                         (
 981                                                 min(
 982                                                         angle,
 983                                                         this.beam_maxangle
 984                                                 )
 985                                                 /
 986                                                 this.beam_degreespersegment
 987                                         ),
 988                                         max_allowed_segments
 989                                 );
 990                         }
 991                         else { segments = 1; }
 992                 }
 993                 else { segments = 1; }
 994
 995                 // set the beam direction which the rest of the code will refer to
 996                 beamdir = this.beam_dir;
 997
 998                 // finally, set this.angles to the proper direction so that muzzle attachment points in proper direction
 999                 this.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1000         }
1001         else
1002         {
1003                 // set the values from the provided info from the networked entity
1004                 start_pos = this.origin;
1005                 wantdir = this.v_angle;
1006                 beamdir = this.angles;
1007
1008                 if(beamdir != wantdir)
1009                 {
1010                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1011
1012                         // calculate how many segments are needed
1013                         float max_allowed_segments;
1014
1015                         if(this.beam_distancepersegment)
1016                         {
1017                                 max_allowed_segments = min(
1018                                         ARC_MAX_SEGMENTS,
1019                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1020                                 );
1021                         }
1022                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1023
1024                         if(this.beam_degreespersegment)
1025                         {
1026                                 segments = bound(
1027                                         1,
1028                                         (
1029                                                 min(
1030                                                         angle,
1031                                                         this.beam_maxangle
1032                                                 )
1033                                                 /
1034                                                 this.beam_degreespersegment
1035                                         ),
1036                                         max_allowed_segments
1037                                 );
1038                         }
1039                         else { segments = 1; }
1040                 }
1041                 else { segments = 1; }
1042         }
1043
1044         setorigin(this, start_pos);
1045         this.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1046
1047         vector beam_endpos = (start_pos + (beamdir * this.beam_range));
1048         vector beam_controlpoint = start_pos + wantdir * (this.beam_range * (1 - this.beam_tightness));
1049
1050         Draw_ArcBeam_callback_entity = this;
1051         Draw_ArcBeam_callback_last_thickness = 0;
1052         Draw_ArcBeam_callback_last_top = start_pos;
1053         Draw_ArcBeam_callback_last_bottom = start_pos;
1054
1055         vector last_origin = start_pos;
1056         vector original_start_pos = start_pos;
1057
1058         float i;
1059         for(i = 1; i <= segments; ++i)
1060         {
1061                 // WEAPONTODO (client):
1062                 // In order to do nice fading and pointing on the starting segment, we must always
1063                 // have that drawn as a separate triangle... However, that is difficult to do when
1064                 // keeping in mind the above problems and also optimizing the amount of segments
1065                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1066
1067                 vector new_origin = bezier_quadratic_getpoint(
1068                         start_pos,
1069                         beam_controlpoint,
1070                         beam_endpos,
1071                         i / segments);
1072
1073                 WarpZone_TraceBox_ThroughZone(
1074                         last_origin,
1075                         '0 0 0',
1076                         '0 0 0',
1077                         new_origin,
1078                         MOVE_NORMAL,
1079                         NULL,
1080                         NULL,
1081                         Draw_ArcBeam_callback
1082                 );
1083
1084                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1085                 // system (if we hit a player, that's always BEHIND the last passed wz).
1086                 last_origin = trace_endpos;
1087                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1088                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1089                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1090                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1091                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1092                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1093
1094                 if(trace_fraction < 1) { break; }
1095         }
1096
1097         // visual effects for startpoint and endpoint
1098         if(this.beam_hiteffect)
1099         {
1100                 // FIXME we really should do this on the server so it actually
1101                 // matches gameplay. What this client side stuff is doing is no
1102                 // more than guesswork.
1103                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1104                 pointparticles(
1105                         this.beam_hiteffect,
1106                         last_origin,
1107                         beamdir * -1,
1108                         frametime * 2
1109                 );
1110         }
1111         if(this.beam_hitlight[0])
1112         {
1113                 adddynamiclight(
1114                         last_origin,
1115                         this.beam_hitlight[0],
1116                         vec3(
1117                                 this.beam_hitlight[1],
1118                                 this.beam_hitlight[2],
1119                                 this.beam_hitlight[3]
1120                         )
1121                 );
1122         }
1123         if(this.beam_muzzleeffect)
1124         {
1125                 pointparticles(
1126                         this.beam_muzzleeffect,
1127                         original_start_pos + wantdir * 20,
1128                         wantdir * 1000,
1129                         frametime * 0.1
1130                 );
1131         }
1132         if(this.beam_muzzlelight[0])
1133         {
1134                 adddynamiclight(
1135                         original_start_pos + wantdir * 20,
1136                         this.beam_muzzlelight[0],
1137                         vec3(
1138                                 this.beam_muzzlelight[1],
1139                                 this.beam_muzzlelight[2],
1140                                 this.beam_muzzlelight[3]
1141                         )
1142                 );
1143         }
1144
1145         // cleanup
1146         Draw_ArcBeam_callback_entity = NULL;
1147         Draw_ArcBeam_callback_last_thickness = 0;
1148         Draw_ArcBeam_callback_last_top = '0 0 0';
1149         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1150 }
1151
1152 void Remove_ArcBeam(entity this)
1153 {
1154         delete(this.beam_muzzleentity);
1155         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1156 }
1157
1158 NET_HANDLE(ENT_CLIENT_ARC_BEAM, bool isnew)
1159 {
1160         int sf = ReadByte();
1161         int slot = ReadByte();
1162         entity flash;
1163
1164         if(isnew)
1165         {
1166                 int gunalign = W_GunAlign(viewmodels[slot], STAT(GUNALIGN)) - 1;
1167
1168                 this.beam_shotorigin = arc_shotorigin[gunalign];
1169
1170                 // set other main attributes of the beam
1171                 this.draw = Draw_ArcBeam;
1172                 IL_PUSH(g_drawables, this);
1173                 this.entremove = Remove_ArcBeam;
1174                 this.move_time = time;
1175                 loopsound(this, CH_SHOTS_SINGLE, SND_ARC_LOOP, VOL_BASE, ATTEN_NORM);
1176
1177                 flash = spawn();
1178                 flash.owner = this;
1179                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1180                 flash.drawmask = MASK_NORMAL;
1181                 flash.solid = SOLID_NOT;
1182                 flash.avelocity_z = 5000;
1183                 setattachment(flash, this, "");
1184                 setorigin(flash, '0 0 0');
1185
1186                 this.beam_muzzleentity = flash;
1187         }
1188         else
1189         {
1190                 flash = this.beam_muzzleentity;
1191         }
1192
1193         if(sf & ARC_SF_SETTINGS) // settings information
1194         {
1195                 this.beam_degreespersegment = ReadShort();
1196                 this.beam_distancepersegment = ReadShort();
1197                 this.beam_maxangle = ReadShort();
1198                 this.beam_range = ReadCoord();
1199                 this.beam_returnspeed = ReadShort();
1200                 this.beam_tightness = (ReadByte() / 10);
1201
1202                 if(ReadByte())
1203                 {
1204                         if(autocvar_chase_active)
1205                                 { this.beam_usevieworigin = 1; }
1206                         else // use view origin
1207                                 { this.beam_usevieworigin = 2; }
1208                 }
1209                 else
1210                 {
1211                         this.beam_usevieworigin = 0;
1212                 }
1213
1214                 this.sv_entnum = ReadByte();
1215         }
1216
1217         if(!this.beam_usevieworigin)
1218         {
1219                 // this.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1220                 this.iflags = IFLAG_ORIGIN;
1221
1222                 InterpolateOrigin_Undo(this);
1223         }
1224
1225         if(sf & ARC_SF_START) // starting location
1226         {
1227                 this.origin_x = ReadCoord();
1228                 this.origin_y = ReadCoord();
1229                 this.origin_z = ReadCoord();
1230         }
1231         else if(this.beam_usevieworigin) // infer the location from player location
1232         {
1233                 if(this.beam_usevieworigin == 2)
1234                 {
1235                         // use view origin
1236                         this.origin = view_origin;
1237                 }
1238                 else
1239                 {
1240                         // use player origin so that third person display still works
1241                         this.origin = entcs_receiver(player_localnum).origin + ('0 0 1' * STAT(VIEWHEIGHT));
1242                 }
1243         }
1244
1245         setorigin(this, this.origin);
1246
1247         if(sf & ARC_SF_WANTDIR) // want/aim direction
1248         {
1249                 this.v_angle_x = ReadCoord();
1250                 this.v_angle_y = ReadCoord();
1251                 this.v_angle_z = ReadCoord();
1252         }
1253
1254         if(sf & ARC_SF_BEAMDIR) // beam direction
1255         {
1256                 this.angles_x = ReadCoord();
1257                 this.angles_y = ReadCoord();
1258                 this.angles_z = ReadCoord();
1259         }
1260
1261         if(sf & ARC_SF_BEAMTYPE) // beam type
1262         {
1263                 this.beam_type = ReadByte();
1264
1265                 vector beamcolor = ((autocvar_cl_arcbeam_teamcolor) ? colormapPaletteColor(entcs_GetClientColors(this.sv_entnum - 1) & 0x0F, true) : '1 1 1');
1266                 switch(this.beam_type)
1267                 {
1268                         case ARC_BT_MISS:
1269                         {
1270                                 this.beam_color = beamcolor;
1271                                 this.beam_alpha = 0.5;
1272                                 this.beam_thickness = 8;
1273                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1274                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1275                                 this.beam_hitlight[0] = 0;
1276                                 this.beam_hitlight[1] = 1;
1277                                 this.beam_hitlight[2] = 1;
1278                                 this.beam_hitlight[3] = 1;
1279                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1280                                 this.beam_muzzlelight[0] = 0;
1281                                 this.beam_muzzlelight[1] = 1;
1282                                 this.beam_muzzlelight[2] = 1;
1283                                 this.beam_muzzlelight[3] = 1;
1284                                 if(this.beam_muzzleeffect)
1285                                 {
1286                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1287                                         flash.alpha = this.beam_alpha;
1288                                         flash.colormod = this.beam_color;
1289                                         flash.scale = 0.5;
1290                                 }
1291                                 break;
1292                         }
1293                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1294                         {
1295                                 this.beam_color = beamcolor;
1296                                 this.beam_alpha = 0.5;
1297                                 this.beam_thickness = 8;
1298                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1299                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1300                                 this.beam_hitlight[0] = 0;
1301                                 this.beam_hitlight[1] = 1;
1302                                 this.beam_hitlight[2] = 1;
1303                                 this.beam_hitlight[3] = 1;
1304                                 this.beam_muzzleeffect = NULL; // (EFFECT_GRENADE_MUZZLEFLASH);
1305                                 this.beam_muzzlelight[0] = 0;
1306                                 this.beam_muzzlelight[1] = 1;
1307                                 this.beam_muzzlelight[2] = 1;
1308                                 this.beam_muzzlelight[3] = 1;
1309                                 this.beam_image = "particles/lgbeam";
1310                                 if(this.beam_muzzleeffect)
1311                                 {
1312                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1313                                         flash.alpha = this.beam_alpha;
1314                                         flash.colormod = this.beam_color;
1315                                         flash.scale = 0.5;
1316                                 }
1317                                 break;
1318                         }
1319                         case ARC_BT_HEAL:
1320                         {
1321                                 this.beam_color = beamcolor;
1322                                 this.beam_alpha = 0.5;
1323                                 this.beam_thickness = 8;
1324                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1325                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT);
1326                                 this.beam_hitlight[0] = 0;
1327                                 this.beam_hitlight[1] = 1;
1328                                 this.beam_hitlight[2] = 1;
1329                                 this.beam_hitlight[3] = 1;
1330                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1331                                 this.beam_muzzlelight[0] = 0;
1332                                 this.beam_muzzlelight[1] = 1;
1333                                 this.beam_muzzlelight[2] = 1;
1334                                 this.beam_muzzlelight[3] = 1;
1335                                 this.beam_image = "particles/lgbeam";
1336                                 if(this.beam_muzzleeffect)
1337                                 {
1338                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1339                                         flash.alpha = this.beam_alpha;
1340                                         flash.colormod = this.beam_color;
1341                                         flash.scale = 0.5;
1342                                 }
1343                                 break;
1344                         }
1345                         case ARC_BT_HIT:
1346                         {
1347                                 this.beam_color = beamcolor;
1348                                 this.beam_alpha = 0.5;
1349                                 this.beam_thickness = 8;
1350                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1351                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1352                                 this.beam_hitlight[0] = 20;
1353                                 this.beam_hitlight[1] = 1;
1354                                 this.beam_hitlight[2] = 0;
1355                                 this.beam_hitlight[3] = 0;
1356                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1357                                 this.beam_muzzlelight[0] = 50;
1358                                 this.beam_muzzlelight[1] = 1;
1359                                 this.beam_muzzlelight[2] = 0;
1360                                 this.beam_muzzlelight[3] = 0;
1361                                 this.beam_image = "particles/lgbeam";
1362                                 if(this.beam_muzzleeffect)
1363                                 {
1364                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1365                                         flash.alpha = this.beam_alpha;
1366                                         flash.colormod = this.beam_color;
1367                                         flash.scale = 0.5;
1368                                 }
1369                                 break;
1370                         }
1371                         case ARC_BT_BURST_MISS:
1372                         {
1373                                 this.beam_color = beamcolor;
1374                                 this.beam_alpha = 0.5;
1375                                 this.beam_thickness = 14;
1376                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1377                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1378                                 this.beam_hitlight[0] = 0;
1379                                 this.beam_hitlight[1] = 1;
1380                                 this.beam_hitlight[2] = 1;
1381                                 this.beam_hitlight[3] = 1;
1382                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1383                                 this.beam_muzzlelight[0] = 0;
1384                                 this.beam_muzzlelight[1] = 1;
1385                                 this.beam_muzzlelight[2] = 1;
1386                                 this.beam_muzzlelight[3] = 1;
1387                                 this.beam_image = "particles/lgbeam";
1388                                 if(this.beam_muzzleeffect)
1389                                 {
1390                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1391                                         flash.alpha = this.beam_alpha;
1392                                         flash.colormod = this.beam_color;
1393                                         flash.scale = 0.5;
1394                                 }
1395                                 break;
1396                         }
1397                         case ARC_BT_BURST_WALL:
1398                         {
1399                                 this.beam_color = beamcolor;
1400                                 this.beam_alpha = 0.5;
1401                                 this.beam_thickness = 14;
1402                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1403                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1404                                 this.beam_hitlight[0] = 0;
1405                                 this.beam_hitlight[1] = 1;
1406                                 this.beam_hitlight[2] = 1;
1407                                 this.beam_hitlight[3] = 1;
1408                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1409                                 this.beam_muzzlelight[0] = 0;
1410                                 this.beam_muzzlelight[1] = 1;
1411                                 this.beam_muzzlelight[2] = 1;
1412                                 this.beam_muzzlelight[3] = 1;
1413                                 this.beam_image = "particles/lgbeam";
1414                                 if(this.beam_muzzleeffect)
1415                                 {
1416                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1417                                         flash.alpha = this.beam_alpha;
1418                                         flash.colormod = this.beam_color;
1419                                         flash.scale = 0.5;
1420                                 }
1421                                 break;
1422                         }
1423                         case ARC_BT_BURST_HEAL:
1424                         {
1425                                 this.beam_color = beamcolor;
1426                                 this.beam_alpha = 0.5;
1427                                 this.beam_thickness = 14;
1428                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1429                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT2);
1430                                 this.beam_hitlight[0] = 0;
1431                                 this.beam_hitlight[1] = 1;
1432                                 this.beam_hitlight[2] = 1;
1433                                 this.beam_hitlight[3] = 1;
1434                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1435                                 this.beam_muzzlelight[0] = 0;
1436                                 this.beam_muzzlelight[1] = 1;
1437                                 this.beam_muzzlelight[2] = 1;
1438                                 this.beam_muzzlelight[3] = 1;
1439                                 this.beam_image = "particles/lgbeam";
1440                                 if(this.beam_muzzleeffect)
1441                                 {
1442                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1443                                         flash.alpha = this.beam_alpha;
1444                                         flash.colormod = this.beam_color;
1445                                         flash.scale = 0.5;
1446                                 }
1447                                 break;
1448                         }
1449                         case ARC_BT_BURST_HIT:
1450                         {
1451                                 this.beam_color = beamcolor;
1452                                 this.beam_alpha = 0.5;
1453                                 this.beam_thickness = 14;
1454                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1455                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1456                                 this.beam_hitlight[0] = 0;
1457                                 this.beam_hitlight[1] = 1;
1458                                 this.beam_hitlight[2] = 1;
1459                                 this.beam_hitlight[3] = 1;
1460                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1461                                 this.beam_muzzlelight[0] = 0;
1462                                 this.beam_muzzlelight[1] = 1;
1463                                 this.beam_muzzlelight[2] = 1;
1464                                 this.beam_muzzlelight[3] = 1;
1465                                 this.beam_image = "particles/lgbeam";
1466                                 if(this.beam_muzzleeffect)
1467                                 {
1468                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1469                                         flash.alpha = this.beam_alpha;
1470                                         flash.colormod = this.beam_color;
1471                                         flash.scale = 0.5;
1472                                 }
1473                                 break;
1474                         }
1475
1476                         // shouldn't be possible, but lets make it colorful if it does :D
1477                         default:
1478                         {
1479                                 this.beam_color = randomvec();
1480                                 this.beam_alpha = 1;
1481                                 this.beam_thickness = 8;
1482                                 this.beam_traileffect = NULL;
1483                                 this.beam_hiteffect = NULL;
1484                                 this.beam_hitlight[0] = 0;
1485                                 this.beam_hitlight[1] = 1;
1486                                 this.beam_hitlight[2] = 1;
1487                                 this.beam_hitlight[3] = 1;
1488                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1489                                 this.beam_muzzlelight[0] = 0;
1490                                 this.beam_muzzlelight[1] = 1;
1491                                 this.beam_muzzlelight[2] = 1;
1492                                 this.beam_muzzlelight[3] = 1;
1493                                 this.beam_image = "particles/lgbeam";
1494                                 if(this.beam_muzzleeffect)
1495                                 {
1496                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1497                                         flash.alpha = this.beam_alpha;
1498                                         flash.colormod = this.beam_color;
1499                                         flash.scale = 0.5;
1500                                 }
1501                                 break;
1502                         }
1503                 }
1504         }
1505
1506         if(!this.beam_usevieworigin)
1507         {
1508                 InterpolateOrigin_Note(this);
1509         }
1510         return true;
1511 }
1512
1513 #endif