qcsrc/common/weapons/weapon/rifle.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Rifle, Weapon)
   3 /* ammotype  */ ATTRIB(Rifle, ammo_field, .int, ammo_nails);
   4 /* impulse   */ ATTRIB(Rifle, impulse, int, 7);
   5 /* flags     */ ATTRIB(Rifle, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN);
   6 /* rating    */ ATTRIB(Rifle, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   7 /* color     */ ATTRIB(Rifle, wpcolor, vector, '0.5 1 0');
   8 /* modelname */ ATTRIB(Rifle, mdl, string, "campingrifle");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Rifle, m_model, Model, MDL_RIFLE_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Rifle, w_crosshair, string, "gfx/crosshairrifle");
  13 /* crosshair */ ATTRIB(Rifle, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(Rifle, model2, string, "weaponrifle");
  15 /* refname   */ ATTRIB(Rifle, netname, string, "rifle");
  16 /* wepname   */ ATTRIB(Rifle, m_name, string, _("Rifle"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, ammo, float, BOTH) \
  21                 P(class, prefix, animtime, float, BOTH) \
  22                 P(class, prefix, bullethail, float, BOTH) \
  23                 P(class, prefix, burstcost, float, BOTH) \
  24                 P(class, prefix, bursttime, float, NONE) \
  25                 P(class, prefix, damage, float, BOTH) \
  26                 P(class, prefix, force, float, BOTH) \
  27                 P(class, prefix, refire, float, BOTH) \
  28                 P(class, prefix, reload, float, SEC) \
  29                 P(class, prefix, reload_ammo, float, NONE) \
  30         P(class, prefix, reload_time, float, NONE) \
  31                 P(class, prefix, secondary, float, NONE) \
  32                 P(class, prefix, shots, float, BOTH) \
  33                 P(class, prefix, solidpenetration, float, BOTH) \
  34                 P(class, prefix, spread, float, BOTH) \
  35         P(class, prefix, switchdelay_drop, float, NONE) \
  36         P(class, prefix, switchdelay_raise, float, NONE) \
  37                 P(class, prefix, tracer, float, BOTH) \
  38         P(class, prefix, weaponreplace, string, NONE) \
  39         P(class, prefix, weaponstartoverride, float, NONE) \
  40         P(class, prefix, weaponstart, float, NONE) \
  41         P(class, prefix, weaponthrowable, float, NONE) \
  42         END()
  43     W_PROPS(X, Rifle, rifle)
  44 #undef X
  45 ENDCLASS(Rifle)
  46 REGISTER_WEAPON(RIFLE, rifle, NEW(Rifle));
  47
  48
  49 #ifdef SVQC
  50 .float rifle_accumulator;
  51 #endif
  52 #endif
  53 #ifdef IMPLEMENTATION
  54 #ifdef SVQC
  55 spawnfunc(weapon_rifle) { weapon_defaultspawnfunc(this, WEP_RIFLE); }
  56 spawnfunc(weapon_campingrifle) { spawnfunc_weapon_rifle(this); }
  57 spawnfunc(weapon_sniperrifle) { spawnfunc_weapon_rifle(this); }
  58
  59 void W_Rifle_FireBullet(Weapon thiswep, .entity weaponentity, float pSpread, float pDamage, float pForce, float pSolidPenetration, float pAmmo, int deathtype, float pTracer, float pShots, Sound pSound, entity actor)
  60 {
  61         float i;
  62
  63         W_DecreaseAmmo(thiswep, actor, pAmmo);
  64
  65         W_SetupShot(actor, weaponentity, true, 2, pSound, CH_WEAPON_A, pDamage * pShots);
  66
  67         Send_Effect(EFFECT_RIFLE_MUZZLEFLASH, w_shotorg, w_shotdir * 2000, 1);
  68
  69         if(PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) // if zoomed, shoot from the eye
  70         {
  71                 w_shotdir = v_forward;
  72                 w_shotorg = actor.origin + actor.view_ofs + ((w_shotorg - actor.origin - actor.view_ofs) * v_forward) * v_forward;
  73         }
  74
  75         for(i = 0; i < pShots; ++i)
  76                 fireBullet(actor, w_shotorg, w_shotdir, pSpread, pSolidPenetration, pDamage, pForce, deathtype, (pTracer ? EF_RED : EF_BLUE));
  77
  78         if(autocvar_g_casings >= 2)
  79     {
  80         makevectors(actor.v_angle); // for some reason, this is lost
  81                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor, weaponentity);
  82     }
  83 }
  84
  85 void W_Rifle_Attack(entity actor, .entity weaponentity)
  86 {
  87         W_Rifle_FireBullet(WEP_RIFLE, weaponentity, WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, solidpenetration), WEP_CVAR_PRI(rifle, ammo), WEP_RIFLE.m_id, WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), SND_CAMPINGRIFLE_FIRE, actor);
  88 }
  89
  90 void W_Rifle_Attack2(entity actor, .entity weaponentity)
  91 {
  92         W_Rifle_FireBullet(WEP_RIFLE, weaponentity, WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, solidpenetration), WEP_CVAR_SEC(rifle, ammo), WEP_RIFLE.m_id | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), SND_CAMPINGRIFLE_FIRE2, actor);
  93 }
  94
  95 .void(entity actor, .entity weaponentity) rifle_bullethail_attackfunc;
  96 .WFRAME rifle_bullethail_frame;
  97 .float rifle_bullethail_animtime;
  98 .float rifle_bullethail_refire;
  99 void W_Rifle_BulletHail_Continue(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 100 {
 101         float r, af;
 102
 103         Weapon sw = PS(actor).m_switchweapon; // make it not detect weapon changes as reason to abort firing
 104         int slot = weaponslot(weaponentity);
 105         af = ATTACK_FINISHED(actor, slot);
 106         PS(actor).m_switchweapon = PS(actor).m_weapon;
 107         ATTACK_FINISHED(actor, slot) = time;
 108         r = weapon_prepareattack(thiswep, actor, weaponentity, actor.rifle_bullethail_frame == WFRAME_FIRE2, actor.rifle_bullethail_refire);
 109         if(PS(actor).m_switchweapon == PS(actor).m_weapon)
 110                 PS(actor).m_switchweapon = sw;
 111         if(r)
 112         {
 113                 actor.rifle_bullethail_attackfunc(actor, weaponentity);
 114                 weapon_thinkf(actor, weaponentity, actor.rifle_bullethail_frame, actor.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
 115         }
 116         else
 117         {
 118                 ATTACK_FINISHED(actor, slot) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
 119         }
 120 }
 121
 122 void W_Rifle_BulletHail(entity actor, .entity weaponentity, float mode, void(entity actor, .entity weaponentity) AttackFunc, WFRAME fr, float animtime, float refire)
 123 {
 124         // if we get here, we have at least one bullet to fire
 125         AttackFunc(actor, weaponentity);
 126         if(mode)
 127         {
 128                 // continue hail
 129                 actor.rifle_bullethail_attackfunc = AttackFunc;
 130                 actor.rifle_bullethail_frame = fr;
 131                 actor.rifle_bullethail_animtime = animtime;
 132                 actor.rifle_bullethail_refire = refire;
 133                 weapon_thinkf(actor, weaponentity, fr, animtime, W_Rifle_BulletHail_Continue);
 134         }
 135         else
 136         {
 137                 // just one shot
 138                 weapon_thinkf(actor, weaponentity, fr, animtime, w_ready);
 139         }
 140 }
 141
 142 .float bot_secondary_riflemooth;
 143
 144 METHOD(Rifle, wr_aim, void(entity thiswep, entity actor))
 145 {
 146     PHYS_INPUT_BUTTON_ATCK(actor) = false;
 147     PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 148     if(vdist(actor.origin - actor.enemy.origin, >, 1000))
 149         actor.bot_secondary_riflemooth = 0;
 150     if(actor.bot_secondary_riflemooth == 0)
 151     {
 152         if(bot_aim(actor, 1000000, 0, 0.001, false))
 153         {
 154             PHYS_INPUT_BUTTON_ATCK(actor) = true;
 155             if(random() < 0.01) actor.bot_secondary_riflemooth = 1;
 156         }
 157     }
 158     else
 159     {
 160         if(bot_aim(actor, 1000000, 0, 0.001, false))
 161         {
 162             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 163             if(random() < 0.03) actor.bot_secondary_riflemooth = 0;
 164         }
 165     }
 166 }
 167 METHOD(Rifle, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 168 {
 169     if(autocvar_g_balance_rifle_reload_ammo && actor.clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) { // forced reload
 170         thiswep.wr_reload(thiswep, actor, weaponentity);
 171     } else
 172     {
 173         actor.rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), actor.rifle_accumulator, time);
 174         if(fire & 1)
 175         if(weapon_prepareattack_check(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire)))
 176         if(time >= actor.rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
 177         {
 178             weapon_prepareattack_do(actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire));
 179             W_Rifle_BulletHail(actor, weaponentity, WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 180             actor.rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
 181         }
 182         if(fire & 2)
 183         {
 184             if(WEP_CVAR(rifle, secondary))
 185             {
 186                 if(WEP_CVAR_SEC(rifle, reload)) {
 187                     thiswep.wr_reload(thiswep, actor, weaponentity);
 188                 } else
 189                 {
 190                     if(weapon_prepareattack_check(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire)))
 191                     if(time >= actor.rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
 192                     {
 193                         weapon_prepareattack_do(actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire));
 194                         W_Rifle_BulletHail(actor, weaponentity, WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 195                         actor.rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
 196                     }
 197                 }
 198             }
 199         }
 200     }
 201 }
 202 METHOD(Rifle, wr_checkammo1, bool(entity thiswep, entity actor))
 203 {
 204     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(rifle, ammo);
 205     ammo_amount += actor.(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_PRI(rifle, ammo);
 206     return ammo_amount;
 207 }
 208 METHOD(Rifle, wr_checkammo2, bool(entity thiswep, entity actor))
 209 {
 210     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(rifle, ammo);
 211     ammo_amount += actor.(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_SEC(rifle, ammo);
 212     return ammo_amount;
 213 }
 214 METHOD(Rifle, wr_resetplayer, void(entity thiswep, entity actor))
 215 {
 216     actor.rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
 217 }
 218 METHOD(Rifle, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 219 {
 220     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), SND_RELOAD);
 221 }
 222 METHOD(Rifle, wr_suicidemessage, Notification(entity thiswep))
 223 {
 224     return WEAPON_THINKING_WITH_PORTALS;
 225 }
 226 METHOD(Rifle, wr_killmessage, Notification(entity thiswep))
 227 {
 228     if(w_deathtype & HITTYPE_SECONDARY)
 229     {
 230         if(w_deathtype & HITTYPE_BOUNCE)
 231             return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
 232         else
 233             return WEAPON_RIFLE_MURDER_HAIL;
 234     }
 235     else
 236     {
 237         if(w_deathtype & HITTYPE_BOUNCE)
 238             return WEAPON_RIFLE_MURDER_PIERCING;
 239         else
 240             return WEAPON_RIFLE_MURDER;
 241     }
 242 }
 243
 244 #endif
 245 #ifdef CSQC
 246
 247 METHOD(Rifle, wr_impacteffect, void(entity thiswep, entity actor))
 248 {
 249     vector org2;
 250     org2 = w_org + w_backoff * 2;
 251     pointparticles(EFFECT_RIFLE_IMPACT, org2, w_backoff * 1000, 1);
 252     if(!w_issilent)
 253     {
 254         sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
 255     }
 256 }
 257 METHOD(Rifle, wr_init, void(entity thiswep))
 258 {
 259     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 260     {
 261         precache_pic("gfx/reticle_nex");
 262     }
 263 }
 264 METHOD(Rifle, wr_zoomreticle, bool(entity thiswep))
 265 {
 266     if(button_zoom || zoomscript_caught)
 267     {
 268         reticle_image = "gfx/reticle_nex";
 269         return true;
 270     }
 271     else
 272     {
 273         // no weapon specific image for this weapon
 274         return false;
 275     }
 276 }
 277
 278 #endif
 279 #endif