qcsrc/common/weapons/weapon/fireball.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Fireball, Weapon)
   3 /* ammotype  */ //ATTRIB(Fireball, ammo_field, .int, ammo_none)
   4 /* impulse   */ ATTRIB(Fireball, impulse, int, 9)
   5 /* flags     */ ATTRIB(Fireball, spawnflags, int, WEP_FLAG_SUPERWEAPON | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Fireball, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   7 /* color     */ ATTRIB(Fireball, wpcolor, vector, '1 0.5 0');
   8 /* modelname */ ATTRIB(Fireball, mdl, string, "fireball");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Fireball, m_model, Model, MDL_FIREBALL_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Fireball, w_crosshair, string, "gfx/crosshairfireball");
  13 /* crosshair */ //ATTRIB(Fireball, w_crosshair_size, float, 0.65);
  14 /* wepimg    */ ATTRIB(Fireball, model2, string, "weaponfireball");
  15 /* refname   */ ATTRIB(Fireball, netname, string, "fireball");
  16 /* wepname   */ ATTRIB(Fireball, m_name, string, _("Fireball"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, animtime, float, BOTH) \
  21                 P(class, prefix, bfgdamage, float, PRI) \
  22                 P(class, prefix, bfgforce, float, PRI) \
  23                 P(class, prefix, bfgradius, float, PRI) \
  24                 P(class, prefix, damageforcescale, float, BOTH) \
  25                 P(class, prefix, damagetime, float, SEC) \
  26                 P(class, prefix, damage, float, BOTH) \
  27                 P(class, prefix, edgedamage, float, PRI) \
  28                 P(class, prefix, force, float, PRI) \
  29                 P(class, prefix, health, float, PRI) \
  30                 P(class, prefix, laserburntime, float, BOTH) \
  31                 P(class, prefix, laserdamage, float, BOTH) \
  32                 P(class, prefix, laseredgedamage, float, BOTH) \
  33                 P(class, prefix, laserradius, float, BOTH) \
  34                 P(class, prefix, lifetime, float, BOTH) \
  35                 P(class, prefix, radius, float, PRI) \
  36                 P(class, prefix, refire2, float, PRI) \
  37                 P(class, prefix, refire, float, BOTH) \
  38                 P(class, prefix, speed, float, BOTH) \
  39                 P(class, prefix, speed_up, float, SEC) \
  40                 P(class, prefix, speed_z, float, SEC) \
  41                 P(class, prefix, spread, float, BOTH) \
  42                 P(class, prefix, switchdelay_drop, float, NONE) \
  43                 P(class, prefix, switchdelay_raise, float, NONE) \
  44                 P(class, prefix, weaponreplace, string,NONE) \
  45                 P(class, prefix, weaponstartoverride, float, NONE) \
  46                 P(class, prefix, weaponstart, float, NONE) \
  47                 P(class, prefix, weaponthrowable, float, NONE) \
  48         END()
  49         W_PROPS(X, Fireball, fireball)
  50 #undef X
  51
  52 ENDCLASS(Fireball)
  53 REGISTER_WEAPON(FIREBALL, fireball, NEW(Fireball));
  54
  55 #ifdef SVQC
  56 .float bot_primary_fireballmooth; // whatever a mooth is
  57 .vector fireball_impactvec;
  58 .float fireball_primarytime;
  59 #endif
  60 #endif
  61 #ifdef IMPLEMENTATION
  62 #ifdef SVQC
  63 spawnfunc(weapon_fireball) { weapon_defaultspawnfunc(this, WEP_FIREBALL); }
  64
  65 void W_Fireball_Explode(entity this, entity directhitentity)
  66 {
  67         entity e;
  68         float dist;
  69         float points;
  70         vector dir;
  71         float d;
  72
  73         this.event_damage = func_null;
  74         this.takedamage = DAMAGE_NO;
  75
  76         // 1. dist damage
  77         d = (this.realowner.health + this.realowner.armorvalue);
  78         RadiusDamage(this, this.realowner, WEP_CVAR_PRI(fireball, damage), WEP_CVAR_PRI(fireball, edgedamage), WEP_CVAR_PRI(fireball, radius), NULL, NULL, WEP_CVAR_PRI(fireball, force), this.projectiledeathtype, directhitentity);
  79         if(this.realowner.health + this.realowner.armorvalue >= d)
  80         if(!this.cnt)
  81         {
  82                 modeleffect_spawn("models/sphere/sphere.md3", 0, 0, this.origin, '0 0 0', '0 0 0', '0 0 0', 0, WEP_CVAR_PRI(fireball, bfgradius), 0.2, 0.05, 0.25);
  83
  84                 // 2. bfg effect
  85                 // NOTE: this cannot be made warpzone aware by design. So, better intentionally ignore warpzones here.
  86                 for(e = findradius(this.origin, WEP_CVAR_PRI(fireball, bfgradius)); e; e = e.chain)
  87                 if(e != this.realowner) if(e.takedamage == DAMAGE_AIM) if(!IS_PLAYER(e) || !this.realowner || DIFF_TEAM(e, this))
  88                 {
  89                         // can we see fireball?
  90                         traceline(e.origin + e.view_ofs, this.origin, MOVE_NORMAL, e);
  91                         if(/* trace_startsolid || */ trace_fraction != 1) // startsolid should be never happening anyway
  92                                 continue;
  93                         // can we see player who shot fireball?
  94                         traceline(e.origin + e.view_ofs, this.realowner.origin + this.realowner.view_ofs, MOVE_NORMAL, e);
  95                         if(trace_ent != this.realowner)
  96                         if(/* trace_startsolid || */ trace_fraction != 1)
  97                                 continue;
  98                         dist = vlen(this.origin - e.origin - e.view_ofs);
  99                         points = (1 - sqrt(dist / WEP_CVAR_PRI(fireball, bfgradius)));
 100                         if(points <= 0)
 101                                 continue;
 102                         dir = normalize(e.origin + e.view_ofs - this.origin);
 103
 104                         if(accuracy_isgooddamage(this.realowner, e))
 105                                 accuracy_add(this.realowner, WEP_FIREBALL.m_id, 0, WEP_CVAR_PRI(fireball, bfgdamage) * points);
 106
 107                         Damage(e, this, this.realowner, WEP_CVAR_PRI(fireball, bfgdamage) * points, this.projectiledeathtype | HITTYPE_BOUNCE | HITTYPE_SPLASH, e.origin + e.view_ofs, WEP_CVAR_PRI(fireball, bfgforce) * dir);
 108                         Send_Effect(EFFECT_FIREBALL_BFGDAMAGE, e.origin, -1 * dir, 1);
 109                 }
 110         }
 111
 112         remove(this);
 113 }
 114
 115 void W_Fireball_Explode_think(entity this)
 116 {
 117         W_Fireball_Explode(this, NULL);
 118 }
 119
 120 void W_Fireball_Explode_use(entity this, entity actor, entity trigger)
 121 {
 122         W_Fireball_Explode(this, trigger);
 123 }
 124
 125 void W_Fireball_TouchExplode(entity this, entity toucher)
 126 {
 127         PROJECTILE_TOUCH(this, toucher);
 128         W_Fireball_Explode(this, toucher);
 129 }
 130
 131 void W_Fireball_LaserPlay(entity this, float dt, float dist, float damage, float edgedamage, float burntime)
 132 {
 133         entity e;
 134         float d;
 135         vector p;
 136
 137         if(damage <= 0)
 138                 return;
 139
 140         RandomSelection_Init();
 141         for(e = WarpZone_FindRadius(this.origin, dist, true); e; e = e.chain)
 142         if(e != this.realowner) if(e.takedamage == DAMAGE_AIM) if(!IS_PLAYER(e) || !this.realowner || DIFF_TEAM(e, this))
 143         {
 144                 p = e.origin;
 145                 p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
 146                 p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
 147                 p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
 148                 d = vlen(WarpZone_UnTransformOrigin(e, this.origin) - p);
 149                 if(d < dist)
 150                 {
 151                         e.fireball_impactvec = p;
 152                         RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
 153                 }
 154         }
 155         if(RandomSelection_chosen_ent)
 156         {
 157                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, this.origin) - RandomSelection_chosen_ent.fireball_impactvec);
 158                 d = damage + (edgedamage - damage) * (d / dist);
 159                 Fire_AddDamage(RandomSelection_chosen_ent, this.realowner, d * burntime, burntime, this.projectiledeathtype | HITTYPE_BOUNCE);
 160                 //trailparticles(this, particleeffectnum(EFFECT_FIREBALL_LASER), this.origin, RandomSelection_chosen_ent.fireball_impactvec);
 161                 Send_Effect(EFFECT_FIREBALL_LASER, this.origin, RandomSelection_chosen_ent.fireball_impactvec - this.origin, 1);
 162         }
 163 }
 164
 165 void W_Fireball_Think(entity this)
 166 {
 167         if(time > this.pushltime)
 168         {
 169                 this.cnt = 1;
 170                 this.projectiledeathtype |= HITTYPE_SPLASH;
 171                 W_Fireball_Explode(this, NULL);
 172                 return;
 173         }
 174
 175         W_Fireball_LaserPlay(this, 0.1, WEP_CVAR_PRI(fireball, laserradius), WEP_CVAR_PRI(fireball, laserdamage), WEP_CVAR_PRI(fireball, laseredgedamage), WEP_CVAR_PRI(fireball, laserburntime));
 176
 177         this.nextthink = time + 0.1;
 178 }
 179
 180 void W_Fireball_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 181 {
 182         if(this.health <= 0)
 183                 return;
 184
 185         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 186                 return; // g_projectiles_damage says to halt
 187
 188         this.health = this.health - damage;
 189         if(this.health <= 0)
 190         {
 191                 this.cnt = 1;
 192                 W_PrepareExplosionByDamage(this, attacker, W_Fireball_Explode_think);
 193         }
 194 }
 195
 196 void W_Fireball_Attack1(entity actor)
 197 {
 198         entity proj;
 199
 200         W_SetupShot_ProjectileSize(actor, '-16 -16 -16', '16 16 16', false, 2, SND_FIREBALL_FIRE2, CH_WEAPON_A, WEP_CVAR_PRI(fireball, damage) + WEP_CVAR_PRI(fireball, bfgdamage));
 201
 202         Send_Effect(EFFECT_FIREBALL_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 203
 204         proj = new(plasma_prim);
 205         proj.owner = proj.realowner = actor;
 206         proj.bot_dodge = true;
 207         proj.bot_dodgerating = WEP_CVAR_PRI(fireball, damage);
 208         proj.pushltime = time + WEP_CVAR_PRI(fireball, lifetime);
 209         proj.use = W_Fireball_Explode_use;
 210         setthink(proj, W_Fireball_Think);
 211         proj.nextthink = time;
 212         proj.health = WEP_CVAR_PRI(fireball, health);
 213         proj.team = actor.team;
 214         proj.event_damage = W_Fireball_Damage;
 215         proj.takedamage = DAMAGE_YES;
 216         proj.damageforcescale = WEP_CVAR_PRI(fireball, damageforcescale);
 217         PROJECTILE_MAKETRIGGER(proj);
 218         proj.projectiledeathtype = WEP_FIREBALL.m_id;
 219         setorigin(proj, w_shotorg);
 220
 221         proj.movetype = MOVETYPE_FLY;
 222         W_SetupProjVelocity_PRI(proj, fireball);
 223         proj.angles = vectoangles(proj.velocity);
 224         settouch(proj, W_Fireball_TouchExplode);
 225         setsize(proj, '-16 -16 -16', '16 16 16');
 226         proj.flags = FL_PROJECTILE;
 227     proj.missile_flags = MIF_SPLASH | MIF_PROXY;
 228
 229         CSQCProjectile(proj, true, PROJECTILE_FIREBALL, true);
 230
 231         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 232 }
 233
 234 void W_Fireball_AttackEffect(entity actor, float i, vector f_diff)
 235 {
 236         W_SetupShot_ProjectileSize(actor, '-16 -16 -16', '16 16 16', false, 0, SND_Null, 0, 0);
 237         w_shotorg += f_diff.x * v_up + f_diff.y * v_right;
 238         Send_Effect(EFFECT_FIREBALL_PRE_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 239 }
 240
 241 void W_Fireball_Attack1_Frame4(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 242 {
 243         W_Fireball_Attack1(actor);
 244         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(fireball, animtime), w_ready);
 245 }
 246
 247 void W_Fireball_Attack1_Frame3(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 248 {
 249         W_Fireball_AttackEffect(actor, 0, '+1.25 +3.75 0');
 250         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(fireball, animtime), W_Fireball_Attack1_Frame4);
 251 }
 252
 253 void W_Fireball_Attack1_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 254 {
 255         W_Fireball_AttackEffect(actor, 0, '-1.25 +3.75 0');
 256         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(fireball, animtime), W_Fireball_Attack1_Frame3);
 257 }
 258
 259 void W_Fireball_Attack1_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 260 {
 261         W_Fireball_AttackEffect(actor, 1, '+1.25 -3.75 0');
 262         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(fireball, animtime), W_Fireball_Attack1_Frame2);
 263 }
 264
 265 void W_Fireball_Attack1_Frame0(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 266 {
 267         W_Fireball_AttackEffect(actor, 0, '-1.25 -3.75 0');
 268         sound(actor, CH_WEAPON_SINGLE, SND_FIREBALL_PREFIRE2, VOL_BASE, ATTEN_NORM);
 269         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(fireball, animtime), W_Fireball_Attack1_Frame1);
 270 }
 271
 272 void W_Fireball_Firemine_Think(entity this)
 273 {
 274         if(time > this.pushltime)
 275         {
 276                 remove(this);
 277                 return;
 278         }
 279
 280         // make it "hot" once it leaves its owner
 281         if(this.owner)
 282         {
 283                 if(vdist(this.origin - this.owner.origin - this.owner.view_ofs, >, WEP_CVAR_SEC(fireball, laserradius)))
 284                 {
 285                         this.cnt += 1;
 286                         if(this.cnt == 3)
 287                                 this.owner = NULL;
 288                 }
 289                 else
 290                         this.cnt = 0;
 291         }
 292
 293         W_Fireball_LaserPlay(this, 0.1, WEP_CVAR_SEC(fireball, laserradius), WEP_CVAR_SEC(fireball, laserdamage), WEP_CVAR_SEC(fireball, laseredgedamage), WEP_CVAR_SEC(fireball, laserburntime));
 294
 295         this.nextthink = time + 0.1;
 296 }
 297
 298 void W_Fireball_Firemine_Touch(entity this, entity toucher)
 299 {
 300         PROJECTILE_TOUCH(this, toucher);
 301         if(toucher.takedamage == DAMAGE_AIM)
 302         if(Fire_AddDamage(toucher, this.realowner, WEP_CVAR_SEC(fireball, damage), WEP_CVAR_SEC(fireball, damagetime), this.projectiledeathtype) >= 0)
 303         {
 304                 remove(this);
 305                 return;
 306         }
 307         this.projectiledeathtype |= HITTYPE_BOUNCE;
 308 }
 309
 310 void W_Fireball_Attack2(entity actor)
 311 {
 312         entity proj;
 313         vector f_diff;
 314         float c;
 315
 316         c = actor.bulletcounter % 4;
 317         switch(c)
 318         {
 319                 case 0:
 320                         f_diff = '-1.25 -3.75 0';
 321                         break;
 322                 case 1:
 323                         f_diff = '+1.25 -3.75 0';
 324                         break;
 325                 case 2:
 326                         f_diff = '-1.25 +3.75 0';
 327                         break;
 328                 case 3:
 329                 default:
 330                         f_diff = '+1.25 +3.75 0';
 331                         break;
 332         }
 333         W_SetupShot_ProjectileSize(actor, '-4 -4 -4', '4 4 4', false, 2, SND_FIREBALL_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(fireball, damage));
 334         traceline(w_shotorg, w_shotorg + f_diff_x * v_up + f_diff_y * v_right, MOVE_NORMAL, actor);
 335         w_shotorg = trace_endpos;
 336
 337         Send_Effect(EFFECT_FIREBALL_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 338
 339         proj = new(grenade);
 340         proj.owner = proj.realowner = actor;
 341         proj.bot_dodge = true;
 342         proj.bot_dodgerating = WEP_CVAR_SEC(fireball, damage);
 343         proj.movetype = MOVETYPE_BOUNCE;
 344         proj.projectiledeathtype = WEP_FIREBALL.m_id | HITTYPE_SECONDARY;
 345         settouch(proj, W_Fireball_Firemine_Touch);
 346         PROJECTILE_MAKETRIGGER(proj);
 347         setsize(proj, '-4 -4 -4', '4 4 4');
 348         setorigin(proj, w_shotorg);
 349         setthink(proj, W_Fireball_Firemine_Think);
 350         proj.nextthink = time;
 351         proj.damageforcescale = WEP_CVAR_SEC(fireball, damageforcescale);
 352         proj.pushltime = time + WEP_CVAR_SEC(fireball, lifetime);
 353         W_SetupProjVelocity_UP_SEC(proj, fireball);
 354
 355         proj.angles = vectoangles(proj.velocity);
 356         proj.flags = FL_PROJECTILE;
 357     proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 358
 359         CSQCProjectile(proj, true, PROJECTILE_FIREMINE, true);
 360
 361         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 362 }
 363
 364 METHOD(Fireball, wr_aim, void(entity thiswep, entity actor))
 365 {
 366     PHYS_INPUT_BUTTON_ATCK(actor) = false;
 367     PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 368     if(actor.bot_primary_fireballmooth == 0)
 369     {
 370         if(bot_aim(actor, WEP_CVAR_PRI(fireball, speed), 0, WEP_CVAR_PRI(fireball, lifetime), false))
 371         {
 372             PHYS_INPUT_BUTTON_ATCK(actor) = true;
 373             if(random() < 0.02) actor.bot_primary_fireballmooth = 0;
 374         }
 375     }
 376     else
 377     {
 378         if(bot_aim(actor, WEP_CVAR_SEC(fireball, speed), WEP_CVAR_SEC(fireball, speed_up), WEP_CVAR_SEC(fireball, lifetime), true))
 379         {
 380             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 381             if(random() < 0.01) actor.bot_primary_fireballmooth = 1;
 382         }
 383     }
 384 }
 385 METHOD(Fireball, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 386 {
 387     if(fire & 1)
 388     {
 389         if(time >= actor.fireball_primarytime)
 390         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(fireball, refire)))
 391         {
 392             W_Fireball_Attack1_Frame0(thiswep, actor, weaponentity, fire);
 393             actor.fireball_primarytime = time + WEP_CVAR_PRI(fireball, refire2) * W_WeaponRateFactor(actor);
 394         }
 395     }
 396     else if(fire & 2)
 397     {
 398         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(fireball, refire)))
 399         {
 400             W_Fireball_Attack2(actor);
 401             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(fireball, animtime), w_ready);
 402         }
 403     }
 404 }
 405 METHOD(Fireball, wr_setup, void(entity thiswep, entity actor))
 406 {
 407     actor.ammo_field = ammo_none;
 408 }
 409 METHOD(Fireball, wr_checkammo1, bool(entity thiswep, entity actor))
 410 {
 411     return true; // infinite ammo
 412 }
 413 METHOD(Fireball, wr_checkammo2, bool(entity thiswep, entity actor))
 414 {
 415     return true; // fireball has infinite ammo
 416 }
 417 METHOD(Fireball, wr_resetplayer, void(entity thiswep, entity actor))
 418 {
 419     actor.fireball_primarytime = time;
 420 }
 421 METHOD(Fireball, wr_suicidemessage, Notification(entity thiswep))
 422 {
 423     if(w_deathtype & HITTYPE_SECONDARY)
 424         return WEAPON_FIREBALL_SUICIDE_FIREMINE;
 425     else
 426         return WEAPON_FIREBALL_SUICIDE_BLAST;
 427 }
 428 METHOD(Fireball, wr_killmessage, Notification(entity thiswep))
 429 {
 430     if(w_deathtype & HITTYPE_SECONDARY)
 431         return WEAPON_FIREBALL_MURDER_FIREMINE;
 432     else
 433         return WEAPON_FIREBALL_MURDER_BLAST;
 434 }
 435
 436 #endif
 437 #ifdef CSQC
 438
 439 METHOD(Fireball, wr_impacteffect, void(entity thiswep, entity actor))
 440 {
 441     vector org2;
 442     if(w_deathtype & HITTYPE_SECONDARY)
 443     {
 444         // firemine goes out silently
 445     }
 446     else
 447     {
 448         org2 = w_org + w_backoff * 16;
 449         pointparticles(EFFECT_FIREBALL_EXPLODE, org2, '0 0 0', 1);
 450         if(!w_issilent)
 451             sound(actor, CH_SHOTS, SND_FIREBALL_IMPACT2, VOL_BASE, ATTEN_NORM * 0.25); // long range boom
 452     }
 453 }
 454
 455 #endif
 456 #endif