qcsrc/common/weapons/weapon/hmg.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id      */ HMG,
   4 /* function      */ W_HeavyMachineGun,
   5 /* ammotype      */ ammo_nails,
   6 /* impulse       */ 3,
   7 /* flags         */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN | WEP_FLAG_SUPERWEAPON,
   8 /* rating        */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '0.5 0.5 0',
  10 /* modelname */ "ok_hmg",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairuzi 0.6",
  13 /* wepimg    */ "weaponhmg",
  14 /* refname   */ "hmg",
  15 /* wepname   */ _("Heavy Machine Gun")
  16 );
  17
  18 #define HMG_SETTINGS(w_cvar,w_prop) HMG_SETTINGS_LIST(w_cvar, w_prop, HMG, hmg)
  19 #define HMG_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, spread_min) \
  21         w_cvar(id, sn, NONE, spread_max) \
  22         w_cvar(id, sn, NONE, spread_add) \
  23         w_cvar(id, sn, NONE, solidpenetration) \
  24         w_cvar(id, sn, NONE, damage) \
  25         w_cvar(id, sn, NONE, force) \
  26         w_cvar(id, sn, NONE, refire) \
  27         w_cvar(id, sn, NONE, ammo) \
  28         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  29         w_prop(id, sn, float,  reloading_time, reload_time) \
  30         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  31         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  32         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  33         w_prop(id, sn, float,  weaponstart, weaponstart) \
  34         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  35         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  36
  37 #ifdef SVQC
  38 HMG_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  39 #endif
  40 #endif
  41 #ifdef IMPLEMENTATION
  42 #ifdef SVQC
  43
  44 spawnfunc(weapon_hmg) { weapon_defaultspawnfunc(WEP_HMG.m_id); }
  45
  46 void W_HeavyMachineGun_Attack_Auto()
  47 {SELFPARAM();
  48         if (!self.BUTTON_ATCK)
  49         {
  50                 w_ready();
  51                 return;
  52         }
  53
  54         if(!WEP_ACTION(self.weapon, WR_CHECKAMMO1))
  55         if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
  56         {
  57                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
  58                 w_ready();
  59                 return;
  60         }
  61
  62         W_DecreaseAmmo(WEP_CVAR(hmg, ammo));
  63
  64         W_SetupShot (self, true, 0, W_Sound("uzi_fire"), CH_WEAPON_A, WEP_CVAR(hmg, damage));
  65
  66         if(!autocvar_g_norecoil)
  67         {
  68                 self.punchangle_x = random () - 0.5;
  69                 self.punchangle_y = random () - 0.5;
  70         }
  71
  72         float hmg_spread = bound(WEP_CVAR(hmg, spread_min), WEP_CVAR(hmg, spread_min) + (WEP_CVAR(hmg, spread_add) * self.misc_bulletcounter), WEP_CVAR(hmg, spread_max));
  73         fireBullet(w_shotorg, w_shotdir, hmg_spread, WEP_CVAR(hmg, solidpenetration), WEP_CVAR(hmg, damage), WEP_CVAR(hmg, force), WEP_HMG.m_id, 0);
  74
  75         self.misc_bulletcounter = self.misc_bulletcounter + 1;
  76
  77         Send_Effect(EFFECT_MACHINEGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
  78
  79         W_MachineGun_MuzzleFlash();
  80         W_AttachToShotorg(self.muzzle_flash, '5 0 0');
  81
  82         if (autocvar_g_casings >= 2) // casing code
  83                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  84
  85         ATTACK_FINISHED(self) = time + WEP_CVAR(hmg, refire) * W_WeaponRateFactor();
  86         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(hmg, refire), W_HeavyMachineGun_Attack_Auto);
  87 }
  88
  89 bool W_HeavyMachineGun(int req)
  90 {SELFPARAM();
  91         float ammo_amount;
  92         switch(req)
  93         {
  94                 case WR_AIM:
  95                 {
  96                         if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
  97                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, false);
  98                         else
  99                                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, false);
 100
 101                         return true;
 102                 }
 103                 case WR_THINK:
 104                 {
 105                         if(WEP_CVAR(hmg, reload_ammo) && self.clip_load < WEP_CVAR(hmg, ammo)) // forced reload
 106                                 WEP_ACTION(self.weapon, WR_RELOAD);
 107                         else
 108                         {
 109                                 if (self.BUTTON_ATCK)
 110                                 if (weapon_prepareattack(0, 0))
 111                                 {
 112                                         self.misc_bulletcounter = 0;
 113                                         W_HeavyMachineGun_Attack_Auto();
 114                                 }
 115                         }
 116
 117                         return true;
 118                 }
 119                 case WR_INIT:
 120                 {
 121                         precache_sound (W_Sound("uzi_fire"));
 122                         HMG_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 123                         return true;
 124                 }
 125                 case WR_CHECKAMMO1:
 126                 {
 127                         ammo_amount = self.ammo_nails >= WEP_CVAR(hmg, ammo);
 128
 129                         if(autocvar_g_balance_hmg_reload_ammo)
 130                                 ammo_amount += self.(weapon_load[WEP_HMG.m_id]) >= WEP_CVAR(hmg, ammo);
 131
 132                         return ammo_amount;
 133                 }
 134                 case WR_CHECKAMMO2:
 135                 {
 136                         ammo_amount = self.ammo_nails >= WEP_CVAR(hmg, ammo);
 137
 138                         if(autocvar_g_balance_hmg_reload_ammo)
 139                                 ammo_amount += self.(weapon_load[WEP_HMG.m_id]) >= WEP_CVAR(hmg, ammo);
 140
 141                         return ammo_amount;
 142                 }
 143                 case WR_CONFIG:
 144                 {
 145                         HMG_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 146                         return true;
 147                 }
 148                 case WR_RELOAD:
 149                 {
 150                         W_Reload(WEP_CVAR(hmg, ammo), W_Sound("reload"));
 151                         return true;
 152                 }
 153                 case WR_SUICIDEMESSAGE:
 154                 {
 155                         return WEAPON_THINKING_WITH_PORTALS;
 156                 }
 157                 case WR_KILLMESSAGE:
 158                 {
 159                         if(w_deathtype & HITTYPE_SECONDARY)
 160                                 return WEAPON_HMG_MURDER_SNIPE;
 161                         else
 162                                 return WEAPON_HMG_MURDER_SPRAY;
 163                 }
 164         }
 165         return false;
 166 }
 167 #endif
 168 #ifdef CSQC
 169 bool W_HeavyMachineGun(int req)
 170 {SELFPARAM();
 171         switch(req)
 172         {
 173                 case WR_IMPACTEFFECT:
 174                 {
 175                         vector org2;
 176                         org2 = w_org + w_backoff * 2;
 177                         pointparticles(particleeffectnum(EFFECT_MACHINEGUN_IMPACT), org2, w_backoff * 1000, 1);
 178                         if(!w_issilent)
 179                                 if(w_random < 0.05)
 180                                         sound(self, CH_SHOTS, W_Sound("ric1"), VOL_BASE, ATTEN_NORM);
 181                                 else if(w_random < 0.1)
 182                                         sound(self, CH_SHOTS, W_Sound("ric2"), VOL_BASE, ATTEN_NORM);
 183                                 else if(w_random < 0.2)
 184                                         sound(self, CH_SHOTS, W_Sound("ric3"), VOL_BASE, ATTEN_NORM);
 185
 186                         return true;
 187                 }
 188                 case WR_INIT:
 189                 {
 190                         precache_sound(W_Sound("ric1"));
 191                         precache_sound(W_Sound("ric2"));
 192                         precache_sound(W_Sound("ric3"));
 193                         return true;
 194                 }
 195                 case WR_ZOOMRETICLE:
 196                 {
 197                         // no weapon specific image for this weapon
 198                         return false;
 199                 }
 200         }
 201         return false;
 202 }
 203 #endif
 204 #endif