de468896f1bf26b4500871c02a06fa0f5f4141de
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / fireball.qc
1 #ifndef IMPLEMENTATION
2 CLASS(Fireball, Weapon)
3 /* ammotype  */ //ATTRIB(Fireball, ammo_field, .int, ammo_none)
4 /* impulse   */ ATTRIB(Fireball, impulse, int, 9)
5 /* flags     */ ATTRIB(Fireball, spawnflags, int, WEP_FLAG_SUPERWEAPON | WEP_TYPE_SPLASH);
6 /* rating    */ ATTRIB(Fireball, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
7 /* color     */ ATTRIB(Fireball, wpcolor, vector, '1 0.5 0');
8 /* modelname */ ATTRIB(Fireball, mdl, string, "fireball");
9 #ifndef MENUQC
10 /* model     */ ATTRIB(Fireball, m_model, Model, MDL_FIREBALL_ITEM);
11 #endif
12 /* crosshair */ ATTRIB(Fireball, w_crosshair, string, "gfx/crosshairfireball");
13 /* crosshair */ //ATTRIB(Fireball, w_crosshair_size, float, 0.65);
14 /* wepimg    */ ATTRIB(Fireball, model2, string, "weaponfireball");
15 /* refname   */ ATTRIB(Fireball, netname, string, "fireball");
16 /* wepname   */ ATTRIB(Fireball, m_name, string, _("Fireball"));
17
18 #define X(BEGIN, P, END, class, prefix) \
19         BEGIN(class) \
20                 P(class, prefix, animtime, float, BOTH) \
21                 P(class, prefix, bfgdamage, float, PRI) \
22                 P(class, prefix, bfgforce, float, PRI) \
23                 P(class, prefix, bfgradius, float, PRI) \
24                 P(class, prefix, damageforcescale, float, BOTH) \
25                 P(class, prefix, damagetime, float, SEC) \
26                 P(class, prefix, damage, float, BOTH) \
27                 P(class, prefix, edgedamage, float, PRI) \
28                 P(class, prefix, force, float, PRI) \
29                 P(class, prefix, health, float, PRI) \
30                 P(class, prefix, laserburntime, float, BOTH) \
31                 P(class, prefix, laserdamage, float, BOTH) \
32                 P(class, prefix, laseredgedamage, float, BOTH) \
33                 P(class, prefix, laserradius, float, BOTH) \
34                 P(class, prefix, lifetime, float, BOTH) \
35                 P(class, prefix, radius, float, PRI) \
36                 P(class, prefix, refire2, float, PRI) \
37                 P(class, prefix, refire, float, BOTH) \
38                 P(class, prefix, speed, float, BOTH) \
39                 P(class, prefix, speed_up, float, SEC) \
40                 P(class, prefix, speed_z, float, SEC) \
41                 P(class, prefix, spread, float, BOTH) \
42                 P(class, prefix, switchdelay_drop, float, NONE) \
43                 P(class, prefix, switchdelay_raise, float, NONE) \
44                 P(class, prefix, weaponreplace, string,NONE) \
45                 P(class, prefix, weaponstartoverride, float, NONE) \
46                 P(class, prefix, weaponstart, float, NONE) \
47                 P(class, prefix, weaponthrowable, float, NONE) \
48         END()
49         W_PROPS(X, Fireball, fireball)
50 #undef X
51
52 ENDCLASS(Fireball)
53 REGISTER_WEAPON(FIREBALL, fireball, NEW(Fireball));
54
55 #ifdef SVQC
56 .float bot_primary_fireballmooth; // whatever a mooth is
57 .vector fireball_impactvec;
58 .float fireball_primarytime;
59 #endif
60 #endif
61 #ifdef IMPLEMENTATION
62 #ifdef SVQC
63 spawnfunc(weapon_fireball) { weapon_defaultspawnfunc(this, WEP_FIREBALL); }
64
65 void W_Fireball_Explode()
66 {SELFPARAM();
67         entity e;
68         float dist;
69         float points;
70         vector dir;
71         float d;
72
73         self.event_damage = func_null;
74         self.takedamage = DAMAGE_NO;
75
76         // 1. dist damage
77         d = (self.realowner.health + self.realowner.armorvalue);
78         RadiusDamage(self, self.realowner, WEP_CVAR_PRI(fireball, damage), WEP_CVAR_PRI(fireball, edgedamage), WEP_CVAR_PRI(fireball, radius), world, world, WEP_CVAR_PRI(fireball, force), self.projectiledeathtype, other);
79         if(self.realowner.health + self.realowner.armorvalue >= d)
80         if(!self.cnt)
81         {
82                 modeleffect_spawn("models/sphere/sphere.md3", 0, 0, self.origin, '0 0 0', '0 0 0', '0 0 0', 0, WEP_CVAR_PRI(fireball, bfgradius), 0.2, 0.05, 0.25);
83
84                 // 2. bfg effect
85                 // NOTE: this cannot be made warpzone aware by design. So, better intentionally ignore warpzones here.
86                 for(e = findradius(self.origin, WEP_CVAR_PRI(fireball, bfgradius)); e; e = e.chain)
87                 if(e != self.realowner) if(e.takedamage == DAMAGE_AIM) if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
88                 {
89                         // can we see fireball?
90                         traceline(e.origin + e.view_ofs, self.origin, MOVE_NORMAL, e);
91                         if(/* trace_startsolid || */ trace_fraction != 1) // startsolid should be never happening anyway
92                                 continue;
93                         // can we see player who shot fireball?
94                         traceline(e.origin + e.view_ofs, self.realowner.origin + self.realowner.view_ofs, MOVE_NORMAL, e);
95                         if(trace_ent != self.realowner)
96                         if(/* trace_startsolid || */ trace_fraction != 1)
97                                 continue;
98                         dist = vlen(self.origin - e.origin - e.view_ofs);
99                         points = (1 - sqrt(dist / WEP_CVAR_PRI(fireball, bfgradius)));
100                         if(points <= 0)
101                                 continue;
102                         dir = normalize(e.origin + e.view_ofs - self.origin);
103
104                         if(accuracy_isgooddamage(self.realowner, e))
105                                 accuracy_add(self.realowner, WEP_FIREBALL.m_id, 0, WEP_CVAR_PRI(fireball, bfgdamage) * points);
106
107                         Damage(e, self, self.realowner, WEP_CVAR_PRI(fireball, bfgdamage) * points, self.projectiledeathtype | HITTYPE_BOUNCE | HITTYPE_SPLASH, e.origin + e.view_ofs, WEP_CVAR_PRI(fireball, bfgforce) * dir);
108                         Send_Effect(EFFECT_FIREBALL_BFGDAMAGE, e.origin, -1 * dir, 1);
109                 }
110         }
111
112         remove(self);
113 }
114
115 void W_Fireball_Explode_use(entity this, entity actor, entity trigger)
116 {
117         WITHSELF(this, W_Fireball_Explode());
118 }
119
120 void W_Fireball_TouchExplode()
121 {
122         PROJECTILE_TOUCH;
123         W_Fireball_Explode();
124 }
125
126 void W_Fireball_LaserPlay(float dt, float dist, float damage, float edgedamage, float burntime)
127 {SELFPARAM();
128         entity e;
129         float d;
130         vector p;
131
132         if(damage <= 0)
133                 return;
134
135         RandomSelection_Init();
136         for(e = WarpZone_FindRadius(self.origin, dist, true); e; e = e.chain)
137         if(e != self.realowner) if(e.takedamage == DAMAGE_AIM) if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
138         {
139                 p = e.origin;
140                 p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
141                 p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
142                 p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
143                 d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
144                 if(d < dist)
145                 {
146                         e.fireball_impactvec = p;
147                         RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
148                 }
149         }
150         if(RandomSelection_chosen_ent)
151         {
152                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
153                 d = damage + (edgedamage - damage) * (d / dist);
154                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
155                 //trailparticles(self, particleeffectnum(EFFECT_FIREBALL_LASER), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
156                 Send_Effect(EFFECT_FIREBALL_LASER, self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
157         }
158 }
159
160 void W_Fireball_Think()
161 {SELFPARAM();
162         if(time > self.pushltime)
163         {
164                 self.cnt = 1;
165                 self.projectiledeathtype |= HITTYPE_SPLASH;
166                 W_Fireball_Explode();
167                 return;
168         }
169
170         W_Fireball_LaserPlay(0.1, WEP_CVAR_PRI(fireball, laserradius), WEP_CVAR_PRI(fireball, laserdamage), WEP_CVAR_PRI(fireball, laseredgedamage), WEP_CVAR_PRI(fireball, laserburntime));
171
172         self.nextthink = time + 0.1;
173 }
174
175 void W_Fireball_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
176 {
177         if(this.health <= 0)
178                 return;
179
180         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
181                 return; // g_projectiles_damage says to halt
182
183         this.health = this.health - damage;
184         if(this.health <= 0)
185         {
186                 this.cnt = 1;
187                 W_PrepareExplosionByDamage(this, attacker, W_Fireball_Explode);
188         }
189 }
190
191 void W_Fireball_Attack1()
192 {SELFPARAM();
193         entity proj;
194
195         W_SetupShot_ProjectileSize(self, '-16 -16 -16', '16 16 16', false, 2, SND_FIREBALL_FIRE2, CH_WEAPON_A, WEP_CVAR_PRI(fireball, damage) + WEP_CVAR_PRI(fireball, bfgdamage));
196
197         Send_Effect(EFFECT_FIREBALL_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
198
199         proj = new(plasma_prim);
200         proj.owner = proj.realowner = self;
201         proj.bot_dodge = true;
202         proj.bot_dodgerating = WEP_CVAR_PRI(fireball, damage);
203         proj.pushltime = time + WEP_CVAR_PRI(fireball, lifetime);
204         proj.use = W_Fireball_Explode_use;
205         setthink(proj, W_Fireball_Think);
206         proj.nextthink = time;
207         proj.health = WEP_CVAR_PRI(fireball, health);
208         proj.team = self.team;
209         proj.event_damage = W_Fireball_Damage;
210         proj.takedamage = DAMAGE_YES;
211         proj.damageforcescale = WEP_CVAR_PRI(fireball, damageforcescale);
212         PROJECTILE_MAKETRIGGER(proj);
213         proj.projectiledeathtype = WEP_FIREBALL.m_id;
214         setorigin(proj, w_shotorg);
215
216         proj.movetype = MOVETYPE_FLY;
217         W_SetupProjVelocity_PRI(proj, fireball);
218         proj.angles = vectoangles(proj.velocity);
219         settouch(proj, W_Fireball_TouchExplode);
220         setsize(proj, '-16 -16 -16', '16 16 16');
221         proj.flags = FL_PROJECTILE;
222     proj.missile_flags = MIF_SPLASH | MIF_PROXY;
223
224         CSQCProjectile(proj, true, PROJECTILE_FIREBALL, true);
225
226         MUTATOR_CALLHOOK(EditProjectile, self, proj);
227 }
228
229 void W_Fireball_AttackEffect(float i, vector f_diff)
230 {SELFPARAM();
231         W_SetupShot_ProjectileSize(self, '-16 -16 -16', '16 16 16', false, 0, SND_Null, 0, 0);
232         w_shotorg += f_diff.x * v_up + f_diff.y * v_right;
233         Send_Effect(EFFECT_FIREBALL_PRE_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
234 }
235
236 void W_Fireball_Attack1_Frame4(Weapon thiswep, entity actor, .entity weaponentity, int fire)
237 {
238         W_Fireball_Attack1();
239         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(fireball, animtime), w_ready);
240 }
241
242 void W_Fireball_Attack1_Frame3(Weapon thiswep, entity actor, .entity weaponentity, int fire)
243 {
244         W_Fireball_AttackEffect(0, '+1.25 +3.75 0');
245         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(fireball, animtime), W_Fireball_Attack1_Frame4);
246 }
247
248 void W_Fireball_Attack1_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
249 {
250         W_Fireball_AttackEffect(0, '-1.25 +3.75 0');
251         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(fireball, animtime), W_Fireball_Attack1_Frame3);
252 }
253
254 void W_Fireball_Attack1_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
255 {
256         W_Fireball_AttackEffect(1, '+1.25 -3.75 0');
257         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(fireball, animtime), W_Fireball_Attack1_Frame2);
258 }
259
260 void W_Fireball_Attack1_Frame0(Weapon thiswep, entity actor, .entity weaponentity, int fire)
261 {SELFPARAM();
262         W_Fireball_AttackEffect(0, '-1.25 -3.75 0');
263         sound(self, CH_WEAPON_SINGLE, SND_FIREBALL_PREFIRE2, VOL_BASE, ATTEN_NORM);
264         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(fireball, animtime), W_Fireball_Attack1_Frame1);
265 }
266
267 void W_Fireball_Firemine_Think()
268 {SELFPARAM();
269         if(time > self.pushltime)
270         {
271                 remove(self);
272                 return;
273         }
274
275         // make it "hot" once it leaves its owner
276         if(self.owner)
277         {
278                 if(vdist(self.origin - self.owner.origin - self.owner.view_ofs, >, WEP_CVAR_SEC(fireball, laserradius)))
279                 {
280                         self.cnt += 1;
281                         if(self.cnt == 3)
282                                 self.owner = world;
283                 }
284                 else
285                         self.cnt = 0;
286         }
287
288         W_Fireball_LaserPlay(0.1, WEP_CVAR_SEC(fireball, laserradius), WEP_CVAR_SEC(fireball, laserdamage), WEP_CVAR_SEC(fireball, laseredgedamage), WEP_CVAR_SEC(fireball, laserburntime));
289
290         self.nextthink = time + 0.1;
291 }
292
293 void W_Fireball_Firemine_Touch()
294 {SELFPARAM();
295         PROJECTILE_TOUCH;
296         if(other.takedamage == DAMAGE_AIM)
297         if(Fire_AddDamage(other, self.realowner, WEP_CVAR_SEC(fireball, damage), WEP_CVAR_SEC(fireball, damagetime), self.projectiledeathtype) >= 0)
298         {
299                 remove(self);
300                 return;
301         }
302         self.projectiledeathtype |= HITTYPE_BOUNCE;
303 }
304
305 void W_Fireball_Attack2()
306 {SELFPARAM();
307         entity proj;
308         vector f_diff;
309         float c;
310
311         c = self.bulletcounter % 4;
312         switch(c)
313         {
314                 case 0:
315                         f_diff = '-1.25 -3.75 0';
316                         break;
317                 case 1:
318                         f_diff = '+1.25 -3.75 0';
319                         break;
320                 case 2:
321                         f_diff = '-1.25 +3.75 0';
322                         break;
323                 case 3:
324                 default:
325                         f_diff = '+1.25 +3.75 0';
326                         break;
327         }
328         W_SetupShot_ProjectileSize(self, '-4 -4 -4', '4 4 4', false, 2, SND_FIREBALL_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(fireball, damage));
329         traceline(w_shotorg, w_shotorg + f_diff_x * v_up + f_diff_y * v_right, MOVE_NORMAL, self);
330         w_shotorg = trace_endpos;
331
332         Send_Effect(EFFECT_FIREBALL_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
333
334         proj = new(grenade);
335         proj.owner = proj.realowner = self;
336         proj.bot_dodge = true;
337         proj.bot_dodgerating = WEP_CVAR_SEC(fireball, damage);
338         proj.movetype = MOVETYPE_BOUNCE;
339         proj.projectiledeathtype = WEP_FIREBALL.m_id | HITTYPE_SECONDARY;
340         settouch(proj, W_Fireball_Firemine_Touch);
341         PROJECTILE_MAKETRIGGER(proj);
342         setsize(proj, '-4 -4 -4', '4 4 4');
343         setorigin(proj, w_shotorg);
344         setthink(proj, W_Fireball_Firemine_Think);
345         proj.nextthink = time;
346         proj.damageforcescale = WEP_CVAR_SEC(fireball, damageforcescale);
347         proj.pushltime = time + WEP_CVAR_SEC(fireball, lifetime);
348         W_SetupProjVelocity_UP_SEC(proj, fireball);
349
350         proj.angles = vectoangles(proj.velocity);
351         proj.flags = FL_PROJECTILE;
352     proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
353
354         CSQCProjectile(proj, true, PROJECTILE_FIREMINE, true);
355
356         MUTATOR_CALLHOOK(EditProjectile, self, proj);
357 }
358
359 METHOD(Fireball, wr_aim, void(entity thiswep))
360 {
361     SELFPARAM();
362     PHYS_INPUT_BUTTON_ATCK(self) = false;
363     PHYS_INPUT_BUTTON_ATCK2(self) = false;
364     if(self.bot_primary_fireballmooth == 0)
365     {
366         if(bot_aim(self, WEP_CVAR_PRI(fireball, speed), 0, WEP_CVAR_PRI(fireball, lifetime), false))
367         {
368             PHYS_INPUT_BUTTON_ATCK(self) = true;
369             if(random() < 0.02) self.bot_primary_fireballmooth = 0;
370         }
371     }
372     else
373     {
374         if(bot_aim(self, WEP_CVAR_SEC(fireball, speed), WEP_CVAR_SEC(fireball, speed_up), WEP_CVAR_SEC(fireball, lifetime), true))
375         {
376             PHYS_INPUT_BUTTON_ATCK2(self) = true;
377             if(random() < 0.01) self.bot_primary_fireballmooth = 1;
378         }
379     }
380 }
381 METHOD(Fireball, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
382 {
383     if(fire & 1)
384     {
385         if(time >= actor.fireball_primarytime)
386         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(fireball, refire)))
387         {
388             W_Fireball_Attack1_Frame0(thiswep, actor, weaponentity, fire);
389             actor.fireball_primarytime = time + WEP_CVAR_PRI(fireball, refire2) * W_WeaponRateFactor();
390         }
391     }
392     else if(fire & 2)
393     {
394         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(fireball, refire)))
395         {
396             W_Fireball_Attack2();
397             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(fireball, animtime), w_ready);
398         }
399     }
400 }
401 METHOD(Fireball, wr_setup, void(entity thiswep))
402 {
403     SELFPARAM();
404     self.ammo_field = ammo_none;
405 }
406 METHOD(Fireball, wr_checkammo1, bool(entity thiswep, entity actor))
407 {
408     return true; // infinite ammo
409 }
410 METHOD(Fireball, wr_checkammo2, bool(entity thiswep, entity actor))
411 {
412     return true; // fireball has infinite ammo
413 }
414 METHOD(Fireball, wr_resetplayer, void(entity thiswep))
415 {
416     SELFPARAM();
417     self.fireball_primarytime = time;
418 }
419 METHOD(Fireball, wr_suicidemessage, Notification(entity thiswep))
420 {
421     if(w_deathtype & HITTYPE_SECONDARY)
422         return WEAPON_FIREBALL_SUICIDE_FIREMINE;
423     else
424         return WEAPON_FIREBALL_SUICIDE_BLAST;
425 }
426 METHOD(Fireball, wr_killmessage, Notification(entity thiswep))
427 {
428     if(w_deathtype & HITTYPE_SECONDARY)
429         return WEAPON_FIREBALL_MURDER_FIREMINE;
430     else
431         return WEAPON_FIREBALL_MURDER_BLAST;
432 }
433
434 #endif
435 #ifdef CSQC
436
437 METHOD(Fireball, wr_impacteffect, void(entity thiswep))
438 {
439     SELFPARAM();
440     vector org2;
441     if(w_deathtype & HITTYPE_SECONDARY)
442     {
443         // firemine goes out silently
444     }
445     else
446     {
447         org2 = w_org + w_backoff * 16;
448         pointparticles(EFFECT_FIREBALL_EXPLODE, org2, '0 0 0', 1);
449         if(!w_issilent)
450             sound(self, CH_SHOTS, SND_FIREBALL_IMPACT2, VOL_BASE, ATTEN_NORM * 0.25); // long range boom
451     }
452 }
453
454 #endif
455 #endif