qcsrc/common/weapons/weapon/rifle.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Rifle, Weapon)
   3 /* ammotype  */ ATTRIB(Rifle, ammo_field, .int, ammo_nails)
   4 /* impulse   */ ATTRIB(Rifle, impulse, int, 7)
   5 /* flags     */ ATTRIB(Rifle, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN);
   6 /* rating    */ ATTRIB(Rifle, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   7 /* color     */ ATTRIB(Rifle, wpcolor, vector, '0.5 1 0');
   8 /* modelname */ ATTRIB(Rifle, mdl, string, "campingrifle");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Rifle, m_model, Model, MDL_RIFLE_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Rifle, w_crosshair, string, "gfx/crosshairrifle");
  13 /* crosshair */ ATTRIB(Rifle, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(Rifle, model2, string, "weaponrifle");
  15 /* refname   */ ATTRIB(Rifle, netname, string, "rifle");
  16 /* wepname   */ ATTRIB(Rifle, m_name, string, _("Rifle"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, ammo, float, BOTH) \
  21                 P(class, prefix, animtime, float, BOTH) \
  22                 P(class, prefix, bullethail, float, BOTH) \
  23                 P(class, prefix, burstcost, float, BOTH) \
  24                 P(class, prefix, bursttime, float, NONE) \
  25                 P(class, prefix, damage, float, BOTH) \
  26                 P(class, prefix, force, float, BOTH) \
  27                 P(class, prefix, refire, float, BOTH) \
  28                 P(class, prefix, reload, float, SEC) \
  29                 P(class, prefix, reload_ammo, float, NONE) \
  30         P(class, prefix, reload_time, float, NONE) \
  31                 P(class, prefix, secondary, float, NONE) \
  32                 P(class, prefix, shots, float, BOTH) \
  33                 P(class, prefix, solidpenetration, float, BOTH) \
  34                 P(class, prefix, spread, float, BOTH) \
  35         P(class, prefix, switchdelay_drop, float, NONE) \
  36         P(class, prefix, switchdelay_raise, float, NONE) \
  37                 P(class, prefix, tracer, float, BOTH) \
  38         P(class, prefix, weaponreplace, string, NONE) \
  39         P(class, prefix, weaponstartoverride, float, NONE) \
  40         P(class, prefix, weaponstart, float, NONE) \
  41         P(class, prefix, weaponthrowable, float, NONE) \
  42         END()
  43     W_PROPS(X, Rifle, rifle)
  44 #undef X
  45 ENDCLASS(Rifle)
  46 REGISTER_WEAPON(RIFLE, rifle, NEW(Rifle));
  47
  48
  49 #ifdef SVQC
  50 .float rifle_accumulator;
  51 #endif
  52 #endif
  53 #ifdef IMPLEMENTATION
  54 #ifdef SVQC
  55 spawnfunc(weapon_rifle) { weapon_defaultspawnfunc(this, WEP_RIFLE); }
  56 spawnfunc(weapon_campingrifle) { spawnfunc_weapon_rifle(this); }
  57 spawnfunc(weapon_sniperrifle) { spawnfunc_weapon_rifle(this); }
  58
  59 void W_Rifle_FireBullet(Weapon thiswep, float pSpread, float pDamage, float pForce, float pSolidPenetration, float pAmmo, int deathtype, float pTracer, float pShots, string pSound)
  60 {SELFPARAM();
  61         float i;
  62
  63         W_DecreaseAmmo(thiswep, self, pAmmo);
  64
  65         W_SetupShot(self, true, 2, pSound, CH_WEAPON_A, pDamage * pShots);
  66
  67         Send_Effect(EFFECT_RIFLE_MUZZLEFLASH, w_shotorg, w_shotdir * 2000, 1);
  68
  69         if(PHYS_INPUT_BUTTON_ZOOM(self) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(self)) // if zoomed, shoot from the eye
  70         {
  71                 w_shotdir = v_forward;
  72                 w_shotorg = self.origin + self.view_ofs + ((w_shotorg - self.origin - self.view_ofs) * v_forward) * v_forward;
  73         }
  74
  75         for(i = 0; i < pShots; ++i)
  76                 fireBullet(w_shotorg, w_shotdir, pSpread, pSolidPenetration, pDamage, pForce, deathtype, (pTracer ? EF_RED : EF_BLUE));
  77
  78         if(autocvar_g_casings >= 2)
  79                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  80 }
  81
  82 void W_Rifle_Attack()
  83 {
  84         W_Rifle_FireBullet(WEP_RIFLE, WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, solidpenetration), WEP_CVAR_PRI(rifle, ammo), WEP_RIFLE.m_id, WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), SND(CAMPINGRIFLE_FIRE));
  85 }
  86
  87 void W_Rifle_Attack2()
  88 {
  89         W_Rifle_FireBullet(WEP_RIFLE, WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, solidpenetration), WEP_CVAR_SEC(rifle, ammo), WEP_RIFLE.m_id | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), SND(CAMPINGRIFLE_FIRE2));
  90 }
  91
  92 .void() rifle_bullethail_attackfunc;
  93 .WFRAME rifle_bullethail_frame;
  94 .float rifle_bullethail_animtime;
  95 .float rifle_bullethail_refire;
  96 void W_Rifle_BulletHail_Continue(Weapon thiswep, entity actor, .entity weaponentity, int fire)
  97 {
  98         float r, af;
  99
 100         Weapon sw = PS(actor).m_switchweapon; // make it not detect weapon changes as reason to abort firing
 101         int slot = weaponslot(weaponentity);
 102         af = ATTACK_FINISHED(actor, slot);
 103         PS(actor).m_switchweapon = PS(actor).m_weapon;
 104         ATTACK_FINISHED(actor, slot) = time;
 105         r = weapon_prepareattack(thiswep, actor, weaponentity, actor.rifle_bullethail_frame == WFRAME_FIRE2, actor.rifle_bullethail_refire);
 106         if(PS(actor).m_switchweapon == PS(actor).m_weapon)
 107                 PS(actor).m_switchweapon = sw;
 108         if(r)
 109         {
 110                 actor.rifle_bullethail_attackfunc();
 111                 weapon_thinkf(actor, weaponentity, actor.rifle_bullethail_frame, actor.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
 112         }
 113         else
 114         {
 115                 ATTACK_FINISHED(actor, slot) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
 116         }
 117 }
 118
 119 void W_Rifle_BulletHail(.entity weaponentity, float mode, void() AttackFunc, WFRAME fr, float animtime, float refire)
 120 {SELFPARAM();
 121         // if we get here, we have at least one bullet to fire
 122         AttackFunc();
 123         if(mode)
 124         {
 125                 // continue hail
 126                 self.rifle_bullethail_attackfunc = AttackFunc;
 127                 self.rifle_bullethail_frame = fr;
 128                 self.rifle_bullethail_animtime = animtime;
 129                 self.rifle_bullethail_refire = refire;
 130                 weapon_thinkf(self, weaponentity, fr, animtime, W_Rifle_BulletHail_Continue);
 131         }
 132         else
 133         {
 134                 // just one shot
 135                 weapon_thinkf(self, weaponentity, fr, animtime, w_ready);
 136         }
 137 }
 138
 139 .float bot_secondary_riflemooth;
 140
 141 METHOD(Rifle, wr_aim, void(entity thiswep))
 142 {
 143     PHYS_INPUT_BUTTON_ATCK(self) = false;
 144     PHYS_INPUT_BUTTON_ATCK2(self) = false;
 145     if(vdist(self.origin - self.enemy.origin, >, 1000))
 146         self.bot_secondary_riflemooth = 0;
 147     if(self.bot_secondary_riflemooth == 0)
 148     {
 149         if(bot_aim(1000000, 0, 0.001, false))
 150         {
 151             PHYS_INPUT_BUTTON_ATCK(self) = true;
 152             if(random() < 0.01) self.bot_secondary_riflemooth = 1;
 153         }
 154     }
 155     else
 156     {
 157         if(bot_aim(1000000, 0, 0.001, false))
 158         {
 159             PHYS_INPUT_BUTTON_ATCK2(self) = true;
 160             if(random() < 0.03) self.bot_secondary_riflemooth = 0;
 161         }
 162     }
 163 }
 164 METHOD(Rifle, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 165 {
 166     if(autocvar_g_balance_rifle_reload_ammo && actor.clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) { // forced reload
 167         thiswep.wr_reload(thiswep, actor, weaponentity);
 168     } else
 169     {
 170         actor.rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), actor.rifle_accumulator, time);
 171         if(fire & 1)
 172         if(weapon_prepareattack_check(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire)))
 173         if(time >= actor.rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
 174         {
 175             weapon_prepareattack_do(actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire));
 176             W_Rifle_BulletHail(weaponentity, WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 177             actor.rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
 178         }
 179         if(fire & 2)
 180         {
 181             if(WEP_CVAR(rifle, secondary))
 182             {
 183                 if(WEP_CVAR_SEC(rifle, reload)) {
 184                     thiswep.wr_reload(thiswep, actor, weaponentity);
 185                 } else
 186                 {
 187                     if(weapon_prepareattack_check(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire)))
 188                     if(time >= actor.rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
 189                     {
 190                         weapon_prepareattack_do(actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire));
 191                         W_Rifle_BulletHail(weaponentity, WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 192                         actor.rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
 193                     }
 194                 }
 195             }
 196         }
 197     }
 198 }
 199 METHOD(Rifle, wr_checkammo1, bool(entity thiswep))
 200 {
 201     float ammo_amount = self.(thiswep.ammo_field) >= WEP_CVAR_PRI(rifle, ammo);
 202     ammo_amount += self.(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_PRI(rifle, ammo);
 203     return ammo_amount;
 204 }
 205 METHOD(Rifle, wr_checkammo2, bool(entity thiswep))
 206 {
 207     float ammo_amount = self.(thiswep.ammo_field) >= WEP_CVAR_SEC(rifle, ammo);
 208     ammo_amount += self.(weapon_load[WEP_RIFLE.m_id]) >= WEP_CVAR_SEC(rifle, ammo);
 209     return ammo_amount;
 210 }
 211 METHOD(Rifle, wr_resetplayer, void(entity thiswep))
 212 {
 213     self.rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
 214 }
 215 METHOD(Rifle, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 216 {
 217     W_Reload(self, min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), SND(RELOAD));
 218 }
 219 METHOD(Rifle, wr_suicidemessage, Notification(entity thiswep))
 220 {
 221     return WEAPON_THINKING_WITH_PORTALS;
 222 }
 223 METHOD(Rifle, wr_killmessage, Notification(entity thiswep))
 224 {
 225     if(w_deathtype & HITTYPE_SECONDARY)
 226     {
 227         if(w_deathtype & HITTYPE_BOUNCE)
 228             return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
 229         else
 230             return WEAPON_RIFLE_MURDER_HAIL;
 231     }
 232     else
 233     {
 234         if(w_deathtype & HITTYPE_BOUNCE)
 235             return WEAPON_RIFLE_MURDER_PIERCING;
 236         else
 237             return WEAPON_RIFLE_MURDER;
 238     }
 239 }
 240
 241 #endif
 242 #ifdef CSQC
 243
 244 METHOD(Rifle, wr_impacteffect, void(entity thiswep))
 245 {
 246     vector org2;
 247     org2 = w_org + w_backoff * 2;
 248     pointparticles(EFFECT_RIFLE_IMPACT, org2, w_backoff * 1000, 1);
 249     if(!w_issilent)
 250     {
 251         sound(self, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
 252     }
 253 }
 254 METHOD(Rifle, wr_init, void(entity thiswep))
 255 {
 256     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 257     {
 258         precache_pic("gfx/reticle_nex");
 259     }
 260 }
 261 METHOD(Rifle, wr_zoomreticle, bool(entity thiswep))
 262 {
 263     if(button_zoom || zoomscript_caught)
 264     {
 265         reticle_image = "gfx/reticle_nex";
 266         return true;
 267     }
 268     else
 269     {
 270         // no weapon specific image for this weapon
 271         return false;
 272     }
 273 }
 274
 275 #endif
 276 #endif