qcsrc/common/weapons/weapon/rifle.qc

   1 #include "rifle.qh"
   2
   3 #ifdef SVQC
   4
   5 void W_Rifle_FireBullet(Weapon thiswep, .entity weaponentity, float pSpread, float pDamage, float pForce, float pSolidPenetration, float pAmmo, int deathtype, float pTracer, float pShots, Sound pSound, entity actor)
   6 {
   7         float i;
   8
   9         W_DecreaseAmmo(thiswep, actor, pAmmo, weaponentity);
  10
  11         W_SetupShot(actor, weaponentity, true, 2, pSound, CH_WEAPON_A, pDamage * pShots, deathtype);
  12
  13         W_MuzzleFlash(actor, weaponentity, EFFECT_RIFLE_MUZZLEFLASH, w_shotorg, w_shotdir * 2000);
  14
  15         if(PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) // if zoomed, shoot from the eye
  16         {
  17                 w_shotdir = v_forward;
  18                 w_shotorg = actor.origin + actor.view_ofs + ((w_shotorg - actor.origin - actor.view_ofs) * v_forward) * v_forward;
  19         }
  20
  21         for(i = 0; i < pShots; ++i)
  22                 fireBullet(actor, weaponentity, w_shotorg, w_shotdir, pSpread, pSolidPenetration, pDamage, pForce, deathtype, (pTracer ? EFFECT_RIFLE : EFFECT_RIFLE_WEAK));
  23
  24         if(autocvar_g_casings >= 2)
  25     {
  26         makevectors(actor.v_angle); // for some reason, this is lost
  27                 SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor, weaponentity);
  28     }
  29 }
  30
  31 void W_Rifle_Attack(Weapon thiswep, entity actor, .entity weaponentity)
  32 {
  33         W_Rifle_FireBullet(thiswep, weaponentity, WEP_CVAR_PRI(rifle, spread), WEP_CVAR_PRI(rifle, damage), WEP_CVAR_PRI(rifle, force), WEP_CVAR_PRI(rifle, solidpenetration), WEP_CVAR_PRI(rifle, ammo), thiswep.m_id, WEP_CVAR_PRI(rifle, tracer), WEP_CVAR_PRI(rifle, shots), SND_CAMPINGRIFLE_FIRE, actor);
  34 }
  35
  36 void W_Rifle_Attack2(Weapon thiswep, entity actor, .entity weaponentity)
  37 {
  38         W_Rifle_FireBullet(thiswep, weaponentity, WEP_CVAR_SEC(rifle, spread), WEP_CVAR_SEC(rifle, damage), WEP_CVAR_SEC(rifle, force), WEP_CVAR_SEC(rifle, solidpenetration), WEP_CVAR_SEC(rifle, ammo), thiswep.m_id | HITTYPE_SECONDARY, WEP_CVAR_SEC(rifle, tracer), WEP_CVAR_SEC(rifle, shots), SND_CAMPINGRIFLE_FIRE2, actor);
  39 }
  40
  41 .void(Weapon thiswep, entity actor, .entity weaponentity) rifle_bullethail_attackfunc;
  42 .WFRAME rifle_bullethail_frame;
  43 .float rifle_bullethail_animtime;
  44 .float rifle_bullethail_refire;
  45 void W_Rifle_BulletHail_Continue(Weapon thiswep, entity actor, .entity weaponentity, int fire)
  46 {
  47         float r, af;
  48
  49         Weapon sw = actor.(weaponentity).m_switchweapon; // make it not detect weapon changes as reason to abort firing
  50         af = ATTACK_FINISHED(actor, weaponentity);
  51         actor.(weaponentity).m_switchweapon = actor.(weaponentity).m_weapon;
  52         ATTACK_FINISHED(actor, weaponentity) = time;
  53         r = weapon_prepareattack(thiswep, actor, weaponentity, actor.rifle_bullethail_frame == WFRAME_FIRE2, actor.rifle_bullethail_refire);
  54         if(actor.(weaponentity).m_switchweapon == actor.(weaponentity).m_weapon)
  55                 actor.(weaponentity).m_switchweapon = sw;
  56         if(r)
  57         {
  58                 actor.rifle_bullethail_attackfunc(thiswep, actor, weaponentity);
  59                 weapon_thinkf(actor, weaponentity, actor.rifle_bullethail_frame, actor.rifle_bullethail_animtime, W_Rifle_BulletHail_Continue);
  60         }
  61         else
  62         {
  63                 ATTACK_FINISHED(actor, weaponentity) = af; // reset attack_finished if we didn't fire, so the last shot enforces the refire time
  64         }
  65 }
  66
  67 void W_Rifle_BulletHail(Weapon thiswep, entity actor, .entity weaponentity, float mode, void(Weapon thiswep, entity actor, .entity weaponentity) AttackFunc, WFRAME fr, float animtime, float refire)
  68 {
  69         // if we get here, we have at least one bullet to fire
  70         AttackFunc(thiswep, actor, weaponentity);
  71         if(mode)
  72         {
  73                 // continue hail
  74                 actor.rifle_bullethail_attackfunc = AttackFunc;
  75                 actor.rifle_bullethail_frame = fr;
  76                 actor.rifle_bullethail_animtime = animtime;
  77                 actor.rifle_bullethail_refire = refire;
  78                 weapon_thinkf(actor, weaponentity, fr, animtime, W_Rifle_BulletHail_Continue);
  79         }
  80         else
  81         {
  82                 // just one shot
  83                 weapon_thinkf(actor, weaponentity, fr, animtime, w_ready);
  84         }
  85 }
  86
  87 .float bot_secondary_riflemooth;
  88
  89 METHOD(Rifle, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
  90 {
  91     PHYS_INPUT_BUTTON_ATCK(actor) = false;
  92     PHYS_INPUT_BUTTON_ATCK2(actor) = false;
  93     if(vdist(actor.origin - actor.enemy.origin, >, 1000))
  94         actor.bot_secondary_riflemooth = 0;
  95     if(actor.bot_secondary_riflemooth == 0)
  96     {
  97         if(bot_aim(actor, weaponentity, 1000000, 0, 0.001, false))
  98         {
  99             PHYS_INPUT_BUTTON_ATCK(actor) = true;
 100             if(random() < 0.01) actor.bot_secondary_riflemooth = 1;
 101         }
 102     }
 103     else
 104     {
 105         if(bot_aim(actor, weaponentity, 1000000, 0, 0.001, false))
 106         {
 107             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 108             if(random() < 0.03) actor.bot_secondary_riflemooth = 0;
 109         }
 110     }
 111 }
 112 METHOD(Rifle, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 113 {
 114     if(autocvar_g_balance_rifle_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo))) { // forced reload
 115         thiswep.wr_reload(thiswep, actor, weaponentity);
 116     } else
 117     {
 118         actor.(weaponentity).rifle_accumulator = bound(time - WEP_CVAR(rifle, bursttime), actor.(weaponentity).rifle_accumulator, time);
 119         if(fire & 1)
 120         if(weapon_prepareattack_check(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire)))
 121         if(time >= actor.(weaponentity).rifle_accumulator + WEP_CVAR_PRI(rifle, burstcost))
 122         {
 123             weapon_prepareattack_do(actor, weaponentity, false, WEP_CVAR_PRI(rifle, refire));
 124             W_Rifle_BulletHail(thiswep, actor, weaponentity, WEP_CVAR_PRI(rifle, bullethail), W_Rifle_Attack, WFRAME_FIRE1, WEP_CVAR_PRI(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 125             actor.(weaponentity).rifle_accumulator += WEP_CVAR_PRI(rifle, burstcost);
 126         }
 127         if(fire & 2)
 128         {
 129             if(WEP_CVAR(rifle, secondary))
 130             {
 131                 if(WEP_CVAR_SEC(rifle, reload)) {
 132                     thiswep.wr_reload(thiswep, actor, weaponentity);
 133                 } else
 134                 {
 135                     if(weapon_prepareattack_check(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire)))
 136                     if(time >= actor.(weaponentity).rifle_accumulator + WEP_CVAR_SEC(rifle, burstcost))
 137                     {
 138                         weapon_prepareattack_do(actor, weaponentity, true, WEP_CVAR_SEC(rifle, refire));
 139                         W_Rifle_BulletHail(thiswep, actor, weaponentity, WEP_CVAR_SEC(rifle, bullethail), W_Rifle_Attack2, WFRAME_FIRE2, WEP_CVAR_SEC(rifle, animtime), WEP_CVAR_PRI(rifle, refire));
 140                         actor.(weaponentity).rifle_accumulator += WEP_CVAR_SEC(rifle, burstcost);
 141                     }
 142                 }
 143             }
 144         }
 145     }
 146 }
 147 METHOD(Rifle, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 148 {
 149     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(rifle, ammo);
 150     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(rifle, ammo);
 151     return ammo_amount;
 152 }
 153 METHOD(Rifle, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 154 {
 155     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(rifle, ammo);
 156     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_SEC(rifle, ammo);
 157     return ammo_amount;
 158 }
 159 METHOD(Rifle, wr_resetplayer, void(entity thiswep, entity actor))
 160 {
 161     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 162     {
 163         .entity weaponentity = weaponentities[slot];
 164         actor.(weaponentity).rifle_accumulator = time - WEP_CVAR(rifle, bursttime);
 165     }
 166 }
 167 METHOD(Rifle, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 168 {
 169     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(rifle, ammo), WEP_CVAR_SEC(rifle, ammo)), SND_RELOAD);
 170 }
 171 METHOD(Rifle, wr_suicidemessage, Notification(entity thiswep))
 172 {
 173     return WEAPON_THINKING_WITH_PORTALS;
 174 }
 175 METHOD(Rifle, wr_killmessage, Notification(entity thiswep))
 176 {
 177     if(w_deathtype & HITTYPE_SECONDARY)
 178     {
 179         if(w_deathtype & HITTYPE_BOUNCE)
 180             return WEAPON_RIFLE_MURDER_HAIL_PIERCING;
 181         else
 182             return WEAPON_RIFLE_MURDER_HAIL;
 183     }
 184     else
 185     {
 186         if(w_deathtype & HITTYPE_BOUNCE)
 187             return WEAPON_RIFLE_MURDER_PIERCING;
 188         else
 189             return WEAPON_RIFLE_MURDER;
 190     }
 191 }
 192 METHOD(Rifle, wr_zoom, bool(entity thiswep, entity actor))
 193 {
 194     return PHYS_INPUT_BUTTON_ATCK2(actor) && WEP_CVAR(rifle, secondary) == 0;
 195 }
 196
 197 #endif
 198 #ifdef CSQC
 199
 200 METHOD(Rifle, wr_impacteffect, void(entity thiswep, entity actor))
 201 {
 202     vector org2;
 203     org2 = w_org + w_backoff * 2;
 204     pointparticles(EFFECT_RIFLE_IMPACT, org2, w_backoff * 1000, 1);
 205     if(!w_issilent)
 206     {
 207         sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTN_NORM);
 208     }
 209 }
 210 METHOD(Rifle, wr_init, void(entity thiswep))
 211 {
 212     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 213     {
 214         precache_pic("gfx/reticle_nex");
 215     }
 216 }
 217 METHOD(Rifle, wr_zoom, bool(entity thiswep, entity actor))
 218 {
 219     if(button_zoom || zoomscript_caught)
 220     {
 221         return true;
 222     }
 223     else
 224     {
 225         // no weapon specific image for this weapon
 226         return false;
 227     }
 228 }
 229 METHOD(Rifle, wr_zoomdir, bool(entity thiswep))
 230 {
 231     return button_attack2 && !WEP_CVAR(rifle, secondary);
 232 }
 233
 234 #endif