qcsrc/common/weapons/weapon/devastator.qc

   1 #include "devastator.qh"
   2
   3 #ifdef SVQC
   4
   5 .entity lastrocket;
   6
   7 void W_Devastator_Unregister(entity this)
   8 {
   9         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  10         {
  11                 .entity weaponentity = weaponentities[slot];
  12                 if(this.realowner.(weaponentity).lastrocket == this)
  13                         this.realowner.(weaponentity).lastrocket = NULL;
  14         }
  15 }
  16
  17 void W_Devastator_Explode(entity this, entity directhitentity)
  18 {
  19         W_Devastator_Unregister(this);
  20
  21         if(directhitentity.takedamage == DAMAGE_AIM)
  22                 if(IS_PLAYER(directhitentity))
  23                         if(DIFF_TEAM(this.realowner, directhitentity))
  24                                 if(!IS_DEAD(directhitentity))
  25                                         if(IsFlying(directhitentity))
  26                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  27
  28         this.event_damage = func_null;
  29         this.takedamage = DAMAGE_NO;
  30
  31         RadiusDamage(
  32                 this,
  33                 this.realowner,
  34                 WEP_CVAR(devastator, damage),
  35                 WEP_CVAR(devastator, edgedamage),
  36                 WEP_CVAR(devastator, radius),
  37                 NULL,
  38                 NULL,
  39                 WEP_CVAR(devastator, force),
  40                 this.projectiledeathtype,
  41                 this.weaponentity_fld,
  42                 directhitentity
  43         );
  44
  45         Weapon thiswep = WEP_DEVASTATOR;
  46         .entity weaponentity = this.weaponentity_fld;
  47         if(this.realowner.(weaponentity).m_weapon == thiswep)
  48         {
  49                 if(GetResourceAmount(this.realowner, thiswep.ammo_type) < WEP_CVAR(devastator, ammo))
  50                 if(!(this.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
  51                 {
  52                         this.realowner.cnt = WEP_DEVASTATOR.m_id;
  53                         int slot = weaponslot(weaponentity);
  54                         ATTACK_FINISHED(this.realowner, slot) = time;
  55                         this.realowner.(weaponentity).m_switchweapon = w_getbestweapon(this.realowner, weaponentity);
  56                 }
  57         }
  58         delete(this);
  59 }
  60
  61 void W_Devastator_Explode_think(entity this)
  62 {
  63         W_Devastator_Explode(this, NULL);
  64 }
  65
  66 void W_Devastator_DoRemoteExplode(entity this, .entity weaponentity)
  67 {
  68         W_Devastator_Unregister(this);
  69
  70         this.event_damage = func_null;
  71         this.takedamage = DAMAGE_NO;
  72
  73         bool handled_as_rocketjump = false;
  74         entity head = NULL;
  75
  76         if(WEP_CVAR(devastator, remote_jump_radius))
  77         {
  78                 head = WarpZone_FindRadius(
  79                         this.origin,
  80                         WEP_CVAR(devastator, remote_jump_radius),
  81                         false
  82                 );
  83
  84                 while(head)
  85                 {
  86                         if(head.takedamage && (head == this.realowner))
  87                         {
  88                                 if(vdist(this.origin - head.WarpZone_findradius_nearest, <=, WEP_CVAR(devastator, remote_jump_radius)))
  89                                 {
  90                                         // we handled this as a rocketjump :)
  91                                         handled_as_rocketjump = true;
  92
  93                                         // modify velocity
  94                                         if(WEP_CVAR(devastator, remote_jump_velocity_z_add))
  95                                         {
  96                                                 head.velocity_x *= 0.9;
  97                                                 head.velocity_y *= 0.9;
  98                                                 head.velocity_z = bound(
  99                                                         WEP_CVAR(devastator, remote_jump_velocity_z_min),
 100                                                         head.velocity.z + WEP_CVAR(devastator, remote_jump_velocity_z_add),
 101                                                         WEP_CVAR(devastator, remote_jump_velocity_z_max)
 102                                                 );
 103                                         }
 104
 105                                         // now do the damage
 106                                         RadiusDamage(
 107                                                 this,
 108                                                 head,
 109                                                 WEP_CVAR(devastator, remote_jump_damage),
 110                                                 WEP_CVAR(devastator, remote_jump_damage),
 111                                                 WEP_CVAR(devastator, remote_jump_radius),
 112                                                 NULL,
 113                                                 head,
 114                                                 (WEP_CVAR(devastator, remote_jump_force) ? WEP_CVAR(devastator, remote_jump_force) : 0),
 115                                                 this.projectiledeathtype | HITTYPE_BOUNCE,
 116                                                 this.weaponentity_fld,
 117                                                 NULL
 118                                         );
 119                                         break;
 120                                 }
 121                         }
 122                         head = head.chain;
 123                 }
 124         }
 125
 126         RadiusDamage(
 127                 this,
 128                 this.realowner,
 129                 WEP_CVAR(devastator, remote_damage),
 130                 WEP_CVAR(devastator, remote_edgedamage),
 131                 WEP_CVAR(devastator, remote_radius),
 132                 (handled_as_rocketjump ? head : NULL),
 133                 NULL,
 134                 WEP_CVAR(devastator, remote_force),
 135                 this.projectiledeathtype | HITTYPE_BOUNCE,
 136                 this.weaponentity_fld,
 137                 NULL
 138         );
 139
 140         Weapon thiswep = WEP_DEVASTATOR;
 141         if(this.realowner.(weaponentity).m_weapon == thiswep)
 142         {
 143                 if(GetResourceAmount(this.realowner, thiswep.ammo_type) < WEP_CVAR(devastator, ammo))
 144                 if(!(this.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
 145                 {
 146                         this.realowner.cnt = WEP_DEVASTATOR.m_id;
 147                         int slot = weaponslot(weaponentity);
 148                         ATTACK_FINISHED(this.realowner, slot) = time;
 149                         this.realowner.(weaponentity).m_switchweapon = w_getbestweapon(this.realowner, weaponentity);
 150                 }
 151         }
 152         delete(this);
 153 }
 154
 155 void W_Devastator_RemoteExplode(entity this, .entity weaponentity)
 156 {
 157         if(!IS_DEAD(this.realowner))
 158         if(this.realowner.(weaponentity).lastrocket)
 159         {
 160                 if((this.spawnshieldtime >= 0)
 161                         ? (time >= this.spawnshieldtime) // timer
 162                         : (vdist(NearestPointOnBox(this.realowner, this.origin) - this.origin, >, WEP_CVAR(devastator, remote_radius))) // safety device
 163                 )
 164                 {
 165                         W_Devastator_DoRemoteExplode(this, weaponentity);
 166                 }
 167         }
 168 }
 169
 170 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 171 {
 172         if(thisdir * goaldir > maxturn_cos)
 173                 return goaldir;
 174         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 175                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 176         float f, m2;
 177         vector v;
 178         // solve:
 179         //   g = normalize(thisdir + goaldir * X)
 180         //   thisdir * g = maxturn
 181         //
 182         //   gg = thisdir + goaldir * X
 183         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 184         //
 185         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 186         f = thisdir * goaldir;
 187         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 188         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 189         m2 = maxturn_cos * maxturn_cos;
 190         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 191         return normalize(thisdir + goaldir * v.y); // the larger solution!
 192 }
 193 // assume thisdir == -goaldir:
 194 //   f == -1
 195 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 196 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 197 //   x^2 - 2 * x + 1 = 0
 198 //   (x - 1)^2 = 0
 199 //   x = 1
 200 //   normalize(thisdir + goaldir)
 201 //   normalize(0)
 202
 203 void W_Devastator_Think(entity this)
 204 {
 205         vector desireddir, olddir, newdir, desiredorigin, goal;
 206         float velspeed, f;
 207         this.nextthink = time;
 208         if(time > this.cnt)
 209         {
 210                 this.projectiledeathtype |= HITTYPE_BOUNCE;
 211                 W_Devastator_Explode(this, NULL);
 212                 return;
 213         }
 214
 215         // accelerate
 216         makevectors(this.angles.x * '-1 0 0' + this.angles.y * '0 1 0');
 217         velspeed = WEP_CVAR(devastator, speed) * W_WeaponSpeedFactor(this.realowner) - (this.velocity * v_forward);
 218         if(velspeed > 0)
 219                 this.velocity = this.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * W_WeaponSpeedFactor(this.realowner) * frametime, velspeed);
 220
 221         // laser guided, or remote detonation
 222         .entity weaponentity = this.weaponentity_fld;
 223         if(this.realowner.(weaponentity).m_weapon == WEP_DEVASTATOR)
 224         {
 225                 if(this == this.realowner.(weaponentity).lastrocket)
 226                 if(!this.realowner.(weaponentity).rl_release)
 227                 if(!PHYS_INPUT_BUTTON_ATCK2(this))
 228                 if(WEP_CVAR(devastator, guiderate))
 229                 if(time > this.pushltime)
 230                 if(!IS_DEAD(this.realowner))
 231                 {
 232                         f = WEP_CVAR(devastator, guideratedelay);
 233                         if(f)
 234                                 f = bound(0, (time - this.pushltime) / f, 1);
 235                         else
 236                                 f = 1;
 237
 238                         velspeed = vlen(this.velocity);
 239
 240                         makevectors(this.realowner.v_angle);
 241                         desireddir = WarpZone_RefSys_TransformVelocity(this.realowner, this, v_forward);
 242                         desiredorigin = WarpZone_RefSys_TransformOrigin(this.realowner, this, this.realowner.origin + this.realowner.view_ofs);
 243                         olddir = normalize(this.velocity);
 244
 245                         // now it gets tricky... we want to move like some curve to approximate the target direction
 246                         // but we are limiting the rate at which we can turn!
 247                         goal = desiredorigin + ((this.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 248                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - this.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 249
 250                         this.velocity = newdir * velspeed;
 251                         this.angles = vectoangles(this.velocity);
 252
 253                         if(!this.count)
 254                         {
 255                                 Send_Effect(EFFECT_ROCKET_GUIDE, this.origin, this.velocity, 1);
 256                                 // TODO add a better sound here
 257                                 sound(this.realowner, CH_WEAPON_B, SND_ROCKET_MODE, VOL_BASE, ATTN_NORM);
 258                                 this.count = 1;
 259                         }
 260                 }
 261
 262                 if(this.rl_detonate_later)
 263                         W_Devastator_RemoteExplode(this, weaponentity);
 264         }
 265
 266         if(this.csqcprojectile_clientanimate == 0)
 267                 UpdateCSQCProjectile(this);
 268 }
 269
 270 void W_Devastator_Touch(entity this, entity toucher)
 271 {
 272         if(WarpZone_Projectile_Touch(this, toucher))
 273         {
 274                 if(wasfreed(this))
 275                         W_Devastator_Unregister(this);
 276                 return;
 277         }
 278         W_Devastator_Unregister(this);
 279         W_Devastator_Explode(this, toucher);
 280 }
 281
 282 void W_Devastator_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 283 {
 284         if(this.health <= 0)
 285                 return;
 286
 287         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 288                 return; // g_projectiles_damage says to halt
 289
 290         this.health = this.health - damage;
 291         this.angles = vectoangles(this.velocity);
 292
 293         if(this.health <= 0)
 294                 W_PrepareExplosionByDamage(this, attacker, W_Devastator_Explode_think);
 295 }
 296
 297 void W_Devastator_Attack(Weapon thiswep, entity actor, .entity weaponentity)
 298 {
 299         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(devastator, ammo), weaponentity);
 300
 301         W_SetupShot_ProjectileSize(actor, weaponentity, '-3 -3 -3', '3 3 3', false, 5, SND_ROCKET_FIRE, CH_WEAPON_A, WEP_CVAR(devastator, damage), WEP_DEVASTATOR.m_id);
 302         Send_Effect(EFFECT_ROCKET_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 303
 304         entity missile = WarpZone_RefSys_SpawnSameRefSys(actor);
 305         missile.weaponentity_fld = weaponentity;
 306         missile.owner = missile.realowner = actor;
 307         actor.(weaponentity).lastrocket = missile;
 308         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 309                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 310         else
 311                 missile.spawnshieldtime = -1;
 312         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 313         missile.classname = "rocket";
 314         missile.bot_dodge = true;
 315         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 316
 317         missile.takedamage = DAMAGE_YES;
 318         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 319         missile.health = WEP_CVAR(devastator, health);
 320         missile.event_damage = W_Devastator_Damage;
 321         missile.damagedbycontents = true;
 322         IL_PUSH(g_damagedbycontents, missile);
 323
 324         set_movetype(missile, MOVETYPE_FLY);
 325         PROJECTILE_MAKETRIGGER(missile);
 326         missile.projectiledeathtype = WEP_DEVASTATOR.m_id;
 327         setsize(missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 328
 329         setorigin(missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 330         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 331         missile.angles = vectoangles(missile.velocity);
 332
 333         settouch(missile, W_Devastator_Touch);
 334         setthink(missile, W_Devastator_Think);
 335         missile.nextthink = time;
 336         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 337         missile.flags = FL_PROJECTILE;
 338         IL_PUSH(g_projectiles, missile);
 339         IL_PUSH(g_bot_dodge, missile);
 340         missile.missile_flags = MIF_SPLASH;
 341
 342         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, false); // because of fly sound
 343
 344         // muzzle flash for 1st person view
 345         entity flash = spawn();
 346         setmodel(flash, MDL_DEVASTATOR_MUZZLEFLASH); // precision set below
 347         SUB_SetFade(flash, time, 0.1);
 348         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 349         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
 350
 351         // common properties
 352         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 353 }
 354
 355 METHOD(Devastator, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 356 {
 357     // aim and decide to fire if appropriate
 358     PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 359     if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 360     {
 361         // decide whether to detonate rockets
 362         float edgedamage, coredamage, edgeradius, recipricoledgeradius;
 363         float selfdamage, teamdamage, enemydamage;
 364         edgedamage = WEP_CVAR(devastator, edgedamage);
 365         coredamage = WEP_CVAR(devastator, damage);
 366         edgeradius = WEP_CVAR(devastator, radius);
 367         recipricoledgeradius = 1 / edgeradius;
 368         selfdamage = 0;
 369         teamdamage = 0;
 370         enemydamage = 0;
 371         IL_EACH(g_projectiles, it.realowner == actor && it.classname == "rocket",
 372         {
 373             entity rocket = it;
 374             IL_EACH(g_bot_targets, it.bot_attack,
 375             {
 376                 float d = vlen(it.origin + (it.mins + it.maxs) * 0.5 - rocket.origin);
 377                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 378                 // count potential damage according to type of target
 379                 if(it == actor)
 380                         selfdamage = selfdamage + d;
 381                 else if(SAME_TEAM(it, actor))
 382                         teamdamage = teamdamage + d;
 383                 else if(bot_shouldattack(actor, it))
 384                         enemydamage = enemydamage + d;
 385             });
 386         });
 387         float desirabledamage;
 388         desirabledamage = enemydamage;
 389         if(time > actor.invincible_finished && time > actor.spawnshieldtime)
 390             desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 391         if(teamplay && actor.team)
 392             desirabledamage = desirabledamage - teamdamage;
 393
 394         makevectors(actor.v_angle);
 395         IL_EACH(g_projectiles, it.realowner == actor && it.classname == "rocket",
 396         {
 397             if(skill > 9) // normal players only do this for the target they are tracking
 398             {
 399                     entity rocket = it;
 400                     IL_EACH(g_bot_targets, it.bot_attack,
 401                     {
 402                         if((v_forward * normalize(rocket.origin - it.origin) < 0.1)
 403                             && desirabledamage > 0.1 * coredamage
 404                             ) PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 405                     });
 406                 }
 407                 else
 408                 {
 409                 //As the distance gets larger, a correct detonation gets near imposible
 410                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 411                 if((v_forward * normalize(it.origin - actor.enemy.origin) < 0.1)
 412                         && IS_PLAYER(actor.enemy)
 413                         && (desirabledamage >= 0.1 * coredamage)
 414                         )
 415                 {
 416                         float distance = bound(300, vlen(actor.origin - actor.enemy.origin), 30000);
 417                         if(random() / distance * 300 > frametime * bound(0, (10 - skill) * 0.2, 1))
 418                                 PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 419                 }
 420                 }
 421         });
 422         // if we would be doing at X percent of the core damage, detonate it
 423         // but don't fire a new shot at the same time!
 424         if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 425             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 426         if((skill > 6.5) && (selfdamage > actor.health))
 427             PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 428         //if(PHYS_INPUT_BUTTON_ATCK2(actor) == true)
 429         //      dprint(ftos(desirabledamage),"\n");
 430         if(PHYS_INPUT_BUTTON_ATCK2(actor)) PHYS_INPUT_BUTTON_ATCK(actor) = false;
 431     }
 432 }
 433
 434 METHOD(Devastator, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 435 {
 436     if(WEP_CVAR(devastator, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR(devastator, ammo)) { // forced reload
 437         thiswep.wr_reload(thiswep, actor, weaponentity);
 438     } else {
 439         if(fire & 1)
 440         {
 441             if(actor.(weaponentity).rl_release || WEP_CVAR(devastator, guidestop))
 442             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(devastator, refire)))
 443             {
 444                 W_Devastator_Attack(thiswep, actor, weaponentity);
 445                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 446                 actor.(weaponentity).rl_release = 0;
 447             }
 448         }
 449         else
 450             actor.(weaponentity).rl_release = 1;
 451
 452         if(fire & 2)
 453         if(actor.(weaponentity).m_switchweapon == WEP_DEVASTATOR)
 454         {
 455             bool rockfound = false;
 456             IL_EACH(g_projectiles, it.realowner == actor && it.classname == "rocket",
 457             {
 458                 if(!it.rl_detonate_later)
 459                 {
 460                     it.rl_detonate_later = true;
 461                     rockfound = true;
 462                 }
 463             });
 464             if(rockfound)
 465                 sound(actor, CH_WEAPON_B, SND_ROCKET_DET, VOL_BASE, ATTN_NORM);
 466         }
 467     }
 468 }
 469 METHOD(Devastator, wr_setup, void(entity thiswep, entity actor, .entity weaponentity))
 470 {
 471     actor.(weaponentity).rl_release = 1;
 472 }
 473 METHOD(Devastator, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 474 {
 475     #if 0
 476     // don't switch while guiding a missile
 477     if(ATTACK_FINISHED(actor, slot) <= time || PS(actor).m_weapon != WEP_DEVASTATOR)
 478     {
 479         ammo_amount = false;
 480         if(WEP_CVAR(devastator, reload_ammo))
 481         {
 482             if(GetResourceAmount(actor, thiswep.ammo_type) < WEP_CVAR(devastator, ammo) && actor.(weaponentity).(weapon_load[WEP_DEVASTATOR.m_id]) < WEP_CVAR(devastator, ammo))
 483                 ammo_amount = true;
 484         }
 485         else if(GetResourceAmount(actor, thiswep.ammo_type) < WEP_CVAR(devastator, ammo))
 486             ammo_amount = true;
 487         return !ammo_amount;
 488     }
 489     #endif
 490     #if 0
 491     if(actor.rl_release == 0)
 492     {
 493         LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: TRUE", actor.rl_release, GetResourceAmount(actor, thiswep.ammo_type), WEP_CVAR(devastator, ammo));
 494         return true;
 495     }
 496     else
 497     {
 498         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(devastator, ammo);
 499         ammo_amount += actor.(weaponentity).(weapon_load[WEP_DEVASTATOR.m_id]) >= WEP_CVAR(devastator, ammo);
 500         LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: %s", actor.rl_release, GetResourceAmount(actor, thiswep.ammo_type), WEP_CVAR(devastator, ammo), (ammo_amount ? "TRUE" : "FALSE"));
 501         return ammo_amount;
 502     }
 503     #else
 504     float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(devastator, ammo);
 505     ammo_amount += actor.(weaponentity).(weapon_load[WEP_DEVASTATOR.m_id]) >= WEP_CVAR(devastator, ammo);
 506     return ammo_amount;
 507     #endif
 508 }
 509 METHOD(Devastator, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 510 {
 511     return false;
 512 }
 513 METHOD(Devastator, wr_resetplayer, void(entity thiswep, entity actor))
 514 {
 515     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 516     {
 517         .entity weaponentity = weaponentities[slot];
 518         actor.(weaponentity).lastrocket = NULL; // stop rocket guiding, no revenge from the grave!
 519         actor.(weaponentity).rl_release = 0;
 520     }
 521 }
 522 METHOD(Devastator, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 523 {
 524     W_Reload(actor, weaponentity, WEP_CVAR(devastator, ammo), SND_RELOAD);
 525 }
 526 METHOD(Devastator, wr_suicidemessage, Notification(entity thiswep))
 527 {
 528     return WEAPON_DEVASTATOR_SUICIDE;
 529 }
 530 METHOD(Devastator, wr_killmessage, Notification(entity thiswep))
 531 {
 532     if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 533         return WEAPON_DEVASTATOR_MURDER_SPLASH;
 534     else
 535         return WEAPON_DEVASTATOR_MURDER_DIRECT;
 536 }
 537
 538 #endif
 539 #ifdef CSQC
 540
 541 METHOD(Devastator, wr_impacteffect, void(entity thiswep, entity actor))
 542 {
 543     vector org2;
 544     org2 = w_org + w_backoff * 12;
 545     pointparticles(EFFECT_ROCKET_EXPLODE, org2, '0 0 0', 1);
 546     if(!w_issilent)
 547         sound(actor, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTN_NORM);
 548 }
 549
 550 #endif