Hook: merge offhand and weapon behaviour
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / hook.qc
1 #ifndef IMPLEMENTATION
2 CLASS(Hook, Weapon)
3 /* ammotype  */ ATTRIB(Hook, ammo_field, .int, ammo_fuel)
4 /* impulse   */ ATTRIB(Hook, impulse, int, 0)
5 /* flags     */ ATTRIB(Hook, spawnflags, int, WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
6 /* rating    */ ATTRIB(Hook, bot_pickupbasevalue, float, 0);
7 /* color     */ ATTRIB(Hook, wpcolor, vector, '0 0.5 0');
8 /* modelname */ ATTRIB(Hook, mdl, string, "hookgun");
9 #ifndef MENUQC
10 /* model     */ ATTRIB(Hook, m_model, Model, MDL_HOOK_ITEM);
11 #endif
12 /* crosshair */ ATTRIB(Hook, w_crosshair, string, "gfx/crosshairhook");
13 /* crosshair */ ATTRIB(Hook, w_crosshair_size, float, 0.5);
14 /* wepimg    */ ATTRIB(Hook, model2, string, "weaponhook");
15 /* refname   */ ATTRIB(Hook, netname, string, "hook");
16 /* wepname   */ ATTRIB(Hook, message, string, _("Grappling Hook"));
17 ENDCLASS(Hook)
18 REGISTER_WEAPON(HOOK, NEW(Hook));
19
20 CLASS(OffhandHook, OffhandWeapon)
21     METHOD(OffhandHook, offhand_think, void(OffhandHook this, entity actor, bool key_pressed))
22     {
23         Weapon wep = WEP_HOOK;
24         wep.wr_think(wep, actor, key_pressed, false);
25     }
26 ENDCLASS(OffhandHook)
27 OffhandHook OFFHAND_HOOK; STATIC_INIT(OFFHAND_HOOK) { OFFHAND_HOOK = NEW(OffhandHook); }
28
29 #define HOOK_SETTINGS(w_cvar,w_prop) HOOK_SETTINGS_LIST(w_cvar, w_prop, HOOK, hook)
30 #define HOOK_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
31         w_cvar(id, sn, BOTH, animtime) \
32         w_cvar(id, sn, BOTH, refire) \
33         w_cvar(id, sn, PRI,  ammo) \
34         w_cvar(id, sn, PRI,  hooked_ammo) \
35         w_cvar(id, sn, PRI,  hooked_time_free) \
36         w_cvar(id, sn, PRI,  hooked_time_max) \
37         w_cvar(id, sn, SEC,  damage) \
38         w_cvar(id, sn, SEC,  duration) \
39         w_cvar(id, sn, SEC,  edgedamage) \
40         w_cvar(id, sn, SEC,  force) \
41         w_cvar(id, sn, SEC,  gravity) \
42         w_cvar(id, sn, SEC,  lifetime) \
43         w_cvar(id, sn, SEC,  power) \
44         w_cvar(id, sn, SEC,  radius) \
45         w_cvar(id, sn, SEC,  speed) \
46         w_cvar(id, sn, SEC,  health) \
47         w_cvar(id, sn, SEC,  damageforcescale) \
48         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
49         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
50         w_prop(id, sn, string, weaponreplace, weaponreplace) \
51         w_prop(id, sn, float,  weaponstart, weaponstart) \
52         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
53         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
54
55 #ifdef SVQC
56 HOOK_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
57
58 .float dmg;
59 .float dmg_edge;
60 .float dmg_radius;
61 .float dmg_force;
62 .float dmg_power;
63 .float dmg_duration;
64 .float dmg_last;
65 .float hook_refire;
66 .float hook_time_hooked;
67 .float hook_time_fueldecrease;
68 #endif
69 #endif
70 #ifdef IMPLEMENTATION
71 #ifdef SVQC
72
73 spawnfunc(weapon_hook) { weapon_defaultspawnfunc(WEP_HOOK.m_id); }
74
75 void W_Hook_ExplodeThink(void)
76 {SELFPARAM();
77         float dt, dmg_remaining_next, f;
78
79         dt = time - self.teleport_time;
80         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
81
82         f = self.dmg_last - dmg_remaining_next;
83         self.dmg_last = dmg_remaining_next;
84
85         RadiusDamage(self, self.realowner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.realowner, world, self.dmg_force * f, self.projectiledeathtype, world);
86         self.projectiledeathtype |= HITTYPE_BOUNCE;
87         //RadiusDamage(self, world, self.dmg * f, self.dmg_edge * f, self.dmg_radius, world, world, self.dmg_force * f, self.projectiledeathtype, world);
88
89         if(dt < self.dmg_duration)
90                 self.nextthink = time + 0.05; // soon
91         else
92                 remove(self);
93 }
94
95 void W_Hook_Explode2(void)
96 {SELFPARAM();
97         self.event_damage = func_null;
98         self.touch = func_null;
99         self.effects |= EF_NODRAW;
100
101         self.think = W_Hook_ExplodeThink;
102         self.nextthink = time;
103         self.dmg = WEP_CVAR_SEC(hook, damage);
104         self.dmg_edge = WEP_CVAR_SEC(hook, edgedamage);
105         self.dmg_radius = WEP_CVAR_SEC(hook, radius);
106         self.dmg_force = WEP_CVAR_SEC(hook, force);
107         self.dmg_power = WEP_CVAR_SEC(hook, power);
108         self.dmg_duration = WEP_CVAR_SEC(hook, duration);
109         self.teleport_time = time;
110         self.dmg_last = 1;
111         self.movetype = MOVETYPE_NONE;
112 }
113
114 void W_Hook_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
115 {SELFPARAM();
116         if(self.health <= 0)
117                 return;
118
119         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
120                 return; // g_projectiles_damage says to halt
121
122         self.health = self.health - damage;
123
124         if(self.health <= 0)
125                 W_PrepareExplosionByDamage(self.realowner, W_Hook_Explode2);
126 }
127
128 void W_Hook_Touch2(void)
129 {SELFPARAM();
130         PROJECTILE_TOUCH;
131         self.use();
132 }
133
134 void W_Hook_Attack2(Weapon thiswep, entity actor)
135 {
136         //W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hook, ammo)); // WEAPONTODO: Figure out how to handle ammo with hook secondary (gravitybomb)
137         W_SetupShot(actor, false, 4, SND(HOOKBOMB_FIRE), CH_WEAPON_A, WEP_CVAR_SEC(hook, damage));
138
139         entity gren = new(hookbomb);
140         gren.owner = gren.realowner = actor;
141         gren.bot_dodge = true;
142         gren.bot_dodgerating = WEP_CVAR_SEC(hook, damage);
143         gren.movetype = MOVETYPE_TOSS;
144         PROJECTILE_MAKETRIGGER(gren);
145         gren.projectiledeathtype = WEP_HOOK.m_id | HITTYPE_SECONDARY;
146         setorigin(gren, w_shotorg);
147         setsize(gren, '0 0 0', '0 0 0');
148
149         gren.nextthink = time + WEP_CVAR_SEC(hook, lifetime);
150         gren.think = adaptor_think2use_hittype_splash;
151         gren.use = W_Hook_Explode2;
152         gren.touch = W_Hook_Touch2;
153
154         gren.takedamage = DAMAGE_YES;
155         gren.health = WEP_CVAR_SEC(hook, health);
156         gren.damageforcescale = WEP_CVAR_SEC(hook, damageforcescale);
157         gren.event_damage = W_Hook_Damage;
158         gren.damagedbycontents = true;
159         gren.missile_flags = MIF_SPLASH | MIF_ARC;
160
161         gren.velocity = '0 0 1' * WEP_CVAR_SEC(hook, speed);
162         if (autocvar_g_projectiles_newton_style)
163                 gren.velocity = gren.velocity + actor.velocity;
164
165         gren.gravity = WEP_CVAR_SEC(hook, gravity);
166         //W_SetupProjVelocity_Basic(gren); // just falling down!
167
168         gren.angles = '0 0 0';
169         gren.flags = FL_PROJECTILE;
170
171         CSQCProjectile(gren, true, PROJECTILE_HOOKBOMB, true);
172
173         MUTATOR_CALLHOOK(EditProjectile, actor, gren);
174 }
175
176                 METHOD(Hook, wr_think, void(entity thiswep, entity actor, bool fire1, bool fire2))
177                 {
178                         if (fire1) {
179                                 if(!actor.hook)
180                                 if(!(actor.hook_state & HOOK_WAITING_FOR_RELEASE))
181                                 if(time > actor.hook_refire)
182                                 if(weapon_prepareattack(thiswep, actor, false, -1))
183                                 {
184                                         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_PRI(hook, ammo));
185                                         actor.hook_state |= HOOK_FIRING;
186                                         actor.hook_state |= HOOK_WAITING_FOR_RELEASE;
187                                         weapon_thinkf(actor, WFRAME_FIRE1, WEP_CVAR_PRI(hook, animtime), w_ready);
188                                 }
189                         } else {
190                                 actor.hook_state |= HOOK_REMOVING;
191                                 actor.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
192                         }
193
194                         if(fire2)
195                         {
196                                 if(weapon_prepareattack(thiswep, actor, true, WEP_CVAR_SEC(hook, refire)))
197                                 {
198                                         W_Hook_Attack2(thiswep, actor);
199                                         weapon_thinkf(actor, WFRAME_FIRE2, WEP_CVAR_SEC(hook, animtime), w_ready);
200                                 }
201                         }
202
203                         if(actor.hook)
204                         {
205                                 // if hooked, no bombs, and increase the timer
206                                 actor.hook_refire = max(actor.hook_refire, time + WEP_CVAR_PRI(hook, refire) * W_WeaponRateFactor());
207
208                                 // hook also inhibits health regeneration, but only for 1 second
209                                 if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
210                                         actor.pauseregen_finished = max(actor.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
211                         }
212
213                         if(actor.hook && actor.hook.state == 1)
214                         {
215                                 float hooked_time_max = WEP_CVAR_PRI(hook, hooked_time_max);
216                                 if(hooked_time_max > 0)
217                                 {
218                                         if( time > actor.hook_time_hooked + hooked_time_max )
219                                                 actor.hook_state |= HOOK_REMOVING;
220                                 }
221
222                                 float hooked_fuel = WEP_CVAR_PRI(hook, hooked_ammo);
223                                 if(hooked_fuel > 0)
224                                 {
225                                         if( time > actor.hook_time_fueldecrease )
226                                         {
227                                                 if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
228                                                 {
229                                                         if( actor.ammo_fuel >= (time - actor.hook_time_fueldecrease) * hooked_fuel )
230                                                         {
231                                                                 W_DecreaseAmmo(thiswep, actor, (time - actor.hook_time_fueldecrease) * hooked_fuel);
232                                                                 actor.hook_time_fueldecrease = time;
233                                                                 // decrease next frame again
234                                                         }
235                                                         else
236                                                         {
237                                                                 actor.ammo_fuel = 0;
238                                                                 actor.hook_state |= HOOK_REMOVING;
239                                                                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
240                                                         }
241                                                 }
242                                         }
243                                 }
244                         }
245                         else
246                         {
247                                 actor.hook_time_hooked = time;
248                                 actor.hook_time_fueldecrease = time + WEP_CVAR_PRI(hook, hooked_time_free);
249                         }
250
251                         actor.hook_state = BITSET(actor.hook_state, HOOK_PULLING, (!actor.BUTTON_CROUCH || !autocvar_g_balance_grapplehook_crouchslide));
252
253                         if (actor.hook_state & HOOK_FIRING)
254                         {
255                                 if (actor.hook)
256                                         RemoveGrapplingHook(actor);
257                                 WITH(entity, self, actor, FireGrapplingHook());
258                                 actor.hook_state &= ~HOOK_FIRING;
259                                 actor.hook_refire = max(actor.hook_refire, time + autocvar_g_balance_grapplehook_refire * W_WeaponRateFactor());
260                         }
261                         else if (actor.hook_state & HOOK_REMOVING)
262                         {
263                                 if (actor.hook)
264                                         RemoveGrapplingHook(actor);
265                                 actor.hook_state &= ~HOOK_REMOVING;
266                         }
267                 }
268                 METHOD(Hook, wr_init, void(entity thiswep))
269                 {
270                         HOOK_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
271                 }
272                 METHOD(Hook, wr_setup, void(entity thiswep))
273                 {
274                         self.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
275                 }
276                 METHOD(Hook, wr_checkammo1, bool(entity thiswep))
277                 {
278                         if(self.hook)
279                                 return self.ammo_fuel > 0;
280                         else
281                                 return self.ammo_fuel >= WEP_CVAR_PRI(hook, ammo);
282                 }
283                 METHOD(Hook, wr_checkammo2, bool(entity thiswep))
284                 {
285                         // infinite ammo for now
286                         return true; // self.ammo_cells >= WEP_CVAR_SEC(hook, ammo); // WEAPONTODO: see above
287                 }
288                 METHOD(Hook, wr_config, void(entity thiswep))
289                 {
290                         HOOK_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
291                 }
292                 METHOD(Hook, wr_resetplayer, void(entity thiswep))
293                 {
294                         self.hook_refire = time;
295                 }
296                 METHOD(Hook, wr_suicidemessage, int(entity thiswep))
297                 {
298                         return false;
299                 }
300                 METHOD(Hook, wr_killmessage, int(entity thiswep))
301                 {
302                         return WEAPON_HOOK_MURDER;
303                 }
304
305 #endif
306 #ifdef CSQC
307
308                 METHOD(Hook, wr_impacteffect, void(entity thiswep))
309                 {
310                         vector org2;
311                         org2 = w_org + w_backoff * 2;
312                         pointparticles(particleeffectnum(EFFECT_HOOK_EXPLODE), org2, '0 0 0', 1);
313                         if(!w_issilent)
314                                 sound(self, CH_SHOTS, SND_HOOKBOMB_IMPACT, VOL_BASE, ATTN_NORM);
315                 }
316
317 #endif
318 #endif