qcsrc/common/weapons/weapon/porto.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ PORTO,
   4 /* function  */ W_Porto,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 0,
   7 /* flags     */ WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON,
   8 /* rating    */ 0,
   9 /* color     */ '0.5 0.5 0.5',
  10 /* modelname */ "porto",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairporto 0.6",
  13 /* wepimg    */ "weaponporto",
  14 /* refname   */ "porto",
  15 /* wepname   */ _("Port-O-Launch")
  16 );
  17
  18 #define PORTO_SETTINGS(w_cvar,w_prop) PORTO_SETTINGS_LIST(w_cvar, w_prop, PORTO, porto)
  19 #define PORTO_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, BOTH, animtime) \
  21         w_cvar(id, sn, BOTH, lifetime) \
  22         w_cvar(id, sn, BOTH, refire) \
  23         w_cvar(id, sn, BOTH, speed) \
  24         w_cvar(id, sn, NONE, secondary) \
  25         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  26         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  27         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  28         w_prop(id, sn, float,  weaponstart, weaponstart) \
  29         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  30         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  31
  32 #ifdef SVQC
  33 PORTO_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  34 .entity porto_current;
  35 .vector porto_v_angle; // holds "held" view angles
  36 .float porto_v_angle_held;
  37 .vector right_vector;
  38 #endif
  39 #endif
  40 #ifdef IMPLEMENTATION
  41 #ifdef SVQC
  42 #include "../../triggers/trigger/jumppads.qh"
  43
  44 void spawnfunc_weapon_porto(void) { weapon_defaultspawnfunc(WEP_PORTO.m_id); }
  45
  46 void W_Porto_Success(void)
  47 {SELFPARAM();
  48         if(self.realowner == world)
  49         {
  50                 objerror("Cannot succeed successfully: no owner\n");
  51                 return;
  52         }
  53
  54         self.realowner.porto_current = world;
  55         remove(self);
  56 }
  57
  58 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  59 void W_Porto_Fail(float failhard)
  60 {SELFPARAM();
  61         if(self.realowner == world)
  62         {
  63                 objerror("Cannot fail successfully: no owner\n");
  64                 return;
  65         }
  66
  67         // no portals here!
  68         if(self.cnt < 0)
  69         {
  70                 Portal_ClearWithID(self.realowner, self.portal_id);
  71         }
  72
  73         self.realowner.porto_current = world;
  74
  75         if(self.cnt < 0 && !failhard && self.realowner.playerid == self.playerid && self.realowner.deadflag == DEAD_NO && !(self.realowner.weapons & WEPSET_PORTO))
  76         {
  77                 setsize(self, '-16 -16 0', '16 16 32');
  78                 setorigin(self, self.origin + trace_plane_normal);
  79                 if(move_out_of_solid(self))
  80                 {
  81                         self.flags = FL_ITEM;
  82                         self.velocity = trigger_push_calculatevelocity(self.origin, self.realowner, 128);
  83                         tracetoss(self, self);
  84                         if(vlen(trace_endpos - self.realowner.origin) < 128)
  85                         {
  86                                 W_ThrowNewWeapon(self.realowner, WEP_PORTO.m_id, 0, self.origin, self.velocity);
  87                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_FAILED);
  88                         }
  89                 }
  90         }
  91         remove(self);
  92 }
  93
  94 void W_Porto_Remove(entity p)
  95 {SELFPARAM();
  96         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
  97         {
  98                 WITH(entity, self, p.porto_current, W_Porto_Fail(1));
  99         }
 100 }
 101
 102 void W_Porto_Think(void)
 103 {SELFPARAM();
 104         trace_plane_normal = '0 0 0';
 105         if(self.realowner.playerid != self.playerid)
 106                 remove(self);
 107         else
 108                 W_Porto_Fail(0);
 109 }
 110
 111 void W_Porto_Touch(void)
 112 {SELFPARAM();
 113         vector norm;
 114
 115         // do not use PROJECTILE_TOUCH here
 116         // FIXME but DO handle warpzones!
 117
 118         if(other.classname == "portal")
 119                 return; // handled by the portal
 120
 121         norm = trace_plane_normal;
 122         if(trace_ent.iscreature)
 123         {
 124                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * PL_MIN.z, MOVE_WORLDONLY, self);
 125                 if(trace_fraction >= 1)
 126                         return;
 127                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 128                         return;
 129                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 130                         return;
 131         }
 132
 133         if(self.realowner.playerid != self.playerid)
 134         {
 135                 sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 136                 remove(self);
 137         }
 138         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 139         {
 140                 spamsound(self, CH_SHOTS, SND(PORTO_BOUNCE), VOL_BASE, ATTEN_NORM);
 141                 // just reflect
 142                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
 143                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
 144         }
 145         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 146         {
 147                 sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 148                 W_Porto_Fail(0);
 149                 if(self.cnt < 0)
 150                         Portal_ClearAll_PortalsOnly(self.realowner);
 151         }
 152         else if(self.cnt == 0)
 153         {
 154                 // in-portal only
 155                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 156                 {
 157                         sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 158                         trace_plane_normal = norm;
 159                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 160                         W_Porto_Success();
 161                 }
 162                 else
 163                 {
 164                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 165                         trace_plane_normal = norm;
 166                         W_Porto_Fail(0);
 167                 }
 168         }
 169         else if(self.cnt == 1)
 170         {
 171                 // out-portal only
 172                 if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 173                 {
 174                         sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 175                         trace_plane_normal = norm;
 176                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 177                         W_Porto_Success();
 178                 }
 179                 else
 180                 {
 181                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 182                         trace_plane_normal = norm;
 183                         W_Porto_Fail(0);
 184                 }
 185         }
 186         else if(self.effects & EF_RED)
 187         {
 188                 self.effects += EF_BLUE - EF_RED;
 189                 if(Portal_SpawnInPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 190                 {
 191                         sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 192                         trace_plane_normal = norm;
 193                         Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 194                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * norm);
 195                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * norm));
 196                         CSQCProjectile(self, true, PROJECTILE_PORTO_BLUE, true); // change type
 197                 }
 198                 else
 199                 {
 200                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 201                         trace_plane_normal = norm;
 202                         Portal_ClearAll_PortalsOnly(self.realowner);
 203                         W_Porto_Fail(0);
 204                 }
 205         }
 206         else
 207         {
 208                 if(self.realowner.portal_in.portal_id == self.portal_id)
 209                 {
 210                         if(Portal_SpawnOutPortalAtTrace(self.realowner, self.right_vector, self.portal_id))
 211                         {
 212                                 sound(self, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 213                                 trace_plane_normal = norm;
 214                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 215                                 W_Porto_Success();
 216                         }
 217                         else
 218                         {
 219                                 sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 220                                 Portal_ClearAll_PortalsOnly(self.realowner);
 221                                 W_Porto_Fail(0);
 222                         }
 223                 }
 224                 else
 225                 {
 226                         sound(self, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 227                         Portal_ClearAll_PortalsOnly(self.realowner);
 228                         W_Porto_Fail(0);
 229                 }
 230         }
 231 }
 232
 233 void W_Porto_Attack(float type)
 234 {SELFPARAM();
 235         entity gren;
 236
 237         W_SetupShot(self, false, 4, SND(PORTO_FIRE), CH_WEAPON_A, 0);
 238         // always shoot from the eye
 239         w_shotdir = v_forward;
 240         w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
 241
 242         //Send_Effect(EFFECT_GRENADE_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 243
 244         gren = spawn();
 245         gren.cnt = type;
 246         gren.owner = gren.realowner = self;
 247         gren.playerid = self.playerid;
 248         gren.classname = "porto";
 249         gren.bot_dodge = true;
 250         gren.bot_dodgerating = 200;
 251         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 252         PROJECTILE_MAKETRIGGER(gren);
 253         gren.effects = EF_RED;
 254         gren.scale = 4;
 255         setorigin(gren, w_shotorg);
 256         setsize(gren, '0 0 0', '0 0 0');
 257
 258         gren.nextthink = time + WEP_CVAR_BOTH(porto, (type <= 0), lifetime);
 259         gren.think = W_Porto_Think;
 260         gren.touch = W_Porto_Touch;
 261
 262         if(self.items & ITEM_Strength.m_itemid)
 263                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed) * autocvar_g_balance_powerup_strength_force, 0);
 264         else
 265                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed), 0);
 266
 267         gren.angles = vectoangles(gren.velocity);
 268         gren.flags = FL_PROJECTILE;
 269
 270         gren.portal_id = time;
 271         self.porto_current = gren;
 272         gren.playerid = self.playerid;
 273         fixedmakevectors(fixedvectoangles(gren.velocity));
 274         gren.right_vector = v_right;
 275
 276         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 277
 278         if(type > 0)
 279                 CSQCProjectile(gren, true, PROJECTILE_PORTO_BLUE, true);
 280         else
 281                 CSQCProjectile(gren, true, PROJECTILE_PORTO_RED, true);
 282
 283         MUTATOR_CALLHOOK(EditProjectile, self, gren);
 284 }
 285
 286 bool w_nexball_weapon(int req); // WEAPONTODO
 287 bool W_Porto(int req)
 288 {SELFPARAM();
 289         //vector v_angle_save;
 290
 291         if(g_nexball) { return w_nexball_weapon(req); }
 292
 293         switch(req)
 294         {
 295                 case WR_AIM:
 296                 {
 297                         self.BUTTON_ATCK = false;
 298                         self.BUTTON_ATCK2 = false;
 299                         if(!WEP_CVAR(porto, secondary))
 300                                 if(bot_aim(WEP_CVAR_PRI(porto, speed), 0, WEP_CVAR_PRI(porto, lifetime), false))
 301                                         self.BUTTON_ATCK = true;
 302
 303                         return true;
 304                 }
 305                 case WR_CONFIG:
 306                 {
 307                         PORTO_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 308                         return true;
 309                 }
 310                 case WR_THINK:
 311                 {
 312                         if(WEP_CVAR(porto, secondary))
 313                         {
 314                                 if(self.BUTTON_ATCK)
 315                                 if(!self.porto_current)
 316                                 if(!self.porto_forbidden)
 317                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 318                                 {
 319                                         W_Porto_Attack(0);
 320                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 321                                 }
 322
 323                                 if(self.BUTTON_ATCK2)
 324                                 if(!self.porto_current)
 325                                 if(!self.porto_forbidden)
 326                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(porto, refire)))
 327                                 {
 328                                         W_Porto_Attack(1);
 329                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(porto, animtime), w_ready);
 330                                 }
 331                         }
 332                         else
 333                         {
 334                                 if(self.porto_v_angle_held)
 335                                 {
 336                                         if(!self.BUTTON_ATCK2)
 337                                         {
 338                                                 self.porto_v_angle_held = 0;
 339
 340                                                 ClientData_Touch(self);
 341                                         }
 342                                 }
 343                                 else
 344                                 {
 345                                         if(self.BUTTON_ATCK2)
 346                                         {
 347                                                 self.porto_v_angle = self.v_angle;
 348                                                 self.porto_v_angle_held = 1;
 349
 350                                                 ClientData_Touch(self);
 351                                         }
 352                                 }
 353                                 if(self.porto_v_angle_held)
 354                                         makevectors(self.porto_v_angle); // override the previously set angles
 355
 356                                 if(self.BUTTON_ATCK)
 357                                 if(!self.porto_current)
 358                                 if(!self.porto_forbidden)
 359                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(porto, refire)))
 360                                 {
 361                                         W_Porto_Attack(-1);
 362                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 363                                 }
 364                         }
 365
 366                         return true;
 367                 }
 368                 case WR_CHECKAMMO1:
 369                 case WR_CHECKAMMO2:
 370                 {
 371                         // always allow infinite ammo
 372                         return true;
 373                 }
 374                 case WR_INIT:
 375                 {
 376                         PORTO_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 377                         return true;
 378                 }
 379                 case WR_SETUP:
 380                 {
 381                         self.ammo_field = ammo_none;
 382                         return true;
 383                 }
 384                 case WR_RESETPLAYER:
 385                 {
 386                         self.porto_current = world;
 387                         return true;
 388                 }
 389         }
 390         return false;
 391 }
 392 #endif
 393 #ifdef CSQC
 394 bool W_Porto(int req)
 395 {SELFPARAM();
 396         switch(req)
 397         {
 398                 case WR_IMPACTEFFECT:
 399                 {
 400                         LOG_INFO("Since when does Porto send DamageInfo?\n");
 401                         return true;
 402                 }
 403                 case WR_INIT:
 404                 {
 405                         // nothing to do
 406                         return true;
 407                 }
 408                 case WR_ZOOMRETICLE:
 409                 {
 410                         // no weapon specific image for this weapon
 411                         return false;
 412                 }
 413         }
 414         return false;
 415 }
 416 #endif
 417 #endif