qcsrc/common/weapons/weapon/hook.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Hook, Weapon)
   3 /* ammotype  */ ATTRIB(Hook, ammo_field, .int, ammo_fuel)
   4 /* impulse   */ ATTRIB(Hook, impulse, int, 0)
   5 /* flags     */ ATTRIB(Hook, spawnflags, int, WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Hook, bot_pickupbasevalue, float, 0);
   7 /* color     */ ATTRIB(Hook, wpcolor, vector, '0 0.5 0');
   8 /* modelname */ ATTRIB(Hook, mdl, string, "hookgun");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Hook, m_model, Model, MDL_HOOK_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Hook, w_crosshair, string, "gfx/crosshairhook");
  13 /* crosshair */ ATTRIB(Hook, w_crosshair_size, float, 0.5);
  14 /* wepimg    */ ATTRIB(Hook, model2, string, "weaponhook");
  15 /* refname   */ ATTRIB(Hook, netname, string, "hook");
  16 /* wepname   */ ATTRIB(Hook, m_name, string, _("Grappling Hook"));
  17         ATTRIB(Hook, ammo_factor, float, 1)
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21                 P(class, prefix, ammo, float, PRI) \
  22                 P(class, prefix, animtime, float, BOTH) \
  23                 P(class, prefix, damageforcescale, float, SEC) \
  24                 P(class, prefix, damage, float, SEC) \
  25                 P(class, prefix, duration, float, SEC) \
  26                 P(class, prefix, edgedamage, float, SEC) \
  27                 P(class, prefix, force, float, SEC) \
  28                 P(class, prefix, gravity, float, SEC) \
  29                 P(class, prefix, health, float, SEC) \
  30                 P(class, prefix, hooked_ammo, float, PRI) \
  31                 P(class, prefix, hooked_time_free, float, PRI) \
  32                 P(class, prefix, hooked_time_max, float, PRI) \
  33                 P(class, prefix, lifetime, float, SEC) \
  34                 P(class, prefix, power, float, SEC) \
  35                 P(class, prefix, radius, float, SEC) \
  36                 P(class, prefix, refire, float, BOTH) \
  37                 P(class, prefix, speed, float, SEC) \
  38         P(class, prefix, switchdelay_drop, float, NONE) \
  39                 P(class, prefix, switchdelay_raise, float, NONE) \
  40         P(class, prefix, weaponreplace, string, NONE) \
  41         P(class, prefix, weaponstartoverride, float, NONE) \
  42         P(class, prefix, weaponstart, float, NONE) \
  43         P(class, prefix, weaponthrowable, float, NONE) \
  44         END()
  45     W_PROPS(X, Hook, hook)
  46 #undef X
  47
  48 ENDCLASS(Hook)
  49 REGISTER_WEAPON(HOOK, hook, NEW(Hook));
  50
  51 CLASS(OffhandHook, OffhandWeapon)
  52 #ifdef SVQC
  53     METHOD(OffhandHook, offhand_think, void(OffhandHook this, entity actor, bool key_pressed))
  54     {
  55         Weapon wep = WEP_HOOK;
  56         .entity weaponentity = weaponentities[1];
  57         wep.wr_think(wep, actor, weaponentity, key_pressed ? 1 : 0);
  58     }
  59 #endif
  60 ENDCLASS(OffhandHook)
  61 OffhandHook OFFHAND_HOOK; STATIC_INIT(OFFHAND_HOOK) { OFFHAND_HOOK = NEW(OffhandHook); }
  62
  63 #ifdef SVQC
  64
  65 .float dmg;
  66 .float dmg_edge;
  67 .float dmg_radius;
  68 .float dmg_force;
  69 .float dmg_power;
  70 .float dmg_duration;
  71 .float dmg_last;
  72 .float hook_refire;
  73 .float hook_time_hooked;
  74 .float hook_time_fueldecrease;
  75 #endif
  76 #endif
  77 #ifdef IMPLEMENTATION
  78 #ifdef SVQC
  79
  80 spawnfunc(weapon_hook) { weapon_defaultspawnfunc(this, WEP_HOOK); }
  81
  82 void W_Hook_ExplodeThink()
  83 {SELFPARAM();
  84         float dt, dmg_remaining_next, f;
  85
  86         dt = time - self.teleport_time;
  87         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
  88
  89         f = self.dmg_last - dmg_remaining_next;
  90         self.dmg_last = dmg_remaining_next;
  91
  92         RadiusDamage(self, self.realowner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.realowner, world, self.dmg_force * f, self.projectiledeathtype, world);
  93         self.projectiledeathtype |= HITTYPE_BOUNCE;
  94         //RadiusDamage(self, world, self.dmg * f, self.dmg_edge * f, self.dmg_radius, world, world, self.dmg_force * f, self.projectiledeathtype, world);
  95
  96         if(dt < self.dmg_duration)
  97                 self.nextthink = time + 0.05; // soon
  98         else
  99                 remove(self);
 100 }
 101
 102 void W_Hook_Explode2()
 103 {SELFPARAM();
 104         self.event_damage = func_null;
 105         self.touch = func_null;
 106         self.effects |= EF_NODRAW;
 107
 108         self.think = W_Hook_ExplodeThink;
 109         self.nextthink = time;
 110         self.dmg = WEP_CVAR_SEC(hook, damage);
 111         self.dmg_edge = WEP_CVAR_SEC(hook, edgedamage);
 112         self.dmg_radius = WEP_CVAR_SEC(hook, radius);
 113         self.dmg_force = WEP_CVAR_SEC(hook, force);
 114         self.dmg_power = WEP_CVAR_SEC(hook, power);
 115         self.dmg_duration = WEP_CVAR_SEC(hook, duration);
 116         self.teleport_time = time;
 117         self.dmg_last = 1;
 118         self.movetype = MOVETYPE_NONE;
 119 }
 120
 121 void W_Hook_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 122 {
 123         if(this.health <= 0)
 124                 return;
 125
 126         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 127                 return; // g_projectiles_damage says to halt
 128
 129         this.health = this.health - damage;
 130
 131         if(this.health <= 0)
 132                 WITH(entity, self, this, W_PrepareExplosionByDamage(this.realowner, W_Hook_Explode2));
 133 }
 134
 135 void W_Hook_Touch2()
 136 {SELFPARAM();
 137         PROJECTILE_TOUCH;
 138         self.use();
 139 }
 140
 141 void W_Hook_Attack2(Weapon thiswep, entity actor)
 142 {
 143         //W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hook, ammo)); // WEAPONTODO: Figure out how to handle ammo with hook secondary (gravitybomb)
 144         W_SetupShot(actor, false, 4, SND_HOOKBOMB_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(hook, damage));
 145
 146         entity gren = new(hookbomb);
 147         gren.owner = gren.realowner = actor;
 148         gren.bot_dodge = true;
 149         gren.bot_dodgerating = WEP_CVAR_SEC(hook, damage);
 150         gren.movetype = MOVETYPE_TOSS;
 151         PROJECTILE_MAKETRIGGER(gren);
 152         gren.projectiledeathtype = WEP_HOOK.m_id | HITTYPE_SECONDARY;
 153         setorigin(gren, w_shotorg);
 154         setsize(gren, '0 0 0', '0 0 0');
 155
 156         gren.nextthink = time + WEP_CVAR_SEC(hook, lifetime);
 157         gren.think = adaptor_think2use_hittype_splash;
 158         gren.use = W_Hook_Explode2;
 159         gren.touch = W_Hook_Touch2;
 160
 161         gren.takedamage = DAMAGE_YES;
 162         gren.health = WEP_CVAR_SEC(hook, health);
 163         gren.damageforcescale = WEP_CVAR_SEC(hook, damageforcescale);
 164         gren.event_damage = W_Hook_Damage;
 165         gren.damagedbycontents = true;
 166         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 167
 168         gren.velocity = '0 0 1' * WEP_CVAR_SEC(hook, speed);
 169         if (autocvar_g_projectiles_newton_style)
 170                 gren.velocity = gren.velocity + actor.velocity;
 171
 172         gren.gravity = WEP_CVAR_SEC(hook, gravity);
 173         //W_SetupProjVelocity_Basic(gren); // just falling down!
 174
 175         gren.angles = '0 0 0';
 176         gren.flags = FL_PROJECTILE;
 177
 178         CSQCProjectile(gren, true, PROJECTILE_HOOKBOMB, true);
 179
 180         MUTATOR_CALLHOOK(EditProjectile, actor, gren);
 181 }
 182
 183 METHOD(Hook, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 184 {
 185     SELFPARAM();
 186     if (fire & 1) {
 187         if(!actor.hook)
 188         if(!(actor.hook_state & HOOK_WAITING_FOR_RELEASE))
 189         if(time > actor.hook_refire)
 190         if(weapon_prepareattack(thiswep, actor, weaponentity, false, -1))
 191         {
 192             W_DecreaseAmmo(thiswep, actor, thiswep.ammo_factor * WEP_CVAR_PRI(hook, ammo));
 193             actor.hook_state |= HOOK_FIRING;
 194             actor.hook_state |= HOOK_WAITING_FOR_RELEASE;
 195             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(hook, animtime), w_ready);
 196         }
 197     } else {
 198         actor.hook_state |= HOOK_REMOVING;
 199         actor.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 200     }
 201
 202     if(fire & 2)
 203     {
 204         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(hook, refire)))
 205         {
 206             W_Hook_Attack2(thiswep, actor);
 207             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(hook, animtime), w_ready);
 208         }
 209     }
 210
 211     if(actor.hook)
 212     {
 213         // if hooked, no bombs, and increase the timer
 214         actor.hook_refire = max(actor.hook_refire, time + WEP_CVAR_PRI(hook, refire) * W_WeaponRateFactor());
 215
 216         // hook also inhibits health regeneration, but only for 1 second
 217         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 218             actor.pauseregen_finished = max(actor.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 219     }
 220
 221     if(actor.hook && actor.hook.state == 1)
 222     {
 223         float hooked_time_max = WEP_CVAR_PRI(hook, hooked_time_max);
 224         if(hooked_time_max > 0)
 225         {
 226             if( time > actor.hook_time_hooked + hooked_time_max )
 227                 actor.hook_state |= HOOK_REMOVING;
 228         }
 229
 230         float hooked_fuel = thiswep.ammo_factor * WEP_CVAR_PRI(hook, hooked_ammo);
 231         if(hooked_fuel > 0)
 232         {
 233             if( time > actor.hook_time_fueldecrease )
 234             {
 235                 if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 236                 {
 237                     if( actor.ammo_fuel >= (time - actor.hook_time_fueldecrease) * hooked_fuel )
 238                     {
 239                         W_DecreaseAmmo(thiswep, actor, (time - actor.hook_time_fueldecrease) * hooked_fuel);
 240                         actor.hook_time_fueldecrease = time;
 241                         // decrease next frame again
 242                     }
 243                     else
 244                     {
 245                         actor.ammo_fuel = 0;
 246                         actor.hook_state |= HOOK_REMOVING;
 247                         W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
 248                     }
 249                 }
 250             }
 251         }
 252     }
 253     else
 254     {
 255         actor.hook_time_hooked = time;
 256         actor.hook_time_fueldecrease = time + WEP_CVAR_PRI(hook, hooked_time_free);
 257     }
 258
 259     actor.hook_state = BITSET(actor.hook_state, HOOK_PULLING, (!PHYS_INPUT_BUTTON_CROUCH(actor) || !autocvar_g_balance_grapplehook_crouchslide));
 260
 261     if (actor.hook_state & HOOK_FIRING)
 262     {
 263         if (actor.hook)
 264             RemoveGrapplingHook(actor);
 265         WITH(entity, self, actor, FireGrapplingHook());
 266         actor.hook_state &= ~HOOK_FIRING;
 267         actor.hook_refire = max(actor.hook_refire, time + autocvar_g_balance_grapplehook_refire * W_WeaponRateFactor());
 268     }
 269     else if (actor.hook_state & HOOK_REMOVING)
 270     {
 271         if (actor.hook)
 272             RemoveGrapplingHook(actor);
 273         actor.hook_state &= ~HOOK_REMOVING;
 274     }
 275 }
 276 METHOD(Hook, wr_setup, void(entity thiswep))
 277 {
 278     SELFPARAM();
 279     self.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 280 }
 281 METHOD(Hook, wr_checkammo1, bool(Hook thiswep))
 282 {
 283     SELFPARAM();
 284     if (!thiswep.ammo_factor) return true;
 285     if(self.hook)
 286         return self.ammo_fuel > 0;
 287     else
 288         return self.ammo_fuel >= WEP_CVAR_PRI(hook, ammo);
 289 }
 290 METHOD(Hook, wr_checkammo2, bool(Hook thiswep))
 291 {
 292     // infinite ammo for now
 293     return true; // self.ammo_cells >= WEP_CVAR_SEC(hook, ammo); // WEAPONTODO: see above
 294 }
 295 METHOD(Hook, wr_resetplayer, void(entity thiswep))
 296 {
 297     SELFPARAM();
 298     RemoveGrapplingHook(self);
 299     self.hook_time = 0;
 300     self.hook_refire = time;
 301 }
 302 METHOD(Hook, wr_killmessage, Notification(entity thiswep))
 303 {
 304     return WEAPON_HOOK_MURDER;
 305 }
 306
 307 #endif
 308 #ifdef CSQC
 309
 310 METHOD(Hook, wr_impacteffect, void(entity thiswep))
 311 {
 312     SELFPARAM();
 313     vector org2;
 314     org2 = w_org + w_backoff * 2;
 315     pointparticles(EFFECT_HOOK_EXPLODE, org2, '0 0 0', 1);
 316     if(!w_issilent)
 317         sound(self, CH_SHOTS, SND_HOOKBOMB_IMPACT, VOL_BASE, ATTN_NORM);
 318 }
 319
 320 #endif
 321
 322 #ifdef CSQC
 323 #include <lib/csqcmodel/interpolate.qh>
 324 #include <lib/warpzone/common.qh>
 325
 326 float autocvar_cl_grapplehook_alpha = 1;
 327
 328 void Draw_CylindricLine(vector from, vector to, float thickness, string texture, float aspect, float shift, vector rgb, float theAlpha, float drawflag, vector vieworg);
 329
 330 entityclass(Hook);
 331 class(Hook) .entity HookType; // ENT_CLIENT_*
 332 class(Hook) .vector origin;
 333 class(Hook) .vector velocity;
 334 class(Hook) .float HookSilent;
 335 class(Hook) .float HookRange;
 336
 337 string Draw_GrapplingHook_trace_callback_tex;
 338 float Draw_GrapplingHook_trace_callback_rnd;
 339 vector Draw_GrapplingHook_trace_callback_rgb;
 340 float Draw_GrapplingHook_trace_callback_a;
 341 void Draw_GrapplingHook_trace_callback(vector start, vector hit, vector end)
 342 {
 343         float i;
 344         vector vorg;
 345         vorg = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 346         for(i = 0; i < Draw_GrapplingHook_trace_callback_a; ++i)
 347                 Draw_CylindricLine(hit, start, 8, Draw_GrapplingHook_trace_callback_tex, 0.25, Draw_GrapplingHook_trace_callback_rnd, Draw_GrapplingHook_trace_callback_rgb, min(1, Draw_GrapplingHook_trace_callback_a - i), DRAWFLAG_NORMAL, vorg);
 348         Draw_GrapplingHook_trace_callback_rnd += 0.25 * vlen(hit - start) / 8;
 349 }
 350
 351 class(Hook) .float teleport_time;
 352 void Draw_GrapplingHook(entity this)
 353 {
 354         vector a, b, atrans;
 355         string tex;
 356         vector rgb;
 357         float t;
 358         vector vs;
 359         float intensity, offset;
 360
 361         if(this.teleport_time)
 362         if(time > this.teleport_time)
 363         {
 364                 sound (this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM); // safeguard
 365                 this.teleport_time = 0;
 366         }
 367
 368         InterpolateOrigin_Do(this);
 369
 370         int s = W_GetGunAlignment(world);
 371
 372         switch(this.HookType)
 373         {
 374                 default:
 375                 case NET_ENT_CLIENT_HOOK:
 376                         vs = hook_shotorigin[s];
 377                         break;
 378                 case NET_ENT_CLIENT_ARC_BEAM:
 379                         vs = lightning_shotorigin[s];
 380                         break;
 381         }
 382
 383         if((this.owner.sv_entnum == player_localentnum - 1) && autocvar_chase_active <= 0)
 384         {
 385                 switch(this.HookType)
 386                 {
 387                         default:
 388                         case NET_ENT_CLIENT_HOOK:
 389                                 a = view_origin + view_forward * vs.x + view_right * -vs.y + view_up * vs.z;
 390                                 b = this.origin;
 391                                 break;
 392                         case NET_ENT_CLIENT_ARC_BEAM:
 393                                 if(this.HookRange)
 394                                         b = view_origin + view_forward * this.HookRange;
 395                                 else
 396                                         b = view_origin + view_forward * vlen(this.velocity - this.origin); // honor original length of beam!
 397                                 WarpZone_TraceLine(view_origin, b, MOVE_NORMAL, world);
 398                                 b = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 399                                 a = view_origin + view_forward * vs.x + view_right * -vs.y + view_up * vs.z;
 400                                 break;
 401                 }
 402         }
 403         else
 404         {
 405                 switch(this.HookType)
 406                 {
 407                         default:
 408                         case NET_ENT_CLIENT_HOOK:
 409                                 a = this.velocity;
 410                                 b = this.origin;
 411                                 break;
 412                         case NET_ENT_CLIENT_ARC_BEAM:
 413                                 a = this.origin;
 414                                 b = this.velocity;
 415                                 break;
 416                 }
 417         }
 418
 419         t = entcs_GetTeamColor(this.owner.sv_entnum);
 420
 421         switch(this.HookType)
 422         {
 423                 default:
 424                 case NET_ENT_CLIENT_HOOK:
 425                         intensity = autocvar_cl_grapplehook_alpha;
 426                         offset = 0;
 427                         switch(t)
 428                         {
 429                                 case NUM_TEAM_1: tex = "particles/hook_red"; rgb = '1 0.3 0.3'; break;
 430                                 case NUM_TEAM_2: tex = "particles/hook_blue"; rgb = '0.3 0.3 1'; break;
 431                                 case NUM_TEAM_3: tex = "particles/hook_yellow"; rgb = '1 1 0.3'; break;
 432                                 case NUM_TEAM_4: tex = "particles/hook_pink"; rgb = '1 0.3 1'; break;
 433                                 default: tex = "particles/hook_white"; rgb = entcs_GetColor(this.sv_entnum - 1); break;
 434                         }
 435                         break;
 436                 case NET_ENT_CLIENT_ARC_BEAM: // todo
 437                         intensity = bound(0.2, 1 + Noise_Pink(this, frametime) * 1 + Noise_Burst(this, frametime, 0.03) * 0.3, 2);
 438                         offset = Noise_Brown(this, frametime) * 10;
 439                         tex = "particles/lgbeam";
 440                         rgb = '1 1 1';
 441                         break;
 442         }
 443
 444         Draw_GrapplingHook_trace_callback_tex = tex;
 445         Draw_GrapplingHook_trace_callback_rnd = offset;
 446         Draw_GrapplingHook_trace_callback_rgb = rgb;
 447         Draw_GrapplingHook_trace_callback_a = intensity;
 448         WarpZone_TraceBox_ThroughZone(a, '0 0 0', '0 0 0', b, ((this.HookType == NET_ENT_CLIENT_HOOK) ? MOVE_NOTHING : MOVE_NORMAL), world, world, Draw_GrapplingHook_trace_callback);
 449         Draw_GrapplingHook_trace_callback_tex = string_null;
 450
 451         atrans = WarpZone_TransformOrigin(WarpZone_trace_transform, a);
 452
 453         switch(this.HookType)
 454         {
 455                 default:
 456                 case NET_ENT_CLIENT_HOOK:
 457                         if(vdist(trace_endpos - atrans, >, 0.5))
 458                         {
 459                                 setorigin(this, trace_endpos); // hook endpoint!
 460                                 this.angles = vectoangles(trace_endpos - atrans);
 461                                 this.drawmask = MASK_NORMAL;
 462                         }
 463                         else
 464                         {
 465                                 this.drawmask = 0;
 466                         }
 467                         break;
 468                 case NET_ENT_CLIENT_ARC_BEAM:
 469                         setorigin(this, a); // beam origin!
 470                         break;
 471         }
 472
 473         switch(this.HookType)
 474         {
 475                 default:
 476                 case NET_ENT_CLIENT_HOOK:
 477                         break;
 478                 case NET_ENT_CLIENT_ARC_BEAM:
 479                         pointparticles(EFFECT_ARC_LIGHTNING2, trace_endpos, normalize(atrans - trace_endpos), frametime * intensity); // todo: new effect
 480                         break;
 481         }
 482 }
 483
 484 void Remove_GrapplingHook(entity this)
 485 {
 486         sound (this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 487
 488         if(csqcplayer && csqcplayer.hook == this)
 489                 csqcplayer.hook = NULL;
 490 }
 491
 492 NET_HANDLE(ENT_CLIENT_HOOK, bool bIsNew)
 493 {
 494         self.HookType = NET_ENT_CLIENT_HOOK;
 495
 496         int sf = ReadByte();
 497
 498         self.HookSilent = (sf & 0x80);
 499         self.iflags = IFLAG_VELOCITY | IFLAG_ORIGIN;
 500
 501         InterpolateOrigin_Undo(self);
 502
 503         if(sf & 1)
 504         {
 505                 int myowner = ReadByte();
 506                 self.owner = playerslots[myowner - 1];
 507                 self.sv_entnum = myowner;
 508                 if(csqcplayer && myowner == player_localentnum)
 509                         csqcplayer.hook = self;
 510                 switch(self.HookType)
 511                 {
 512                         default:
 513                         case NET_ENT_CLIENT_HOOK:
 514                                 self.HookRange = 0;
 515                                 break;
 516                         case NET_ENT_CLIENT_ARC_BEAM:
 517                                 self.HookRange = ReadCoord();
 518                                 break;
 519                 }
 520         }
 521         if(sf & 2)
 522         {
 523                 self.origin_x = ReadCoord();
 524                 self.origin_y = ReadCoord();
 525                 self.origin_z = ReadCoord();
 526                 setorigin(self, self.origin);
 527         }
 528         if(sf & 4)
 529         {
 530                 self.velocity_x = ReadCoord();
 531                 self.velocity_y = ReadCoord();
 532                 self.velocity_z = ReadCoord();
 533         }
 534
 535         InterpolateOrigin_Note(this);
 536
 537         if(bIsNew || !self.teleport_time)
 538         {
 539                 self.draw = Draw_GrapplingHook;
 540                 self.entremove = Remove_GrapplingHook;
 541
 542                 switch(self.HookType)
 543                 {
 544                         default:
 545                         case NET_ENT_CLIENT_HOOK:
 546                                 // for the model
 547                                 setmodel(self, MDL_HOOK);
 548                                 self.drawmask = MASK_NORMAL;
 549                                 break;
 550                         case NET_ENT_CLIENT_ARC_BEAM:
 551                                 sound (self, CH_SHOTS_SINGLE, SND_LGBEAM_FLY, VOL_BASE, ATTEN_NORM);
 552                                 break;
 553                 }
 554         }
 555
 556         self.teleport_time = time + 10;
 557         return true;
 558 }
 559
 560 // TODO: hook: temporarily transform self.origin for drawing the model along warpzones!
 561 #endif
 562
 563 #endif