qcsrc/common/weapons/weapon/hook.qc

   1 #include "hook.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Hook, Weapon)
   4 /* ammotype  */ ATTRIB(Hook, ammo_field, .int, ammo_fuel);
   5 /* impulse   */ ATTRIB(Hook, impulse, int, 0);
   6 /* flags     */ ATTRIB(Hook, spawnflags, int, WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   7 /* rating    */ ATTRIB(Hook, bot_pickupbasevalue, float, 0);
   8 /* color     */ ATTRIB(Hook, wpcolor, vector, '0 0.5 0');
   9 /* modelname */ ATTRIB(Hook, mdl, string, "hookgun");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Hook, m_model, Model, MDL_HOOK_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Hook, w_crosshair, string, "gfx/crosshairhook");
  14 /* crosshair */ ATTRIB(Hook, w_crosshair_size, float, 0.5);
  15 /* wepimg    */ ATTRIB(Hook, model2, string, "weaponhook");
  16 /* refname   */ ATTRIB(Hook, netname, string, "hook");
  17 /* wepname   */ ATTRIB(Hook, m_name, string, _("Grappling Hook"));
  18         ATTRIB(Hook, ammo_factor, float, 1);
  19
  20 #define X(BEGIN, P, END, class, prefix) \
  21         BEGIN(class) \
  22                 P(class, prefix, ammo, float, PRI) \
  23                 P(class, prefix, animtime, float, BOTH) \
  24                 P(class, prefix, damageforcescale, float, SEC) \
  25                 P(class, prefix, damage, float, SEC) \
  26                 P(class, prefix, duration, float, SEC) \
  27                 P(class, prefix, edgedamage, float, SEC) \
  28                 P(class, prefix, force, float, SEC) \
  29                 P(class, prefix, gravity, float, SEC) \
  30                 P(class, prefix, health, float, SEC) \
  31                 P(class, prefix, hooked_ammo, float, PRI) \
  32                 P(class, prefix, hooked_time_free, float, PRI) \
  33                 P(class, prefix, hooked_time_max, float, PRI) \
  34                 P(class, prefix, lifetime, float, SEC) \
  35                 P(class, prefix, power, float, SEC) \
  36                 P(class, prefix, radius, float, SEC) \
  37                 P(class, prefix, refire, float, BOTH) \
  38                 P(class, prefix, speed, float, SEC) \
  39         P(class, prefix, switchdelay_drop, float, NONE) \
  40                 P(class, prefix, switchdelay_raise, float, NONE) \
  41         P(class, prefix, weaponreplace, string, NONE) \
  42         P(class, prefix, weaponstartoverride, float, NONE) \
  43         P(class, prefix, weaponstart, float, NONE) \
  44         P(class, prefix, weaponthrowable, float, NONE) \
  45         END()
  46     W_PROPS(X, Hook, hook)
  47 #undef X
  48
  49 ENDCLASS(Hook)
  50 REGISTER_WEAPON(HOOK, hook, NEW(Hook));
  51
  52 CLASS(OffhandHook, OffhandWeapon)
  53 #ifdef SVQC
  54     METHOD(OffhandHook, offhand_think, void(OffhandHook this, entity actor, bool key_pressed))
  55     {
  56         Weapon wep = WEP_HOOK;
  57         .entity weaponentity = weaponentities[1];
  58         wep.wr_think(wep, actor, weaponentity, key_pressed ? 1 : 0);
  59     }
  60 #endif
  61 ENDCLASS(OffhandHook)
  62 OffhandHook OFFHAND_HOOK; STATIC_INIT(OFFHAND_HOOK) { OFFHAND_HOOK = NEW(OffhandHook); }
  63
  64 #ifdef SVQC
  65
  66 .float dmg;
  67 .float dmg_edge;
  68 .float dmg_radius;
  69 .float dmg_force;
  70 .float dmg_power;
  71 .float dmg_duration;
  72 .float dmg_last;
  73 .float hook_refire;
  74 .float hook_time_hooked;
  75 .float hook_time_fueldecrease;
  76 #endif
  77 #endif
  78 #ifdef IMPLEMENTATION
  79 #ifdef SVQC
  80
  81 spawnfunc(weapon_hook) { weapon_defaultspawnfunc(this, WEP_HOOK); }
  82
  83 void W_Hook_ExplodeThink(entity this)
  84 {
  85         float dt, dmg_remaining_next, f;
  86
  87         dt = time - this.teleport_time;
  88         dmg_remaining_next = pow(bound(0, 1 - dt / this.dmg_duration, 1), this.dmg_power);
  89
  90         f = this.dmg_last - dmg_remaining_next;
  91         this.dmg_last = dmg_remaining_next;
  92
  93         RadiusDamage(this, this.realowner, this.dmg * f, this.dmg_edge * f, this.dmg_radius, this.realowner, NULL, this.dmg_force * f, this.projectiledeathtype, NULL);
  94         this.projectiledeathtype |= HITTYPE_BOUNCE;
  95         //RadiusDamage(this, NULL, this.dmg * f, this.dmg_edge * f, this.dmg_radius, NULL, NULL, this.dmg_force * f, this.projectiledeathtype, NULL);
  96
  97         if(dt < this.dmg_duration)
  98                 this.nextthink = time + 0.05; // soon
  99         else
 100                 delete(this);
 101 }
 102
 103 void W_Hook_Explode2(entity this)
 104 {
 105         this.event_damage = func_null;
 106         settouch(this, func_null);
 107         this.effects |= EF_NODRAW;
 108
 109         setthink(this, W_Hook_ExplodeThink);
 110         this.nextthink = time;
 111         this.dmg = WEP_CVAR_SEC(hook, damage);
 112         this.dmg_edge = WEP_CVAR_SEC(hook, edgedamage);
 113         this.dmg_radius = WEP_CVAR_SEC(hook, radius);
 114         this.dmg_force = WEP_CVAR_SEC(hook, force);
 115         this.dmg_power = WEP_CVAR_SEC(hook, power);
 116         this.dmg_duration = WEP_CVAR_SEC(hook, duration);
 117         this.teleport_time = time;
 118         this.dmg_last = 1;
 119         set_movetype(this, MOVETYPE_NONE);
 120 }
 121
 122 void W_Hook_Explode2_use(entity this, entity actor, entity trigger)
 123 {
 124         W_Hook_Explode2(this);
 125 }
 126
 127 void W_Hook_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 128 {
 129         if(this.health <= 0)
 130                 return;
 131
 132         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 133                 return; // g_projectiles_damage says to halt
 134
 135         this.health = this.health - damage;
 136
 137         if(this.health <= 0)
 138                 W_PrepareExplosionByDamage(this, this.realowner, W_Hook_Explode2);
 139 }
 140
 141 void W_Hook_Touch2(entity this, entity toucher)
 142 {
 143         PROJECTILE_TOUCH(this, toucher);
 144         this.use(this, NULL, NULL);
 145 }
 146
 147 void W_Hook_Attack2(Weapon thiswep, entity actor, .entity weaponentity)
 148 {
 149         //W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hook, ammo)); // WEAPONTODO: Figure out how to handle ammo with hook secondary (gravitybomb)
 150         W_SetupShot(actor, weaponentity, false, 4, SND_HOOKBOMB_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(hook, damage));
 151
 152         entity gren = new(hookbomb);
 153         gren.owner = gren.realowner = actor;
 154         gren.bot_dodge = true;
 155         gren.bot_dodgerating = WEP_CVAR_SEC(hook, damage);
 156         set_movetype(gren, MOVETYPE_TOSS);
 157         PROJECTILE_MAKETRIGGER(gren);
 158         gren.projectiledeathtype = WEP_HOOK.m_id | HITTYPE_SECONDARY;
 159         setorigin(gren, w_shotorg);
 160         setsize(gren, '0 0 0', '0 0 0');
 161
 162         gren.nextthink = time + WEP_CVAR_SEC(hook, lifetime);
 163         setthink(gren, adaptor_think2use_hittype_splash);
 164         gren.use = W_Hook_Explode2_use;
 165         settouch(gren, W_Hook_Touch2);
 166
 167         gren.takedamage = DAMAGE_YES;
 168         gren.health = WEP_CVAR_SEC(hook, health);
 169         gren.damageforcescale = WEP_CVAR_SEC(hook, damageforcescale);
 170         gren.event_damage = W_Hook_Damage;
 171         gren.damagedbycontents = true;
 172         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 173
 174         gren.velocity = '0 0 1' * WEP_CVAR_SEC(hook, speed);
 175         if (autocvar_g_projectiles_newton_style)
 176                 gren.velocity = gren.velocity + actor.velocity;
 177
 178         gren.gravity = WEP_CVAR_SEC(hook, gravity);
 179         //W_SetupProjVelocity_Basic(gren); // just falling down!
 180
 181         gren.angles = '0 0 0';
 182         gren.flags = FL_PROJECTILE;
 183         IL_PUSH(g_projectiles, gren);
 184         IL_PUSH(g_bot_dodge, gren);
 185
 186         CSQCProjectile(gren, true, PROJECTILE_HOOKBOMB, true);
 187
 188         MUTATOR_CALLHOOK(EditProjectile, actor, gren);
 189 }
 190
 191 METHOD(Hook, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 192 {
 193     if (fire & 1) {
 194         if(!actor.(weaponentity).hook)
 195         if(!(actor.(weaponentity).hook_state & HOOK_WAITING_FOR_RELEASE))
 196         if(time > actor.(weaponentity).hook_refire)
 197         if(weapon_prepareattack(thiswep, actor, weaponentity, false, -1))
 198         {
 199             W_DecreaseAmmo(thiswep, actor, thiswep.ammo_factor * WEP_CVAR_PRI(hook, ammo), weaponentity);
 200             actor.(weaponentity).hook_state |= HOOK_FIRING;
 201             actor.(weaponentity).hook_state |= HOOK_WAITING_FOR_RELEASE;
 202             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(hook, animtime), w_ready);
 203         }
 204     } else {
 205         actor.(weaponentity).hook_state |= HOOK_REMOVING;
 206         actor.(weaponentity).hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 207     }
 208
 209     if(fire & 2)
 210     {
 211         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(hook, refire)))
 212         {
 213             W_Hook_Attack2(thiswep, actor, weaponentity);
 214             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(hook, animtime), w_ready);
 215         }
 216     }
 217
 218     if(actor.(weaponentity).hook)
 219     {
 220         // if hooked, no bombs, and increase the timer
 221         actor.(weaponentity).hook_refire = max(actor.(weaponentity).hook_refire, time + WEP_CVAR_PRI(hook, refire) * W_WeaponRateFactor(actor));
 222
 223         // hook also inhibits health regeneration, but only for 1 second
 224         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 225             actor.pauseregen_finished = max(actor.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 226     }
 227
 228     if(actor.(weaponentity).hook && actor.(weaponentity).hook.state == 1)
 229     {
 230         float hooked_time_max = WEP_CVAR_PRI(hook, hooked_time_max);
 231         if(hooked_time_max > 0)
 232         {
 233             if( time > actor.(weaponentity).hook_time_hooked + hooked_time_max )
 234                 actor.(weaponentity).hook_state |= HOOK_REMOVING;
 235         }
 236
 237         float hooked_fuel = thiswep.ammo_factor * WEP_CVAR_PRI(hook, hooked_ammo);
 238         if(hooked_fuel > 0)
 239         {
 240             if( time > actor.(weaponentity).hook_time_fueldecrease )
 241             {
 242                 if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 243                 {
 244                     if( actor.ammo_fuel >= (time - actor.(weaponentity).hook_time_fueldecrease) * hooked_fuel )
 245                     {
 246                         W_DecreaseAmmo(thiswep, actor, (time - actor.(weaponentity).hook_time_fueldecrease) * hooked_fuel, weaponentity);
 247                         actor.(weaponentity).hook_time_fueldecrease = time;
 248                         // decrease next frame again
 249                     }
 250                     else
 251                     {
 252                         actor.ammo_fuel = 0;
 253                         actor.(weaponentity).hook_state |= HOOK_REMOVING;
 254                         W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 255                     }
 256                 }
 257             }
 258         }
 259     }
 260     else
 261     {
 262         actor.(weaponentity).hook_time_hooked = time;
 263         actor.(weaponentity).hook_time_fueldecrease = time + WEP_CVAR_PRI(hook, hooked_time_free);
 264     }
 265
 266     actor.(weaponentity).hook_state = BITSET(actor.(weaponentity).hook_state, HOOK_PULLING, (!PHYS_INPUT_BUTTON_CROUCH(actor) || !autocvar_g_balance_grapplehook_crouchslide));
 267
 268     if (actor.(weaponentity).hook_state & HOOK_FIRING)
 269     {
 270         if (actor.(weaponentity).hook)
 271             RemoveHook(actor.(weaponentity).hook);
 272         FireGrapplingHook(actor, weaponentity);
 273         actor.(weaponentity).hook_state &= ~HOOK_FIRING;
 274         actor.(weaponentity).hook_refire = max(actor.(weaponentity).hook_refire, time + autocvar_g_balance_grapplehook_refire * W_WeaponRateFactor(actor));
 275     }
 276     else if (actor.(weaponentity).hook_state & HOOK_REMOVING)
 277     {
 278         if (actor.(weaponentity).hook)
 279             RemoveHook(actor.(weaponentity).hook);
 280         actor.(weaponentity).hook_state &= ~HOOK_REMOVING;
 281     }
 282 }
 283 METHOD(Hook, wr_setup, void(entity thiswep, entity actor, .entity weaponentity))
 284 {
 285         actor.(weaponentity).hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 286 }
 287 METHOD(Hook, wr_checkammo1, bool(Hook thiswep, entity actor, .entity weaponentity))
 288 {
 289     if (!thiswep.ammo_factor) return true;
 290
 291     if(actor.(weaponentity).hook)
 292         return actor.ammo_fuel > 0;
 293
 294     return actor.ammo_fuel >= WEP_CVAR_PRI(hook, ammo);
 295 }
 296 METHOD(Hook, wr_checkammo2, bool(Hook thiswep, entity actor, .entity weaponentity))
 297 {
 298     // infinite ammo for now
 299     return true; // actor.ammo_cells >= WEP_CVAR_SEC(hook, ammo); // WEAPONTODO: see above
 300 }
 301 METHOD(Hook, wr_resetplayer, void(entity thiswep, entity actor))
 302 {
 303     RemoveGrapplingHooks(actor);
 304     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 305     {
 306         .entity weaponentity = weaponentities[slot];
 307         actor.(weaponentity).hook_time = 0;
 308         actor.(weaponentity).hook_refire = time;
 309     }
 310 }
 311 METHOD(Hook, wr_killmessage, Notification(entity thiswep))
 312 {
 313     return WEAPON_HOOK_MURDER;
 314 }
 315
 316 #endif
 317 #ifdef CSQC
 318
 319 METHOD(Hook, wr_impacteffect, void(entity thiswep, entity actor))
 320 {
 321     vector org2;
 322     org2 = w_org + w_backoff * 2;
 323     pointparticles(EFFECT_HOOK_EXPLODE, org2, '0 0 0', 1);
 324     if(!w_issilent)
 325         sound(actor, CH_SHOTS, SND_HOOKBOMB_IMPACT, VOL_BASE, ATTN_NORM);
 326 }
 327
 328 #endif
 329
 330 #ifdef CSQC
 331 #include <lib/csqcmodel/interpolate.qh>
 332 #include <lib/warpzone/common.qh>
 333
 334 float autocvar_cl_grapplehook_alpha = 1;
 335
 336 void Draw_CylindricLine(vector from, vector to, float thickness, string texture, float aspect, float shift, vector rgb, float theAlpha, float drawflag, vector vieworg);
 337
 338 entityclass(Hook);
 339 class(Hook) .entity HookType; // ENT_CLIENT_*
 340 class(Hook) .vector origin;
 341 class(Hook) .vector velocity;
 342 class(Hook) .float HookSilent;
 343 class(Hook) .float HookRange;
 344
 345 string Draw_GrapplingHook_trace_callback_tex;
 346 float Draw_GrapplingHook_trace_callback_rnd;
 347 vector Draw_GrapplingHook_trace_callback_rgb;
 348 float Draw_GrapplingHook_trace_callback_a;
 349 void Draw_GrapplingHook_trace_callback(vector start, vector hit, vector end)
 350 {
 351         float i;
 352         vector vorg;
 353         vorg = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 354         for(i = 0; i < Draw_GrapplingHook_trace_callback_a; ++i)
 355                 Draw_CylindricLine(hit, start, 8, Draw_GrapplingHook_trace_callback_tex, 0.25, Draw_GrapplingHook_trace_callback_rnd, Draw_GrapplingHook_trace_callback_rgb, min(1, Draw_GrapplingHook_trace_callback_a - i), DRAWFLAG_NORMAL, vorg);
 356         Draw_GrapplingHook_trace_callback_rnd += 0.25 * vlen(hit - start) / 8;
 357 }
 358
 359 class(Hook) .float teleport_time;
 360 void Draw_GrapplingHook(entity this)
 361 {
 362         vector a, b, atrans;
 363         string tex;
 364         vector rgb;
 365         float t;
 366         vector vs;
 367         float intensity, offset;
 368
 369         if(this.teleport_time)
 370         if(time > this.teleport_time)
 371         {
 372                 sound (this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM); // safeguard
 373                 this.teleport_time = 0;
 374         }
 375
 376         InterpolateOrigin_Do(this);
 377
 378         int s = W_GunAlign(viewmodels[this.cnt], STAT(GUNALIGN)) - 1;
 379
 380         switch(this.HookType)
 381         {
 382                 default:
 383                 case NET_ENT_CLIENT_HOOK:
 384                         vs = hook_shotorigin[s];
 385                         break;
 386                 case NET_ENT_CLIENT_ARC_BEAM:
 387                         vs = lightning_shotorigin[s];
 388                         break;
 389         }
 390
 391         if((this.owner.sv_entnum == player_localentnum - 1))
 392         {
 393                 switch(this.HookType)
 394                 {
 395                         default:
 396                         case NET_ENT_CLIENT_HOOK:
 397                                 if(autocvar_chase_active > 0)
 398                                         a = csqcplayer.origin;
 399                                 else
 400                                         a = view_origin + view_forward * vs.x + view_right * -vs.y + view_up * vs.z;
 401                                 b = this.origin;
 402                                 break;
 403                         case NET_ENT_CLIENT_ARC_BEAM:
 404                                 if(this.HookRange)
 405                                         b = view_origin + view_forward * this.HookRange;
 406                                 else
 407                                         b = view_origin + view_forward * vlen(this.velocity - this.origin); // honor original length of beam!
 408                                 WarpZone_TraceLine(view_origin, b, MOVE_NORMAL, NULL);
 409                                 b = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 410                                 a = view_origin + view_forward * vs.x + view_right * -vs.y + view_up * vs.z;
 411                                 break;
 412                 }
 413         }
 414         else
 415         {
 416                 switch(this.HookType)
 417                 {
 418                         default:
 419                         case NET_ENT_CLIENT_HOOK:
 420                                 a = this.velocity;
 421                                 b = this.origin;
 422                                 break;
 423                         case NET_ENT_CLIENT_ARC_BEAM:
 424                                 a = this.origin;
 425                                 b = this.velocity;
 426                                 break;
 427                 }
 428         }
 429
 430         t = entcs_GetTeamColor(this.owner.sv_entnum);
 431
 432         switch(this.HookType)
 433         {
 434                 default:
 435                 case NET_ENT_CLIENT_HOOK:
 436                         intensity = autocvar_cl_grapplehook_alpha;
 437                         offset = 0;
 438                         switch(t)
 439                         {
 440                                 case NUM_TEAM_1: tex = "particles/hook_red"; rgb = '1 0.3 0.3'; break;
 441                                 case NUM_TEAM_2: tex = "particles/hook_blue"; rgb = '0.3 0.3 1'; break;
 442                                 case NUM_TEAM_3: tex = "particles/hook_yellow"; rgb = '1 1 0.3'; break;
 443                                 case NUM_TEAM_4: tex = "particles/hook_pink"; rgb = '1 0.3 1'; break;
 444                                 default: tex = "particles/hook_white"; rgb = entcs_GetColor(this.sv_entnum - 1); break;
 445                         }
 446                         break;
 447                 case NET_ENT_CLIENT_ARC_BEAM: // todo
 448                         intensity = bound(0.2, 1 + Noise_Pink(this, frametime) * 1 + Noise_Burst(this, frametime, 0.03) * 0.3, 2);
 449                         offset = Noise_Brown(this, frametime) * 10;
 450                         tex = "particles/lgbeam";
 451                         rgb = '1 1 1';
 452                         break;
 453         }
 454
 455         MUTATOR_CALLHOOK(DrawGrapplingHook, this, tex, rgb, t);
 456         tex = M_ARGV(1, string);
 457         rgb = M_ARGV(2, vector);
 458
 459         Draw_GrapplingHook_trace_callback_tex = tex;
 460         Draw_GrapplingHook_trace_callback_rnd = offset;
 461         Draw_GrapplingHook_trace_callback_rgb = rgb;
 462         Draw_GrapplingHook_trace_callback_a = intensity;
 463         WarpZone_TraceBox_ThroughZone(a, '0 0 0', '0 0 0', b, ((this.HookType == NET_ENT_CLIENT_HOOK) ? MOVE_NOTHING : MOVE_NORMAL), NULL, NULL, Draw_GrapplingHook_trace_callback);
 464         Draw_GrapplingHook_trace_callback_tex = string_null;
 465
 466         atrans = WarpZone_TransformOrigin(WarpZone_trace_transform, a);
 467
 468         switch(this.HookType)
 469         {
 470                 default:
 471                 case NET_ENT_CLIENT_HOOK:
 472                         if(vdist(trace_endpos - atrans, >, 0.5))
 473                         {
 474                                 setorigin(this, trace_endpos); // hook endpoint!
 475                                 this.angles = vectoangles(trace_endpos - atrans);
 476                                 this.drawmask = MASK_NORMAL;
 477                         }
 478                         else
 479                         {
 480                                 this.drawmask = 0;
 481                         }
 482                         break;
 483                 case NET_ENT_CLIENT_ARC_BEAM:
 484                         setorigin(this, a); // beam origin!
 485                         break;
 486         }
 487
 488         switch(this.HookType)
 489         {
 490                 default:
 491                 case NET_ENT_CLIENT_HOOK:
 492                         break;
 493                 case NET_ENT_CLIENT_ARC_BEAM:
 494                         pointparticles(EFFECT_ARC_LIGHTNING2, trace_endpos, normalize(atrans - trace_endpos), frametime * intensity); // todo: new effect
 495                         break;
 496         }
 497 }
 498
 499 void Remove_GrapplingHook(entity this)
 500 {
 501         sound (this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 502
 503         if(csqcplayer && csqcplayer.hook == this)
 504                 csqcplayer.hook = NULL;
 505 }
 506
 507 NET_HANDLE(ENT_CLIENT_HOOK, bool bIsNew)
 508 {
 509         this.HookType = NET_ENT_CLIENT_HOOK;
 510
 511         int sf = ReadByte();
 512
 513         this.HookSilent = (sf & 0x80);
 514         this.iflags = IFLAG_VELOCITY | IFLAG_ORIGIN;
 515
 516         InterpolateOrigin_Undo(this);
 517
 518         if(sf & 1)
 519         {
 520                 int myowner = ReadByte();
 521                 int slot = ReadByte();
 522                 this.owner = playerslots[myowner - 1];
 523                 this.sv_entnum = myowner;
 524                 if(myowner == player_localentnum)
 525                         viewmodels[slot].hook = this;
 526                 this.cnt = slot;
 527                 switch(this.HookType)
 528                 {
 529                         default:
 530                         case NET_ENT_CLIENT_HOOK:
 531                                 this.HookRange = 0;
 532                                 break;
 533                         case NET_ENT_CLIENT_ARC_BEAM:
 534                                 this.HookRange = ReadCoord();
 535                                 break;
 536                 }
 537         }
 538         if(sf & 2)
 539         {
 540                 this.origin_x = ReadCoord();
 541                 this.origin_y = ReadCoord();
 542                 this.origin_z = ReadCoord();
 543                 setorigin(this, this.origin);
 544         }
 545         if(sf & 4)
 546         {
 547                 this.velocity_x = ReadCoord();
 548                 this.velocity_y = ReadCoord();
 549                 this.velocity_z = ReadCoord();
 550         }
 551
 552         InterpolateOrigin_Note(this);
 553
 554         if(bIsNew || !this.teleport_time)
 555         {
 556                 this.draw = Draw_GrapplingHook;
 557                 IL_PUSH(g_drawables, this);
 558                 this.entremove = Remove_GrapplingHook;
 559
 560                 switch(this.HookType)
 561                 {
 562                         default:
 563                         case NET_ENT_CLIENT_HOOK:
 564                                 // for the model
 565                                 setmodel(this, MDL_HOOK);
 566                                 this.drawmask = MASK_NORMAL;
 567                                 break;
 568                         case NET_ENT_CLIENT_ARC_BEAM:
 569                                 sound (this, CH_SHOTS_SINGLE, SND_LGBEAM_FLY, VOL_BASE, ATTEN_NORM);
 570                                 break;
 571                 }
 572         }
 573
 574         this.teleport_time = time + 10;
 575         return true;
 576 }
 577
 578 // TODO: hook: temporarily transform this.origin for drawing the model along warpzones!
 579 #endif
 580
 581 #endif