qcsrc/common/weapons/weapon/hook.qc

   1 #include "hook.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Hook, Weapon)
   4 /* ammotype  */ ATTRIB(Hook, ammo_field, .int, ammo_fuel);
   5 /* impulse   */ ATTRIB(Hook, impulse, int, 0);
   6 /* flags     */ ATTRIB(Hook, spawnflags, int, WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   7 /* rating    */ ATTRIB(Hook, bot_pickupbasevalue, float, 0);
   8 /* color     */ ATTRIB(Hook, wpcolor, vector, '0 0.5 0');
   9 /* modelname */ ATTRIB(Hook, mdl, string, "hookgun");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Hook, m_model, Model, MDL_HOOK_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Hook, w_crosshair, string, "gfx/crosshairhook");
  14 /* crosshair */ ATTRIB(Hook, w_crosshair_size, float, 0.5);
  15 /* wepimg    */ ATTRIB(Hook, model2, string, "weaponhook");
  16 /* refname   */ ATTRIB(Hook, netname, string, "hook");
  17 /* wepname   */ ATTRIB(Hook, m_name, string, _("Grappling Hook"));
  18         ATTRIB(Hook, ammo_factor, float, 1);
  19
  20 #define X(BEGIN, P, END, class, prefix) \
  21         BEGIN(class) \
  22                 P(class, prefix, ammo, float, PRI) \
  23                 P(class, prefix, animtime, float, BOTH) \
  24                 P(class, prefix, damageforcescale, float, SEC) \
  25                 P(class, prefix, damage, float, SEC) \
  26                 P(class, prefix, duration, float, SEC) \
  27                 P(class, prefix, edgedamage, float, SEC) \
  28                 P(class, prefix, force, float, SEC) \
  29                 P(class, prefix, gravity, float, SEC) \
  30                 P(class, prefix, health, float, SEC) \
  31                 P(class, prefix, hooked_ammo, float, PRI) \
  32                 P(class, prefix, hooked_time_free, float, PRI) \
  33                 P(class, prefix, hooked_time_max, float, PRI) \
  34                 P(class, prefix, lifetime, float, SEC) \
  35                 P(class, prefix, power, float, SEC) \
  36                 P(class, prefix, radius, float, SEC) \
  37                 P(class, prefix, refire, float, BOTH) \
  38                 P(class, prefix, speed, float, SEC) \
  39         P(class, prefix, switchdelay_drop, float, NONE) \
  40                 P(class, prefix, switchdelay_raise, float, NONE) \
  41         P(class, prefix, weaponreplace, string, NONE) \
  42         P(class, prefix, weaponstartoverride, float, NONE) \
  43         P(class, prefix, weaponstart, float, NONE) \
  44         P(class, prefix, weaponthrowable, float, NONE) \
  45         END()
  46     W_PROPS(X, Hook, hook)
  47 #undef X
  48
  49 ENDCLASS(Hook)
  50 REGISTER_WEAPON(HOOK, hook, NEW(Hook));
  51
  52 CLASS(OffhandHook, OffhandWeapon)
  53 #ifdef SVQC
  54     METHOD(OffhandHook, offhand_think, void(OffhandHook this, entity actor, bool key_pressed))
  55     {
  56         Weapon wep = WEP_HOOK;
  57         .entity weaponentity = weaponentities[1];
  58         wep.wr_think(wep, actor, weaponentity, key_pressed ? 1 : 0);
  59     }
  60 #endif
  61 ENDCLASS(OffhandHook)
  62 OffhandHook OFFHAND_HOOK; STATIC_INIT(OFFHAND_HOOK) { OFFHAND_HOOK = NEW(OffhandHook); }
  63
  64 #ifdef SVQC
  65
  66 .float dmg;
  67 .float dmg_edge;
  68 .float dmg_radius;
  69 .float dmg_force;
  70 .float dmg_power;
  71 .float dmg_duration;
  72 .float dmg_last;
  73 .float hook_refire;
  74 .float hook_time_hooked;
  75 .float hook_time_fueldecrease;
  76 #endif
  77 #endif
  78 #ifdef IMPLEMENTATION
  79 #ifdef SVQC
  80
  81 spawnfunc(weapon_hook) { weapon_defaultspawnfunc(this, WEP_HOOK); }
  82
  83 void W_Hook_ExplodeThink(entity this)
  84 {
  85         float dt, dmg_remaining_next, f;
  86
  87         dt = time - this.teleport_time;
  88         dmg_remaining_next = pow(bound(0, 1 - dt / this.dmg_duration, 1), this.dmg_power);
  89
  90         f = this.dmg_last - dmg_remaining_next;
  91         this.dmg_last = dmg_remaining_next;
  92
  93         RadiusDamage(this, this.realowner, this.dmg * f, this.dmg_edge * f, this.dmg_radius, this.realowner, NULL, this.dmg_force * f, this.projectiledeathtype, NULL);
  94         this.projectiledeathtype |= HITTYPE_BOUNCE;
  95         //RadiusDamage(this, NULL, this.dmg * f, this.dmg_edge * f, this.dmg_radius, NULL, NULL, this.dmg_force * f, this.projectiledeathtype, NULL);
  96
  97         if(dt < this.dmg_duration)
  98                 this.nextthink = time + 0.05; // soon
  99         else
 100                 delete(this);
 101 }
 102
 103 void W_Hook_Explode2(entity this)
 104 {
 105         this.event_damage = func_null;
 106         settouch(this, func_null);
 107         this.effects |= EF_NODRAW;
 108
 109         setthink(this, W_Hook_ExplodeThink);
 110         this.nextthink = time;
 111         this.dmg = WEP_CVAR_SEC(hook, damage);
 112         this.dmg_edge = WEP_CVAR_SEC(hook, edgedamage);
 113         this.dmg_radius = WEP_CVAR_SEC(hook, radius);
 114         this.dmg_force = WEP_CVAR_SEC(hook, force);
 115         this.dmg_power = WEP_CVAR_SEC(hook, power);
 116         this.dmg_duration = WEP_CVAR_SEC(hook, duration);
 117         this.teleport_time = time;
 118         this.dmg_last = 1;
 119         set_movetype(this, MOVETYPE_NONE);
 120 }
 121
 122 void W_Hook_Explode2_use(entity this, entity actor, entity trigger)
 123 {
 124         W_Hook_Explode2(this);
 125 }
 126
 127 void W_Hook_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 128 {
 129         if(this.health <= 0)
 130                 return;
 131
 132         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 133                 return; // g_projectiles_damage says to halt
 134
 135         this.health = this.health - damage;
 136
 137         if(this.health <= 0)
 138                 W_PrepareExplosionByDamage(this, this.realowner, W_Hook_Explode2);
 139 }
 140
 141 void W_Hook_Touch2(entity this, entity toucher)
 142 {
 143         PROJECTILE_TOUCH(this, toucher);
 144         this.use(this, NULL, NULL);
 145 }
 146
 147 void W_Hook_Attack2(Weapon thiswep, entity actor, .entity weaponentity)
 148 {
 149         //W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hook, ammo)); // WEAPONTODO: Figure out how to handle ammo with hook secondary (gravitybomb)
 150         W_SetupShot(actor, weaponentity, false, 4, SND_HOOKBOMB_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(hook, damage));
 151
 152         entity gren = new(hookbomb);
 153         gren.owner = gren.realowner = actor;
 154         gren.bot_dodge = true;
 155         gren.bot_dodgerating = WEP_CVAR_SEC(hook, damage);
 156         set_movetype(gren, MOVETYPE_TOSS);
 157         PROJECTILE_MAKETRIGGER(gren);
 158         gren.projectiledeathtype = WEP_HOOK.m_id | HITTYPE_SECONDARY;
 159         setorigin(gren, w_shotorg);
 160         setsize(gren, '0 0 0', '0 0 0');
 161
 162         gren.nextthink = time + WEP_CVAR_SEC(hook, lifetime);
 163         setthink(gren, adaptor_think2use_hittype_splash);
 164         gren.use = W_Hook_Explode2_use;
 165         settouch(gren, W_Hook_Touch2);
 166
 167         gren.takedamage = DAMAGE_YES;
 168         gren.health = WEP_CVAR_SEC(hook, health);
 169         gren.damageforcescale = WEP_CVAR_SEC(hook, damageforcescale);
 170         gren.event_damage = W_Hook_Damage;
 171         gren.damagedbycontents = true;
 172         IL_PUSH(g_damagedbycontents, gren);
 173         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 174
 175         gren.velocity = '0 0 1' * WEP_CVAR_SEC(hook, speed);
 176         if (autocvar_g_projectiles_newton_style)
 177                 gren.velocity = gren.velocity + actor.velocity;
 178
 179         gren.gravity = WEP_CVAR_SEC(hook, gravity);
 180         //W_SetupProjVelocity_Basic(gren); // just falling down!
 181
 182         gren.angles = '0 0 0';
 183         gren.flags = FL_PROJECTILE;
 184         IL_PUSH(g_projectiles, gren);
 185         IL_PUSH(g_bot_dodge, gren);
 186
 187         CSQCProjectile(gren, true, PROJECTILE_HOOKBOMB, true);
 188
 189         MUTATOR_CALLHOOK(EditProjectile, actor, gren);
 190 }
 191
 192 METHOD(Hook, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 193 {
 194     if (fire & 1) {
 195         if(!actor.hook)
 196         if(!(actor.hook_state & HOOK_WAITING_FOR_RELEASE))
 197         if(time > actor.hook_refire)
 198         if(weapon_prepareattack(thiswep, actor, weaponentity, false, -1))
 199         {
 200             W_DecreaseAmmo(thiswep, actor, thiswep.ammo_factor * WEP_CVAR_PRI(hook, ammo));
 201             actor.hook_state |= HOOK_FIRING;
 202             actor.hook_state |= HOOK_WAITING_FOR_RELEASE;
 203             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(hook, animtime), w_ready);
 204         }
 205     } else {
 206         actor.hook_state |= HOOK_REMOVING;
 207         actor.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 208     }
 209
 210     if(fire & 2)
 211     {
 212         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(hook, refire)))
 213         {
 214             W_Hook_Attack2(thiswep, actor, weaponentity);
 215             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(hook, animtime), w_ready);
 216         }
 217     }
 218
 219     if(actor.hook)
 220     {
 221         // if hooked, no bombs, and increase the timer
 222         actor.hook_refire = max(actor.hook_refire, time + WEP_CVAR_PRI(hook, refire) * W_WeaponRateFactor(actor));
 223
 224         // hook also inhibits health regeneration, but only for 1 second
 225         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 226             actor.pauseregen_finished = max(actor.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 227     }
 228
 229     if(actor.hook && actor.hook.state == 1)
 230     {
 231         float hooked_time_max = WEP_CVAR_PRI(hook, hooked_time_max);
 232         if(hooked_time_max > 0)
 233         {
 234             if( time > actor.hook_time_hooked + hooked_time_max )
 235                 actor.hook_state |= HOOK_REMOVING;
 236         }
 237
 238         float hooked_fuel = thiswep.ammo_factor * WEP_CVAR_PRI(hook, hooked_ammo);
 239         if(hooked_fuel > 0)
 240         {
 241             if( time > actor.hook_time_fueldecrease )
 242             {
 243                 if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 244                 {
 245                     if( actor.ammo_fuel >= (time - actor.hook_time_fueldecrease) * hooked_fuel )
 246                     {
 247                         W_DecreaseAmmo(thiswep, actor, (time - actor.hook_time_fueldecrease) * hooked_fuel);
 248                         actor.hook_time_fueldecrease = time;
 249                         // decrease next frame again
 250                     }
 251                     else
 252                     {
 253                         actor.ammo_fuel = 0;
 254                         actor.hook_state |= HOOK_REMOVING;
 255                         W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
 256                     }
 257                 }
 258             }
 259         }
 260     }
 261     else
 262     {
 263         actor.hook_time_hooked = time;
 264         actor.hook_time_fueldecrease = time + WEP_CVAR_PRI(hook, hooked_time_free);
 265     }
 266
 267     actor.hook_state = BITSET(actor.hook_state, HOOK_PULLING, (!PHYS_INPUT_BUTTON_CROUCH(actor) || !autocvar_g_balance_grapplehook_crouchslide));
 268
 269     if (actor.hook_state & HOOK_FIRING)
 270     {
 271         if (actor.hook)
 272             RemoveGrapplingHook(actor);
 273         FireGrapplingHook(actor);
 274         actor.hook_state &= ~HOOK_FIRING;
 275         actor.hook_refire = max(actor.hook_refire, time + autocvar_g_balance_grapplehook_refire * W_WeaponRateFactor(actor));
 276     }
 277     else if (actor.hook_state & HOOK_REMOVING)
 278     {
 279         if (actor.hook)
 280             RemoveGrapplingHook(actor);
 281         actor.hook_state &= ~HOOK_REMOVING;
 282     }
 283 }
 284 METHOD(Hook, wr_setup, void(entity thiswep, entity actor))
 285 {
 286     actor.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 287 }
 288 METHOD(Hook, wr_checkammo1, bool(Hook thiswep, entity actor))
 289 {
 290     if (!thiswep.ammo_factor) return true;
 291     if(actor.hook)
 292         return actor.ammo_fuel > 0;
 293     else
 294         return actor.ammo_fuel >= WEP_CVAR_PRI(hook, ammo);
 295 }
 296 METHOD(Hook, wr_checkammo2, bool(Hook thiswep, entity actor))
 297 {
 298     // infinite ammo for now
 299     return true; // actor.ammo_cells >= WEP_CVAR_SEC(hook, ammo); // WEAPONTODO: see above
 300 }
 301 METHOD(Hook, wr_resetplayer, void(entity thiswep, entity actor))
 302 {
 303     RemoveGrapplingHook(actor);
 304     actor.hook_time = 0;
 305     actor.hook_refire = time;
 306 }
 307 METHOD(Hook, wr_killmessage, Notification(entity thiswep))
 308 {
 309     return WEAPON_HOOK_MURDER;
 310 }
 311
 312 #endif
 313 #ifdef CSQC
 314
 315 METHOD(Hook, wr_impacteffect, void(entity thiswep, entity actor))
 316 {
 317     vector org2;
 318     org2 = w_org + w_backoff * 2;
 319     pointparticles(EFFECT_HOOK_EXPLODE, org2, '0 0 0', 1);
 320     if(!w_issilent)
 321         sound(actor, CH_SHOTS, SND_HOOKBOMB_IMPACT, VOL_BASE, ATTN_NORM);
 322 }
 323
 324 #endif
 325
 326 #ifdef CSQC
 327 #include <lib/csqcmodel/interpolate.qh>
 328 #include <lib/warpzone/common.qh>
 329
 330 float autocvar_cl_grapplehook_alpha = 1;
 331
 332 void Draw_CylindricLine(vector from, vector to, float thickness, string texture, float aspect, float shift, vector rgb, float theAlpha, float drawflag, vector vieworg);
 333
 334 entityclass(Hook);
 335 class(Hook) .entity HookType; // ENT_CLIENT_*
 336 class(Hook) .vector origin;
 337 class(Hook) .vector velocity;
 338 class(Hook) .float HookSilent;
 339 class(Hook) .float HookRange;
 340
 341 string Draw_GrapplingHook_trace_callback_tex;
 342 float Draw_GrapplingHook_trace_callback_rnd;
 343 vector Draw_GrapplingHook_trace_callback_rgb;
 344 float Draw_GrapplingHook_trace_callback_a;
 345 void Draw_GrapplingHook_trace_callback(vector start, vector hit, vector end)
 346 {
 347         float i;
 348         vector vorg;
 349         vorg = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 350         for(i = 0; i < Draw_GrapplingHook_trace_callback_a; ++i)
 351                 Draw_CylindricLine(hit, start, 8, Draw_GrapplingHook_trace_callback_tex, 0.25, Draw_GrapplingHook_trace_callback_rnd, Draw_GrapplingHook_trace_callback_rgb, min(1, Draw_GrapplingHook_trace_callback_a - i), DRAWFLAG_NORMAL, vorg);
 352         Draw_GrapplingHook_trace_callback_rnd += 0.25 * vlen(hit - start) / 8;
 353 }
 354
 355 class(Hook) .float teleport_time;
 356 void Draw_GrapplingHook(entity this)
 357 {
 358         vector a, b, atrans;
 359         string tex;
 360         vector rgb;
 361         float t;
 362         vector vs;
 363         float intensity, offset;
 364
 365         if(this.teleport_time)
 366         if(time > this.teleport_time)
 367         {
 368                 sound (this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM); // safeguard
 369                 this.teleport_time = 0;
 370         }
 371
 372         InterpolateOrigin_Do(this);
 373
 374         int s = W_GetGunAlignment(NULL);
 375
 376         switch(this.HookType)
 377         {
 378                 default:
 379                 case NET_ENT_CLIENT_HOOK:
 380                         vs = hook_shotorigin[s];
 381                         break;
 382                 case NET_ENT_CLIENT_ARC_BEAM:
 383                         vs = lightning_shotorigin[s];
 384                         break;
 385         }
 386
 387         if((this.owner.sv_entnum == player_localentnum - 1))
 388         {
 389                 switch(this.HookType)
 390                 {
 391                         default:
 392                         case NET_ENT_CLIENT_HOOK:
 393                                 if(autocvar_chase_active > 0)
 394                                         a = csqcplayer.origin;
 395                                 else
 396                                         a = view_origin + view_forward * vs.x + view_right * -vs.y + view_up * vs.z;
 397                                 b = this.origin;
 398                                 break;
 399                         case NET_ENT_CLIENT_ARC_BEAM:
 400                                 if(this.HookRange)
 401                                         b = view_origin + view_forward * this.HookRange;
 402                                 else
 403                                         b = view_origin + view_forward * vlen(this.velocity - this.origin); // honor original length of beam!
 404                                 WarpZone_TraceLine(view_origin, b, MOVE_NORMAL, NULL);
 405                                 b = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 406                                 a = view_origin + view_forward * vs.x + view_right * -vs.y + view_up * vs.z;
 407                                 break;
 408                 }
 409         }
 410         else
 411         {
 412                 switch(this.HookType)
 413                 {
 414                         default:
 415                         case NET_ENT_CLIENT_HOOK:
 416                                 a = this.velocity;
 417                                 b = this.origin;
 418                                 break;
 419                         case NET_ENT_CLIENT_ARC_BEAM:
 420                                 a = this.origin;
 421                                 b = this.velocity;
 422                                 break;
 423                 }
 424         }
 425
 426         t = entcs_GetTeamColor(this.owner.sv_entnum);
 427
 428         switch(this.HookType)
 429         {
 430                 default:
 431                 case NET_ENT_CLIENT_HOOK:
 432                         intensity = autocvar_cl_grapplehook_alpha;
 433                         offset = 0;
 434                         switch(t)
 435                         {
 436                                 case NUM_TEAM_1: tex = "particles/hook_red"; rgb = '1 0.3 0.3'; break;
 437                                 case NUM_TEAM_2: tex = "particles/hook_blue"; rgb = '0.3 0.3 1'; break;
 438                                 case NUM_TEAM_3: tex = "particles/hook_yellow"; rgb = '1 1 0.3'; break;
 439                                 case NUM_TEAM_4: tex = "particles/hook_pink"; rgb = '1 0.3 1'; break;
 440                                 default: tex = "particles/hook_white"; rgb = entcs_GetColor(this.sv_entnum - 1); break;
 441                         }
 442                         break;
 443                 case NET_ENT_CLIENT_ARC_BEAM: // todo
 444                         intensity = bound(0.2, 1 + Noise_Pink(this, frametime) * 1 + Noise_Burst(this, frametime, 0.03) * 0.3, 2);
 445                         offset = Noise_Brown(this, frametime) * 10;
 446                         tex = "particles/lgbeam";
 447                         rgb = '1 1 1';
 448                         break;
 449         }
 450
 451         MUTATOR_CALLHOOK(DrawGrapplingHook, this, tex, rgb, t);
 452         tex = M_ARGV(1, string);
 453         rgb = M_ARGV(2, vector);
 454
 455         Draw_GrapplingHook_trace_callback_tex = tex;
 456         Draw_GrapplingHook_trace_callback_rnd = offset;
 457         Draw_GrapplingHook_trace_callback_rgb = rgb;
 458         Draw_GrapplingHook_trace_callback_a = intensity;
 459         WarpZone_TraceBox_ThroughZone(a, '0 0 0', '0 0 0', b, ((this.HookType == NET_ENT_CLIENT_HOOK) ? MOVE_NOTHING : MOVE_NORMAL), NULL, NULL, Draw_GrapplingHook_trace_callback);
 460         Draw_GrapplingHook_trace_callback_tex = string_null;
 461
 462         atrans = WarpZone_TransformOrigin(WarpZone_trace_transform, a);
 463
 464         switch(this.HookType)
 465         {
 466                 default:
 467                 case NET_ENT_CLIENT_HOOK:
 468                         if(vdist(trace_endpos - atrans, >, 0.5))
 469                         {
 470                                 setorigin(this, trace_endpos); // hook endpoint!
 471                                 this.angles = vectoangles(trace_endpos - atrans);
 472                                 this.drawmask = MASK_NORMAL;
 473                         }
 474                         else
 475                         {
 476                                 this.drawmask = 0;
 477                         }
 478                         break;
 479                 case NET_ENT_CLIENT_ARC_BEAM:
 480                         setorigin(this, a); // beam origin!
 481                         break;
 482         }
 483
 484         switch(this.HookType)
 485         {
 486                 default:
 487                 case NET_ENT_CLIENT_HOOK:
 488                         break;
 489                 case NET_ENT_CLIENT_ARC_BEAM:
 490                         pointparticles(EFFECT_ARC_LIGHTNING2, trace_endpos, normalize(atrans - trace_endpos), frametime * intensity); // todo: new effect
 491                         break;
 492         }
 493 }
 494
 495 void Remove_GrapplingHook(entity this)
 496 {
 497         sound (this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 498
 499         if(csqcplayer && csqcplayer.hook == this)
 500                 csqcplayer.hook = NULL;
 501 }
 502
 503 NET_HANDLE(ENT_CLIENT_HOOK, bool bIsNew)
 504 {
 505         this.HookType = NET_ENT_CLIENT_HOOK;
 506
 507         int sf = ReadByte();
 508
 509         this.HookSilent = (sf & 0x80);
 510         this.iflags = IFLAG_VELOCITY | IFLAG_ORIGIN;
 511
 512         InterpolateOrigin_Undo(this);
 513
 514         if(sf & 1)
 515         {
 516                 int myowner = ReadByte();
 517                 this.owner = playerslots[myowner - 1];
 518                 this.sv_entnum = myowner;
 519                 if(csqcplayer && myowner == player_localentnum)
 520                         csqcplayer.hook = this;
 521                 switch(this.HookType)
 522                 {
 523                         default:
 524                         case NET_ENT_CLIENT_HOOK:
 525                                 this.HookRange = 0;
 526                                 break;
 527                         case NET_ENT_CLIENT_ARC_BEAM:
 528                                 this.HookRange = ReadCoord();
 529                                 break;
 530                 }
 531         }
 532         if(sf & 2)
 533         {
 534                 this.origin_x = ReadCoord();
 535                 this.origin_y = ReadCoord();
 536                 this.origin_z = ReadCoord();
 537                 setorigin(this, this.origin);
 538         }
 539         if(sf & 4)
 540         {
 541                 this.velocity_x = ReadCoord();
 542                 this.velocity_y = ReadCoord();
 543                 this.velocity_z = ReadCoord();
 544         }
 545
 546         InterpolateOrigin_Note(this);
 547
 548         if(bIsNew || !this.teleport_time)
 549         {
 550                 this.draw = Draw_GrapplingHook;
 551                 IL_PUSH(g_drawables, this);
 552                 this.entremove = Remove_GrapplingHook;
 553
 554                 switch(this.HookType)
 555                 {
 556                         default:
 557                         case NET_ENT_CLIENT_HOOK:
 558                                 // for the model
 559                                 setmodel(this, MDL_HOOK);
 560                                 this.drawmask = MASK_NORMAL;
 561                                 break;
 562                         case NET_ENT_CLIENT_ARC_BEAM:
 563                                 sound (this, CH_SHOTS_SINGLE, SND_LGBEAM_FLY, VOL_BASE, ATTEN_NORM);
 564                                 break;
 565                 }
 566         }
 567
 568         this.teleport_time = time + 10;
 569         return true;
 570 }
 571
 572 // TODO: hook: temporarily transform this.origin for drawing the model along warpzones!
 573 #endif
 574
 575 #endif