qcsrc/common/weapons/weapon/minelayer.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ MINE_LAYER,
   4 /* function  */ W_MineLayer,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 4,
   7 /* flags     */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '0.75 1 0',
  10 /* modelname */ "minelayer",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairminelayer 0.9",
  13 /* wepimg    */ "weaponminelayer",
  14 /* refname   */ "minelayer",
  15 /* wepname   */ _("Mine Layer")
  16 );
  17
  18 #define MINELAYER_SETTINGS(w_cvar,w_prop) MINELAYER_SETTINGS_LIST(w_cvar, w_prop, MINE_LAYER, minelayer)
  19 #define MINELAYER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, ammo) \
  21         w_cvar(id, sn, NONE, animtime) \
  22         w_cvar(id, sn, NONE, damage) \
  23         w_cvar(id, sn, NONE, damageforcescale) \
  24         w_cvar(id, sn, NONE, detonatedelay) \
  25         w_cvar(id, sn, NONE, edgedamage) \
  26         w_cvar(id, sn, NONE, force) \
  27         w_cvar(id, sn, NONE, health) \
  28         w_cvar(id, sn, NONE, lifetime) \
  29         w_cvar(id, sn, NONE, lifetime_countdown) \
  30         w_cvar(id, sn, NONE, limit) \
  31         w_cvar(id, sn, NONE, protection) \
  32         w_cvar(id, sn, NONE, proximityradius) \
  33         w_cvar(id, sn, NONE, radius) \
  34         w_cvar(id, sn, NONE, refire) \
  35         w_cvar(id, sn, NONE, remote_damage) \
  36         w_cvar(id, sn, NONE, remote_edgedamage) \
  37         w_cvar(id, sn, NONE, remote_force) \
  38         w_cvar(id, sn, NONE, remote_radius) \
  39         w_cvar(id, sn, NONE, speed) \
  40         w_cvar(id, sn, NONE, time) \
  41         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  42         w_prop(id, sn, float,  reloading_time, reload_time) \
  43         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  44         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  45         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  46         w_prop(id, sn, float,  weaponstart, weaponstart) \
  47         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  48         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  49
  50 #ifdef SVQC
  51 MINELAYER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  52 void W_MineLayer_Think(void);
  53 .float minelayer_detonate, mine_explodeanyway;
  54 .float mine_time;
  55 .vector mine_orientation;
  56 #endif
  57 #endif
  58 #ifdef IMPLEMENTATION
  59 #ifdef SVQC
  60 void spawnfunc_weapon_minelayer(void) { weapon_defaultspawnfunc(WEP_MINE_LAYER.m_id); }
  61
  62 void W_MineLayer_Stick(entity to)
  63 {SELFPARAM();
  64         spamsound(self, CH_SHOTS, SND(MINE_STICK), VOL_BASE, ATTN_NORM);
  65
  66         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  67
  68         entity newmine;
  69         newmine = spawn();
  70         newmine.classname = self.classname;
  71
  72         newmine.bot_dodge = self.bot_dodge;
  73         newmine.bot_dodgerating = self.bot_dodgerating;
  74
  75         newmine.owner = self.owner;
  76         newmine.realowner = self.realowner;
  77         setsize(newmine, '-4 -4 -4', '4 4 4');
  78         setorigin(newmine, self.origin);
  79         setmodel(newmine, MDL_MINELAYER_MINE);
  80         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  81
  82         newmine.mine_orientation = -trace_plane_normal;
  83
  84         newmine.takedamage = self.takedamage;
  85         newmine.damageforcescale = self.damageforcescale;
  86         newmine.health = self.health;
  87         newmine.event_damage = self.event_damage;
  88         newmine.spawnshieldtime = self.spawnshieldtime;
  89         newmine.damagedbycontents = true;
  90
  91         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  92         newmine.projectiledeathtype = self.projectiledeathtype;
  93
  94         newmine.mine_time = self.mine_time;
  95
  96         newmine.touch = func_null;
  97         newmine.think = W_MineLayer_Think;
  98         newmine.nextthink = time;
  99         newmine.cnt = self.cnt;
 100         newmine.flags = self.flags;
 101
 102         remove(self);
 103         setself(newmine);
 104
 105         if(to)
 106                 SetMovetypeFollow(self, to);
 107 }
 108
 109 void W_MineLayer_Explode(void)
 110 {SELFPARAM();
 111         if(other.takedamage == DAMAGE_AIM)
 112                 if(IS_PLAYER(other))
 113                         if(DIFF_TEAM(self.realowner, other))
 114                                 if(other.deadflag == DEAD_NO)
 115                                         if(IsFlying(other))
 116                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
 117
 118         self.event_damage = func_null;
 119         self.takedamage = DAMAGE_NO;
 120
 121         RadiusDamage(self, self.realowner, WEP_CVAR(minelayer, damage), WEP_CVAR(minelayer, edgedamage), WEP_CVAR(minelayer, radius), world, world, WEP_CVAR(minelayer, force), self.projectiledeathtype, other);
 122
 123         if(self.realowner.weapon == WEP_MINE_LAYER.m_id)
 124         {
 125                 setself(self.realowner);
 126                 if(!WEP_ACTION(WEP_MINE_LAYER.m_id, WR_CHECKAMMO1))
 127                 {
 128                         self.cnt = WEP_MINE_LAYER.m_id;
 129                         ATTACK_FINISHED(self) = time;
 130                         self.switchweapon = w_getbestweapon(self);
 131                 }
 132                 setself(this);
 133         }
 134         self.realowner.minelayer_mines -= 1;
 135         remove(self);
 136 }
 137
 138 void W_MineLayer_DoRemoteExplode(void)
 139 {SELFPARAM();
 140         self.event_damage = func_null;
 141         self.takedamage = DAMAGE_NO;
 142
 143         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 144                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 145
 146         RadiusDamage(self, self.realowner, WEP_CVAR(minelayer, remote_damage), WEP_CVAR(minelayer, remote_edgedamage), WEP_CVAR(minelayer, remote_radius), world, world, WEP_CVAR(minelayer, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 147
 148         if(self.realowner.weapon == WEP_MINE_LAYER.m_id)
 149         {
 150                 setself(self.realowner);
 151                 if(!WEP_ACTION(WEP_MINE_LAYER.m_id, WR_CHECKAMMO1))
 152                 {
 153                         self.cnt = WEP_MINE_LAYER.m_id;
 154                         ATTACK_FINISHED(self) = time;
 155                         self.switchweapon = w_getbestweapon(self);
 156                 }
 157                 setself(this);
 158         }
 159         self.realowner.minelayer_mines -= 1;
 160         remove(self);
 161 }
 162
 163 void W_MineLayer_RemoteExplode(void)
 164 {SELFPARAM();
 165         if(self.realowner.deadflag == DEAD_NO)
 166                 if((self.spawnshieldtime >= 0)
 167                         ? (time >= self.spawnshieldtime) // timer
 168                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(minelayer, remote_radius)) // safety device
 169                 )
 170                 {
 171                         W_MineLayer_DoRemoteExplode();
 172                 }
 173 }
 174
 175 void W_MineLayer_ProximityExplode(void)
 176 {SELFPARAM();
 177         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 178         if(WEP_CVAR(minelayer, protection) && self.mine_explodeanyway == 0)
 179         {
 180                 entity head;
 181                 head = findradius(self.origin, WEP_CVAR(minelayer, radius));
 182                 while(head)
 183                 {
 184                         if(head == self.realowner || SAME_TEAM(head, self.realowner))
 185                                 return;
 186                         head = head.chain;
 187                 }
 188         }
 189
 190         self.mine_time = 0;
 191         W_MineLayer_Explode();
 192 }
 193
 194 int W_MineLayer_Count(entity e)
 195 {
 196         int minecount = 0;
 197         entity mine;
 198         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 199                 minecount += 1;
 200
 201         return minecount;
 202 }
 203
 204 void W_MineLayer_Think(void)
 205 {SELFPARAM();
 206         entity head;
 207
 208         self.nextthink = time;
 209
 210         if(self.movetype == MOVETYPE_FOLLOW)
 211         {
 212                 if(LostMovetypeFollow(self))
 213                 {
 214                         UnsetMovetypeFollow(self);
 215                         self.movetype = MOVETYPE_NONE;
 216                 }
 217         }
 218
 219         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 220         // TODO: replace this mine_trigger.wav sound with a real countdown
 221         if((time > self.cnt) && (!self.mine_time) && (self.cnt > 0))
 222         {
 223                 if(WEP_CVAR(minelayer, lifetime_countdown) > 0)
 224                         spamsound(self, CH_SHOTS, SND(MINE_TRIGGER), VOL_BASE, ATTN_NORM);
 225                 self.mine_time = time + WEP_CVAR(minelayer, lifetime_countdown);
 226                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 227         }
 228
 229         // a player's mines shall explode if he disconnects or dies
 230         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 231         if(!IS_PLAYER(self.realowner) || self.realowner.deadflag != DEAD_NO || self.realowner.frozen)
 232         {
 233                 other = world;
 234                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 235                 W_MineLayer_Explode();
 236                 return;
 237         }
 238
 239         // set the mine for detonation when a foe gets close enough
 240         head = findradius(self.origin, WEP_CVAR(minelayer, proximityradius));
 241         while(head)
 242         {
 243                 if(IS_PLAYER(head) && head.deadflag == DEAD_NO && !head.frozen)
 244                 if(head != self.realowner && DIFF_TEAM(head, self.realowner)) // don't trigger for team mates
 245                 if(!self.mine_time)
 246                 {
 247                         spamsound(self, CH_SHOTS, SND(MINE_TRIGGER), VOL_BASE, ATTN_NORM);
 248                         self.mine_time = time + WEP_CVAR(minelayer, time);
 249                 }
 250                 head = head.chain;
 251         }
 252
 253         // explode if it's time to
 254         if(self.mine_time && time >= self.mine_time)
 255         {
 256                 W_MineLayer_ProximityExplode();
 257                 return;
 258         }
 259
 260         // remote detonation
 261         if(self.realowner.weapon == WEP_MINE_LAYER.m_id)
 262         if(self.realowner.deadflag == DEAD_NO)
 263         if(self.minelayer_detonate)
 264                 W_MineLayer_RemoteExplode();
 265 }
 266
 267 void W_MineLayer_Touch(void)
 268 {SELFPARAM();
 269         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 270                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 271
 272         if(WarpZone_Projectile_Touch())
 273         {
 274                 if(wasfreed(self))
 275                         self.realowner.minelayer_mines -= 1;
 276                 return;
 277         }
 278
 279         if(other && IS_PLAYER(other) && other.deadflag == DEAD_NO)
 280         {
 281                 // hit a player
 282                 // don't stick
 283         }
 284         else
 285         {
 286                 W_MineLayer_Stick(other);
 287         }
 288 }
 289
 290 void W_MineLayer_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 291 {SELFPARAM();
 292         if(self.health <= 0)
 293                 return;
 294
 295         float is_from_enemy = (inflictor.realowner != self.realowner);
 296
 297         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 298                 return; // g_projectiles_damage says to halt
 299
 300         self.health = self.health - damage;
 301         self.angles = vectoangles(self.velocity);
 302
 303         if(self.health <= 0)
 304                 W_PrepareExplosionByDamage(attacker, W_MineLayer_Explode);
 305 }
 306
 307 void W_MineLayer_Attack(void)
 308 {SELFPARAM();
 309         entity mine;
 310         entity flash;
 311
 312         // scan how many mines we placed, and return if we reached our limit
 313         if(WEP_CVAR(minelayer, limit))
 314         {
 315                 if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 316                 {
 317                         // the refire delay keeps this message from being spammed
 318                         Send_Notification(NOTIF_ONE, self, MSG_MULTI, WEAPON_MINELAYER_LIMIT, WEP_CVAR(minelayer, limit));
 319                         play2(self, SND(UNAVAILABLE));
 320                         return;
 321                 }
 322         }
 323
 324         W_DecreaseAmmo(WEP_CVAR(minelayer, ammo));
 325
 326         W_SetupShot_ProjectileSize(self, '-4 -4 -4', '4 4 4', false, 5, SND(MINE_FIRE), CH_WEAPON_A, WEP_CVAR(minelayer, damage));
 327         Send_Effect(EFFECT_ROCKET_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 328
 329         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 330         mine.owner = mine.realowner = self;
 331         if(WEP_CVAR(minelayer, detonatedelay) >= 0)
 332                 mine.spawnshieldtime = time + WEP_CVAR(minelayer, detonatedelay);
 333         else
 334                 mine.spawnshieldtime = -1;
 335         mine.classname = "mine";
 336         mine.bot_dodge = true;
 337         mine.bot_dodgerating = WEP_CVAR(minelayer, damage) * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 338
 339         mine.takedamage = DAMAGE_YES;
 340         mine.damageforcescale = WEP_CVAR(minelayer, damageforcescale);
 341         mine.health = WEP_CVAR(minelayer, health);
 342         mine.event_damage = W_MineLayer_Damage;
 343         mine.damagedbycontents = true;
 344
 345         mine.movetype = MOVETYPE_TOSS;
 346         PROJECTILE_MAKETRIGGER(mine);
 347         mine.projectiledeathtype = WEP_MINE_LAYER.m_id;
 348         setsize(mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 349
 350         setorigin(mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 351         W_SetupProjVelocity_Basic(mine, WEP_CVAR(minelayer, speed), 0);
 352         mine.angles = vectoangles(mine.velocity);
 353
 354         mine.touch = W_MineLayer_Touch;
 355         mine.think = W_MineLayer_Think;
 356         mine.nextthink = time;
 357         mine.cnt = (WEP_CVAR(minelayer, lifetime) - WEP_CVAR(minelayer, lifetime_countdown));
 358         mine.flags = FL_PROJECTILE;
 359         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 360
 361         if(mine.cnt > 0) { mine.cnt += time; }
 362
 363         CSQCProjectile(mine, true, PROJECTILE_MINE, true);
 364
 365         // muzzle flash for 1st person view
 366         flash = spawn();
 367         setmodel(flash, MDL_MINELAYER_MUZZLEFLASH); // precision set below
 368         SUB_SetFade(flash, time, 0.1);
 369         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 370         W_AttachToShotorg(flash, '5 0 0');
 371
 372         // common properties
 373
 374         MUTATOR_CALLHOOK(EditProjectile, self, mine);
 375
 376         self.minelayer_mines = W_MineLayer_Count(self);
 377 }
 378
 379 float W_MineLayer_PlacedMines(float detonate)
 380 {SELFPARAM();
 381         entity mine;
 382         float minfound = 0;
 383
 384         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 385         {
 386                 if(detonate)
 387                 {
 388                         if(!mine.minelayer_detonate)
 389                         {
 390                                 mine.minelayer_detonate = true;
 391                                 minfound = 1;
 392                         }
 393                 }
 394                 else
 395                         minfound = 1;
 396         }
 397         return minfound;
 398 }
 399
 400 bool W_MineLayer(int req)
 401 {SELFPARAM();
 402         entity mine;
 403         float ammo_amount;
 404         switch(req)
 405         {
 406                 case WR_AIM:
 407                 {
 408                         // aim and decide to fire if appropriate
 409                         if(self.minelayer_mines >= WEP_CVAR(minelayer, limit))
 410                                 self.BUTTON_ATCK = false;
 411                         else
 412                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(minelayer, speed), 0, WEP_CVAR(minelayer, lifetime), false);
 413                         if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 414                         {
 415                                 // decide whether to detonate mines
 416                                 entity targetlist, targ;
 417                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 418                                 float selfdamage, teamdamage, enemydamage;
 419                                 edgedamage = WEP_CVAR(minelayer, edgedamage);
 420                                 coredamage = WEP_CVAR(minelayer, damage);
 421                                 edgeradius = WEP_CVAR(minelayer, radius);
 422                                 recipricoledgeradius = 1 / edgeradius;
 423                                 selfdamage = 0;
 424                                 teamdamage = 0;
 425                                 enemydamage = 0;
 426                                 targetlist = findchainfloat(bot_attack, true);
 427                                 mine = find(world, classname, "mine");
 428                                 while(mine)
 429                                 {
 430                                         if(mine.realowner != self)
 431                                         {
 432                                                 mine = find(mine, classname, "mine");
 433                                                 continue;
 434                                         }
 435                                         targ = targetlist;
 436                                         while(targ)
 437                                         {
 438                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 439                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 440                                                 // count potential damage according to type of target
 441                                                 if(targ == self)
 442                                                         selfdamage = selfdamage + d;
 443                                                 else if(targ.team == self.team && teamplay)
 444                                                         teamdamage = teamdamage + d;
 445                                                 else if(bot_shouldattack(targ))
 446                                                         enemydamage = enemydamage + d;
 447                                                 targ = targ.chain;
 448                                         }
 449                                         mine = find(mine, classname, "mine");
 450                                 }
 451                                 float desirabledamage;
 452                                 desirabledamage = enemydamage;
 453                                 if(time > self.invincible_finished && time > self.spawnshieldtime)
 454                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 455                                 if(teamplay && self.team)
 456                                         desirabledamage = desirabledamage - teamdamage;
 457
 458                                 mine = find(world, classname, "mine");
 459                                 while(mine)
 460                                 {
 461                                         if(mine.realowner != self)
 462                                         {
 463                                                 mine = find(mine, classname, "mine");
 464                                                 continue;
 465                                         }
 466                                         makevectors(mine.v_angle);
 467                                         targ = targetlist;
 468                                         if(skill > 9) // normal players only do this for the target they are tracking
 469                                         {
 470                                                 targ = targetlist;
 471                                                 while(targ)
 472                                                 {
 473                                                         if(
 474                                                                 (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 475                                                                 && desirabledamage > 0.1*coredamage
 476                                                         )self.BUTTON_ATCK2 = true;
 477                                                         targ = targ.chain;
 478                                                 }
 479                                         }else{
 480                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 481                                                 //As the distance gets larger, a correct detonation gets near imposible
 482                                                 //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 483                                                 if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 484                                                         if(IS_PLAYER(self.enemy))
 485                                                                 if(desirabledamage >= 0.1*coredamage)
 486                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 487                                                                                 self.BUTTON_ATCK2 = true;
 488                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 489                                         }
 490
 491                                         mine = find(mine, classname, "mine");
 492                                 }
 493                                 // if we would be doing at X percent of the core damage, detonate it
 494                                 // but don't fire a new shot at the same time!
 495                                 if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 496                                         self.BUTTON_ATCK2 = true;
 497                                 if((skill > 6.5) && (selfdamage > self.health))
 498                                         self.BUTTON_ATCK2 = false;
 499                                 //if(self.BUTTON_ATCK2 == true)
 500                                 //      dprint(ftos(desirabledamage),"\n");
 501                                 if(self.BUTTON_ATCK2 == true) self.BUTTON_ATCK = false;
 502                         }
 503
 504                         return true;
 505                 }
 506                 case WR_THINK:
 507                 {
 508                         if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < WEP_CVAR(minelayer, ammo)) // forced reload
 509                         {
 510                                 // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 511                                 if(!(W_MineLayer_PlacedMines(false) && self.WEP_AMMO(MINE_LAYER) < WEP_CVAR(minelayer, ammo)))
 512                                         WEP_ACTION(self.weapon, WR_RELOAD);
 513                         }
 514                         else if(self.BUTTON_ATCK)
 515                         {
 516                                 if(weapon_prepareattack(0, WEP_CVAR(minelayer, refire)))
 517                                 {
 518                                         W_MineLayer_Attack();
 519                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(minelayer, animtime), w_ready);
 520                                 }
 521                         }
 522
 523                         if(self.BUTTON_ATCK2)
 524                         {
 525                                 if(W_MineLayer_PlacedMines(true))
 526                                         sound(self, CH_WEAPON_B, SND_MINE_DET, VOL_BASE, ATTN_NORM);
 527                         }
 528
 529                         return true;
 530                 }
 531                 case WR_INIT:
 532                 {
 533                         MINELAYER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 534                         return true;
 535                 }
 536                 case WR_CHECKAMMO1:
 537                 {
 538                         // don't switch while placing a mine
 539                         if(ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER.m_id)
 540                         {
 541                                 ammo_amount = self.WEP_AMMO(MINE_LAYER) >= WEP_CVAR(minelayer, ammo);
 542                                 ammo_amount += self.(weapon_load[WEP_MINE_LAYER.m_id]) >= WEP_CVAR(minelayer, ammo);
 543                                 return ammo_amount;
 544                         }
 545                         return true;
 546                 }
 547                 case WR_CHECKAMMO2:
 548                 {
 549                         if(W_MineLayer_PlacedMines(false))
 550                                 return true;
 551                         else
 552                                 return false;
 553                 }
 554                 case WR_CONFIG:
 555                 {
 556                         MINELAYER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 557                         return true;
 558                 }
 559                 case WR_RESETPLAYER:
 560                 {
 561                         self.minelayer_mines = 0;
 562                         return true;
 563                 }
 564                 case WR_RELOAD:
 565                 {
 566                         W_Reload(WEP_CVAR(minelayer, ammo), SND(RELOAD));
 567                         return true;
 568                 }
 569                 case WR_SUICIDEMESSAGE:
 570                 {
 571                         return WEAPON_MINELAYER_SUICIDE;
 572                 }
 573                 case WR_KILLMESSAGE:
 574                 {
 575                         return WEAPON_MINELAYER_MURDER;
 576                 }
 577         }
 578         return false;
 579 }
 580 #endif
 581 #ifdef CSQC
 582 bool W_MineLayer(int req)
 583 {SELFPARAM();
 584         switch(req)
 585         {
 586                 case WR_IMPACTEFFECT:
 587                 {
 588                         vector org2;
 589                         org2 = w_org + w_backoff * 12;
 590                         pointparticles(particleeffectnum(EFFECT_ROCKET_EXPLODE), org2, '0 0 0', 1);
 591                         if(!w_issilent)
 592                                 sound(self, CH_SHOTS, SND_MINE_EXP, VOL_BASE, ATTN_NORM);
 593
 594                         return true;
 595                 }
 596                 case WR_INIT:
 597                 {
 598                         return true;
 599                 }
 600                 case WR_ZOOMRETICLE:
 601                 {
 602                         // no weapon specific image for this weapon
 603                         return false;
 604                 }
 605         }
 606         return false;
 607 }
 608 #endif
 609 #endif