qcsrc/common/weapons/weapon/seeker.qc

   1 #include "seeker.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Seeker, Weapon)
   4 /* ammotype  */ ATTRIB(Seeker, ammo_field, .int, ammo_rockets);
   5 /* impulse   */ ATTRIB(Seeker, impulse, int, 8);
   6 /* flags     */ ATTRIB(Seeker, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH);
   7 /* rating    */ ATTRIB(Seeker, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   8 /* color     */ ATTRIB(Seeker, wpcolor, vector, '0.5 1 0');
   9 /* modelname */ ATTRIB(Seeker, mdl, string, "seeker");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Seeker, m_model, Model, MDL_SEEKER_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Seeker, w_crosshair, string, "gfx/crosshairseeker");
  14 /* crosshair */ ATTRIB(Seeker, w_crosshair_size, float, 0.8);
  15 /* wepimg    */ ATTRIB(Seeker, model2, string, "weaponseeker");
  16 /* refname   */ ATTRIB(Seeker, netname, string, "seeker");
  17 /* wepname   */ ATTRIB(Seeker, m_name, string, _("T.A.G. Seeker"));
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21         P(class, prefix, flac_ammo, float, NONE) \
  22         P(class, prefix, flac_animtime, float, NONE) \
  23         P(class, prefix, flac_damage, float, NONE) \
  24         P(class, prefix, flac_edgedamage, float, NONE) \
  25         P(class, prefix, flac_force, float, NONE) \
  26         P(class, prefix, flac_lifetime, float, NONE) \
  27         P(class, prefix, flac_lifetime_rand, float, NONE) \
  28         P(class, prefix, flac_radius, float, NONE) \
  29         P(class, prefix, flac_refire, float, NONE) \
  30         P(class, prefix, flac_speed, float, NONE) \
  31         P(class, prefix, flac_speed_up, float, NONE) \
  32         P(class, prefix, flac_speed_z, float, NONE) \
  33         P(class, prefix, flac_spread, float, NONE) \
  34         P(class, prefix, missile_accel, float, NONE) \
  35         P(class, prefix, missile_ammo, float, NONE) \
  36         P(class, prefix, missile_animtime, float, NONE) \
  37         P(class, prefix, missile_count, float, NONE) \
  38         P(class, prefix, missile_damageforcescale, float, NONE) \
  39         P(class, prefix, missile_damage, float, NONE) \
  40         P(class, prefix, missile_decel, float, NONE) \
  41         P(class, prefix, missile_delay, float, NONE) \
  42         P(class, prefix, missile_edgedamage, float, NONE) \
  43         P(class, prefix, missile_force, float, NONE) \
  44         P(class, prefix, missile_health, float, NONE) \
  45         P(class, prefix, missile_lifetime, float, NONE) \
  46         P(class, prefix, missile_proxy, float, NONE) \
  47         P(class, prefix, missile_proxy_delay, float, NONE) \
  48         P(class, prefix, missile_proxy_maxrange, float, NONE) \
  49         P(class, prefix, missile_radius, float, NONE) \
  50         P(class, prefix, missile_refire, float, NONE) \
  51         P(class, prefix, missile_smart, float, NONE) \
  52         P(class, prefix, missile_smart_mindist, float, NONE) \
  53         P(class, prefix, missile_smart_trace_max, float, NONE) \
  54         P(class, prefix, missile_smart_trace_min, float, NONE) \
  55         P(class, prefix, missile_speed, float, NONE) \
  56         P(class, prefix, missile_speed_max, float, NONE) \
  57         P(class, prefix, missile_speed_up, float, NONE) \
  58         P(class, prefix, missile_speed_z, float, NONE) \
  59         P(class, prefix, missile_spread, float, NONE) \
  60         P(class, prefix, missile_turnrate, float, NONE) \
  61         P(class, prefix, reload_ammo, float, NONE) \
  62                 P(class, prefix, reload_time, float, NONE) \
  63                 P(class, prefix, switchdelay_drop, float, NONE) \
  64                 P(class, prefix, switchdelay_raise, float, NONE) \
  65         P(class, prefix, tag_ammo, float, NONE) \
  66         P(class, prefix, tag_animtime, float, NONE) \
  67         P(class, prefix, tag_damageforcescale, float, NONE) \
  68         P(class, prefix, tag_health, float, NONE) \
  69         P(class, prefix, tag_lifetime, float, NONE) \
  70         P(class, prefix, tag_refire, float, NONE) \
  71         P(class, prefix, tag_speed, float, NONE) \
  72         P(class, prefix, tag_spread, float, NONE) \
  73         P(class, prefix, tag_tracker_lifetime, float, NONE) \
  74                 P(class, prefix, type, float, NONE) \
  75                 P(class, prefix, weaponreplace, string, NONE) \
  76                 P(class, prefix, weaponstartoverride, float, NONE) \
  77                 P(class, prefix, weaponstart, float, NONE) \
  78                 P(class, prefix, weaponthrowable, float, NONE) \
  79         END()
  80         W_PROPS(X, Seeker, seeker)
  81 #undef X
  82 ENDCLASS(Seeker)
  83 REGISTER_WEAPON(SEEKER, seeker, NEW(Seeker));
  84
  85
  86 #ifdef SVQC
  87 .entity tag_target, wps_tag_tracker;
  88 .float tag_time;
  89 #endif
  90 #endif
  91 #ifdef IMPLEMENTATION
  92 #ifdef SVQC
  93 spawnfunc(weapon_seeker) { weapon_defaultspawnfunc(this, WEP_SEEKER); }
  94
  95 // ============================
  96 // Begin: Missile functions, these are general functions to be manipulated by other code
  97 // ============================
  98 void W_Seeker_Missile_Explode(entity this, entity directhitentity)
  99 {
 100         this.event_damage = func_null;
 101         RadiusDamage(this, this.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), NULL, NULL, WEP_CVAR(seeker, missile_force), this.projectiledeathtype, directhitentity);
 102
 103         delete(this);
 104 }
 105
 106 void W_Seeker_Missile_Explode_think(entity this)
 107 {
 108         W_Seeker_Missile_Explode(this, NULL);
 109 }
 110
 111 void W_Seeker_Missile_Touch(entity this, entity toucher)
 112 {
 113         PROJECTILE_TOUCH(this, toucher);
 114
 115         W_Seeker_Missile_Explode(this, toucher);
 116 }
 117
 118 void W_Seeker_Missile_Think(entity this)
 119 {
 120         entity e;
 121         vector desireddir, olddir, newdir, eorg;
 122         float turnrate;
 123         float dist;
 124         float spd;
 125
 126         if(time > this.cnt)
 127         {
 128                 this.projectiledeathtype |= HITTYPE_SPLASH;
 129                 W_Seeker_Missile_Explode(this, NULL);
 130         }
 131
 132         spd = vlen(this.velocity);
 133         spd = bound(
 134                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 135                 WEP_CVAR(seeker, missile_speed_max),
 136                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 137         );
 138
 139         if(this.enemy != NULL)
 140                 if(this.enemy.takedamage != DAMAGE_AIM || IS_DEAD(this.enemy))
 141                         this.enemy = NULL;
 142
 143         if(this.enemy != NULL)
 144         {
 145                 e               = this.enemy;
 146                 eorg            = 0.5 * (e.absmin + e.absmax);
 147                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 148                 desireddir      = normalize(eorg - this.origin);
 149                 olddir          = normalize(this.velocity); // get my current direction
 150                 dist            = vlen(eorg - this.origin);
 151
 152                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 153                 if(WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 154                 {
 155                         // Is it a better idea (shorter distance) to trace to the target itthis?
 156                         if( vdist(this.origin + olddir * this.wait, <, dist))
 157                                 traceline(this.origin, this.origin + olddir * this.wait, false, this);
 158                         else
 159                                 traceline(this.origin, eorg, false, this);
 160
 161                         // Setup adaptive tracelength
 162                         this.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(this.origin - trace_endpos), this.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 163
 164                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 165                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 166                 }
 167
 168                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 169                 this.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 170         }
 171         else
 172                 dist = 0;
 173
 174         // Proxy
 175         if(WEP_CVAR(seeker, missile_proxy))
 176         {
 177                 if(dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 178                 {
 179                         if(this.autoswitch == 0)
 180                         {
 181                                 this.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 182                         }
 183                         else
 184                         {
 185                                 if(this.autoswitch <= time)
 186                                 {
 187                                         W_Seeker_Missile_Explode(this, NULL);
 188                                         this.autoswitch = 0;
 189                                 }
 190                         }
 191                 }
 192                 else
 193                 {
 194                         if(this.autoswitch != 0)
 195                                 this.autoswitch = 0;
 196                 }
 197         }
 198         ///////////////
 199
 200         if(IS_DEAD(this.enemy))
 201         {
 202                 this.enemy = NULL;
 203                 this.cnt = time + 1 + (random() * 4);
 204                 this.nextthink = this.cnt;
 205                 return;
 206         }
 207
 208         //this.angles = vectoangles(this.velocity);                     // turn model in the new flight direction
 209         this.nextthink = time;// + 0.05; // csqc projectiles
 210         UpdateCSQCProjectile(this);
 211 }
 212
 213
 214
 215 void W_Seeker_Missile_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 216 {
 217         if(this.health <= 0)
 218                 return;
 219
 220         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 221                 return; // g_projectiles_damage says to halt
 222
 223         if(this.realowner == attacker)
 224                 this.health = this.health - (damage * 0.25);
 225         else
 226                 this.health = this.health - damage;
 227
 228         if(this.health <= 0)
 229                 W_PrepareExplosionByDamage(this, attacker, W_Seeker_Missile_Explode_think);
 230 }
 231
 232 /*
 233 void W_Seeker_Missile_Animate(entity this)
 234 {
 235         this.frame = this.frame +1;
 236         this.nextthink = time + 0.05;
 237
 238         if(this.enemy != NULL)
 239                 if(this.enemy.takedamage != DAMAGE_AIM || IS_DEAD(this.enemy))
 240                         this.enemy = NULL;
 241
 242         if(this.frame == 5)
 243         {
 244                 this.think           = W_Seeker_Missile_Think;
 245                 this.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 246
 247                 if(autocvar_g_balance_seeker_missile_proxy)
 248                         this.move_movetype    = MOVETYPE_BOUNCEMISSILE;
 249                 else
 250                         this.move_movetype    = MOVETYPE_FLYMISSILE;
 251         }
 252
 253         UpdateCSQCProjectile(this);
 254 }
 255 */
 256
 257 void W_Seeker_Fire_Missile(Weapon thiswep, entity actor, .entity weaponentity, vector f_diff, entity m_target)
 258 {
 259         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, missile_ammo));
 260
 261         makevectors(actor.v_angle);
 262         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_SEEKER_FIRE, CH_WEAPON_A, 0);
 263         w_shotorg += f_diff;
 264         Send_Effect(EFFECT_SEEKER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 265
 266         //actor.detornator         = false;
 267
 268         entity missile                 = new(seeker_missile);
 269         missile.owner           = missile.realowner = actor;
 270         missile.bot_dodge       = true;
 271         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 272
 273         setthink(missile, W_Seeker_Missile_Think);
 274         settouch(missile, W_Seeker_Missile_Touch);
 275         missile.event_damage    = W_Seeker_Missile_Damage;
 276         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 277         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 278         missile.enemy           = m_target;
 279         missile.solid           = SOLID_BBOX;
 280         missile.scale           = 2;
 281         missile.takedamage      = DAMAGE_YES;
 282         missile.health          = WEP_CVAR(seeker, missile_health);
 283         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 284         missile.damagedbycontents = true;
 285         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 286
 287         if(missile.enemy != NULL)
 288                 missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 289         else
 290                 missile.projectiledeathtype = WEP_SEEKER.m_id;
 291
 292
 293         setorigin(missile, w_shotorg);
 294         setsize(missile, '-4 -4 -4', '4 4 4');
 295         set_movetype(missile, MOVETYPE_FLYMISSILE);
 296         missile.flags = FL_PROJECTILE;
 297         IL_PUSH(g_projectiles, missile);
 298         IL_PUSH(g_bot_dodge, missile);
 299         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 300
 301         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 302
 303         missile.angles = vectoangles(missile.velocity);
 304
 305         CSQCProjectile(missile, false, PROJECTILE_SEEKER, true);
 306
 307         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 308 }
 309
 310 // ============================
 311 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 312 // ============================
 313 void W_Seeker_Flac_Explode(entity this, entity directhitentity)
 314 {
 315         this.event_damage = func_null;
 316
 317         RadiusDamage(this, this.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), NULL, NULL, WEP_CVAR(seeker, flac_force), this.projectiledeathtype, directhitentity);
 318
 319         delete(this);
 320 }
 321
 322 void W_Seeker_Flac_Touch(entity this, entity toucher)
 323 {
 324         W_Seeker_Flac_Explode(this, toucher);
 325 }
 326
 327 void W_Seeker_Flac_Explode_use(entity this, entity actor, entity trigger)
 328 {
 329         W_Seeker_Flac_Explode(this, trigger);
 330 }
 331
 332 void W_Seeker_Fire_Flac(Weapon thiswep, entity actor, .entity weaponentity)
 333 {
 334         entity missile;
 335         vector f_diff;
 336         float c;
 337
 338         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, flac_ammo));
 339
 340         c = actor.bulletcounter % 4;
 341         switch(c)
 342         {
 343                 case 0:
 344                         f_diff = '-1.25 -3.75 0';
 345                         break;
 346                 case 1:
 347                         f_diff = '+1.25 -3.75 0';
 348                         break;
 349                 case 2:
 350                         f_diff = '-1.25 +3.75 0';
 351                         break;
 352                 case 3:
 353                 default:
 354                         f_diff = '+1.25 +3.75 0';
 355                         break;
 356         }
 357         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_FLAC_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 358         w_shotorg += f_diff;
 359
 360         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 361
 362         missile                                 = new(missile);
 363         missile.owner                   = missile.realowner = actor;
 364         missile.bot_dodge               = true;
 365         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 366         settouch(missile, W_Seeker_Flac_Touch);
 367         missile.use                     = W_Seeker_Flac_Explode_use;
 368         setthink(missile, adaptor_think2use_hittype_splash);
 369         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 370         missile.solid                   = SOLID_BBOX;
 371         set_movetype(missile, MOVETYPE_FLY);
 372         missile.projectiledeathtype = WEP_SEEKER.m_id;
 373         missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 374         missile.flags = FL_PROJECTILE;
 375         IL_PUSH(g_projectiles, missile);
 376         IL_PUSH(g_bot_dodge, missile);
 377         missile.missile_flags       = MIF_SPLASH;
 378
 379         // csqc projectiles
 380         //missile.angles                                = vectoangles(missile.velocity);
 381         //missile.scale = 0.4; // BUG: the model is too big
 382
 383         setorigin(missile, w_shotorg);
 384         setsize(missile, '-2 -2 -2', '2 2 2');
 385
 386         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 387         CSQCProjectile(missile, true, PROJECTILE_FLAC, true);
 388
 389         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 390 }
 391
 392 // ============================
 393 // Begin: Tag and rocket controllers
 394 // ============================
 395 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
 396 {
 397         entity tag;
 398         for(tag = NULL; (tag = find(tag, classname, "tag_tracker")); )
 399                 if((tag.realowner == isowner) && (tag.tag_target == istarget))
 400                         return tag;
 401
 402         return NULL;
 403 }
 404
 405 void W_Seeker_Attack(entity actor, .entity weaponentity)
 406 {
 407         entity tracker, closest_target;
 408
 409         closest_target = NULL;
 410         for(tracker = NULL; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == actor)
 411         {
 412                 if(closest_target)
 413                 {
 414                         if(vlen2(actor.origin - tracker.tag_target.origin) < vlen2(actor.origin - closest_target.origin))
 415                                 closest_target = tracker.tag_target;
 416                 }
 417                 else
 418                         closest_target = tracker.tag_target;
 419         }
 420
 421         traceline(actor.origin + actor.view_ofs, closest_target.origin, MOVE_NOMONSTERS, actor);
 422         if((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 423                 closest_target = NULL;
 424
 425         W_Seeker_Fire_Missile(WEP_SEEKER, actor, weaponentity, '0 0 0', closest_target);
 426 }
 427
 428 void W_Seeker_Vollycontroller_Think(entity this) // TODO: Merge this with W_Seeker_Attack
 429 {
 430         float c;
 431         entity oldenemy;
 432         this.cnt = this.cnt - 1;
 433
 434         Weapon thiswep = WEP_SEEKER;
 435         if((!(this.realowner.items & IT_UNLIMITED_AMMO) && this.realowner.(thiswep.ammo_field) < WEP_CVAR(seeker, missile_ammo)) || (this.cnt <= -1) || (IS_DEAD(this.realowner)) || (PS(this.realowner).m_switchweapon != WEP_SEEKER))
 436         {
 437                 delete(this);
 438                 return;
 439         }
 440
 441         this.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor(this.realowner);
 442
 443         entity own = this.realowner;
 444
 445         oldenemy = own.enemy;
 446         own.enemy = this.enemy;
 447         .entity weaponentity = this.weaponentity_fld;
 448
 449         c = own.cnt % 4;
 450         switch(c)
 451         {
 452                 case 0:
 453                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '-1.25 -3.75 0', own.enemy); // TODO
 454                         break;
 455                 case 1:
 456                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '+1.25 -3.75 0', own.enemy); // TODO
 457                         break;
 458                 case 2:
 459                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '-1.25 +3.75 0', own.enemy); // TODO
 460                         break;
 461                 case 3:
 462                 default:
 463                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '+1.25 +3.75 0', own.enemy); // TODO
 464                         break;
 465         }
 466
 467         own.enemy = oldenemy;
 468 }
 469
 470 void W_Seeker_Tracker_Think(entity this)
 471 {
 472         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 473         if((IS_DEAD(this.realowner)) || (IS_DEAD(this.tag_target)) || (PS(this.realowner).m_switchweapon != WEP_SEEKER)
 474         || (time > this.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 475         {
 476                 if(this)
 477                 {
 478                         WaypointSprite_Kill(this.tag_target.wps_tag_tracker);
 479                         delete(this);
 480                 }
 481                 return;
 482         }
 483
 484         // Update the think method information
 485         this.nextthink = time;
 486 }
 487
 488 // ============================
 489 // Begin: Tag projectile
 490 // ============================
 491 void W_Seeker_Tag_Explode(entity this)
 492 {
 493         //if(other==this.realowner)
 494         //    return;
 495         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE, 0, this);
 496
 497         delete(this);
 498 }
 499
 500 void W_Seeker_Tag_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 501 {
 502         if(this.health <= 0)
 503                 return;
 504         this.health = this.health - damage;
 505         if(this.health <= 0)
 506                 W_Seeker_Tag_Explode(this);
 507 }
 508
 509 void W_Seeker_Tag_Touch(entity this, entity toucher)
 510 {
 511         vector dir;
 512         vector org2;
 513         entity e;
 514
 515         PROJECTILE_TOUCH(this, toucher);
 516
 517         dir     = normalize(this.realowner.origin - this.origin);
 518         org2    = findbetterlocation(this.origin, 8);
 519
 520         te_knightspike(org2);
 521
 522         this.event_damage = func_null;
 523         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY, toucher.species, this);
 524
 525         if(toucher.takedamage == DAMAGE_AIM && !IS_DEAD(toucher))
 526         {
 527                 // check to see if this person is already tagged by me
 528                 entity tag = W_Seeker_Tagged_Info(this.realowner, toucher);
 529
 530                 if(tag != NULL)
 531                 {
 532                         if(toucher.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 533                                 WaypointSprite_Kill(toucher.wps_tag_tracker);
 534
 535                         tag.tag_time = time;
 536                 }
 537                 else
 538                 {
 539                         //sprint(this.realowner, strcat("You just tagged ^2", toucher.netname, "^7 with a tracking device!\n"));
 540                         e             = new(tag_tracker);
 541                         e.weaponentity_fld = this.weaponentity_fld;
 542                         e.cnt         = WEP_CVAR(seeker, missile_count);
 543                         e.owner       = this.owner;
 544                         e.realowner   = this.realowner;
 545
 546                         if(WEP_CVAR(seeker, type) == 1)
 547                         {
 548                                 e.tag_target  = toucher;
 549                                 e.tag_time    = time;
 550                                 setthink(e, W_Seeker_Tracker_Think);
 551                         }
 552                         else
 553                         {
 554                                 e.enemy     = toucher;
 555                                 setthink(e, W_Seeker_Vollycontroller_Think);
 556                         }
 557
 558                         e.nextthink   = time;
 559                 }
 560
 561                 if(WEP_CVAR(seeker, type) == 1)
 562                 {
 563                         WaypointSprite_Spawn(WP_Seeker, WEP_CVAR(seeker, tag_tracker_lifetime), 0, toucher, '0 0 64', this.realowner, 0, toucher, wps_tag_tracker, true, RADARICON_TAGGED);
 564                         WaypointSprite_UpdateRule(toucher.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 565                 }
 566         }
 567
 568         delete(this);
 569         return;
 570 }
 571
 572 void W_Seeker_Fire_Tag(Weapon thiswep, entity actor, .entity weaponentity)
 573 {
 574         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, tag_ammo));
 575
 576         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_TAG_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 577
 578         entity missile          = new(seeker_tag);
 579         missile.weaponentity_fld = weaponentity;
 580         missile.owner           = missile.realowner = actor;
 581         missile.bot_dodge       = true;
 582         missile.bot_dodgerating = 50;
 583         settouch(missile, W_Seeker_Tag_Touch);
 584         setthink(missile, SUB_Remove);
 585         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 586         set_movetype(missile, MOVETYPE_FLY);
 587         missile.solid           = SOLID_BBOX;
 588
 589         missile.takedamage       = DAMAGE_YES;
 590         missile.event_damage     = W_Seeker_Tag_Damage;
 591         missile.health           = WEP_CVAR(seeker, tag_health);
 592         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 593
 594         setorigin(missile, w_shotorg);
 595         setsize(missile, '-2 -2 -2', '2 2 2');
 596
 597         missile.flags = FL_PROJECTILE;
 598         IL_PUSH(g_projectiles, missile);
 599         IL_PUSH(g_bot_dodge, missile);
 600         //missile.missile_flags = MIF_..?;
 601
 602         set_movetype(missile, MOVETYPE_FLY);
 603         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 604         missile.angles = vectoangles(missile.velocity);
 605
 606         CSQCProjectile(missile, true, PROJECTILE_TAG, false); // has sound
 607
 608         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 609 }
 610
 611 // ============================
 612 // Begin: Genereal weapon functions
 613 // ============================
 614
 615 METHOD(Seeker, wr_aim, void(entity thiswep, entity actor))
 616 {
 617     if(WEP_CVAR(seeker, type) == 1)
 618         if(W_Seeker_Tagged_Info(actor, actor.enemy) != NULL)
 619             PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), false);
 620         else
 621             PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 622     else
 623         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 624 }
 625 METHOD(Seeker, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 626 {
 627     if(autocvar_g_balance_seeker_reload_ammo && actor.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) { // forced reload
 628         thiswep.wr_reload(thiswep, actor, weaponentity);
 629     } else if(fire & 1)
 630     {
 631         if(WEP_CVAR(seeker, type) == 1)
 632         {
 633             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, missile_refire)))
 634             {
 635                 W_Seeker_Attack(actor, weaponentity);
 636                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 637             }
 638         }
 639         else
 640         {
 641             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 642             {
 643                 W_Seeker_Fire_Tag(thiswep, actor, weaponentity);
 644                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 645             }
 646         }
 647     }
 648
 649     else if(fire & 2)
 650     {
 651         if(WEP_CVAR(seeker, type) == 1)
 652         {
 653             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 654             {
 655                 W_Seeker_Fire_Tag(thiswep, actor, weaponentity);
 656                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 657             }
 658         }
 659         else
 660         {
 661             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, flac_refire)))
 662             {
 663                 W_Seeker_Fire_Flac(thiswep, actor, weaponentity);
 664                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 665             }
 666         }
 667     }
 668 }
 669 METHOD(Seeker, wr_checkammo1, bool(entity thiswep, entity actor))
 670 {
 671     float ammo_amount;
 672     if(WEP_CVAR(seeker, type) == 1)
 673     {
 674         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, missile_ammo);
 675         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, missile_ammo);
 676     }
 677     else
 678     {
 679         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, tag_ammo);
 680         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 681     }
 682     return ammo_amount;
 683 }
 684 METHOD(Seeker, wr_checkammo2, bool(entity thiswep, entity actor))
 685 {
 686     float ammo_amount;
 687     if(WEP_CVAR(seeker, type) == 1)
 688     {
 689         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, tag_ammo);
 690         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 691     }
 692     else
 693     {
 694         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, flac_ammo);
 695         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, flac_ammo);
 696     }
 697     return ammo_amount;
 698 }
 699 METHOD(Seeker, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 700 {
 701     W_Reload(actor, weaponentity, min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), SND_RELOAD);
 702 }
 703 METHOD(Seeker, wr_suicidemessage, Notification(entity thiswep))
 704 {
 705     return WEAPON_SEEKER_SUICIDE;
 706 }
 707 METHOD(Seeker, wr_killmessage, Notification(entity thiswep))
 708 {
 709     if(w_deathtype & HITTYPE_SECONDARY)
 710         return WEAPON_SEEKER_MURDER_TAG;
 711     else
 712         return WEAPON_SEEKER_MURDER_SPRAY;
 713 }
 714
 715 #endif
 716 #ifdef CSQC
 717
 718 METHOD(Seeker, wr_impacteffect, void(entity thiswep, entity actor))
 719 {
 720     vector org2;
 721     org2 = w_org + w_backoff * 6;
 722     if(w_deathtype & HITTYPE_BOUNCE)
 723     {
 724         if(w_deathtype & HITTYPE_SECONDARY)
 725         {
 726             if(!w_issilent)
 727                 sound(actor, CH_SHOTS, SND_TAG_IMPACT, 1, ATTEN_NORM);
 728         }
 729         else
 730         {
 731             pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 732             if(!w_issilent)
 733             {
 734                 if(w_random<0.15)
 735                     sound(actor, CH_SHOTS, SND_TAGEXP1, 1, ATTEN_NORM);
 736                 else if(w_random<0.7)
 737                     sound(actor, CH_SHOTS, SND_TAGEXP2, 1, ATTEN_NORM);
 738                 else
 739                     sound(actor, CH_SHOTS, SND_TAGEXP3, 1, ATTEN_NORM);
 740             }
 741         }
 742     }
 743     else
 744     {
 745         pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 746         if(!w_issilent)
 747         {
 748             if(w_random<0.15)
 749                 sound(actor, CH_SHOTS, SND_SEEKEREXP1, 1, ATTEN_NORM);
 750             else if(w_random<0.7)
 751                 sound(actor, CH_SHOTS, SND_SEEKEREXP2, 1, ATTEN_NORM);
 752             else
 753                 sound(actor, CH_SHOTS, SND_SEEKEREXP3, 1, ATTEN_NORM);
 754         }
 755     }
 756 }
 757
 758 #endif
 759 #endif