qcsrc/common/weapons/weapon/devastator.qc

   1 #include "devastator.qh"
   2
   3 #ifdef SVQC
   4
   5 .entity lastrocket;
   6
   7 void W_Devastator_Unregister(entity this)
   8 {
   9         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  10         {
  11                 .entity weaponentity = weaponentities[slot];
  12                 if(this.realowner.(weaponentity).lastrocket == this)
  13                         this.realowner.(weaponentity).lastrocket = NULL;
  14         }
  15 }
  16
  17 void W_Devastator_Explode(entity this, entity directhitentity)
  18 {
  19         W_Devastator_Unregister(this);
  20
  21         if(directhitentity.takedamage == DAMAGE_AIM)
  22                 if(IS_PLAYER(directhitentity))
  23                         if(DIFF_TEAM(this.realowner, directhitentity))
  24                                 if(!IS_DEAD(directhitentity))
  25                                         if(IsFlying(directhitentity))
  26                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  27
  28         this.event_damage = func_null;
  29         this.takedamage = DAMAGE_NO;
  30
  31         RadiusDamage(
  32                 this,
  33                 this.realowner,
  34                 WEP_CVAR(devastator, damage),
  35                 WEP_CVAR(devastator, edgedamage),
  36                 WEP_CVAR(devastator, radius),
  37                 NULL,
  38                 NULL,
  39                 WEP_CVAR(devastator, force),
  40                 this.projectiledeathtype,
  41                 this.weaponentity_fld,
  42                 directhitentity
  43         );
  44
  45         Weapon thiswep = WEP_DEVASTATOR;
  46         .entity weaponentity = this.weaponentity_fld;
  47         if(this.realowner.(weaponentity).m_weapon == thiswep)
  48         {
  49                 if(GetResource(this.realowner, thiswep.ammo_type) < WEP_CVAR(devastator, ammo))
  50                 if(!(this.realowner.items & IT_UNLIMITED_AMMO))
  51                 {
  52                         this.realowner.cnt = thiswep.m_id;
  53                         ATTACK_FINISHED(this.realowner, weaponentity) = time;
  54                         this.realowner.(weaponentity).m_switchweapon = w_getbestweapon(this.realowner, weaponentity);
  55                 }
  56         }
  57         delete(this);
  58 }
  59
  60 void W_Devastator_Explode_think(entity this)
  61 {
  62         W_Devastator_Explode(this, NULL);
  63 }
  64
  65 void W_Devastator_DoRemoteExplode(entity this, .entity weaponentity)
  66 {
  67         W_Devastator_Unregister(this);
  68
  69         this.event_damage = func_null;
  70         this.takedamage = DAMAGE_NO;
  71
  72         bool handled_as_rocketjump = false;
  73         entity head = NULL;
  74         bool allow_rocketjump = WEP_CVAR(devastator, remote_jump);
  75         MUTATOR_CALLHOOK(AllowRocketJumping, allow_rocketjump);
  76         allow_rocketjump = M_ARGV(0, bool);
  77
  78         if(allow_rocketjump && WEP_CVAR(devastator, remote_jump_radius))
  79         {
  80                 head = WarpZone_FindRadius(
  81                         this.origin,
  82                         WEP_CVAR(devastator, remote_jump_radius),
  83                         false
  84                 );
  85
  86                 while(head)
  87                 {
  88                         if(head.takedamage && (head == this.realowner))
  89                         {
  90                                 if(vdist(this.origin - head.WarpZone_findradius_nearest, <=, WEP_CVAR(devastator, remote_jump_radius)))
  91                                 {
  92                                         // we handled this as a rocketjump :)
  93                                         handled_as_rocketjump = true;
  94
  95                                         // modify velocity
  96                                         if(WEP_CVAR(devastator, remote_jump_velocity_z_add))
  97                                         {
  98                                                 head.velocity_x *= 0.9;
  99                                                 head.velocity_y *= 0.9;
 100                                                 head.velocity_z = bound(
 101                                                         WEP_CVAR(devastator, remote_jump_velocity_z_min),
 102                                                         head.velocity.z + WEP_CVAR(devastator, remote_jump_velocity_z_add),
 103                                                         WEP_CVAR(devastator, remote_jump_velocity_z_max)
 104                                                 );
 105                                         }
 106
 107                                         // now do the damage
 108                                         RadiusDamage(
 109                                                 this,
 110                                                 head,
 111                                                 WEP_CVAR(devastator, remote_jump_damage),
 112                                                 WEP_CVAR(devastator, remote_jump_damage),
 113                                                 WEP_CVAR(devastator, remote_jump_radius),
 114                                                 NULL,
 115                                                 head,
 116                                                 (WEP_CVAR(devastator, remote_jump_force) ? WEP_CVAR(devastator, remote_jump_force) : 0),
 117                                                 this.projectiledeathtype | HITTYPE_BOUNCE,
 118                                                 this.weaponentity_fld,
 119                                                 NULL
 120                                         );
 121                                         break;
 122                                 }
 123                         }
 124                         head = head.chain;
 125                 }
 126         }
 127
 128         RadiusDamage(
 129                 this,
 130                 this.realowner,
 131                 WEP_CVAR(devastator, remote_damage),
 132                 WEP_CVAR(devastator, remote_edgedamage),
 133                 WEP_CVAR(devastator, remote_radius),
 134                 (handled_as_rocketjump ? head : NULL),
 135                 NULL,
 136                 WEP_CVAR(devastator, remote_force),
 137                 this.projectiledeathtype | HITTYPE_BOUNCE,
 138                 this.weaponentity_fld,
 139                 NULL
 140         );
 141
 142         Weapon thiswep = WEP_DEVASTATOR;
 143         if(this.realowner.(weaponentity).m_weapon == thiswep)
 144         {
 145                 if(GetResource(this.realowner, thiswep.ammo_type) < WEP_CVAR(devastator, ammo))
 146                 if(!(this.realowner.items & IT_UNLIMITED_AMMO))
 147                 {
 148                         this.realowner.cnt = thiswep.m_id;
 149                         ATTACK_FINISHED(this.realowner, weaponentity) = time;
 150                         this.realowner.(weaponentity).m_switchweapon = w_getbestweapon(this.realowner, weaponentity);
 151                 }
 152         }
 153         delete(this);
 154 }
 155
 156 void W_Devastator_RemoteExplode(entity this, .entity weaponentity)
 157 {
 158         if(!IS_DEAD(this.realowner))
 159         if(this.realowner.(weaponentity).lastrocket)
 160         {
 161                 if((this.spawnshieldtime >= 0)
 162                         ? (time >= this.spawnshieldtime) // timer
 163                         : (vdist(NearestPointOnBox(this.realowner, this.origin) - this.origin, >, WEP_CVAR(devastator, remote_radius))) // safety device
 164                 )
 165                 {
 166                         W_Devastator_DoRemoteExplode(this, weaponentity);
 167                 }
 168         }
 169 }
 170
 171 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 172 {
 173         if(thisdir * goaldir > maxturn_cos)
 174                 return goaldir;
 175         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 176                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 177         float f, m2;
 178         vector v;
 179         // solve:
 180         //   g = normalize(thisdir + goaldir * X)
 181         //   thisdir * g = maxturn
 182         //
 183         //   gg = thisdir + goaldir * X
 184         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 185         //
 186         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 187         f = thisdir * goaldir;
 188         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 189         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 190         m2 = maxturn_cos * maxturn_cos;
 191         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 192         return normalize(thisdir + goaldir * v.y); // the larger solution!
 193 }
 194 // assume thisdir == -goaldir:
 195 //   f == -1
 196 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 197 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 198 //   x^2 - 2 * x + 1 = 0
 199 //   (x - 1)^2 = 0
 200 //   x = 1
 201 //   normalize(thisdir + goaldir)
 202 //   normalize(0)
 203
 204 void W_Devastator_Think(entity this)
 205 {
 206         vector desireddir, olddir, newdir, desiredorigin, goal;
 207         float velspeed, f;
 208         this.nextthink = time;
 209         if(time > this.cnt)
 210         {
 211                 this.projectiledeathtype |= HITTYPE_BOUNCE;
 212                 W_Devastator_Explode(this, NULL);
 213                 return;
 214         }
 215
 216         // accelerate
 217         makevectors(this.angles.x * '-1 0 0' + this.angles.y * '0 1 0');
 218         velspeed = WEP_CVAR(devastator, speed) * W_WeaponSpeedFactor(this.realowner) - (this.velocity * v_forward);
 219         if(velspeed > 0)
 220                 this.velocity = this.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * W_WeaponSpeedFactor(this.realowner) * frametime, velspeed);
 221
 222         // laser guided, or remote detonation
 223         .entity weaponentity = this.weaponentity_fld;
 224         if(this.realowner.(weaponentity).m_weapon == WEP_DEVASTATOR)
 225         {
 226                 if(this == this.realowner.(weaponentity).lastrocket)
 227                 if(!this.realowner.(weaponentity).rl_release)
 228                 if(!PHYS_INPUT_BUTTON_ATCK2(this))
 229                 if(WEP_CVAR(devastator, guiderate))
 230                 if(time > this.pushltime)
 231                 if(!IS_DEAD(this.realowner))
 232                 {
 233                         f = WEP_CVAR(devastator, guideratedelay);
 234                         if(f)
 235                                 f = bound(0, (time - this.pushltime) / f, 1);
 236                         else
 237                                 f = 1;
 238
 239                         vector md = this.realowner.(weaponentity).movedir;
 240                         vector vecs = ((md.x > 0) ? md : '0 0 0');
 241
 242                         vector dv = v_right * -vecs.y + v_up * vecs.z;
 243
 244                         if(!W_DualWielding(this.realowner))
 245                                 dv = '0 0 0'; // don't override!
 246
 247                         velspeed = vlen(this.velocity);
 248
 249                         makevectors(this.realowner.v_angle);
 250                         desireddir = WarpZone_RefSys_TransformVelocity(this.realowner, this, v_forward);
 251                         desiredorigin = WarpZone_RefSys_TransformOrigin(this.realowner, this, this.realowner.origin + this.realowner.view_ofs + dv);
 252                         olddir = normalize(this.velocity);
 253
 254                         // now it gets tricky... we want to move like some curve to approximate the target direction
 255                         // but we are limiting the rate at which we can turn!
 256                         goal = desiredorigin + ((this.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 257                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - this.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 258
 259                         this.velocity = newdir * velspeed;
 260                         this.angles = vectoangles(this.velocity);
 261
 262                         if(!this.count)
 263                         {
 264                                 Send_Effect(EFFECT_ROCKET_GUIDE, this.origin, this.velocity, 1);
 265                                 // TODO add a better sound here
 266                                 sound(this.realowner, CH_WEAPON_B, SND_ROCKET_MODE, VOL_BASE, ATTN_NORM);
 267                                 this.count = 1;
 268                         }
 269                 }
 270
 271                 if(this.rl_detonate_later)
 272                         W_Devastator_RemoteExplode(this, weaponentity);
 273         }
 274
 275         if(this.csqcprojectile_clientanimate == 0)
 276                 UpdateCSQCProjectile(this);
 277 }
 278
 279 void W_Devastator_Touch(entity this, entity toucher)
 280 {
 281         if(WarpZone_Projectile_Touch(this, toucher))
 282         {
 283                 if(wasfreed(this))
 284                         W_Devastator_Unregister(this);
 285                 return;
 286         }
 287         W_Devastator_Unregister(this);
 288         W_Devastator_Explode(this, toucher);
 289 }
 290
 291 void W_Devastator_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 292 {
 293         if(GetResource(this, RES_HEALTH) <= 0)
 294                 return;
 295
 296         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 297                 return; // g_projectiles_damage says to halt
 298
 299         TakeResource(this, RES_HEALTH, damage);
 300         this.angles = vectoangles(this.velocity);
 301
 302         if(GetResource(this, RES_HEALTH) <= 0)
 303                 W_PrepareExplosionByDamage(this, attacker, W_Devastator_Explode_think);
 304 }
 305
 306 void W_Devastator_Attack(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 307 {
 308         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(devastator, ammo), weaponentity);
 309
 310         W_SetupShot_ProjectileSize(actor, weaponentity, '-3 -3 -3', '3 3 3', false, 5, SND_ROCKET_FIRE, CH_WEAPON_A, WEP_CVAR(devastator, damage), thiswep.m_id);
 311         W_MuzzleFlash(actor, weaponentity, EFFECT_ROCKET_MUZZLEFLASH, w_shotorg, w_shotdir * 1000);
 312
 313         entity missile = WarpZone_RefSys_SpawnSameRefSys(actor);
 314         missile.weaponentity_fld = weaponentity;
 315         missile.owner = missile.realowner = actor;
 316         actor.(weaponentity).lastrocket = missile;
 317         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 318                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 319         else
 320                 missile.spawnshieldtime = -1; // NOTE: proximity based when rocket jumping
 321         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 322         missile.classname = "rocket";
 323         missile.bot_dodge = true;
 324         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 325
 326         missile.takedamage = DAMAGE_YES;
 327         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 328         SetResourceExplicit(missile, RES_HEALTH, WEP_CVAR(devastator, health));
 329         missile.event_damage = W_Devastator_Damage;
 330         missile.damagedbycontents = true;
 331         IL_PUSH(g_damagedbycontents, missile);
 332
 333         set_movetype(missile, MOVETYPE_FLY);
 334         PROJECTILE_MAKETRIGGER(missile);
 335         missile.projectiledeathtype = thiswep.m_id;
 336         setsize(missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 337
 338         setorigin(missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 339         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 340         missile.angles = vectoangles(missile.velocity);
 341
 342         settouch(missile, W_Devastator_Touch);
 343         setthink(missile, W_Devastator_Think);
 344         missile.nextthink = time;
 345         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 346         missile.rl_detonate_later = (fire & 2); // allow instant detonation
 347         missile.flags = FL_PROJECTILE;
 348         IL_PUSH(g_projectiles, missile);
 349         IL_PUSH(g_bot_dodge, missile);
 350         missile.missile_flags = MIF_SPLASH;
 351
 352         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, false); // because of fly sound
 353
 354         // muzzle flash for 1st person view
 355         // TODO: handle on the client side
 356         entity flash = spawn();
 357         setmodel(flash, MDL_DEVASTATOR_MUZZLEFLASH); // precision set below
 358         SUB_SetFade(flash, time, 0.1);
 359         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 360         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
 361
 362         // common properties
 363         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 364
 365         if (time >= missile.nextthink)
 366         {
 367                 getthink(missile)(missile);
 368         }
 369 }
 370
 371 METHOD(Devastator, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 372 {
 373     // aim and decide to fire if appropriate
 374     PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 375     if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 376     {
 377         // decide whether to detonate rockets
 378         float edgedamage, coredamage, edgeradius, recipricoledgeradius;
 379         float selfdamage, teamdamage, enemydamage;
 380         edgedamage = WEP_CVAR(devastator, edgedamage);
 381         coredamage = WEP_CVAR(devastator, damage);
 382         edgeradius = WEP_CVAR(devastator, radius);
 383         recipricoledgeradius = 1 / edgeradius;
 384         selfdamage = 0;
 385         teamdamage = 0;
 386         enemydamage = 0;
 387         IL_EACH(g_projectiles, it.realowner == actor && it.classname == "rocket",
 388         {
 389             entity rocket = it;
 390             IL_EACH(g_bot_targets, it.bot_attack,
 391             {
 392                 float d = vlen(it.origin + (it.mins + it.maxs) * 0.5 - rocket.origin);
 393                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 394                 // count potential damage according to type of target
 395                 if(it == actor)
 396                         selfdamage = selfdamage + d;
 397                 else if(SAME_TEAM(it, actor))
 398                         teamdamage = teamdamage + d;
 399                 else if(bot_shouldattack(actor, it))
 400                         enemydamage = enemydamage + d;
 401             });
 402         });
 403         float desirabledamage;
 404         desirabledamage = enemydamage;
 405         if(time > STAT(INVINCIBLE_FINISHED, actor) && time > actor.spawnshieldtime)
 406             desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 407         if(teamplay && actor.team)
 408             desirabledamage = desirabledamage - teamdamage;
 409
 410         makevectors(actor.v_angle);
 411         IL_EACH(g_projectiles, it.realowner == actor && it.classname == "rocket",
 412         {
 413             if(skill > 9) // normal players only do this for the target they are tracking
 414             {
 415                     entity rocket = it;
 416                     IL_EACH(g_bot_targets, it.bot_attack,
 417                     {
 418                         if((v_forward * normalize(rocket.origin - it.origin) < 0.1)
 419                             && desirabledamage > 0.1 * coredamage
 420                             ) PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 421                     });
 422                 }
 423                 else
 424                 {
 425                 //As the distance gets larger, a correct detonation gets near imposible
 426                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 427                 if((v_forward * normalize(it.origin - actor.enemy.origin) < 0.1)
 428                         && IS_PLAYER(actor.enemy)
 429                         && (desirabledamage >= 0.1 * coredamage)
 430                         )
 431                 {
 432                         float distance = bound(300, vlen(actor.origin - actor.enemy.origin), 30000);
 433                         if(random() / distance * 300 > frametime * bound(0, (10 - skill) * 0.2, 1))
 434                                 PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 435                 }
 436                 }
 437         });
 438         // if we would be doing at X percent of the core damage, detonate it
 439         // but don't fire a new shot at the same time!
 440         if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 441             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 442         if((skill > 6.5) && (selfdamage > GetResource(actor, RES_HEALTH)))
 443             PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 444         //if(PHYS_INPUT_BUTTON_ATCK2(actor) == true)
 445         //      dprint(ftos(desirabledamage),"\n");
 446         if(PHYS_INPUT_BUTTON_ATCK2(actor)) PHYS_INPUT_BUTTON_ATCK(actor) = false;
 447     }
 448 }
 449
 450 METHOD(Devastator, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 451 {
 452     if(WEP_CVAR(devastator, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR(devastator, ammo)) { // forced reload
 453         thiswep.wr_reload(thiswep, actor, weaponentity);
 454     } else {
 455         if(fire & 1)
 456         {
 457             if(actor.(weaponentity).rl_release || WEP_CVAR(devastator, guidestop))
 458             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(devastator, refire)))
 459             {
 460                 W_Devastator_Attack(thiswep, actor, weaponentity, fire);
 461                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 462                 actor.(weaponentity).rl_release = 0;
 463             }
 464         }
 465         else
 466             actor.(weaponentity).rl_release = 1;
 467
 468         if(fire & 2)
 469         if(actor.(weaponentity).m_switchweapon == thiswep)
 470         {
 471             bool rockfound = false;
 472             IL_EACH(g_projectiles, it.realowner == actor && it.classname == "rocket",
 473             {
 474                 if(!it.rl_detonate_later)
 475                 {
 476                     it.rl_detonate_later = true;
 477                     rockfound = true;
 478                 }
 479             });
 480             if(rockfound)
 481                 sound(actor, CH_WEAPON_B, SND_ROCKET_DET, VOL_BASE, ATTN_NORM);
 482         }
 483     }
 484 }
 485 METHOD(Devastator, wr_setup, void(entity thiswep, entity actor, .entity weaponentity))
 486 {
 487     actor.(weaponentity).rl_release = 1;
 488 }
 489 METHOD(Devastator, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 490 {
 491     #if 0
 492     // don't switch while guiding a missile
 493     if(ATTACK_FINISHED(actor, weaponentity) <= time || PS(actor).m_weapon != WEP_DEVASTATOR)
 494     {
 495         ammo_amount = false;
 496         if(WEP_CVAR(devastator, reload_ammo))
 497         {
 498             if(GetResource(actor, thiswep.ammo_type) < WEP_CVAR(devastator, ammo) && actor.(weaponentity).(weapon_load[WEP_DEVASTATOR.m_id]) < WEP_CVAR(devastator, ammo))
 499                 ammo_amount = true;
 500         }
 501         else if(GetResource(actor, thiswep.ammo_type) < WEP_CVAR(devastator, ammo))
 502             ammo_amount = true;
 503         return !ammo_amount;
 504     }
 505     #endif
 506     #if 0
 507     if(actor.rl_release == 0)
 508     {
 509         LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: TRUE", actor.rl_release, GetResource(actor, thiswep.ammo_type), WEP_CVAR(devastator, ammo));
 510         return true;
 511     }
 512     else
 513     {
 514         ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR(devastator, ammo);
 515         ammo_amount += actor.(weaponentity).(weapon_load[WEP_DEVASTATOR.m_id]) >= WEP_CVAR(devastator, ammo);
 516         LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: %s", actor.rl_release, GetResource(actor, thiswep.ammo_type), WEP_CVAR(devastator, ammo), (ammo_amount ? "TRUE" : "FALSE"));
 517         return ammo_amount;
 518     }
 519     #else
 520     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR(devastator, ammo);
 521     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR(devastator, ammo);
 522     return ammo_amount;
 523     #endif
 524 }
 525 METHOD(Devastator, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 526 {
 527     return false;
 528 }
 529 METHOD(Devastator, wr_resetplayer, void(entity thiswep, entity actor))
 530 {
 531     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 532     {
 533         .entity weaponentity = weaponentities[slot];
 534         actor.(weaponentity).lastrocket = NULL; // stop rocket guiding, no revenge from the grave!
 535         actor.(weaponentity).rl_release = 0;
 536     }
 537 }
 538 METHOD(Devastator, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 539 {
 540     W_Reload(actor, weaponentity, WEP_CVAR(devastator, ammo), SND_RELOAD);
 541 }
 542 METHOD(Devastator, wr_suicidemessage, Notification(entity thiswep))
 543 {
 544     return WEAPON_DEVASTATOR_SUICIDE;
 545 }
 546 METHOD(Devastator, wr_killmessage, Notification(entity thiswep))
 547 {
 548     if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 549         return WEAPON_DEVASTATOR_MURDER_SPLASH;
 550     else
 551         return WEAPON_DEVASTATOR_MURDER_DIRECT;
 552 }
 553
 554 #endif
 555 #ifdef CSQC
 556
 557 METHOD(Devastator, wr_impacteffect, void(entity thiswep, entity actor))
 558 {
 559     vector org2;
 560     org2 = w_org + w_backoff * 12;
 561     pointparticles(EFFECT_ROCKET_EXPLODE, org2, '0 0 0', 1);
 562     if(!w_issilent)
 563         sound(actor, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTN_NORM);
 564 }
 565
 566 #endif