qcsrc/common/weapons/weapon/rifle.qc

   1 #include "rifle.qh"
   2
   3 #ifdef SVQC
   4
   5 void W_Rifle_FireBullet(Weapon thiswep, .entity weaponentity, float pSpread, float pDamage, float pForce, float pSolidPenetration, float pAmmo, int deathtype, float pTracer, float pShots, Sound pSound, entity actor)
   6 {
   7         float i;
   8
   9         W_DecreaseAmmo(thiswep, actor, pAmmo, weaponentity);
  10
  11         W_SetupShot(actor, weaponentity, true, 2, pSound, CH_WEAPON_A, pDamage * pShots, deathtype);
  12
  13         Send_Effect(EFFECT_RIFLE_MUZZLEFLASH, w_shotorg, w_shotdir * 2000, 1);
  14
  15         if(PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) // if zoomed, shoot from the eye
  16         {
  17                 w_shotdir = v_forward;
  18                 w_shotorg = actor.origin + actor.view_ofs + ((w_shotorg - actor.origin - actor.view_ofs) * v_forward) * v_forward;
  19         }
  20
  21         for(i = 0; i < pShots; ++i)
  22                 fireBullet(actor, weaponentity, w_shotorg, w_shotdir, pSpread, pSolidPenetration, pDamage, pForce, deathtype, (pTracer ? EF_RED : EF_BLUE));
  23
  24         if(autocvar_g_casings >= 2)
  25     {
  26         makevectors(actor.v_angle); // for some reason, this is lost
  27                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor, weaponentity);
  28     }
  29 }
  30
  31 void W_Rifle_Attack(entity actor, .entity weaponentity)
  32 {
  33         W_Rifle_FireBullet(WEP_RIFLE, weaponentity, WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, solidpenetration), WEP_CVAR_PRI(rifle, ammo), WEP_RIFLE.m_id, WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), SND_CAMPINGRIFLE_FIRE, actor);
  34 }
  35
  36 void W_Rifle_Attack2(entity actor, .entity weaponentity)
  37 {
  38         W_Rifle_FireBullet(WEP_RIFLE, weaponentity, WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, solidpenetration), WEP_CVAR_SEC(rifle, ammo), WEP_RIFLE.m_id | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), SND_CAMPINGRIFLE_FIRE2, actor);
  39 }
  40
  41 .void(entity actor, .entity weaponentity) rifle_bullethail_attackfunc;
  42 .WFRAME rifle_bullethail_frame;
  43 .float rifle_bullethail_animtime;
  44 .float rifle_bullethail_refire;
  45 void W_Rifle_BulletHail_Continue(Weapon thiswep, entity actor, .entity weaponentity, int fire)
  46 {
  47         float r, af;
  48
  49         Weapon sw = actor.(weaponentity).m_switchweapon; // make it not detect weapon changes as reason to abort firing
  50         int slot = weaponslot(weaponentity);
  51         af = ATTACK_FINISHED(actor, slot);
  52         actor.(weaponentity).m_switchweapon = actor.(weaponentity).m_weapon;
  53         ATTACK_FINISHED(actor, slot) = time;
  54         r = weapon_prepareattack(thiswep, actor, weaponentity, actor.rifle_bullethail_frame == WFRAME_FIRE2, actor.rifle_bullethail_refire);
  55         if(actor.(weaponentity).m_switchweapon == actor.(weaponentity).m_weapon)
  56                 actor.(weaponentity).m_switchweapon = sw;
  57         if(r)
  58         {
  59                 actor.rifle_bullethail_attackfunc(actor, weaponentity);
  60                 weapon_thinkf(actor, weaponentity, actor.rifle_bullethail_frame, actor.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
  61         }
  62         else
  63         {
  64                 ATTACK_FINISHED(actor, slot) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
  65         }
  66 }
  67
  68 void W_Rifle_BulletHail(entity actor, .entity weaponentity, float mode, void(entity actor, .entity weaponentity) AttackFunc, WFRAME fr, float animtime, float refire)
  69 {
  70         // if we get here, we have at least one bullet to fire
  71         AttackFunc(actor, weaponentity);
  72         if(mode)
  73         {
  74                 // continue hail
  75                 actor.rifle_bullethail_attackfunc = AttackFunc;
  76                 actor.rifle_bullethail_frame = fr;
  77                 actor.rifle_bullethail_animtime = animtime;
  78                 actor.rifle_bullethail_refire = refire;
  79                 weapon_thinkf(actor, weaponentity, fr, animtime, W_Rifle_BulletHail_Continue);
  80         }
  81         else
  82         {
  83                 // just one shot
  84                 weapon_thinkf(actor, weaponentity, fr, animtime, w_ready);
  85         }
  86 }
  87
  88 .float bot_secondary_riflemooth;
  89
  90 METHOD(Rifle, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
  91 {
  92     PHYS_INPUT_BUTTON_ATCK(actor) = false;
  93     PHYS_INPUT_BUTTON_ATCK2(actor) = false;
  94     if(vdist(actor.origin - actor.enemy.origin, >, 1000))
  95         actor.bot_secondary_riflemooth = 0;
  96     if(actor.bot_secondary_riflemooth == 0)
  97     {
  98         if(bot_aim(actor, weaponentity, 1000000, 0, 0.001, false))
  99         {
 100             PHYS_INPUT_BUTTON_ATCK(actor) = true;
 101             if(random() < 0.01) actor.bot_secondary_riflemooth = 1;
 102         }
 103     }
 104     else
 105     {
 106         if(bot_aim(actor, weaponentity, 1000000, 0, 0.001, false))
 107         {
 108             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 109             if(random() < 0.03) actor.bot_secondary_riflemooth = 0;
 110         }
 111     }
 112 }
 113 METHOD(Rifle, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 114 {
 115     if(autocvar_g_balance_rifle_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) { // forced reload
 116         thiswep.wr_reload(thiswep, actor, weaponentity);
 117     } else
 118     {
 119         actor.(weaponentity).rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), actor.(weaponentity).rifle_accumulator, time);
 120         if(fire & 1)
 121         if(weapon_prepareattack_check(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire)))
 122         if(time >= actor.(weaponentity).rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
 123         {
 124             weapon_prepareattack_do(actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire));
 125             W_Rifle_BulletHail(actor, weaponentity, WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 126             actor.(weaponentity).rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
 127         }
 128         if(fire & 2)
 129         {
 130             if(WEP_CVAR(rifle, secondary))
 131             {
 132                 if(WEP_CVAR_SEC(rifle, reload)) {
 133                     thiswep.wr_reload(thiswep, actor, weaponentity);
 134                 } else
 135                 {
 136                     if(weapon_prepareattack_check(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire)))
 137                     if(time >= actor.(weaponentity).rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
 138                     {
 139                         weapon_prepareattack_do(actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire));
 140                         W_Rifle_BulletHail(actor, weaponentity, WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 141                         actor.(weaponentity).rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
 142                     }
 143                 }
 144             }
 145         }
 146     }
 147 }
 148 METHOD(Rifle, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 149 {
 150     float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(rifle, ammo);
 151     ammo_amount += actor.(weaponentity).(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_PRI(rifle, ammo);
 152     return ammo_amount;
 153 }
 154 METHOD(Rifle, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 155 {
 156     float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(rifle, ammo);
 157     ammo_amount += actor.(weaponentity).(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_SEC(rifle, ammo);
 158     return ammo_amount;
 159 }
 160 METHOD(Rifle, wr_resetplayer, void(entity thiswep, entity actor))
 161 {
 162     actor.rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
 163 }
 164 METHOD(Rifle, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 165 {
 166     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), SND_RELOAD);
 167 }
 168 METHOD(Rifle, wr_suicidemessage, Notification(entity thiswep))
 169 {
 170     return WEAPON_THINKING_WITH_PORTALS;
 171 }
 172 METHOD(Rifle, wr_killmessage, Notification(entity thiswep))
 173 {
 174     if(w_deathtype & HITTYPE_SECONDARY)
 175     {
 176         if(w_deathtype & HITTYPE_BOUNCE)
 177             return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
 178         else
 179             return WEAPON_RIFLE_MURDER_HAIL;
 180     }
 181     else
 182     {
 183         if(w_deathtype & HITTYPE_BOUNCE)
 184             return WEAPON_RIFLE_MURDER_PIERCING;
 185         else
 186             return WEAPON_RIFLE_MURDER;
 187     }
 188 }
 189 METHOD(Rifle, wr_zoom, bool(entity thiswep, entity actor))
 190 {
 191     return PHYS_INPUT_BUTTON_ATCK2(actor) && WEP_CVAR(rifle, secondary) == 0;
 192 }
 193
 194 #endif
 195 #ifdef CSQC
 196
 197 METHOD(Rifle, wr_impacteffect, void(entity thiswep, entity actor))
 198 {
 199     vector org2;
 200     org2 = w_org + w_backoff * 2;
 201     pointparticles(EFFECT_RIFLE_IMPACT, org2, w_backoff * 1000, 1);
 202     if(!w_issilent)
 203     {
 204         sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
 205     }
 206 }
 207 METHOD(Rifle, wr_init, void(entity thiswep))
 208 {
 209     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 210     {
 211         precache_pic("gfx/reticle_nex");
 212     }
 213 }
 214 METHOD(Rifle, wr_zoom, bool(entity thiswep, entity actor))
 215 {
 216     if(button_zoom || zoomscript_caught)
 217     {
 218         return true;
 219     }
 220     else
 221     {
 222         // no weapon specific image for this weapon
 223         return false;
 224     }
 225 }
 226 METHOD(Rifle, wr_zoomdir, bool(entity thiswep))
 227 {
 228     return button_attack2 && !WEP_CVAR(rifle, secondary);
 229 }
 230
 231 #endif