qcsrc/common/weapons/weapon/porto.qc

   1 #include "porto.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(PortoLaunch, Weapon)
   4 /* ammotype  */ ATTRIB(PortoLaunch, ammo_field, .int, ammo_none);
   5 /* impulse   */ ATTRIB(PortoLaunch, impulse, int, 0);
   6 /* flags     */ ATTRIB(PortoLaunch, spawnflags, int, WEP_TYPE_OTHER | WEP_FLAG_SUPERWEAPON);
   7 /* rating    */ ATTRIB(PortoLaunch, bot_pickupbasevalue, float, 0);
   8 /* color     */ ATTRIB(PortoLaunch, wpcolor, vector, '0.5 0.5 0.5');
   9 /* modelname */ ATTRIB(PortoLaunch, mdl, string, "porto");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(PortoLaunch, m_model, Model, MDL_PORTO_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(PortoLaunch, w_crosshair, string, "gfx/crosshairporto");
  14 /* crosshair */ ATTRIB(PortoLaunch, w_crosshair_size, float, 0.6);
  15 /* wepimg    */ ATTRIB(PortoLaunch, model2, string, "weaponporto");
  16 /* refname   */ ATTRIB(PortoLaunch, netname, string, "porto");
  17 /* wepname   */ ATTRIB(PortoLaunch, m_name, string, _("Port-O-Launch"));
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21                 P(class, prefix, animtime, float, BOTH) \
  22                 P(class, prefix, lifetime, float, BOTH) \
  23                 P(class, prefix, refire, float, BOTH) \
  24                 P(class, prefix, secondary, float, NONE) \
  25                 P(class, prefix, speed, float, BOTH) \
  26         P(class, prefix, switchdelay_drop, float, NONE) \
  27                 P(class, prefix, switchdelay_raise, float, NONE) \
  28         P(class, prefix, weaponreplace, string,NONE) \
  29         P(class, prefix, weaponstartoverride, float, NONE) \
  30         P(class, prefix, weaponstart, float, NONE) \
  31         P(class, prefix, weaponthrowable, float, NONE) \
  32         END()
  33     W_PROPS(X, PortoLaunch, porto)
  34 #undef X
  35 ENDCLASS(PortoLaunch)
  36 REGISTER_WEAPON(PORTO, porto, NEW(PortoLaunch));
  37
  38 #ifdef SVQC
  39 .entity porto_current;
  40 .vector porto_v_angle; // holds "held" view angles
  41 .float porto_v_angle_held;
  42 .vector right_vector;
  43 .float porto_forbidden;
  44 #endif
  45 #endif
  46 #ifdef IMPLEMENTATION
  47 #ifdef SVQC
  48 #include <common/triggers/trigger/jumppads.qh>
  49
  50 spawnfunc(weapon_porto) { weapon_defaultspawnfunc(this, WEP_PORTO); }
  51
  52 REGISTER_MUTATOR(porto_ticker, true);
  53 MUTATOR_HOOKFUNCTION(porto_ticker, SV_StartFrame) {
  54         FOREACH_CLIENT(IS_PLAYER(it), it.porto_forbidden = max(0, it.porto_forbidden - 1));
  55 }
  56
  57 void W_Porto_Success(entity this)
  58 {
  59         if(this.realowner == NULL)
  60         {
  61                 objerror(this, "Cannot succeed successfully: no owner\n");
  62                 return;
  63         }
  64
  65         this.realowner.porto_current = NULL;
  66         delete(this);
  67 }
  68
  69 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo, .entity weaponentity);
  70 void W_Porto_Fail(entity this, float failhard)
  71 {
  72         if(this.realowner == NULL)
  73         {
  74                 objerror(this, "Cannot fail successfully: no owner\n");
  75                 return;
  76         }
  77
  78         // no portals here!
  79         if(this.cnt < 0)
  80         {
  81                 Portal_ClearWithID(this.realowner, this.portal_id);
  82         }
  83
  84         this.realowner.porto_current = NULL;
  85
  86         if(this.cnt < 0 && !failhard && this.realowner.playerid == this.playerid && !IS_DEAD(this.realowner) && !(this.realowner.weapons & WEPSET(PORTO)))
  87         {
  88                 setsize(this, '-16 -16 0', '16 16 32');
  89                 setorigin(this, this.origin + trace_plane_normal);
  90                 if(move_out_of_solid(this))
  91                 {
  92                         this.flags = FL_ITEM;
  93                         IL_PUSH(g_items, this);
  94                         this.velocity = trigger_push_calculatevelocity(this.origin, this.realowner, 128);
  95                         tracetoss(this, this);
  96                         if(vdist(trace_endpos - this.realowner.origin, <, 128))
  97                         {
  98                                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
  99                                 W_ThrowNewWeapon(this.realowner, WEP_PORTO.m_id, 0, this.origin, this.velocity, weaponentity);
 100                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_CENTER, CENTER_PORTO_FAILED);
 101                         }
 102                 }
 103         }
 104         delete(this);
 105 }
 106
 107 void W_Porto_Remove(entity p)
 108 {
 109         if(p.porto_current.realowner == p && p.porto_current.classname == "porto")
 110         {
 111                 W_Porto_Fail(p.porto_current, 1);
 112         }
 113 }
 114
 115 void W_Porto_Think(entity this)
 116 {
 117         trace_plane_normal = '0 0 0';
 118         if(this.realowner.playerid != this.playerid)
 119                 delete(this);
 120         else
 121                 W_Porto_Fail(this, 0);
 122 }
 123
 124 void W_Porto_Touch(entity this, entity toucher)
 125 {
 126         vector norm;
 127
 128         // do not use PROJECTILE_TOUCH here
 129         // FIXME but DO handle warpzones!
 130
 131         if(toucher.classname == "portal")
 132                 return; // handled by the portal
 133
 134         norm = trace_plane_normal;
 135         if(trace_ent.iscreature)
 136         {
 137                 traceline(trace_ent.origin, trace_ent.origin + '0 0 2' * STAT(PL_MIN, NULL).z, MOVE_WORLDONLY, this);
 138                 if(trace_fraction >= 1)
 139                         return;
 140                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 141                         return;
 142                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 143                         return;
 144         }
 145
 146         if(this.realowner.playerid != this.playerid)
 147         {
 148                 sound(this, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 149                 delete(this);
 150         }
 151         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 152         {
 153                 spamsound(this, CH_SHOTS, SND(PORTO_BOUNCE), VOL_BASE, ATTEN_NORM);
 154                 // just reflect
 155                 this.right_vector = this.right_vector - 2 * trace_plane_normal * (this.right_vector * trace_plane_normal);
 156                 this.angles = vectoangles(this.velocity - 2 * trace_plane_normal * (this.velocity * trace_plane_normal));
 157         }
 158         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 159         {
 160                 sound(this, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 161                 W_Porto_Fail(this, 0);
 162                 if(this.cnt < 0)
 163                         Portal_ClearAll_PortalsOnly(this.realowner);
 164         }
 165         else if(this.cnt == 0)
 166         {
 167                 // in-portal only
 168                 if(Portal_SpawnInPortalAtTrace(this.realowner, this.right_vector, this.portal_id))
 169                 {
 170                         sound(this, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 171                         trace_plane_normal = norm;
 172                         Send_Notification(NOTIF_ONE, this.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 173                         W_Porto_Success(this);
 174                 }
 175                 else
 176                 {
 177                         sound(this, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 178                         trace_plane_normal = norm;
 179                         W_Porto_Fail(this, 0);
 180                 }
 181         }
 182         else if(this.cnt == 1)
 183         {
 184                 // out-portal only
 185                 if(Portal_SpawnOutPortalAtTrace(this.realowner, this.right_vector, this.portal_id))
 186                 {
 187                         sound(this, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 188                         trace_plane_normal = norm;
 189                         Send_Notification(NOTIF_ONE, this.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 190                         W_Porto_Success(this);
 191                 }
 192                 else
 193                 {
 194                         sound(this, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 195                         trace_plane_normal = norm;
 196                         W_Porto_Fail(this, 0);
 197                 }
 198         }
 199         else if(this.effects & EF_RED)
 200         {
 201                 this.effects += EF_BLUE - EF_RED;
 202                 if(Portal_SpawnInPortalAtTrace(this.realowner, this.right_vector, this.portal_id))
 203                 {
 204                         sound(this, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 205                         trace_plane_normal = norm;
 206                         Send_Notification(NOTIF_ONE, this.realowner, MSG_CENTER, CENTER_PORTO_CREATED_IN);
 207                         this.right_vector = this.right_vector - 2 * trace_plane_normal * (this.right_vector * norm);
 208                         this.angles = vectoangles(this.velocity - 2 * trace_plane_normal * (this.velocity * norm));
 209                         CSQCProjectile(this, true, PROJECTILE_PORTO_BLUE, true); // change type
 210                 }
 211                 else
 212                 {
 213                         sound(this, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 214                         trace_plane_normal = norm;
 215                         Portal_ClearAll_PortalsOnly(this.realowner);
 216                         W_Porto_Fail(this, 0);
 217                 }
 218         }
 219         else
 220         {
 221                 if(this.realowner.portal_in.portal_id == this.portal_id)
 222                 {
 223                         if(Portal_SpawnOutPortalAtTrace(this.realowner, this.right_vector, this.portal_id))
 224                         {
 225                                 sound(this, CH_SHOTS, SND_PORTO_CREATE, VOL_BASE, ATTEN_NORM);
 226                                 trace_plane_normal = norm;
 227                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_CENTER, CENTER_PORTO_CREATED_OUT);
 228                                 W_Porto_Success(this);
 229                         }
 230                         else
 231                         {
 232                                 sound(this, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 233                                 Portal_ClearAll_PortalsOnly(this.realowner);
 234                                 W_Porto_Fail(this, 0);
 235                         }
 236                 }
 237                 else
 238                 {
 239                         sound(this, CH_SHOTS, SND_PORTO_UNSUPPORTED, VOL_BASE, ATTEN_NORM);
 240                         Portal_ClearAll_PortalsOnly(this.realowner);
 241                         W_Porto_Fail(this, 0);
 242                 }
 243         }
 244 }
 245
 246 void W_Porto_Attack(entity actor, .entity weaponentity, float type)
 247 {
 248         entity gren;
 249
 250         W_SetupShot(actor, weaponentity, false, 4, SND_PORTO_FIRE, CH_WEAPON_A, 0);
 251         // always shoot from the eye
 252         w_shotdir = v_forward;
 253         w_shotorg = actor.origin + actor.view_ofs + ((w_shotorg - actor.origin - actor.view_ofs) * v_forward) * v_forward;
 254
 255         //Send_Effect(EFFECT_GRENADE_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 256
 257         gren = new(porto);
 258         gren.cnt = type;
 259         gren.owner = gren.realowner = actor;
 260         gren.playerid = actor.playerid;
 261         gren.bot_dodge = true;
 262         gren.bot_dodgerating = 200;
 263         set_movetype(gren, MOVETYPE_BOUNCEMISSILE);
 264         PROJECTILE_MAKETRIGGER(gren);
 265         gren.effects = EF_RED;
 266         gren.scale = 4;
 267         setorigin(gren, w_shotorg);
 268         setsize(gren, '0 0 0', '0 0 0');
 269
 270         gren.nextthink = time + WEP_CVAR_BOTH(porto, (type <= 0), lifetime);
 271         setthink(gren, W_Porto_Think);
 272         settouch(gren, W_Porto_Touch);
 273
 274         if(actor.items & ITEM_Strength.m_itemid)
 275                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed) * autocvar_g_balance_powerup_strength_force, 0);
 276         else
 277                 W_SetupProjVelocity_Basic(gren, WEP_CVAR_BOTH(porto, (type <= 0), speed), 0);
 278
 279         gren.angles = vectoangles(gren.velocity);
 280         gren.flags = FL_PROJECTILE;
 281         IL_PUSH(g_projectiles, gren);
 282         IL_PUSH(g_bot_dodge, gren);
 283
 284         gren.portal_id = time;
 285         actor.porto_current = gren;
 286         gren.playerid = actor.playerid;
 287         fixedmakevectors(fixedvectoangles(gren.velocity));
 288         gren.right_vector = v_right;
 289
 290         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 291
 292         if(type > 0)
 293                 CSQCProjectile(gren, true, PROJECTILE_PORTO_BLUE, true);
 294         else
 295                 CSQCProjectile(gren, true, PROJECTILE_PORTO_RED, true);
 296
 297         MUTATOR_CALLHOOK(EditProjectile, actor, gren);
 298 }
 299
 300 METHOD(PortoLaunch, wr_aim, void(entity thiswep, entity actor))
 301 {
 302     PHYS_INPUT_BUTTON_ATCK(actor) = false;
 303     PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 304     if(!WEP_CVAR(porto, secondary))
 305         if(bot_aim(actor, WEP_CVAR_PRI(porto, speed), 0, WEP_CVAR_PRI(porto, lifetime), false))
 306             PHYS_INPUT_BUTTON_ATCK(actor) = true;
 307 }
 308 METHOD(PortoLaunch, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 309 {
 310     if(WEP_CVAR(porto, secondary))
 311     {
 312         if(fire & 1)
 313         if(!actor.porto_current)
 314         if(!actor.porto_forbidden)
 315         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(porto, refire)))
 316         {
 317             W_Porto_Attack(actor, weaponentity, 0);
 318             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 319         }
 320
 321         if(fire & 2)
 322         if(!actor.porto_current)
 323         if(!actor.porto_forbidden)
 324         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(porto, refire)))
 325         {
 326             W_Porto_Attack(actor, weaponentity, 1);
 327             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(porto, animtime), w_ready);
 328         }
 329     }
 330     else
 331     {
 332         if(actor.porto_v_angle_held)
 333         {
 334             if(!(fire & 2))
 335             {
 336                 actor.porto_v_angle_held = 0;
 337
 338                 ClientData_Touch(actor);
 339             }
 340         }
 341         else
 342         {
 343             if(fire & 2)
 344             {
 345                 actor.porto_v_angle = actor.v_angle;
 346                 actor.porto_v_angle_held = 1;
 347
 348                 ClientData_Touch(actor);
 349             }
 350         }
 351         if(actor.porto_v_angle_held)
 352             makevectors(actor.porto_v_angle); // override the previously set angles
 353
 354         if(fire & 1)
 355         if(!actor.porto_current)
 356         if(!actor.porto_forbidden)
 357         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(porto, refire)))
 358         {
 359             W_Porto_Attack(actor, weaponentity, -1);
 360             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(porto, animtime), w_ready);
 361         }
 362     }
 363 }
 364 METHOD(PortoLaunch, wr_checkammo1, bool(entity thiswep, entity this))
 365 {
 366     // always allow infinite ammo
 367     return true;
 368 }
 369 METHOD(PortoLaunch, wr_checkammo2, bool(entity thiswep, entity this))
 370 {
 371     // always allow infinite ammo
 372     return true;
 373 }
 374 METHOD(PortoLaunch, wr_setup, void(entity thiswep, entity actor))
 375 {
 376     actor.ammo_field = ammo_none;
 377 }
 378 METHOD(PortoLaunch, wr_resetplayer, void(entity thiswep, entity actor))
 379 {
 380     actor.porto_current = NULL;
 381 }
 382 #endif
 383 #ifdef CSQC
 384 METHOD(PortoLaunch, wr_impacteffect, void(entity this, entity actor)) {
 385     LOG_WARN("Since when does Porto send DamageInfo?");
 386 }
 387 #endif
 388 #endif