qcsrc/common/weapons/weapon/electro.qc

   1 #include "electro.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Electro, Weapon)
   4 /* ammotype  */ ATTRIB(Electro, ammo_field, .int, ammo_cells);
   5 /* impulse   */ ATTRIB(Electro, impulse, int, 5);
   6 /* flags     */ ATTRIB(Electro, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   7 /* rating    */ ATTRIB(Electro, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   8 /* color     */ ATTRIB(Electro, wpcolor, vector, '0 0.5 1');
   9 /* modelname */ ATTRIB(Electro, mdl, string, "electro");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Electro, m_model, Model, MDL_ELECTRO_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Electro, w_crosshair, string, "gfx/crosshairelectro");
  14 /* crosshair */ ATTRIB(Electro, w_crosshair_size, float, 0.6);
  15 /* wepimg    */ ATTRIB(Electro, model2, string, "weaponelectro");
  16 /* refname   */ ATTRIB(Electro, netname, string, "electro");
  17 /* wepname   */ ATTRIB(Electro, m_name, string, _("Electro"));
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21                 P(class, prefix, ammo, float, BOTH) \
  22                 P(class, prefix, animtime, float, BOTH) \
  23                 P(class, prefix, bouncefactor, float, SEC) \
  24                 P(class, prefix, bouncestop, float, SEC) \
  25                 P(class, prefix, comboradius, float, PRI) \
  26                 P(class, prefix, combo_comboradius, float, NONE) \
  27                 P(class, prefix, combo_comboradius_thruwall, float, NONE) \
  28                 P(class, prefix, combo_damage, float, NONE) \
  29                 P(class, prefix, combo_edgedamage, float, NONE) \
  30                 P(class, prefix, combo_force, float, NONE) \
  31                 P(class, prefix, combo_radius, float, NONE) \
  32                 P(class, prefix, combo_safeammocheck, float, NONE) \
  33                 P(class, prefix, combo_speed, float, NONE) \
  34                 P(class, prefix, count, float, SEC) \
  35                 P(class, prefix, damagedbycontents, float, SEC) \
  36                 P(class, prefix, damageforcescale, float, SEC) \
  37                 P(class, prefix, damage, float, BOTH) \
  38                 P(class, prefix, edgedamage, float, BOTH) \
  39                 P(class, prefix, force, float, BOTH) \
  40                 P(class, prefix, health, float, SEC) \
  41                 P(class, prefix, lifetime, float, BOTH) \
  42                 P(class, prefix, midaircombo_explode, float, PRI) \
  43                 P(class, prefix, midaircombo_interval, float, PRI) \
  44                 P(class, prefix, midaircombo_radius, float, PRI) \
  45                 P(class, prefix, radius, float, BOTH) \
  46                 P(class, prefix, refire2, float, SEC) \
  47                 P(class, prefix, refire, float, BOTH) \
  48                 P(class, prefix, reload_ammo, float, NONE) \
  49                 P(class, prefix, reload_time, float, NONE) \
  50                 P(class, prefix, speed, float, BOTH) \
  51                 P(class, prefix, speed_up, float, SEC) \
  52                 P(class, prefix, speed_z, float, SEC) \
  53                 P(class, prefix, spread, float, BOTH) \
  54                 P(class, prefix, stick, float, SEC) \
  55                 P(class, prefix, switchdelay_drop, float, NONE) \
  56                 P(class, prefix, switchdelay_raise, float, NONE) \
  57                 P(class, prefix, touchexplode, float, SEC) \
  58                 P(class, prefix, weaponreplace, string,NONE) \
  59                 P(class, prefix, weaponstartoverride, float, NONE) \
  60                 P(class, prefix, weaponstart, float, NONE) \
  61                 P(class, prefix, weaponthrowable, float, NONE) \
  62         END()
  63         W_PROPS(X, Electro, electro)
  64 #undef X
  65
  66 ENDCLASS(Electro)
  67 REGISTER_WEAPON(ELECTRO, electro, NEW(Electro));
  68
  69
  70 #ifdef SVQC
  71 .float electro_count;
  72 .float electro_secondarytime;
  73 void W_Electro_ExplodeCombo(entity this);
  74 #endif
  75 #endif
  76 #ifdef IMPLEMENTATION
  77 #ifdef SVQC
  78 spawnfunc(weapon_electro) { weapon_defaultspawnfunc(this, WEP_ELECTRO); }
  79
  80 void W_Electro_TriggerCombo(vector org, float rad, entity own)
  81 {
  82         entity e = WarpZone_FindRadius(org, rad, !WEP_CVAR(electro, combo_comboradius_thruwall));
  83         while(e)
  84         {
  85                 if(e.classname == "electro_orb")
  86                 {
  87                         // do we allow thruwall triggering?
  88                         if(WEP_CVAR(electro, combo_comboradius_thruwall))
  89                         {
  90                                 // if distance is greater than thruwall distance, check to make sure it's not through a wall
  91                                 if(vdist(e.WarpZone_findradius_dist, >, WEP_CVAR(electro, combo_comboradius_thruwall)))
  92                                 {
  93                                         WarpZone_TraceLine(org, e.origin, MOVE_NOMONSTERS, e);
  94                                         if(trace_fraction != 1)
  95                                         {
  96                                                 // trigger is through a wall and outside of thruwall range, abort
  97                                                 e = e.chain;
  98                                                 continue;
  99                                         }
 100                                 }
 101                         }
 102
 103                         // change owner to whoever caused the combo explosion
 104                         e.realowner = own;
 105                         e.takedamage = DAMAGE_NO;
 106                         e.classname = "electro_orb_chain";
 107
 108                         // now set the next one to trigger as well
 109                         setthink(e, W_Electro_ExplodeCombo);
 110
 111                         // delay combo chains, looks cooler
 112                         e.nextthink =
 113                                 (
 114                                         time
 115                                         +
 116                                         (WEP_CVAR(electro, combo_speed) ?
 117                                                 (vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed))
 118                                                 :
 119                                                 0
 120                                         )
 121                                 );
 122                 }
 123                 e = e.chain;
 124         }
 125 }
 126
 127 void W_Electro_ExplodeCombo(entity this)
 128 {
 129         W_Electro_TriggerCombo(this.origin, WEP_CVAR(electro, combo_comboradius), this.realowner);
 130
 131         this.event_damage = func_null;
 132
 133         RadiusDamage(
 134                 this,
 135                 this.realowner,
 136                 WEP_CVAR(electro, combo_damage),
 137                 WEP_CVAR(electro, combo_edgedamage),
 138                 WEP_CVAR(electro, combo_radius),
 139                 NULL,
 140                 NULL,
 141                 WEP_CVAR(electro, combo_force),
 142                 WEP_ELECTRO.m_id | HITTYPE_BOUNCE, // use THIS type for a combo because primary can't bounce
 143                 NULL
 144         );
 145
 146         delete(this);
 147 }
 148
 149 void W_Electro_Explode(entity this, entity directhitentity)
 150 {
 151         if(directhitentity.takedamage == DAMAGE_AIM)
 152                 if(IS_PLAYER(directhitentity))
 153                         if(DIFF_TEAM(this.realowner, directhitentity))
 154                                 if(!IS_DEAD(directhitentity))
 155                                         if(IsFlying(directhitentity))
 156                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
 157
 158         this.event_damage = func_null;
 159         this.takedamage = DAMAGE_NO;
 160
 161         if(this.move_movetype == MOVETYPE_BOUNCE || this.classname == "electro_orb") // TODO: classname is more reliable anyway?
 162         {
 163                 RadiusDamage(
 164                         this,
 165                         this.realowner,
 166                         WEP_CVAR_SEC(electro, damage),
 167                         WEP_CVAR_SEC(electro, edgedamage),
 168                         WEP_CVAR_SEC(electro, radius),
 169                         NULL,
 170                         NULL,
 171                         WEP_CVAR_SEC(electro, force),
 172                         this.projectiledeathtype,
 173                         directhitentity
 174                 );
 175         }
 176         else
 177         {
 178                 W_Electro_TriggerCombo(this.origin, WEP_CVAR_PRI(electro, comboradius), this.realowner);
 179                 RadiusDamage(
 180                         this,
 181                         this.realowner,
 182                         WEP_CVAR_PRI(electro, damage),
 183                         WEP_CVAR_PRI(electro, edgedamage),
 184                         WEP_CVAR_PRI(electro, radius),
 185                         NULL,
 186                         NULL,
 187                         WEP_CVAR_PRI(electro, force),
 188                         this.projectiledeathtype,
 189                         directhitentity
 190                 );
 191         }
 192
 193         delete(this);
 194 }
 195
 196 void W_Electro_Explode_use(entity this, entity actor, entity trigger)
 197 {
 198         W_Electro_Explode(this, trigger);
 199 }
 200
 201 void W_Electro_TouchExplode(entity this, entity toucher)
 202 {
 203         PROJECTILE_TOUCH(this, toucher);
 204         W_Electro_Explode(this, toucher);
 205 }
 206
 207
 208 void sys_phys_update_single(entity this);
 209
 210 void W_Electro_Bolt_Think(entity this)
 211 {
 212         // sys_phys_update_single(this);
 213         if(time >= this.ltime)
 214         {
 215                 this.use(this, NULL, NULL);
 216                 return;
 217         }
 218
 219         if(WEP_CVAR_PRI(electro, midaircombo_radius))
 220         {
 221                 float found = 0;
 222                 entity e = WarpZone_FindRadius(this.origin, WEP_CVAR_PRI(electro, midaircombo_radius), true);
 223
 224                 // loop through nearby orbs and trigger them
 225                 while(e)
 226                 {
 227                         if(e.classname == "electro_orb")
 228                         {
 229                                 // change owner to whoever caused the combo explosion
 230                                 e.realowner = this.realowner;
 231                                 e.takedamage = DAMAGE_NO;
 232                                 e.classname = "electro_orb_chain";
 233
 234                                 // now set the next one to trigger as well
 235                                 setthink(e, W_Electro_ExplodeCombo);
 236
 237                                 // delay combo chains, looks cooler
 238                                 e.nextthink =
 239                                         (
 240                                                 time
 241                                                 +
 242                                                 (WEP_CVAR(electro, combo_speed) ?
 243                                                         (vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed))
 244                                                         :
 245                                                         0
 246                                                 )
 247                                         );
 248
 249                                 ++found;
 250                         }
 251                         e = e.chain;
 252                 }
 253
 254                 // if we triggered an orb, should we explode? if not, lets try again next time
 255                 if(found && WEP_CVAR_PRI(electro, midaircombo_explode))
 256                         { this.use(this, NULL, NULL); }
 257                 else
 258                         { this.nextthink = min(time + WEP_CVAR_PRI(electro, midaircombo_interval), this.ltime); }
 259         }
 260         else { this.nextthink = this.ltime; }
 261         // this.nextthink = time;
 262 }
 263
 264 void W_Electro_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity)
 265 {
 266         entity proj;
 267
 268         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_PRI(electro, ammo));
 269
 270         W_SetupShot_ProjectileSize(
 271                 actor,
 272                 weaponentity,
 273                 '0 0 -3',
 274                 '0 0 -3',
 275                 false,
 276                 2,
 277                 SND_ELECTRO_FIRE,
 278                 CH_WEAPON_A,
 279                 WEP_CVAR_PRI(electro, damage)
 280         );
 281
 282         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 283
 284         proj = new(electro_bolt);
 285         proj.owner = proj.realowner = actor;
 286         proj.bot_dodge = true;
 287         proj.bot_dodgerating = WEP_CVAR_PRI(electro, damage);
 288         proj.use = W_Electro_Explode_use;
 289         setthink(proj, W_Electro_Bolt_Think);
 290         proj.nextthink = time;
 291         proj.ltime = time + WEP_CVAR_PRI(electro, lifetime);
 292         PROJECTILE_MAKETRIGGER(proj);
 293         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 294         setorigin(proj, w_shotorg);
 295
 296         // if (IS_CSQC)
 297         set_movetype(proj, MOVETYPE_FLY);
 298         W_SetupProjVelocity_PRI(proj, electro);
 299         proj.angles = vectoangles(proj.velocity);
 300         settouch(proj, W_Electro_TouchExplode);
 301         setsize(proj, '0 0 -3', '0 0 -3');
 302         proj.flags = FL_PROJECTILE;
 303         IL_PUSH(g_projectiles, proj);
 304         IL_PUSH(g_bot_dodge, proj);
 305         proj.missile_flags = MIF_SPLASH;
 306
 307         CSQCProjectile(proj, true, PROJECTILE_ELECTRO_BEAM, true);
 308
 309         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 310         // proj.com_phys_pos = proj.origin;
 311         // proj.com_phys_vel = proj.velocity;
 312 }
 313
 314 void W_Electro_Orb_Stick(entity this, entity to)
 315 {
 316         entity newproj = spawn();
 317         newproj.classname = this.classname;
 318
 319         newproj.bot_dodge = this.bot_dodge;
 320         newproj.bot_dodgerating = this.bot_dodgerating;
 321
 322         newproj.owner = this.owner;
 323         newproj.realowner = this.realowner;
 324         setsize(newproj, this.mins, this.maxs);
 325         setorigin(newproj, this.origin);
 326         setmodel(newproj, MDL_PROJECTILE_ELECTRO);
 327         newproj.angles = vectoangles(-trace_plane_normal); // face against the surface
 328
 329         newproj.takedamage = this.takedamage;
 330         newproj.damageforcescale = this.damageforcescale;
 331         newproj.health = this.health;
 332         newproj.event_damage = this.event_damage;
 333         newproj.spawnshieldtime = this.spawnshieldtime;
 334         newproj.damagedbycontents = true;
 335         IL_PUSH(g_damagedbycontents, newproj);
 336
 337         set_movetype(newproj, MOVETYPE_NONE); // lock the orb in place
 338         newproj.projectiledeathtype = this.projectiledeathtype;
 339
 340         settouch(newproj, func_null);
 341         setthink(newproj, getthink(this));
 342         newproj.nextthink = this.nextthink;
 343         newproj.use = this.use;
 344         newproj.flags = this.flags;
 345         IL_PUSH(g_projectiles, newproj);
 346         IL_PUSH(g_bot_dodge, newproj);
 347
 348         delete(this);
 349
 350         if(to)
 351                 SetMovetypeFollow(this, to);
 352 }
 353
 354 void W_Electro_Orb_Touch(entity this, entity toucher)
 355 {
 356         PROJECTILE_TOUCH(this, toucher);
 357         if(toucher.takedamage == DAMAGE_AIM)
 358                 { if(WEP_CVAR_SEC(electro, touchexplode)) { W_Electro_Explode(this, toucher); } }
 359         else
 360         {
 361                 //UpdateCSQCProjectile(this);
 362                 spamsound(this, CH_SHOTS, SND(ELECTRO_BOUNCE), VOL_BASE, ATTEN_NORM);
 363                 this.projectiledeathtype |= HITTYPE_BOUNCE;
 364
 365                 if(WEP_CVAR_SEC(electro, stick))
 366                         W_Electro_Orb_Stick(this, toucher);
 367         }
 368 }
 369
 370 void W_Electro_Orb_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 371 {
 372         if(this.health <= 0)
 373                 return;
 374
 375         // note: combos are usually triggered by W_Electro_TriggerCombo, not damage
 376         float is_combo = (inflictor.classname == "electro_orb_chain" || inflictor.classname == "electro_bolt");
 377
 378         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, (is_combo ? 1 : -1)))
 379                 return; // g_projectiles_damage says to halt
 380
 381         this.health = this.health - damage;
 382         if(this.health <= 0)
 383         {
 384                 this.takedamage = DAMAGE_NO;
 385                 this.nextthink = time;
 386                 if(is_combo)
 387                 {
 388                         // change owner to whoever caused the combo explosion
 389                         this.realowner = inflictor.realowner;
 390                         this.classname = "electro_orb_chain";
 391                         setthink(this, W_Electro_ExplodeCombo);
 392                         this.nextthink = time +
 393                                 (
 394                                         // bound the length, inflictor may be in a galaxy far far away (warpzones)
 395                                         min(
 396                                                 WEP_CVAR(electro, combo_radius),
 397                                                 vlen(this.origin - inflictor.origin)
 398                                         )
 399                                         /
 400                                         // delay combo chains, looks cooler
 401                                         WEP_CVAR(electro, combo_speed)
 402                                 );
 403                 }
 404                 else
 405                 {
 406                         this.use = W_Electro_Explode_use;
 407                         setthink(this, adaptor_think2use); // not _hittype_splash, as this runs "immediately"
 408                 }
 409         }
 410 }
 411
 412 void W_Electro_Attack_Orb(Weapon thiswep, entity actor, .entity weaponentity)
 413 {
 414         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(electro, ammo));
 415
 416         W_SetupShot_ProjectileSize(
 417                 actor,
 418                 weaponentity,
 419                 '-4 -4 -4',
 420                 '4 4 4',
 421                 false,
 422                 2,
 423                 SND_ELECTRO_FIRE2,
 424                 CH_WEAPON_A,
 425                 WEP_CVAR_SEC(electro, damage)
 426         );
 427
 428         w_shotdir = v_forward; // no TrueAim for grenades please
 429
 430         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 431
 432         entity proj = new(electro_orb);
 433         proj.owner = proj.realowner = actor;
 434         proj.use = W_Electro_Explode_use;
 435         setthink(proj, adaptor_think2use_hittype_splash);
 436         proj.bot_dodge = true;
 437         proj.bot_dodgerating = WEP_CVAR_SEC(electro, damage);
 438         proj.nextthink = time + WEP_CVAR_SEC(electro, lifetime);
 439         PROJECTILE_MAKETRIGGER(proj);
 440         proj.projectiledeathtype = WEP_ELECTRO.m_id | HITTYPE_SECONDARY;
 441         setorigin(proj, w_shotorg);
 442
 443         //proj.glow_size = 50;
 444         //proj.glow_color = 45;
 445         set_movetype(proj, MOVETYPE_BOUNCE);
 446         W_SetupProjVelocity_UP_SEC(proj, electro);
 447         settouch(proj, W_Electro_Orb_Touch);
 448         setsize(proj, '-4 -4 -4', '4 4 4');
 449         proj.takedamage = DAMAGE_YES;
 450         proj.damageforcescale = WEP_CVAR_SEC(electro, damageforcescale);
 451         proj.health = WEP_CVAR_SEC(electro, health);
 452         proj.event_damage = W_Electro_Orb_Damage;
 453         proj.flags = FL_PROJECTILE;
 454         IL_PUSH(g_projectiles, proj);
 455         IL_PUSH(g_bot_dodge, proj);
 456         proj.damagedbycontents = (WEP_CVAR_SEC(electro, damagedbycontents));
 457         if(proj.damagedbycontents)
 458                 IL_PUSH(g_damagedbycontents, proj);
 459
 460         proj.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 461         proj.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 462         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 463
 464 #if 0
 465         entity p2;
 466         p2 = spawn();
 467         copyentity(proj, p2);
 468         setmodel(p2, MDL_PROJECTILE_ELECTRO);
 469         setsize(p2, proj.mins, proj.maxs);
 470 #endif
 471
 472         CSQCProjectile(proj, true, PROJECTILE_ELECTRO, false); // no culling, it has sound
 473
 474         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 475 }
 476
 477 void W_Electro_CheckAttack(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 478 {
 479         if(actor.electro_count > 1)
 480         if(PHYS_INPUT_BUTTON_ATCK2(actor))
 481         if(weapon_prepareattack(thiswep, actor, weaponentity, true, -1))
 482         {
 483                 W_Electro_Attack_Orb(WEP_ELECTRO, actor, weaponentity);
 484                 actor.electro_count -= 1;
 485                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 486                 return;
 487         }
 488         // WEAPONTODO: when the player releases the button, cut down the length of refire2?
 489         w_ready(thiswep, actor, weaponentity, fire);
 490 }
 491
 492 .float bot_secondary_electromooth;
 493
 494 METHOD(Electro, wr_aim, void(entity thiswep, entity actor))
 495 {
 496     PHYS_INPUT_BUTTON_ATCK(actor) = PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 497     if(vdist(actor.origin - actor.enemy.origin, >, 1000)) { actor.bot_secondary_electromooth = 0; }
 498     if(actor.bot_secondary_electromooth == 0)
 499     {
 500         float shoot;
 501
 502         if(WEP_CVAR_PRI(electro, speed))
 503             shoot = bot_aim(actor, WEP_CVAR_PRI(electro, speed), 0, WEP_CVAR_PRI(electro, lifetime), false);
 504         else
 505             shoot = bot_aim(actor, 1000000, 0, 0.001, false);
 506
 507         if(shoot)
 508         {
 509             PHYS_INPUT_BUTTON_ATCK(actor) = true;
 510             if(random() < 0.01) actor.bot_secondary_electromooth = 1;
 511         }
 512     }
 513     else
 514     {
 515         if(bot_aim(actor, WEP_CVAR_SEC(electro, speed), WEP_CVAR_SEC(electro, speed_up), WEP_CVAR_SEC(electro, lifetime), true))
 516         {
 517             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 518             if(random() < 0.03) actor.bot_secondary_electromooth = 0;
 519         }
 520     }
 521 }
 522 METHOD(Electro, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 523 {
 524     if(autocvar_g_balance_electro_reload_ammo) // forced reload // WEAPONTODO
 525     {
 526         float ammo_amount = 0;
 527         if(actor.clip_load >= WEP_CVAR_PRI(electro, ammo))
 528             ammo_amount = 1;
 529         if(actor.clip_load >= WEP_CVAR_SEC(electro, ammo))
 530             ammo_amount += 1;
 531
 532         if(!ammo_amount)
 533         {
 534             thiswep.wr_reload(thiswep, actor, weaponentity);
 535             return;
 536         }
 537     }
 538
 539     if(fire & 1)
 540     {
 541         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(electro, refire)))
 542         {
 543                 W_Electro_Attack_Bolt(thiswep, actor, weaponentity);
 544                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(electro, animtime), w_ready);
 545         }
 546     }
 547     else if(fire & 2)
 548     {
 549         if(time >= actor.electro_secondarytime)
 550         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(electro, refire)))
 551         {
 552             W_Electro_Attack_Orb(thiswep, actor, weaponentity);
 553             actor.electro_count = WEP_CVAR_SEC(electro, count);
 554             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 555             actor.electro_secondarytime = time + WEP_CVAR_SEC(electro, refire2) * W_WeaponRateFactor(actor);
 556         }
 557     }
 558 }
 559 METHOD(Electro, wr_checkammo1, bool(entity thiswep, entity actor))
 560 {
 561     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(electro, ammo);
 562     ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_PRI(electro, ammo);
 563     return ammo_amount;
 564 }
 565 METHOD(Electro, wr_checkammo2, bool(entity thiswep, entity actor))
 566 {
 567     float ammo_amount;
 568     if(WEP_CVAR(electro, combo_safeammocheck)) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
 569     {
 570         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 571         ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 572     }
 573     else
 574     {
 575         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(electro, ammo);
 576         ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_SEC(electro, ammo);
 577     }
 578     return ammo_amount;
 579 }
 580 METHOD(Electro, wr_resetplayer, void(entity thiswep, entity actor))
 581 {
 582     actor.electro_secondarytime = time;
 583 }
 584 METHOD(Electro, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 585 {
 586     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(electro, ammo), WEP_CVAR_SEC(electro, ammo)), SND_RELOAD);
 587 }
 588 METHOD(Electro, wr_suicidemessage, Notification(entity thiswep))
 589 {
 590     if(w_deathtype & HITTYPE_SECONDARY)
 591         return WEAPON_ELECTRO_SUICIDE_ORBS;
 592     else
 593         return WEAPON_ELECTRO_SUICIDE_BOLT;
 594 }
 595 METHOD(Electro, wr_killmessage, Notification(entity thiswep))
 596 {
 597     if(w_deathtype & HITTYPE_SECONDARY)
 598     {
 599         return WEAPON_ELECTRO_MURDER_ORBS;
 600     }
 601     else
 602     {
 603         if(w_deathtype & HITTYPE_BOUNCE)
 604             return WEAPON_ELECTRO_MURDER_COMBO;
 605         else
 606             return WEAPON_ELECTRO_MURDER_BOLT;
 607     }
 608 }
 609
 610 #endif
 611 #ifdef CSQC
 612
 613 METHOD(Electro, wr_impacteffect, void(entity thiswep, entity actor))
 614 {
 615     vector org2;
 616     org2 = w_org + w_backoff * 6;
 617     if(w_deathtype & HITTYPE_SECONDARY)
 618     {
 619         pointparticles(EFFECT_ELECTRO_BALLEXPLODE, org2, '0 0 0', 1);
 620         if(!w_issilent)
 621             sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
 622     }
 623     else
 624     {
 625         if(w_deathtype & HITTYPE_BOUNCE)
 626         {
 627             // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 628             pointparticles(EFFECT_ELECTRO_COMBO, org2, '0 0 0', 1);
 629             if(!w_issilent)
 630                 sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT_COMBO, VOL_BASE, ATTEN_NORM);
 631         }
 632         else
 633         {
 634             pointparticles(EFFECT_ELECTRO_IMPACT, org2, '0 0 0', 1);
 635             if(!w_issilent)
 636                 sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
 637         }
 638     }
 639 }
 640
 641 #endif
 642 #endif