5f56f19db19b2080d7255318562d150ee2be1787
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / mortar.qc
1 #ifndef IMPLEMENTATION
2 CLASS(Mortar, Weapon)
3 /* ammotype  */ ATTRIB(Mortar, ammo_field, .int, ammo_rockets)
4 /* impulse   */ ATTRIB(Mortar, impulse, int, 4)
5 /* flags     */ ATTRIB(Mortar, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
6 /* rating    */ ATTRIB(Mortar, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
7 /* color     */ ATTRIB(Mortar, wpcolor, vector, '1 0 0');
8 /* modelname */ ATTRIB(Mortar, mdl, string, "gl");
9 #ifndef MENUQC
10 /* model     */ ATTRIB(Mortar, m_model, Model, MDL_MORTAR_ITEM);
11 #endif
12 /* crosshair */ ATTRIB(Mortar, w_crosshair, string, "gfx/crosshairgrenadelauncher");
13 /* crosshair */ ATTRIB(Mortar, w_crosshair_size, float, 0.7);
14 /* wepimg    */ ATTRIB(Mortar, model2, string, "weapongrenadelauncher");
15 /* refname   */ ATTRIB(Mortar, netname, string, "mortar");
16 /* wepname   */ ATTRIB(Mortar, m_name, string, _("Mortar"));
17
18 #define X(BEGIN, P, END, class, prefix) \
19         BEGIN(class) \
20                 P(class, prefix, ammo, float, BOTH) \
21                 P(class, prefix, animtime, float, BOTH) \
22                 P(class, prefix, bouncefactor, float, NONE) \
23                 P(class, prefix, bouncestop, float, NONE) \
24                 P(class, prefix, damageforcescale, float, BOTH) \
25                 P(class, prefix, damage, float, BOTH) \
26                 P(class, prefix, edgedamage, float, BOTH) \
27                 P(class, prefix, force, float, BOTH) \
28                 P(class, prefix, health, float, BOTH) \
29                 P(class, prefix, lifetime, float, BOTH) \
30                 P(class, prefix, lifetime_bounce, float, SEC) \
31                 P(class, prefix, lifetime_stick, float, BOTH) \
32                 P(class, prefix, radius, float, BOTH) \
33                 P(class, prefix, refire, float, BOTH) \
34                 P(class, prefix, reload_ammo, float, NONE) \
35                 P(class, prefix, reload_time, float, NONE) \
36                 P(class, prefix, remote_detonateprimary, float, SEC) \
37                 P(class, prefix, remote_minbouncecnt, float, PRI) \
38                 P(class, prefix, speed, float, BOTH) \
39                 P(class, prefix, speed_up, float, BOTH) \
40                 P(class, prefix, speed_z, float, BOTH) \
41                 P(class, prefix, spread, float, BOTH) \
42                 P(class, prefix, switchdelay_drop, float, NONE) \
43                 P(class, prefix, switchdelay_raise, float, NONE) \
44                 P(class, prefix, type, float, BOTH) \
45                 P(class, prefix, weaponreplace, string, NONE) \
46                 P(class, prefix, weaponstartoverride, float, NONE) \
47                 P(class, prefix, weaponstart, float, NONE) \
48                 P(class, prefix, weaponthrowable, float, NONE) \
49         END()
50     W_PROPS(X, Mortar, mortar)
51 #undef X
52 ENDCLASS(Mortar)
53 REGISTER_WEAPON(MORTAR, mortar, NEW(Mortar));
54
55
56 #ifdef SVQC
57 .float gl_detonate_later;
58 .float gl_bouncecnt;
59 #endif
60 #endif
61 #ifdef IMPLEMENTATION
62 #ifdef SVQC
63
64 spawnfunc(weapon_mortar) { weapon_defaultspawnfunc(this, WEP_MORTAR); }
65 spawnfunc(weapon_grenadelauncher) { spawnfunc_weapon_mortar(this); }
66
67 void W_Mortar_Grenade_Explode(entity this)
68 {
69         if(other.takedamage == DAMAGE_AIM)
70                 if(IS_PLAYER(other))
71                         if(DIFF_TEAM(this.realowner, other))
72                                 if(!IS_DEAD(other))
73                                         if(IsFlying(other))
74                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
75
76         this.event_damage = func_null;
77         this.takedamage = DAMAGE_NO;
78
79         if(this.movetype == MOVETYPE_NONE)
80                 this.velocity = this.oldvelocity;
81
82         RadiusDamage(this, this.realowner, WEP_CVAR_PRI(mortar, damage), WEP_CVAR_PRI(mortar, edgedamage), WEP_CVAR_PRI(mortar, radius), NULL, NULL, WEP_CVAR_PRI(mortar, force), this.projectiledeathtype, other);
83
84         remove(this);
85 }
86
87 void W_Mortar_Grenade_Explode_use(entity this, entity actor, entity trigger)
88 {
89         W_Mortar_Grenade_Explode(this);
90 }
91
92 void W_Mortar_Grenade_Explode2(entity this)
93 {
94         if(other.takedamage == DAMAGE_AIM)
95                 if(IS_PLAYER(other))
96                         if(DIFF_TEAM(this.realowner, other))
97                                 if(!IS_DEAD(other))
98                                         if(IsFlying(other))
99                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
100
101         this.event_damage = func_null;
102         this.takedamage = DAMAGE_NO;
103
104         if(this.movetype == MOVETYPE_NONE)
105                 this.velocity = this.oldvelocity;
106
107         RadiusDamage(this, this.realowner, WEP_CVAR_SEC(mortar, damage), WEP_CVAR_SEC(mortar, edgedamage), WEP_CVAR_SEC(mortar, radius), NULL, NULL, WEP_CVAR_SEC(mortar, force), this.projectiledeathtype, other);
108
109         remove(this);
110 }
111
112 void W_Mortar_Grenade_Explode2_use(entity this, entity actor, entity trigger)
113 {
114         W_Mortar_Grenade_Explode2(this);
115 }
116
117 void W_Mortar_Grenade_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
118 {
119         if(this.health <= 0)
120                 return;
121
122         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
123                 return; // g_projectiles_damage says to halt
124
125         this.health = this.health - damage;
126
127         if(this.health <= 0)
128                 W_PrepareExplosionByDamage(this, attacker, adaptor_think2use);
129 }
130
131 void W_Mortar_Grenade_Think1(entity this)
132 {
133         this.nextthink = time;
134         if(time > this.cnt)
135         {
136                 other = NULL;
137                 this.projectiledeathtype |= HITTYPE_BOUNCE;
138                 W_Mortar_Grenade_Explode(this);
139                 return;
140         }
141         if(this.gl_detonate_later && this.gl_bouncecnt >= WEP_CVAR_PRI(mortar, remote_minbouncecnt))
142                 W_Mortar_Grenade_Explode(this);
143 }
144
145 void W_Mortar_Grenade_Touch1(entity this)
146 {
147         PROJECTILE_TOUCH(this);
148         if(other.takedamage == DAMAGE_AIM || WEP_CVAR_PRI(mortar, type) == 0) // always explode when hitting a player, or if normal mortar projectile
149         {
150                 this.use(this, NULL, NULL);
151         }
152         else if(WEP_CVAR_PRI(mortar, type) == 1) // bounce
153         {
154                 spamsound(this, CH_SHOTS, SND(GRENADE_BOUNCE_RANDOM()), VOL_BASE, ATTN_NORM);
155                 Send_Effect(EFFECT_HAGAR_BOUNCE, this.origin, this.velocity, 1);
156                 this.projectiledeathtype |= HITTYPE_BOUNCE;
157                 this.gl_bouncecnt += 1;
158         }
159         else if(WEP_CVAR_PRI(mortar, type) == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
160         {
161                 spamsound(this, CH_SHOTS, SND(GRENADE_STICK), VOL_BASE, ATTN_NORM);
162
163                 // let it stick whereever it is
164                 this.oldvelocity = this.velocity;
165                 this.velocity = '0 0 0';
166                 this.movetype = MOVETYPE_NONE; // also disables gravity
167                 this.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
168                 UpdateCSQCProjectile(this);
169
170                 // do not respond to any more touches
171                 this.solid = SOLID_NOT;
172
173                 this.nextthink = min(this.nextthink, time + WEP_CVAR_PRI(mortar, lifetime_stick));
174         }
175 }
176
177 void W_Mortar_Grenade_Touch2(entity this)
178 {
179         PROJECTILE_TOUCH(this);
180         if(other.takedamage == DAMAGE_AIM || WEP_CVAR_SEC(mortar, type) == 0) // always explode when hitting a player, or if normal mortar projectile
181         {
182                 this.use(this, NULL, NULL);
183         }
184         else if(WEP_CVAR_SEC(mortar, type) == 1) // bounce
185         {
186                 spamsound(this, CH_SHOTS, SND(GRENADE_BOUNCE_RANDOM()), VOL_BASE, ATTN_NORM);
187                 Send_Effect(EFFECT_HAGAR_BOUNCE, this.origin, this.velocity, 1);
188                 this.projectiledeathtype |= HITTYPE_BOUNCE;
189                 this.gl_bouncecnt += 1;
190
191                 if(WEP_CVAR_SEC(mortar, lifetime_bounce) && this.gl_bouncecnt == 1)
192                         this.nextthink = time + WEP_CVAR_SEC(mortar, lifetime_bounce);
193
194         }
195         else if(WEP_CVAR_SEC(mortar, type) == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
196         {
197                 spamsound(this, CH_SHOTS, SND(GRENADE_STICK), VOL_BASE, ATTN_NORM);
198
199                 // let it stick whereever it is
200                 this.oldvelocity = this.velocity;
201                 this.velocity = '0 0 0';
202                 this.movetype = MOVETYPE_NONE; // also disables gravity
203                 this.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
204                 UpdateCSQCProjectile(this);
205
206                 // do not respond to any more touches
207                 this.solid = SOLID_NOT;
208
209                 this.nextthink = min(this.nextthink, time + WEP_CVAR_SEC(mortar, lifetime_stick));
210         }
211 }
212
213 void W_Mortar_Attack(Weapon thiswep, entity actor)
214 {
215         entity gren;
216
217         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_PRI(mortar, ammo));
218
219         W_SetupShot_ProjectileSize(actor, '-3 -3 -3', '3 3 3', false, 4, SND_GRENADE_FIRE, CH_WEAPON_A, WEP_CVAR_PRI(mortar, damage));
220         w_shotdir = v_forward; // no TrueAim for grenades please
221
222         Send_Effect(EFFECT_GRENADE_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
223
224         gren = new(grenade);
225         gren.owner = gren.realowner = actor;
226         gren.bot_dodge = true;
227         gren.bot_dodgerating = WEP_CVAR_PRI(mortar, damage);
228         gren.movetype = MOVETYPE_BOUNCE;
229         gren.bouncefactor = WEP_CVAR(mortar, bouncefactor);
230         gren.bouncestop = WEP_CVAR(mortar, bouncestop);
231         PROJECTILE_MAKETRIGGER(gren);
232         gren.projectiledeathtype = WEP_MORTAR.m_id;
233         setorigin(gren, w_shotorg);
234         setsize(gren, '-3 -3 -3', '3 3 3');
235
236         gren.cnt = time + WEP_CVAR_PRI(mortar, lifetime);
237         gren.nextthink = time;
238         setthink(gren, W_Mortar_Grenade_Think1);
239         gren.use = W_Mortar_Grenade_Explode_use;
240         settouch(gren, W_Mortar_Grenade_Touch1);
241
242         gren.takedamage = DAMAGE_YES;
243         gren.health = WEP_CVAR_PRI(mortar, health);
244         gren.damageforcescale = WEP_CVAR_PRI(mortar, damageforcescale);
245         gren.event_damage = W_Mortar_Grenade_Damage;
246         gren.damagedbycontents = true;
247         gren.missile_flags = MIF_SPLASH | MIF_ARC;
248         W_SetupProjVelocity_UP_PRI(gren, mortar);
249
250         gren.angles = vectoangles(gren.velocity);
251         gren.flags = FL_PROJECTILE;
252
253         if(WEP_CVAR_PRI(mortar, type) == 0 || WEP_CVAR_PRI(mortar, type) == 2)
254                 CSQCProjectile(gren, true, PROJECTILE_GRENADE, true);
255         else
256                 CSQCProjectile(gren, true, PROJECTILE_GRENADE_BOUNCING, true);
257
258         MUTATOR_CALLHOOK(EditProjectile, actor, gren);
259 }
260
261 void W_Mortar_Attack2(Weapon thiswep, entity actor)
262 {
263         entity gren;
264
265         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(mortar, ammo));
266
267         W_SetupShot_ProjectileSize(actor, '-3 -3 -3', '3 3 3', false, 4, SND_GRENADE_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(mortar, damage));
268         w_shotdir = v_forward; // no TrueAim for grenades please
269
270         Send_Effect(EFFECT_GRENADE_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
271
272         gren = new(grenade);
273         gren.owner = gren.realowner = actor;
274         gren.bot_dodge = true;
275         gren.bot_dodgerating = WEP_CVAR_SEC(mortar, damage);
276         gren.movetype = MOVETYPE_BOUNCE;
277         gren.bouncefactor = WEP_CVAR(mortar, bouncefactor);
278         gren.bouncestop = WEP_CVAR(mortar, bouncestop);
279         PROJECTILE_MAKETRIGGER(gren);
280         gren.projectiledeathtype = WEP_MORTAR.m_id | HITTYPE_SECONDARY;
281         setorigin(gren, w_shotorg);
282         setsize(gren, '-3 -3 -3', '3 3 3');
283
284         gren.nextthink = time + WEP_CVAR_SEC(mortar, lifetime);
285         setthink(gren, adaptor_think2use_hittype_splash);
286         gren.use = W_Mortar_Grenade_Explode2_use;
287         settouch(gren, W_Mortar_Grenade_Touch2);
288
289         gren.takedamage = DAMAGE_YES;
290         gren.health = WEP_CVAR_SEC(mortar, health);
291         gren.damageforcescale = WEP_CVAR_SEC(mortar, damageforcescale);
292         gren.event_damage = W_Mortar_Grenade_Damage;
293         gren.damagedbycontents = true;
294         gren.missile_flags = MIF_SPLASH | MIF_ARC;
295         W_SetupProjVelocity_UP_SEC(gren, mortar);
296
297         gren.angles = vectoangles(gren.velocity);
298         gren.flags = FL_PROJECTILE;
299
300         if(WEP_CVAR_SEC(mortar, type) == 0 || WEP_CVAR_SEC(mortar, type) == 2)
301                 CSQCProjectile(gren, true, PROJECTILE_GRENADE, true);
302         else
303                 CSQCProjectile(gren, true, PROJECTILE_GRENADE_BOUNCING, true);
304
305         MUTATOR_CALLHOOK(EditProjectile, actor, gren);
306 }
307
308 .float bot_secondary_grenademooth;
309
310 METHOD(Mortar, wr_aim, void(entity thiswep, entity actor))
311 {
312     PHYS_INPUT_BUTTON_ATCK(actor) = false;
313     PHYS_INPUT_BUTTON_ATCK2(actor) = false;
314     if(actor.bot_secondary_grenademooth == 0) // WEAPONTODO: merge this into using WEP_CVAR_BOTH
315     {
316         if(bot_aim(actor, WEP_CVAR_PRI(mortar, speed), WEP_CVAR_PRI(mortar, speed_up), WEP_CVAR_PRI(mortar, lifetime), true))
317         {
318             PHYS_INPUT_BUTTON_ATCK(actor) = true;
319             if(random() < 0.01) actor.bot_secondary_grenademooth = 1;
320         }
321     }
322     else
323     {
324         if(bot_aim(actor, WEP_CVAR_SEC(mortar, speed), WEP_CVAR_SEC(mortar, speed_up), WEP_CVAR_SEC(mortar, lifetime), true))
325         {
326             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
327             if(random() < 0.02) actor.bot_secondary_grenademooth = 0;
328         }
329     }
330 }
331 /*case WR_CALCINFO:
332 {
333     wepinfo_pri_refire = max3(sys_frametime, WEP_CVAR_PRI(mortar, refire), WEP_CVAR_PRI(mortar, animtime));
334     wepinfo_pri_dps = (WEP_CVAR_PRI(mortar, damage) * (1 / wepinfo_pri_refire));
335     wepinfo_pri_speed = (1 / max(1, (10000 / max(1, WEP_CVAR_PRI(mortar, speed)))));
336
337     // for the range calculation, closer to 1 is better
338     wepinfo_pri_range_max = 2000 * wepinfo_pri_speed;
339     wepinfo_pri_range = wepinfo_pri_speed * WEP_CVAR_PRI(mortar,
340
341     wepinfo_sec_refire = max3(sys_frametime, WEP_CVAR_SEC(mortar, refire), WEP_CVAR_SEC(mortar, animtime));
342     wepinfo_sec_dps = (WEP_CVAR_SEC(mortar, damage) * (1 / wepinfo_sec_refire));
343
344     wepinfo_sec_dps = (WEP_CVAR_SEC(mortar, damage) * (1 / max3(sys_frametime, WEP_CVAR_SEC(mortar, refire), WEP_CVAR_SEC(mortar, animtime))));
345     wepinfo_ter_dps = 0;
346     */
347 METHOD(Mortar, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
348 {
349     if(autocvar_g_balance_mortar_reload_ammo && actor.clip_load < min(WEP_CVAR_PRI(mortar, ammo), WEP_CVAR_SEC(mortar, ammo))) { // forced reload
350         thiswep.wr_reload(thiswep, actor, weaponentity);
351     } else if(fire & 1)
352     {
353         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(mortar, refire)))
354         {
355             W_Mortar_Attack(thiswep, actor);
356             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(mortar, animtime), w_ready);
357         }
358     }
359     else if(fire & 2)
360     {
361         if(WEP_CVAR_SEC(mortar, remote_detonateprimary))
362         {
363             bool nadefound = false;
364             entity nade;
365             for(nade = NULL; (nade = find(nade, classname, "grenade")); ) if(nade.realowner == actor)
366             {
367                 if(!nade.gl_detonate_later)
368                 {
369                     nade.gl_detonate_later = true;
370                     nadefound = true;
371                 }
372             }
373             if(nadefound)
374                 sound(actor, CH_WEAPON_B, SND_ROCKET_DET, VOL_BASE, ATTN_NORM);
375         }
376         else if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(mortar, refire)))
377         {
378             W_Mortar_Attack2(thiswep, actor);
379             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(mortar, animtime), w_ready);
380         }
381     }
382 }
383 METHOD(Mortar, wr_checkammo1, bool(entity thiswep, entity actor))
384 {
385     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(mortar, ammo);
386     ammo_amount += actor.(weapon_load[WEP_MORTAR.m_id]) >= WEP_CVAR_PRI(mortar, ammo);
387     return ammo_amount;
388 }
389 METHOD(Mortar, wr_checkammo2, bool(entity thiswep, entity actor))
390 {
391     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(mortar, ammo);
392     ammo_amount += actor.(weapon_load[WEP_MORTAR.m_id]) >= WEP_CVAR_SEC(mortar, ammo);
393     return ammo_amount;
394 }
395 METHOD(Mortar, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
396 {
397     W_Reload(actor, min(WEP_CVAR_PRI(mortar, ammo), WEP_CVAR_SEC(mortar, ammo)), SND_RELOAD); // WEAPONTODO
398 }
399 METHOD(Mortar, wr_suicidemessage, Notification(entity thiswep))
400 {
401     if(w_deathtype & HITTYPE_SECONDARY)
402         return WEAPON_MORTAR_SUICIDE_BOUNCE;
403     else
404         return WEAPON_MORTAR_SUICIDE_EXPLODE;
405 }
406 METHOD(Mortar, wr_killmessage, Notification(entity thiswep))
407 {
408     if(w_deathtype & HITTYPE_SECONDARY)
409         return WEAPON_MORTAR_MURDER_BOUNCE;
410     else
411         return WEAPON_MORTAR_MURDER_EXPLODE;
412 }
413
414 #endif
415 #ifdef CSQC
416
417 METHOD(Mortar, wr_impacteffect, void(entity thiswep, entity actor))
418 {
419     vector org2;
420     org2 = w_org + w_backoff * 12;
421     pointparticles(EFFECT_GRENADE_EXPLODE, org2, '0 0 0', 1);
422     if(!w_issilent)
423         sound(actor, CH_SHOTS, SND_GRENADE_IMPACT, VOL_BASE, ATTN_NORM);
424 }
425
426 #endif
427 #endif