2e98fdbe3c8d0f8337e60a003d9e741e464b6454
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / seeker.qc
1 #ifndef IMPLEMENTATION
2 CLASS(Seeker, Weapon)
3 /* ammotype  */ ATTRIB(Seeker, ammo_field, .int, ammo_rockets)
4 /* impulse   */ ATTRIB(Seeker, impulse, int, 8)
5 /* flags     */ ATTRIB(Seeker, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH);
6 /* rating    */ ATTRIB(Seeker, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
7 /* color     */ ATTRIB(Seeker, wpcolor, vector, '0.5 1 0');
8 /* modelname */ ATTRIB(Seeker, mdl, string, "seeker");
9 #ifndef MENUQC
10 /* model     */ ATTRIB(Seeker, m_model, Model, MDL_SEEKER_ITEM);
11 #endif
12 /* crosshair */ ATTRIB(Seeker, w_crosshair, string, "gfx/crosshairseeker");
13 /* crosshair */ ATTRIB(Seeker, w_crosshair_size, float, 0.8);
14 /* wepimg    */ ATTRIB(Seeker, model2, string, "weaponseeker");
15 /* refname   */ ATTRIB(Seeker, netname, string, "seeker");
16 /* wepname   */ ATTRIB(Seeker, m_name, string, _("T.A.G. Seeker"));
17
18 #define X(BEGIN, P, END, class, prefix) \
19         BEGIN(class) \
20         P(class, prefix, flac_ammo, float, NONE) \
21         P(class, prefix, flac_animtime, float, NONE) \
22         P(class, prefix, flac_damage, float, NONE) \
23         P(class, prefix, flac_edgedamage, float, NONE) \
24         P(class, prefix, flac_force, float, NONE) \
25         P(class, prefix, flac_lifetime, float, NONE) \
26         P(class, prefix, flac_lifetime_rand, float, NONE) \
27         P(class, prefix, flac_radius, float, NONE) \
28         P(class, prefix, flac_refire, float, NONE) \
29         P(class, prefix, flac_speed, float, NONE) \
30         P(class, prefix, flac_speed_up, float, NONE) \
31         P(class, prefix, flac_speed_z, float, NONE) \
32         P(class, prefix, flac_spread, float, NONE) \
33         P(class, prefix, missile_accel, float, NONE) \
34         P(class, prefix, missile_ammo, float, NONE) \
35         P(class, prefix, missile_animtime, float, NONE) \
36         P(class, prefix, missile_count, float, NONE) \
37         P(class, prefix, missile_damageforcescale, float, NONE) \
38         P(class, prefix, missile_damage, float, NONE) \
39         P(class, prefix, missile_decel, float, NONE) \
40         P(class, prefix, missile_delay, float, NONE) \
41         P(class, prefix, missile_edgedamage, float, NONE) \
42         P(class, prefix, missile_force, float, NONE) \
43         P(class, prefix, missile_health, float, NONE) \
44         P(class, prefix, missile_lifetime, float, NONE) \
45         P(class, prefix, missile_proxy, float, NONE) \
46         P(class, prefix, missile_proxy_delay, float, NONE) \
47         P(class, prefix, missile_proxy_maxrange, float, NONE) \
48         P(class, prefix, missile_radius, float, NONE) \
49         P(class, prefix, missile_refire, float, NONE) \
50         P(class, prefix, missile_smart, float, NONE) \
51         P(class, prefix, missile_smart_mindist, float, NONE) \
52         P(class, prefix, missile_smart_trace_max, float, NONE) \
53         P(class, prefix, missile_smart_trace_min, float, NONE) \
54         P(class, prefix, missile_speed, float, NONE) \
55         P(class, prefix, missile_speed_max, float, NONE) \
56         P(class, prefix, missile_speed_up, float, NONE) \
57         P(class, prefix, missile_speed_z, float, NONE) \
58         P(class, prefix, missile_spread, float, NONE) \
59         P(class, prefix, missile_turnrate, float, NONE) \
60         P(class, prefix, reload_ammo, float, NONE) \
61                 P(class, prefix, reload_time, float, NONE) \
62                 P(class, prefix, switchdelay_drop, float, NONE) \
63                 P(class, prefix, switchdelay_raise, float, NONE) \
64         P(class, prefix, tag_ammo, float, NONE) \
65         P(class, prefix, tag_animtime, float, NONE) \
66         P(class, prefix, tag_damageforcescale, float, NONE) \
67         P(class, prefix, tag_health, float, NONE) \
68         P(class, prefix, tag_lifetime, float, NONE) \
69         P(class, prefix, tag_refire, float, NONE) \
70         P(class, prefix, tag_speed, float, NONE) \
71         P(class, prefix, tag_spread, float, NONE) \
72         P(class, prefix, tag_tracker_lifetime, float, NONE) \
73                 P(class, prefix, type, float, NONE) \
74                 P(class, prefix, weaponreplace, string, NONE) \
75                 P(class, prefix, weaponstartoverride, float, NONE) \
76                 P(class, prefix, weaponstart, float, NONE) \
77                 P(class, prefix, weaponthrowable, float, NONE) \
78         END()
79         W_PROPS(X, Seeker, seeker)
80 #undef X
81 ENDCLASS(Seeker)
82 REGISTER_WEAPON(SEEKER, seeker, NEW(Seeker));
83
84
85 #ifdef SVQC
86 .entity tag_target, wps_tag_tracker;
87 .float tag_time;
88 #endif
89 #endif
90 #ifdef IMPLEMENTATION
91 #ifdef SVQC
92 spawnfunc(weapon_seeker) { weapon_defaultspawnfunc(this, WEP_SEEKER); }
93
94 // ============================
95 // Begin: Missile functions, these are general functions to be manipulated by other code
96 // ============================
97 void W_Seeker_Missile_Explode()
98 {SELFPARAM();
99         self.event_damage = func_null;
100         RadiusDamage(self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
101
102         remove(self);
103 }
104
105 void W_Seeker_Missile_Touch()
106 {
107         PROJECTILE_TOUCH;
108
109         W_Seeker_Missile_Explode();
110 }
111
112 void W_Seeker_Missile_Think()
113 {SELFPARAM();
114         entity e;
115         vector desireddir, olddir, newdir, eorg;
116         float turnrate;
117         float dist;
118         float spd;
119
120         if(time > self.cnt)
121         {
122                 self.projectiledeathtype |= HITTYPE_SPLASH;
123                 W_Seeker_Missile_Explode();
124         }
125
126         spd = vlen(self.velocity);
127         spd = bound(
128                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
129                 WEP_CVAR(seeker, missile_speed_max),
130                 spd + WEP_CVAR(seeker, missile_accel) * frametime
131         );
132
133         if(self.enemy != world)
134                 if(self.enemy.takedamage != DAMAGE_AIM || IS_DEAD(self.enemy))
135                         self.enemy = world;
136
137         if(self.enemy != world)
138         {
139                 e               = self.enemy;
140                 eorg            = 0.5 * (e.absmin + e.absmax);
141                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
142                 desireddir      = normalize(eorg - self.origin);
143                 olddir          = normalize(self.velocity); // get my current direction
144                 dist            = vlen(eorg - self.origin);
145
146                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
147                 if(WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
148                 {
149                         // Is it a better idea (shorter distance) to trace to the target itself?
150                         if( vdist(self.origin + olddir * self.wait, <, dist))
151                                 traceline(self.origin, self.origin + olddir * self.wait, false, self);
152                         else
153                                 traceline(self.origin, eorg, false, self);
154
155                         // Setup adaptive tracelength
156                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
157
158                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
159                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
160                 }
161
162                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
163                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
164         }
165         else
166                 dist = 0;
167
168         // Proxy
169         if(WEP_CVAR(seeker, missile_proxy))
170         {
171                 if(dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
172                 {
173                         if(self.autoswitch == 0)
174                         {
175                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
176                         }
177                         else
178                         {
179                                 if(self.autoswitch <= time)
180                                 {
181                                         W_Seeker_Missile_Explode();
182                                         self.autoswitch = 0;
183                                 }
184                         }
185                 }
186                 else
187                 {
188                         if(self.autoswitch != 0)
189                                 self.autoswitch = 0;
190                 }
191         }
192         ///////////////
193
194         if(IS_DEAD(self.enemy))
195         {
196                 self.enemy = world;
197                 self.cnt = time + 1 + (random() * 4);
198                 self.nextthink = self.cnt;
199                 return;
200         }
201
202         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
203         self.nextthink = time;// + 0.05; // csqc projectiles
204         UpdateCSQCProjectile(self);
205 }
206
207
208
209 void W_Seeker_Missile_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
210 {
211         if(this.health <= 0)
212                 return;
213
214         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
215                 return; // g_projectiles_damage says to halt
216
217         if(this.realowner == attacker)
218                 this.health = this.health - (damage * 0.25);
219         else
220                 this.health = this.health - damage;
221
222         if(this.health <= 0)
223                 W_PrepareExplosionByDamage(this, attacker, W_Seeker_Missile_Explode);
224 }
225
226 /*
227 void W_Seeker_Missile_Animate()
228 {
229         self.frame = self.frame +1;
230         self.nextthink = time + 0.05;
231
232         if(self.enemy != world)
233                 if(self.enemy.takedamage != DAMAGE_AIM || IS_DEAD(self.enemy))
234                         self.enemy = world;
235
236         if(self.frame == 5)
237         {
238                 self.think           = W_Seeker_Missile_Think;
239                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
240
241                 if(autocvar_g_balance_seeker_missile_proxy)
242                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
243                 else
244                         self.movetype    = MOVETYPE_FLYMISSILE;
245         }
246
247         UpdateCSQCProjectile(self);
248 }
249 */
250
251 void W_Seeker_Fire_Missile(Weapon thiswep, vector f_diff, entity m_target)
252 {SELFPARAM();
253         entity missile;
254
255         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, missile_ammo));
256
257         makevectors(self.v_angle);
258         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND_SEEKER_FIRE, CH_WEAPON_A, 0);
259         w_shotorg += f_diff;
260         Send_Effect(EFFECT_SEEKER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
261
262         //self.detornator         = false;
263
264         missile                 = new(seeker_missile);
265         missile.owner           = missile.realowner = self;
266         missile.bot_dodge       = true;
267         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
268
269         setthink(missile, W_Seeker_Missile_Think);
270         settouch(missile, W_Seeker_Missile_Touch);
271         missile.event_damage    = W_Seeker_Missile_Damage;
272         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
273         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
274         missile.enemy           = m_target;
275         missile.solid           = SOLID_BBOX;
276         missile.scale           = 2;
277         missile.takedamage      = DAMAGE_YES;
278         missile.health          = WEP_CVAR(seeker, missile_health);
279         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
280         missile.damagedbycontents = true;
281         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
282
283         if(missile.enemy != world)
284                 missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
285         else
286                 missile.projectiledeathtype = WEP_SEEKER.m_id;
287
288
289         setorigin(missile, w_shotorg);
290         setsize(missile, '-4 -4 -4', '4 4 4');
291         missile.movetype    = MOVETYPE_FLYMISSILE;
292         missile.flags       = FL_PROJECTILE;
293         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
294
295         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
296
297         missile.angles = vectoangles(missile.velocity);
298
299         CSQCProjectile(missile, false, PROJECTILE_SEEKER, true);
300
301         MUTATOR_CALLHOOK(EditProjectile, self, missile);
302 }
303
304 // ============================
305 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
306 // ============================
307 void W_Seeker_Flac_Explode()
308 {SELFPARAM();
309         self.event_damage = func_null;
310
311         RadiusDamage(self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
312
313         remove(self);
314 }
315
316 void W_Seeker_Flac_Explode_use(entity this, entity actor, entity trigger)
317 {
318         WITHSELF(this, W_Seeker_Flac_Explode());
319 }
320
321 void W_Seeker_Flac_Touch()
322 {
323         PROJECTILE_TOUCH;
324
325         W_Seeker_Flac_Explode();
326 }
327
328 void W_Seeker_Fire_Flac(Weapon thiswep)
329 {SELFPARAM();
330         entity missile;
331         vector f_diff;
332         float c;
333
334         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, flac_ammo));
335
336         c = self.bulletcounter % 4;
337         switch(c)
338         {
339                 case 0:
340                         f_diff = '-1.25 -3.75 0';
341                         break;
342                 case 1:
343                         f_diff = '+1.25 -3.75 0';
344                         break;
345                 case 2:
346                         f_diff = '-1.25 +3.75 0';
347                         break;
348                 case 3:
349                 default:
350                         f_diff = '+1.25 +3.75 0';
351                         break;
352         }
353         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND_FLAC_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
354         w_shotorg += f_diff;
355
356         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
357
358         missile                                 = new(missile);
359         missile.owner                   = missile.realowner = self;
360         missile.bot_dodge               = true;
361         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
362         settouch(missile, W_Seeker_Flac_Explode);
363         missile.use                     = W_Seeker_Flac_Explode_use;
364         setthink(missile, adaptor_think2use_hittype_splash);
365         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
366         missile.solid                   = SOLID_BBOX;
367         missile.movetype                = MOVETYPE_FLY;
368         missile.projectiledeathtype = WEP_SEEKER.m_id;
369         missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
370         missile.flags                           = FL_PROJECTILE;
371         missile.missile_flags       = MIF_SPLASH;
372
373         // csqc projectiles
374         //missile.angles                                = vectoangles(missile.velocity);
375         //missile.scale = 0.4; // BUG: the model is too big
376
377         setorigin(missile, w_shotorg);
378         setsize(missile, '-2 -2 -2', '2 2 2');
379
380         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
381         CSQCProjectile(missile, true, PROJECTILE_FLAC, true);
382
383         MUTATOR_CALLHOOK(EditProjectile, self, missile);
384 }
385
386 // ============================
387 // Begin: Tag and rocket controllers
388 // ============================
389 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
390 {
391         entity tag;
392         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
393                 if((tag.realowner == isowner) && (tag.tag_target == istarget))
394                         return tag;
395
396         return world;
397 }
398
399 void W_Seeker_Attack()
400 {SELFPARAM();
401         entity tracker, closest_target;
402
403         closest_target = world;
404         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
405         {
406                 if(closest_target)
407                 {
408                         if(vlen2(self.origin - tracker.tag_target.origin) < vlen2(self.origin - closest_target.origin))
409                                 closest_target = tracker.tag_target;
410                 }
411                 else
412                         closest_target = tracker.tag_target;
413         }
414
415         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
416         if((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
417                 closest_target = world;
418
419         W_Seeker_Fire_Missile(WEP_SEEKER, '0 0 0', closest_target);
420 }
421
422 void W_Seeker_Vollycontroller_Think() // TODO: Merge this with W_Seeker_Attack
423 {SELFPARAM();
424         float c;
425         entity oldenemy;
426         this.cnt = this.cnt - 1;
427
428         Weapon thiswep = WEP_SEEKER;
429         if((!(this.realowner.items & IT_UNLIMITED_AMMO) && this.realowner.(thiswep.ammo_field) < WEP_CVAR(seeker, missile_ammo)) || (this.cnt <= -1) || (IS_DEAD(this.realowner)) || (PS(this.realowner).m_switchweapon != WEP_SEEKER))
430         {
431                 remove(this);
432                 return;
433         }
434
435         this.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
436
437         entity own = this.realowner;
438
439         oldenemy = own.enemy;
440         own.enemy = this.enemy;
441
442         c = own.cnt % 4;
443         switch(c)
444         {
445                 case 0:
446                         WITHSELF(own, W_Seeker_Fire_Missile(WEP_SEEKER, '-1.25 -3.75 0', own.enemy));
447                         break;
448                 case 1:
449                         WITHSELF(own, W_Seeker_Fire_Missile(WEP_SEEKER, '+1.25 -3.75 0', own.enemy));
450                         break;
451                 case 2:
452                         WITHSELF(own, W_Seeker_Fire_Missile(WEP_SEEKER, '-1.25 +3.75 0', own.enemy));
453                         break;
454                 case 3:
455                 default:
456                         WITHSELF(own, W_Seeker_Fire_Missile(WEP_SEEKER, '+1.25 +3.75 0', own.enemy));
457                         break;
458         }
459
460         own.enemy = oldenemy;
461 }
462
463 void W_Seeker_Tracker_Think()
464 {SELFPARAM();
465         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
466         if((IS_DEAD(self.realowner)) || (IS_DEAD(self.tag_target)) || (PS(self.realowner).m_switchweapon != WEP_SEEKER)
467         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
468         {
469                 if(self)
470                 {
471                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
472                         remove(self);
473                 }
474                 return;
475         }
476
477         // Update the think method information
478         self.nextthink = time;
479 }
480
481 // ============================
482 // Begin: Tag projectile
483 // ============================
484 void W_Seeker_Tag_Explode(entity this)
485 {
486         //if(other==this.realowner)
487         //    return;
488         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE, other.species, this);
489
490         remove(this);
491 }
492
493 void W_Seeker_Tag_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
494 {
495         if(this.health <= 0)
496                 return;
497         this.health = this.health - damage;
498         if(this.health <= 0)
499                 W_Seeker_Tag_Explode(this);
500 }
501
502 void W_Seeker_Tag_Touch()
503 {SELFPARAM();
504         vector dir;
505         vector org2;
506         entity e;
507
508         PROJECTILE_TOUCH;
509
510         dir     = normalize(self.realowner.origin - self.origin);
511         org2    = findbetterlocation(self.origin, 8);
512
513         te_knightspike(org2);
514
515         self.event_damage = func_null;
516         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
517
518         if(other.takedamage == DAMAGE_AIM && !IS_DEAD(other))
519         {
520                 // check to see if this person is already tagged by me
521                 entity tag = W_Seeker_Tagged_Info(self.realowner, other);
522
523                 if(tag != world)
524                 {
525                         if(other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
526                                 WaypointSprite_Kill(other.wps_tag_tracker);
527
528                         tag.tag_time = time;
529                 }
530                 else
531                 {
532                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
533                         e             = new(tag_tracker);
534                         e.cnt         = WEP_CVAR(seeker, missile_count);
535                         e.owner       = self.owner;
536                         e.realowner   = self.realowner;
537
538                         if(WEP_CVAR(seeker, type) == 1)
539                         {
540                                 e.tag_target  = other;
541                                 e.tag_time    = time;
542                                 setthink(e, W_Seeker_Tracker_Think);
543                         }
544                         else
545                         {
546                                 e.enemy     = other;
547                                 setthink(e, W_Seeker_Vollycontroller_Think);
548                         }
549
550                         e.nextthink   = time;
551                 }
552
553                 if(WEP_CVAR(seeker, type) == 1)
554                 {
555                         WaypointSprite_Spawn(WP_Seeker, WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, true, RADARICON_TAGGED);
556                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
557                 }
558         }
559
560         remove(self);
561         return;
562 }
563
564 void W_Seeker_Fire_Tag(Weapon thiswep)
565 {SELFPARAM();
566         entity missile;
567         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, tag_ammo));
568
569         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND_TAG_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
570
571         missile                 = new(seeker_tag);
572         missile.owner           = missile.realowner = self;
573         missile.bot_dodge       = true;
574         missile.bot_dodgerating = 50;
575         settouch(missile, W_Seeker_Tag_Touch);
576         setthink(missile, SUB_Remove_self);
577         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
578         missile.movetype        = MOVETYPE_FLY;
579         missile.solid           = SOLID_BBOX;
580
581         missile.takedamage       = DAMAGE_YES;
582         missile.event_damage     = W_Seeker_Tag_Damage;
583         missile.health           = WEP_CVAR(seeker, tag_health);
584         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
585
586         setorigin(missile, w_shotorg);
587         setsize(missile, '-2 -2 -2', '2 2 2');
588
589         missile.flags       = FL_PROJECTILE;
590         //missile.missile_flags = MIF_..?;
591
592         missile.movetype    = MOVETYPE_FLY;
593         W_SetupProjVelocity_PRE(missile, seeker, tag_);
594         missile.angles = vectoangles(missile.velocity);
595
596         CSQCProjectile(missile, true, PROJECTILE_TAG, false); // has sound
597
598         MUTATOR_CALLHOOK(EditProjectile, self, missile);
599 }
600
601 // ============================
602 // Begin: Genereal weapon functions
603 // ============================
604
605 METHOD(Seeker, wr_aim, void(entity thiswep))
606 {
607     SELFPARAM();
608     if(WEP_CVAR(seeker, type) == 1)
609         if(W_Seeker_Tagged_Info(self, self.enemy) != world)
610             PHYS_INPUT_BUTTON_ATCK(self) = bot_aim(self, WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), false);
611         else
612             PHYS_INPUT_BUTTON_ATCK2(self) = bot_aim(self, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
613     else
614         PHYS_INPUT_BUTTON_ATCK(self) = bot_aim(self, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
615 }
616 METHOD(Seeker, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
617 {
618     if(autocvar_g_balance_seeker_reload_ammo && actor.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) { // forced reload
619         thiswep.wr_reload(thiswep, actor, weaponentity);
620     } else if(fire & 1)
621     {
622         if(WEP_CVAR(seeker, type) == 1)
623         {
624             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, missile_refire)))
625             {
626                 W_Seeker_Attack();
627                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
628             }
629         }
630         else
631         {
632             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
633             {
634                 W_Seeker_Fire_Tag(thiswep);
635                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
636             }
637         }
638     }
639
640     else if(fire & 2)
641     {
642         if(WEP_CVAR(seeker, type) == 1)
643         {
644             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
645             {
646                 W_Seeker_Fire_Tag(thiswep);
647                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
648             }
649         }
650         else
651         {
652             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, flac_refire)))
653             {
654                 W_Seeker_Fire_Flac(thiswep);
655                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
656             }
657         }
658     }
659 }
660 METHOD(Seeker, wr_checkammo1, bool(entity thiswep, entity actor))
661 {
662     float ammo_amount;
663     if(WEP_CVAR(seeker, type) == 1)
664     {
665         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, missile_ammo);
666         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, missile_ammo);
667     }
668     else
669     {
670         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, tag_ammo);
671         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
672     }
673     return ammo_amount;
674 }
675 METHOD(Seeker, wr_checkammo2, bool(entity thiswep, entity actor))
676 {
677     float ammo_amount;
678     if(WEP_CVAR(seeker, type) == 1)
679     {
680         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, tag_ammo);
681         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
682     }
683     else
684     {
685         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, flac_ammo);
686         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, flac_ammo);
687     }
688     return ammo_amount;
689 }
690 METHOD(Seeker, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
691 {
692     SELFPARAM();
693     W_Reload(self, min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), SND_RELOAD);
694 }
695 METHOD(Seeker, wr_suicidemessage, Notification(entity thiswep))
696 {
697     return WEAPON_SEEKER_SUICIDE;
698 }
699 METHOD(Seeker, wr_killmessage, Notification(entity thiswep))
700 {
701     if(w_deathtype & HITTYPE_SECONDARY)
702         return WEAPON_SEEKER_MURDER_TAG;
703     else
704         return WEAPON_SEEKER_MURDER_SPRAY;
705 }
706
707 #endif
708 #ifdef CSQC
709
710 METHOD(Seeker, wr_impacteffect, void(entity thiswep))
711 {
712     SELFPARAM();
713     vector org2;
714     org2 = w_org + w_backoff * 6;
715     if(w_deathtype & HITTYPE_BOUNCE)
716     {
717         if(w_deathtype & HITTYPE_SECONDARY)
718         {
719             if(!w_issilent)
720                 sound(self, CH_SHOTS, SND_TAG_IMPACT, 1, ATTEN_NORM);
721         }
722         else
723         {
724             pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
725             if(!w_issilent)
726             {
727                 if(w_random<0.15)
728                     sound(self, CH_SHOTS, SND_TAGEXP1, 1, ATTEN_NORM);
729                 else if(w_random<0.7)
730                     sound(self, CH_SHOTS, SND_TAGEXP2, 1, ATTEN_NORM);
731                 else
732                     sound(self, CH_SHOTS, SND_TAGEXP3, 1, ATTEN_NORM);
733             }
734         }
735     }
736     else
737     {
738         pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
739         if(!w_issilent)
740         {
741             if(w_random<0.15)
742                 sound(self, CH_SHOTS, SND_SEEKEREXP1, 1, ATTEN_NORM);
743             else if(w_random<0.7)
744                 sound(self, CH_SHOTS, SND_SEEKEREXP2, 1, ATTEN_NORM);
745             else
746                 sound(self, CH_SHOTS, SND_SEEKEREXP3, 1, ATTEN_NORM);
747         }
748     }
749 }
750
751 #endif
752 #endif