8b8512946360ee11a49b4a93517ab27d84fa533e
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / electro.qc
1 #include "electro.qh"
2
3 #ifdef SVQC
4
5 void W_Electro_TriggerCombo(vector org, float rad, entity own)
6 {
7         entity e = WarpZone_FindRadius(org, rad, !WEP_CVAR(electro, combo_comboradius_thruwall));
8         while(e)
9         {
10                 if(e.classname == "electro_orb")
11                 {
12                         // do we allow thruwall triggering?
13                         if(WEP_CVAR(electro, combo_comboradius_thruwall))
14                         {
15                                 // if distance is greater than thruwall distance, check to make sure it's not through a wall
16                                 if(vdist(e.WarpZone_findradius_dist, >, WEP_CVAR(electro, combo_comboradius_thruwall)))
17                                 {
18                                         WarpZone_TraceLine(org, e.origin, MOVE_NOMONSTERS, e);
19                                         if(trace_fraction != 1)
20                                         {
21                                                 // trigger is through a wall and outside of thruwall range, abort
22                                                 e = e.chain;
23                                                 continue;
24                                         }
25                                 }
26                         }
27
28                         // change owner to whoever caused the combo explosion
29                         e.realowner = own;
30                         e.takedamage = DAMAGE_NO;
31                         e.classname = "electro_orb_chain";
32
33                         // now set the next one to trigger as well
34                         setthink(e, W_Electro_ExplodeCombo);
35
36                         // delay combo chains, looks cooler
37                         e.nextthink =
38                                 (
39                                         time
40                                         +
41                                         (WEP_CVAR(electro, combo_speed) ?
42                                                 (vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed))
43                                                 :
44                                                 0
45                                         )
46                                 );
47                 }
48                 e = e.chain;
49         }
50 }
51
52 void W_Electro_ExplodeCombo(entity this)
53 {
54         W_Electro_TriggerCombo(this.origin, WEP_CVAR(electro, combo_comboradius), this.realowner);
55
56         this.event_damage = func_null;
57
58         RadiusDamage(
59                 this,
60                 this.realowner,
61                 WEP_CVAR(electro, combo_damage),
62                 WEP_CVAR(electro, combo_edgedamage),
63                 WEP_CVAR(electro, combo_radius),
64                 NULL,
65                 NULL,
66                 WEP_CVAR(electro, combo_force),
67                 WEP_ELECTRO.m_id | HITTYPE_BOUNCE, // use THIS type for a combo because primary can't bounce
68                 this.weaponentity_fld,
69                 NULL
70         );
71
72         delete(this);
73 }
74
75 void W_Electro_Explode(entity this, entity directhitentity)
76 {
77         if(directhitentity.takedamage == DAMAGE_AIM)
78                 if(IS_PLAYER(directhitentity))
79                         if(DIFF_TEAM(this.realowner, directhitentity))
80                                 if(!IS_DEAD(directhitentity))
81                                         if(IsFlying(directhitentity))
82                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
83
84         this.event_damage = func_null;
85         this.takedamage = DAMAGE_NO;
86
87         if(this.move_movetype == MOVETYPE_BOUNCE || this.classname == "electro_orb") // TODO: classname is more reliable anyway?
88         {
89                 RadiusDamage(
90                         this,
91                         this.realowner,
92                         WEP_CVAR_SEC(electro, damage),
93                         WEP_CVAR_SEC(electro, edgedamage),
94                         WEP_CVAR_SEC(electro, radius),
95                         NULL,
96                         NULL,
97                         WEP_CVAR_SEC(electro, force),
98                         this.projectiledeathtype,
99                         this.weaponentity_fld,
100                         directhitentity
101                 );
102         }
103         else
104         {
105                 W_Electro_TriggerCombo(this.origin, WEP_CVAR_PRI(electro, comboradius), this.realowner);
106                 RadiusDamage(
107                         this,
108                         this.realowner,
109                         WEP_CVAR_PRI(electro, damage),
110                         WEP_CVAR_PRI(electro, edgedamage),
111                         WEP_CVAR_PRI(electro, radius),
112                         NULL,
113                         NULL,
114                         WEP_CVAR_PRI(electro, force),
115                         this.projectiledeathtype,
116                         this.weaponentity_fld,
117                         directhitentity
118                 );
119         }
120
121         delete(this);
122 }
123
124 void W_Electro_Explode_use(entity this, entity actor, entity trigger)
125 {
126         W_Electro_Explode(this, trigger);
127 }
128
129 void W_Electro_TouchExplode(entity this, entity toucher)
130 {
131         PROJECTILE_TOUCH(this, toucher);
132         W_Electro_Explode(this, toucher);
133 }
134
135
136 void sys_phys_update_single(entity this);
137
138 void W_Electro_Bolt_Think(entity this)
139 {
140         // sys_phys_update_single(this);
141         if(time >= this.ltime)
142         {
143                 this.use(this, NULL, NULL);
144                 return;
145         }
146
147         if(WEP_CVAR_PRI(electro, midaircombo_radius))
148         {
149                 float found = 0;
150                 entity e = WarpZone_FindRadius(this.origin, WEP_CVAR_PRI(electro, midaircombo_radius), true);
151
152                 // loop through nearby orbs and trigger them
153                 while(e)
154                 {
155                         if(e.classname == "electro_orb")
156                         {
157                                 // change owner to whoever caused the combo explosion
158                                 e.realowner = this.realowner;
159                                 e.takedamage = DAMAGE_NO;
160                                 e.classname = "electro_orb_chain";
161
162                                 // now set the next one to trigger as well
163                                 setthink(e, W_Electro_ExplodeCombo);
164
165                                 // delay combo chains, looks cooler
166                                 e.nextthink =
167                                         (
168                                                 time
169                                                 +
170                                                 (WEP_CVAR(electro, combo_speed) ?
171                                                         (vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed))
172                                                         :
173                                                         0
174                                                 )
175                                         );
176
177                                 ++found;
178                         }
179                         e = e.chain;
180                 }
181
182                 // if we triggered an orb, should we explode? if not, lets try again next time
183                 if(found && WEP_CVAR_PRI(electro, midaircombo_explode))
184                         { this.use(this, NULL, NULL); }
185                 else
186                         { this.nextthink = min(time + WEP_CVAR_PRI(electro, midaircombo_interval), this.ltime); }
187         }
188         else { this.nextthink = this.ltime; }
189         // this.nextthink = time;
190 }
191
192 void W_Electro_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity)
193 {
194         entity proj;
195
196         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_PRI(electro, ammo), weaponentity);
197
198         W_SetupShot_ProjectileSize(
199                 actor,
200                 weaponentity,
201                 '0 0 -3',
202                 '0 0 -3',
203                 false,
204                 2,
205                 SND_ELECTRO_FIRE,
206                 CH_WEAPON_A,
207                 WEP_CVAR_PRI(electro, damage)
208         );
209
210         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
211
212         proj = new(electro_bolt);
213         proj.owner = proj.realowner = actor;
214         proj.bot_dodge = true;
215         proj.bot_dodgerating = WEP_CVAR_PRI(electro, damage);
216         proj.use = W_Electro_Explode_use;
217         setthink(proj, W_Electro_Bolt_Think);
218         proj.nextthink = time;
219         proj.ltime = time + WEP_CVAR_PRI(electro, lifetime);
220         PROJECTILE_MAKETRIGGER(proj);
221         proj.projectiledeathtype = WEP_ELECTRO.m_id;
222         proj.weaponentity_fld = weaponentity;
223         setorigin(proj, w_shotorg);
224
225         // if (IS_CSQC)
226         set_movetype(proj, MOVETYPE_FLY);
227         W_SetupProjVelocity_PRI(proj, electro);
228         proj.angles = vectoangles(proj.velocity);
229         settouch(proj, W_Electro_TouchExplode);
230         setsize(proj, '0 0 -3', '0 0 -3');
231         proj.flags = FL_PROJECTILE;
232         IL_PUSH(g_projectiles, proj);
233         IL_PUSH(g_bot_dodge, proj);
234         proj.missile_flags = MIF_SPLASH;
235
236         CSQCProjectile(proj, true, PROJECTILE_ELECTRO_BEAM, true);
237
238         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
239         // proj.com_phys_pos = proj.origin;
240         // proj.com_phys_vel = proj.velocity;
241 }
242
243 void W_Electro_Orb_Stick(entity this, entity to)
244 {
245         entity newproj = spawn();
246         newproj.classname = this.classname;
247
248         newproj.bot_dodge = this.bot_dodge;
249         newproj.bot_dodgerating = this.bot_dodgerating;
250
251         newproj.owner = this.owner;
252         newproj.realowner = this.realowner;
253         setsize(newproj, this.mins, this.maxs);
254         setorigin(newproj, this.origin);
255         setmodel(newproj, MDL_PROJECTILE_ELECTRO);
256         newproj.angles = vectoangles(-trace_plane_normal); // face against the surface
257
258         newproj.takedamage = this.takedamage;
259         newproj.damageforcescale = this.damageforcescale;
260         newproj.health = this.health;
261         newproj.event_damage = this.event_damage;
262         newproj.spawnshieldtime = this.spawnshieldtime;
263         newproj.damagedbycontents = true;
264         IL_PUSH(g_damagedbycontents, newproj);
265
266         set_movetype(newproj, MOVETYPE_NONE); // lock the orb in place
267         newproj.projectiledeathtype = this.projectiledeathtype;
268         newproj.weaponentity_fld = this.weaponentity_fld;
269
270         settouch(newproj, func_null);
271         setthink(newproj, getthink(this));
272         newproj.nextthink = this.nextthink;
273         newproj.use = this.use;
274         newproj.flags = this.flags;
275         IL_PUSH(g_projectiles, newproj);
276         IL_PUSH(g_bot_dodge, newproj);
277
278         delete(this);
279
280         if(to)
281                 SetMovetypeFollow(this, to);
282 }
283
284 void W_Electro_Orb_Touch(entity this, entity toucher)
285 {
286         PROJECTILE_TOUCH(this, toucher);
287         if(toucher.takedamage == DAMAGE_AIM)
288                 { if(WEP_CVAR_SEC(electro, touchexplode)) { W_Electro_Explode(this, toucher); } }
289         else if(toucher.owner != this.owner && toucher.classname != this.classname) // don't stick to player's other projectiles!
290         {
291                 //UpdateCSQCProjectile(this);
292                 spamsound(this, CH_SHOTS, SND_ELECTRO_BOUNCE, VOL_BASE, ATTEN_NORM);
293                 this.projectiledeathtype |= HITTYPE_BOUNCE;
294
295                 if(WEP_CVAR_SEC(electro, stick))
296                         W_Electro_Orb_Stick(this, toucher);
297         }
298 }
299
300 void W_Electro_Orb_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
301 {
302         if(this.health <= 0)
303                 return;
304
305         // note: combos are usually triggered by W_Electro_TriggerCombo, not damage
306         float is_combo = (inflictor.classname == "electro_orb_chain" || inflictor.classname == "electro_bolt");
307
308         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, (is_combo ? 1 : -1)))
309                 return; // g_projectiles_damage says to halt
310
311         this.health = this.health - damage;
312         if(this.health <= 0)
313         {
314                 this.takedamage = DAMAGE_NO;
315                 this.nextthink = time;
316                 if(is_combo)
317                 {
318                         // change owner to whoever caused the combo explosion
319                         this.realowner = inflictor.realowner;
320                         this.classname = "electro_orb_chain";
321                         setthink(this, W_Electro_ExplodeCombo);
322                         this.nextthink = time +
323                                 (
324                                         // bound the length, inflictor may be in a galaxy far far away (warpzones)
325                                         min(
326                                                 WEP_CVAR(electro, combo_radius),
327                                                 vlen(this.origin - inflictor.origin)
328                                         )
329                                         /
330                                         // delay combo chains, looks cooler
331                                         WEP_CVAR(electro, combo_speed)
332                                 );
333                 }
334                 else
335                 {
336                         this.use = W_Electro_Explode_use;
337                         setthink(this, adaptor_think2use); // not _hittype_splash, as this runs "immediately"
338                 }
339         }
340 }
341
342 void W_Electro_Attack_Orb(Weapon thiswep, entity actor, .entity weaponentity)
343 {
344         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(electro, ammo), weaponentity);
345
346         W_SetupShot_ProjectileSize(
347                 actor,
348                 weaponentity,
349                 '-4 -4 -4',
350                 '4 4 4',
351                 false,
352                 2,
353                 SND_ELECTRO_FIRE2,
354                 CH_WEAPON_A,
355                 WEP_CVAR_SEC(electro, damage)
356         );
357
358         w_shotdir = v_forward; // no TrueAim for grenades please
359
360         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
361
362         entity proj = new(electro_orb);
363         proj.owner = proj.realowner = actor;
364         proj.use = W_Electro_Explode_use;
365         setthink(proj, adaptor_think2use_hittype_splash);
366         proj.bot_dodge = true;
367         proj.bot_dodgerating = WEP_CVAR_SEC(electro, damage);
368         proj.nextthink = time + WEP_CVAR_SEC(electro, lifetime);
369         PROJECTILE_MAKETRIGGER(proj);
370         proj.projectiledeathtype = WEP_ELECTRO.m_id | HITTYPE_SECONDARY;
371         proj.weaponentity_fld = weaponentity;
372         setorigin(proj, w_shotorg);
373
374         //proj.glow_size = 50;
375         //proj.glow_color = 45;
376         set_movetype(proj, MOVETYPE_BOUNCE);
377         W_SetupProjVelocity_UP_SEC(proj, electro);
378         settouch(proj, W_Electro_Orb_Touch);
379         setsize(proj, '-4 -4 -4', '4 4 4');
380         proj.takedamage = DAMAGE_YES;
381         proj.damageforcescale = WEP_CVAR_SEC(electro, damageforcescale);
382         proj.health = WEP_CVAR_SEC(electro, health);
383         proj.event_damage = W_Electro_Orb_Damage;
384         proj.flags = FL_PROJECTILE;
385         IL_PUSH(g_projectiles, proj);
386         IL_PUSH(g_bot_dodge, proj);
387         proj.damagedbycontents = (WEP_CVAR_SEC(electro, damagedbycontents));
388         if(proj.damagedbycontents)
389                 IL_PUSH(g_damagedbycontents, proj);
390
391         proj.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
392         proj.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
393         proj.missile_flags = MIF_SPLASH | MIF_ARC;
394
395 #if 0
396         entity p2;
397         p2 = spawn();
398         copyentity(proj, p2);
399         setmodel(p2, MDL_PROJECTILE_ELECTRO);
400         setsize(p2, proj.mins, proj.maxs);
401 #endif
402
403         CSQCProjectile(proj, true, PROJECTILE_ELECTRO, false); // no culling, it has sound
404
405         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
406 }
407
408 void W_Electro_CheckAttack(Weapon thiswep, entity actor, .entity weaponentity, int fire)
409 {
410         if(actor.(weaponentity).electro_count > 1)
411         if(PHYS_INPUT_BUTTON_ATCK2(actor))
412         if(weapon_prepareattack(thiswep, actor, weaponentity, true, -1))
413         {
414                 W_Electro_Attack_Orb(WEP_ELECTRO, actor, weaponentity);
415                 actor.(weaponentity).electro_count -= 1;
416                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
417                 return;
418         }
419         // WEAPONTODO: when the player releases the button, cut down the length of refire2?
420         w_ready(thiswep, actor, weaponentity, fire);
421 }
422
423 .float bot_secondary_electromooth;
424
425 METHOD(Electro, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
426 {
427     PHYS_INPUT_BUTTON_ATCK(actor) = PHYS_INPUT_BUTTON_ATCK2(actor) = false;
428     if(vdist(actor.origin - actor.enemy.origin, >, 1000)) { actor.bot_secondary_electromooth = 0; }
429     if(actor.bot_secondary_electromooth == 0)
430     {
431         float shoot;
432
433         if(WEP_CVAR_PRI(electro, speed))
434             shoot = bot_aim(actor, weaponentity, WEP_CVAR_PRI(electro, speed), 0, WEP_CVAR_PRI(electro, lifetime), false);
435         else
436             shoot = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
437
438         if(shoot)
439         {
440             PHYS_INPUT_BUTTON_ATCK(actor) = true;
441             if(random() < 0.01) actor.bot_secondary_electromooth = 1;
442         }
443     }
444     else
445     {
446         if(bot_aim(actor, weaponentity, WEP_CVAR_SEC(electro, speed), WEP_CVAR_SEC(electro, speed_up), WEP_CVAR_SEC(electro, lifetime), true))
447         {
448             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
449             if(random() < 0.03) actor.bot_secondary_electromooth = 0;
450         }
451     }
452 }
453 METHOD(Electro, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
454 {
455     if(autocvar_g_balance_electro_reload_ammo) // forced reload // WEAPONTODO
456     {
457         float ammo_amount = 0;
458         if(actor.(weaponentity).clip_load >= WEP_CVAR_PRI(electro, ammo))
459             ammo_amount = 1;
460         if(actor.(weaponentity).clip_load >= WEP_CVAR_SEC(electro, ammo))
461             ammo_amount += 1;
462
463         if(!ammo_amount)
464         {
465             thiswep.wr_reload(thiswep, actor, weaponentity);
466             return;
467         }
468     }
469
470     if(fire & 1)
471     {
472         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(electro, refire)))
473         {
474                 W_Electro_Attack_Bolt(thiswep, actor, weaponentity);
475                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(electro, animtime), w_ready);
476         }
477     }
478     else if(fire & 2)
479     {
480         if(time >= actor.(weaponentity).electro_secondarytime)
481         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(electro, refire)))
482         {
483             W_Electro_Attack_Orb(thiswep, actor, weaponentity);
484             actor.(weaponentity).electro_count = WEP_CVAR_SEC(electro, count);
485             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
486             actor.(weaponentity).electro_secondarytime = time + WEP_CVAR_SEC(electro, refire2) * W_WeaponRateFactor(actor);
487         }
488     }
489 }
490 METHOD(Electro, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
491 {
492     float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(electro, ammo);
493     ammo_amount += actor.(weaponentity).(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_PRI(electro, ammo);
494     return ammo_amount;
495 }
496 METHOD(Electro, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
497 {
498     float ammo_amount;
499     if(WEP_CVAR(electro, combo_safeammocheck)) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
500     {
501         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
502         ammo_amount += actor.(weaponentity).(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
503     }
504     else
505     {
506         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(electro, ammo);
507         ammo_amount += actor.(weaponentity).(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_SEC(electro, ammo);
508     }
509     return ammo_amount;
510 }
511 METHOD(Electro, wr_resetplayer, void(entity thiswep, entity actor))
512 {
513     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
514     {
515         .entity weaponentity = weaponentities[slot];
516         actor.(weaponentity).electro_secondarytime = time;
517     }
518 }
519 METHOD(Electro, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
520 {
521     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(electro, ammo), WEP_CVAR_SEC(electro, ammo)), SND_RELOAD);
522 }
523 METHOD(Electro, wr_suicidemessage, Notification(entity thiswep))
524 {
525     if(w_deathtype & HITTYPE_SECONDARY)
526         return WEAPON_ELECTRO_SUICIDE_ORBS;
527     else
528         return WEAPON_ELECTRO_SUICIDE_BOLT;
529 }
530 METHOD(Electro, wr_killmessage, Notification(entity thiswep))
531 {
532     if(w_deathtype & HITTYPE_SECONDARY)
533     {
534         return WEAPON_ELECTRO_MURDER_ORBS;
535     }
536     else
537     {
538         if(w_deathtype & HITTYPE_BOUNCE)
539             return WEAPON_ELECTRO_MURDER_COMBO;
540         else
541             return WEAPON_ELECTRO_MURDER_BOLT;
542     }
543 }
544
545 #endif
546 #ifdef CSQC
547
548 METHOD(Electro, wr_impacteffect, void(entity thiswep, entity actor))
549 {
550     vector org2;
551     org2 = w_org + w_backoff * 6;
552     if(w_deathtype & HITTYPE_SECONDARY)
553     {
554         pointparticles(EFFECT_ELECTRO_BALLEXPLODE, org2, '0 0 0', 1);
555         if(!w_issilent)
556             sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
557     }
558     else
559     {
560         if(w_deathtype & HITTYPE_BOUNCE)
561         {
562             // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
563             pointparticles(EFFECT_ELECTRO_COMBO, org2, '0 0 0', 1);
564             if(!w_issilent)
565                 sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT_COMBO, VOL_BASE, ATTEN_NORM);
566         }
567         else
568         {
569             pointparticles(EFFECT_ELECTRO_IMPACT, org2, '0 0 0', 1);
570             if(!w_issilent)
571                 sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
572         }
573     }
574 }
575
576 #endif