qcsrc/common/weapons/weapon/seeker.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Seeker, Weapon)
   3 /* ammotype  */ ATTRIB(Seeker, ammo_field, .int, ammo_rockets)
   4 /* impulse   */ ATTRIB(Seeker, impulse, int, 8)
   5 /* flags     */ ATTRIB(Seeker, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Seeker, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Seeker, wpcolor, vector, '0.5 1 0');
   8 /* modelname */ ATTRIB(Seeker, mdl, string, "seeker");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Seeker, m_model, Model, MDL_SEEKER_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Seeker, w_crosshair, string, "gfx/crosshairseeker");
  13 /* crosshair */ ATTRIB(Seeker, w_crosshair_size, float, 0.8);
  14 /* wepimg    */ ATTRIB(Seeker, model2, string, "weaponseeker");
  15 /* refname   */ ATTRIB(Seeker, netname, string, "seeker");
  16 /* wepname   */ ATTRIB(Seeker, m_name, string, _("T.A.G. Seeker"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20         P(class, prefix, flac_ammo, float, NONE) \
  21         P(class, prefix, flac_animtime, float, NONE) \
  22         P(class, prefix, flac_damage, float, NONE) \
  23         P(class, prefix, flac_edgedamage, float, NONE) \
  24         P(class, prefix, flac_force, float, NONE) \
  25         P(class, prefix, flac_lifetime, float, NONE) \
  26         P(class, prefix, flac_lifetime_rand, float, NONE) \
  27         P(class, prefix, flac_radius, float, NONE) \
  28         P(class, prefix, flac_refire, float, NONE) \
  29         P(class, prefix, flac_speed, float, NONE) \
  30         P(class, prefix, flac_speed_up, float, NONE) \
  31         P(class, prefix, flac_speed_z, float, NONE) \
  32         P(class, prefix, flac_spread, float, NONE) \
  33         P(class, prefix, missile_accel, float, NONE) \
  34         P(class, prefix, missile_ammo, float, NONE) \
  35         P(class, prefix, missile_animtime, float, NONE) \
  36         P(class, prefix, missile_count, float, NONE) \
  37         P(class, prefix, missile_damageforcescale, float, NONE) \
  38         P(class, prefix, missile_damage, float, NONE) \
  39         P(class, prefix, missile_decel, float, NONE) \
  40         P(class, prefix, missile_delay, float, NONE) \
  41         P(class, prefix, missile_edgedamage, float, NONE) \
  42         P(class, prefix, missile_force, float, NONE) \
  43         P(class, prefix, missile_health, float, NONE) \
  44         P(class, prefix, missile_lifetime, float, NONE) \
  45         P(class, prefix, missile_proxy, float, NONE) \
  46         P(class, prefix, missile_proxy_delay, float, NONE) \
  47         P(class, prefix, missile_proxy_maxrange, float, NONE) \
  48         P(class, prefix, missile_radius, float, NONE) \
  49         P(class, prefix, missile_refire, float, NONE) \
  50         P(class, prefix, missile_smart, float, NONE) \
  51         P(class, prefix, missile_smart_mindist, float, NONE) \
  52         P(class, prefix, missile_smart_trace_max, float, NONE) \
  53         P(class, prefix, missile_smart_trace_min, float, NONE) \
  54         P(class, prefix, missile_speed, float, NONE) \
  55         P(class, prefix, missile_speed_max, float, NONE) \
  56         P(class, prefix, missile_speed_up, float, NONE) \
  57         P(class, prefix, missile_speed_z, float, NONE) \
  58         P(class, prefix, missile_spread, float, NONE) \
  59         P(class, prefix, missile_turnrate, float, NONE) \
  60         P(class, prefix, reload_ammo, float, NONE) \
  61                 P(class, prefix, reload_time, float, NONE) \
  62                 P(class, prefix, switchdelay_drop, float, NONE) \
  63                 P(class, prefix, switchdelay_raise, float, NONE) \
  64         P(class, prefix, tag_ammo, float, NONE) \
  65         P(class, prefix, tag_animtime, float, NONE) \
  66         P(class, prefix, tag_damageforcescale, float, NONE) \
  67         P(class, prefix, tag_health, float, NONE) \
  68         P(class, prefix, tag_lifetime, float, NONE) \
  69         P(class, prefix, tag_refire, float, NONE) \
  70         P(class, prefix, tag_speed, float, NONE) \
  71         P(class, prefix, tag_spread, float, NONE) \
  72         P(class, prefix, tag_tracker_lifetime, float, NONE) \
  73                 P(class, prefix, type, float, NONE) \
  74                 P(class, prefix, weaponreplace, string, NONE) \
  75                 P(class, prefix, weaponstartoverride, float, NONE) \
  76                 P(class, prefix, weaponstart, float, NONE) \
  77                 P(class, prefix, weaponthrowable, float, NONE) \
  78         END()
  79         W_PROPS(X, Seeker, seeker)
  80 #undef X
  81 ENDCLASS(Seeker)
  82 REGISTER_WEAPON(SEEKER, seeker, NEW(Seeker));
  83
  84
  85 #ifdef SVQC
  86 .entity tag_target, wps_tag_tracker;
  87 .float tag_time;
  88 #endif
  89 #endif
  90 #ifdef IMPLEMENTATION
  91 #ifdef SVQC
  92 spawnfunc(weapon_seeker) { weapon_defaultspawnfunc(this, WEP_SEEKER); }
  93
  94 // ============================
  95 // Begin: Missile functions, these are general functions to be manipulated by other code
  96 // ============================
  97 void W_Seeker_Missile_Explode(entity this)
  98 {
  99         self.event_damage = func_null;
 100         RadiusDamage(self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
 101
 102         remove(self);
 103 }
 104
 105 void W_Seeker_Missile_Touch(entity this)
 106 {
 107         PROJECTILE_TOUCH;
 108
 109         W_Seeker_Missile_Explode(this);
 110 }
 111
 112 void W_Seeker_Missile_Think(entity this)
 113 {
 114         entity e;
 115         vector desireddir, olddir, newdir, eorg;
 116         float turnrate;
 117         float dist;
 118         float spd;
 119
 120         if(time > self.cnt)
 121         {
 122                 self.projectiledeathtype |= HITTYPE_SPLASH;
 123                 W_Seeker_Missile_Explode(self);
 124         }
 125
 126         spd = vlen(self.velocity);
 127         spd = bound(
 128                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 129                 WEP_CVAR(seeker, missile_speed_max),
 130                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 131         );
 132
 133         if(self.enemy != world)
 134                 if(self.enemy.takedamage != DAMAGE_AIM || IS_DEAD(self.enemy))
 135                         self.enemy = world;
 136
 137         if(self.enemy != world)
 138         {
 139                 e               = self.enemy;
 140                 eorg            = 0.5 * (e.absmin + e.absmax);
 141                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 142                 desireddir      = normalize(eorg - self.origin);
 143                 olddir          = normalize(self.velocity); // get my current direction
 144                 dist            = vlen(eorg - self.origin);
 145
 146                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 147                 if(WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 148                 {
 149                         // Is it a better idea (shorter distance) to trace to the target itself?
 150                         if( vdist(self.origin + olddir * self.wait, <, dist))
 151                                 traceline(self.origin, self.origin + olddir * self.wait, false, self);
 152                         else
 153                                 traceline(self.origin, eorg, false, self);
 154
 155                         // Setup adaptive tracelength
 156                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 157
 158                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 159                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 160                 }
 161
 162                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 163                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 164         }
 165         else
 166                 dist = 0;
 167
 168         // Proxy
 169         if(WEP_CVAR(seeker, missile_proxy))
 170         {
 171                 if(dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 172                 {
 173                         if(self.autoswitch == 0)
 174                         {
 175                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 176                         }
 177                         else
 178                         {
 179                                 if(self.autoswitch <= time)
 180                                 {
 181                                         W_Seeker_Missile_Explode(self);
 182                                         self.autoswitch = 0;
 183                                 }
 184                         }
 185                 }
 186                 else
 187                 {
 188                         if(self.autoswitch != 0)
 189                                 self.autoswitch = 0;
 190                 }
 191         }
 192         ///////////////
 193
 194         if(IS_DEAD(self.enemy))
 195         {
 196                 self.enemy = world;
 197                 self.cnt = time + 1 + (random() * 4);
 198                 self.nextthink = self.cnt;
 199                 return;
 200         }
 201
 202         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 203         self.nextthink = time;// + 0.05; // csqc projectiles
 204         UpdateCSQCProjectile(self);
 205 }
 206
 207
 208
 209 void W_Seeker_Missile_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 210 {
 211         if(this.health <= 0)
 212                 return;
 213
 214         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 215                 return; // g_projectiles_damage says to halt
 216
 217         if(this.realowner == attacker)
 218                 this.health = this.health - (damage * 0.25);
 219         else
 220                 this.health = this.health - damage;
 221
 222         if(this.health <= 0)
 223                 W_PrepareExplosionByDamage(this, attacker, W_Seeker_Missile_Explode);
 224 }
 225
 226 /*
 227 void W_Seeker_Missile_Animate()
 228 {
 229         self.frame = self.frame +1;
 230         self.nextthink = time + 0.05;
 231
 232         if(self.enemy != world)
 233                 if(self.enemy.takedamage != DAMAGE_AIM || IS_DEAD(self.enemy))
 234                         self.enemy = world;
 235
 236         if(self.frame == 5)
 237         {
 238                 self.think           = W_Seeker_Missile_Think;
 239                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 240
 241                 if(autocvar_g_balance_seeker_missile_proxy)
 242                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 243                 else
 244                         self.movetype    = MOVETYPE_FLYMISSILE;
 245         }
 246
 247         UpdateCSQCProjectile(self);
 248 }
 249 */
 250
 251 void W_Seeker_Fire_Missile(Weapon thiswep, entity actor, vector f_diff, entity m_target)
 252 {entity this = actor;
 253         entity missile;
 254
 255         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, missile_ammo));
 256
 257         makevectors(self.v_angle);
 258         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND_SEEKER_FIRE, CH_WEAPON_A, 0);
 259         w_shotorg += f_diff;
 260         Send_Effect(EFFECT_SEEKER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 261
 262         //self.detornator         = false;
 263
 264         missile                 = new(seeker_missile);
 265         missile.owner           = missile.realowner = self;
 266         missile.bot_dodge       = true;
 267         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 268
 269         setthink(missile, W_Seeker_Missile_Think);
 270         settouch(missile, W_Seeker_Missile_Touch);
 271         missile.event_damage    = W_Seeker_Missile_Damage;
 272         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 273         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 274         missile.enemy           = m_target;
 275         missile.solid           = SOLID_BBOX;
 276         missile.scale           = 2;
 277         missile.takedamage      = DAMAGE_YES;
 278         missile.health          = WEP_CVAR(seeker, missile_health);
 279         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 280         missile.damagedbycontents = true;
 281         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 282
 283         if(missile.enemy != world)
 284                 missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 285         else
 286                 missile.projectiledeathtype = WEP_SEEKER.m_id;
 287
 288
 289         setorigin(missile, w_shotorg);
 290         setsize(missile, '-4 -4 -4', '4 4 4');
 291         missile.movetype    = MOVETYPE_FLYMISSILE;
 292         missile.flags       = FL_PROJECTILE;
 293         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 294
 295         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 296
 297         missile.angles = vectoangles(missile.velocity);
 298
 299         CSQCProjectile(missile, false, PROJECTILE_SEEKER, true);
 300
 301         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 302 }
 303
 304 // ============================
 305 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 306 // ============================
 307 void W_Seeker_Flac_Explode(entity this)
 308 {
 309         self.event_damage = func_null;
 310
 311         RadiusDamage(self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 312
 313         remove(self);
 314 }
 315
 316 void W_Seeker_Flac_Explode_use(entity this, entity actor, entity trigger)
 317 {
 318         WITHSELF(this, W_Seeker_Flac_Explode(this));
 319 }
 320
 321 void W_Seeker_Fire_Flac(Weapon thiswep, entity actor)
 322 {entity this = actor;
 323         entity missile;
 324         vector f_diff;
 325         float c;
 326
 327         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, flac_ammo));
 328
 329         c = self.bulletcounter % 4;
 330         switch(c)
 331         {
 332                 case 0:
 333                         f_diff = '-1.25 -3.75 0';
 334                         break;
 335                 case 1:
 336                         f_diff = '+1.25 -3.75 0';
 337                         break;
 338                 case 2:
 339                         f_diff = '-1.25 +3.75 0';
 340                         break;
 341                 case 3:
 342                 default:
 343                         f_diff = '+1.25 +3.75 0';
 344                         break;
 345         }
 346         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND_FLAC_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 347         w_shotorg += f_diff;
 348
 349         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 350
 351         missile                                 = new(missile);
 352         missile.owner                   = missile.realowner = self;
 353         missile.bot_dodge               = true;
 354         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 355         settouch(missile, W_Seeker_Flac_Explode);
 356         missile.use                     = W_Seeker_Flac_Explode_use;
 357         setthink(missile, adaptor_think2use_hittype_splash);
 358         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 359         missile.solid                   = SOLID_BBOX;
 360         missile.movetype                = MOVETYPE_FLY;
 361         missile.projectiledeathtype = WEP_SEEKER.m_id;
 362         missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 363         missile.flags                           = FL_PROJECTILE;
 364         missile.missile_flags       = MIF_SPLASH;
 365
 366         // csqc projectiles
 367         //missile.angles                                = vectoangles(missile.velocity);
 368         //missile.scale = 0.4; // BUG: the model is too big
 369
 370         setorigin(missile, w_shotorg);
 371         setsize(missile, '-2 -2 -2', '2 2 2');
 372
 373         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 374         CSQCProjectile(missile, true, PROJECTILE_FLAC, true);
 375
 376         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 377 }
 378
 379 // ============================
 380 // Begin: Tag and rocket controllers
 381 // ============================
 382 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
 383 {
 384         entity tag;
 385         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 386                 if((tag.realowner == isowner) && (tag.tag_target == istarget))
 387                         return tag;
 388
 389         return world;
 390 }
 391
 392 void W_Seeker_Attack(entity actor)
 393 {entity this = actor;
 394         entity tracker, closest_target;
 395
 396         closest_target = world;
 397         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 398         {
 399                 if(closest_target)
 400                 {
 401                         if(vlen2(self.origin - tracker.tag_target.origin) < vlen2(self.origin - closest_target.origin))
 402                                 closest_target = tracker.tag_target;
 403                 }
 404                 else
 405                         closest_target = tracker.tag_target;
 406         }
 407
 408         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 409         if((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 410                 closest_target = world;
 411
 412         W_Seeker_Fire_Missile(WEP_SEEKER, actor, '0 0 0', closest_target);
 413 }
 414
 415 void W_Seeker_Vollycontroller_Think(entity this) // TODO: Merge this with W_Seeker_Attack
 416 {
 417         float c;
 418         entity oldenemy;
 419         this.cnt = this.cnt - 1;
 420
 421         Weapon thiswep = WEP_SEEKER;
 422         if((!(this.realowner.items & IT_UNLIMITED_AMMO) && this.realowner.(thiswep.ammo_field) < WEP_CVAR(seeker, missile_ammo)) || (this.cnt <= -1) || (IS_DEAD(this.realowner)) || (PS(this.realowner).m_switchweapon != WEP_SEEKER))
 423         {
 424                 remove(this);
 425                 return;
 426         }
 427
 428         this.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 429
 430         entity own = this.realowner;
 431
 432         oldenemy = own.enemy;
 433         own.enemy = this.enemy;
 434
 435         c = own.cnt % 4;
 436         switch(c)
 437         {
 438                 case 0:
 439                         WITHSELF(own, W_Seeker_Fire_Missile(WEP_SEEKER, own, '-1.25 -3.75 0', own.enemy));
 440                         break;
 441                 case 1:
 442                         WITHSELF(own, W_Seeker_Fire_Missile(WEP_SEEKER, own, '+1.25 -3.75 0', own.enemy));
 443                         break;
 444                 case 2:
 445                         WITHSELF(own, W_Seeker_Fire_Missile(WEP_SEEKER, own, '-1.25 +3.75 0', own.enemy));
 446                         break;
 447                 case 3:
 448                 default:
 449                         WITHSELF(own, W_Seeker_Fire_Missile(WEP_SEEKER, own, '+1.25 +3.75 0', own.enemy));
 450                         break;
 451         }
 452
 453         own.enemy = oldenemy;
 454 }
 455
 456 void W_Seeker_Tracker_Think(entity this)
 457 {
 458         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 459         if((IS_DEAD(self.realowner)) || (IS_DEAD(self.tag_target)) || (PS(self.realowner).m_switchweapon != WEP_SEEKER)
 460         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 461         {
 462                 if(self)
 463                 {
 464                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 465                         remove(self);
 466                 }
 467                 return;
 468         }
 469
 470         // Update the think method information
 471         self.nextthink = time;
 472 }
 473
 474 // ============================
 475 // Begin: Tag projectile
 476 // ============================
 477 void W_Seeker_Tag_Explode(entity this)
 478 {
 479         //if(other==this.realowner)
 480         //    return;
 481         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE, other.species, this);
 482
 483         remove(this);
 484 }
 485
 486 void W_Seeker_Tag_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 487 {
 488         if(this.health <= 0)
 489                 return;
 490         this.health = this.health - damage;
 491         if(this.health <= 0)
 492                 W_Seeker_Tag_Explode(this);
 493 }
 494
 495 void W_Seeker_Tag_Touch(entity this)
 496 {
 497         vector dir;
 498         vector org2;
 499         entity e;
 500
 501         PROJECTILE_TOUCH;
 502
 503         dir     = normalize(self.realowner.origin - self.origin);
 504         org2    = findbetterlocation(self.origin, 8);
 505
 506         te_knightspike(org2);
 507
 508         self.event_damage = func_null;
 509         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 510
 511         if(other.takedamage == DAMAGE_AIM && !IS_DEAD(other))
 512         {
 513                 // check to see if this person is already tagged by me
 514                 entity tag = W_Seeker_Tagged_Info(self.realowner, other);
 515
 516                 if(tag != world)
 517                 {
 518                         if(other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 519                                 WaypointSprite_Kill(other.wps_tag_tracker);
 520
 521                         tag.tag_time = time;
 522                 }
 523                 else
 524                 {
 525                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 526                         e             = new(tag_tracker);
 527                         e.cnt         = WEP_CVAR(seeker, missile_count);
 528                         e.owner       = self.owner;
 529                         e.realowner   = self.realowner;
 530
 531                         if(WEP_CVAR(seeker, type) == 1)
 532                         {
 533                                 e.tag_target  = other;
 534                                 e.tag_time    = time;
 535                                 setthink(e, W_Seeker_Tracker_Think);
 536                         }
 537                         else
 538                         {
 539                                 e.enemy     = other;
 540                                 setthink(e, W_Seeker_Vollycontroller_Think);
 541                         }
 542
 543                         e.nextthink   = time;
 544                 }
 545
 546                 if(WEP_CVAR(seeker, type) == 1)
 547                 {
 548                         WaypointSprite_Spawn(WP_Seeker, WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, true, RADARICON_TAGGED);
 549                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 550                 }
 551         }
 552
 553         remove(self);
 554         return;
 555 }
 556
 557 void W_Seeker_Fire_Tag(Weapon thiswep, entity actor)
 558 {entity this = actor;
 559         entity missile;
 560         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, tag_ammo));
 561
 562         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND_TAG_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 563
 564         missile                 = new(seeker_tag);
 565         missile.owner           = missile.realowner = self;
 566         missile.bot_dodge       = true;
 567         missile.bot_dodgerating = 50;
 568         settouch(missile, W_Seeker_Tag_Touch);
 569         setthink(missile, SUB_Remove);
 570         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 571         missile.movetype        = MOVETYPE_FLY;
 572         missile.solid           = SOLID_BBOX;
 573
 574         missile.takedamage       = DAMAGE_YES;
 575         missile.event_damage     = W_Seeker_Tag_Damage;
 576         missile.health           = WEP_CVAR(seeker, tag_health);
 577         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 578
 579         setorigin(missile, w_shotorg);
 580         setsize(missile, '-2 -2 -2', '2 2 2');
 581
 582         missile.flags       = FL_PROJECTILE;
 583         //missile.missile_flags = MIF_..?;
 584
 585         missile.movetype    = MOVETYPE_FLY;
 586         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 587         missile.angles = vectoangles(missile.velocity);
 588
 589         CSQCProjectile(missile, true, PROJECTILE_TAG, false); // has sound
 590
 591         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 592 }
 593
 594 // ============================
 595 // Begin: Genereal weapon functions
 596 // ============================
 597
 598 METHOD(Seeker, wr_aim, void(entity thiswep, entity actor))
 599 {
 600     entity this = actor;
 601     if(WEP_CVAR(seeker, type) == 1)
 602         if(W_Seeker_Tagged_Info(self, self.enemy) != world)
 603             PHYS_INPUT_BUTTON_ATCK(self) = bot_aim(self, WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), false);
 604         else
 605             PHYS_INPUT_BUTTON_ATCK2(self) = bot_aim(self, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 606     else
 607         PHYS_INPUT_BUTTON_ATCK(self) = bot_aim(self, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 608 }
 609 METHOD(Seeker, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 610 {
 611     if(autocvar_g_balance_seeker_reload_ammo && actor.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) { // forced reload
 612         thiswep.wr_reload(thiswep, actor, weaponentity);
 613     } else if(fire & 1)
 614     {
 615         if(WEP_CVAR(seeker, type) == 1)
 616         {
 617             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, missile_refire)))
 618             {
 619                 W_Seeker_Attack(actor);
 620                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 621             }
 622         }
 623         else
 624         {
 625             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 626             {
 627                 W_Seeker_Fire_Tag(thiswep, actor);
 628                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 629             }
 630         }
 631     }
 632
 633     else if(fire & 2)
 634     {
 635         if(WEP_CVAR(seeker, type) == 1)
 636         {
 637             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 638             {
 639                 W_Seeker_Fire_Tag(thiswep, actor);
 640                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 641             }
 642         }
 643         else
 644         {
 645             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, flac_refire)))
 646             {
 647                 W_Seeker_Fire_Flac(thiswep, actor);
 648                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 649             }
 650         }
 651     }
 652 }
 653 METHOD(Seeker, wr_checkammo1, bool(entity thiswep, entity actor))
 654 {
 655     float ammo_amount;
 656     if(WEP_CVAR(seeker, type) == 1)
 657     {
 658         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, missile_ammo);
 659         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, missile_ammo);
 660     }
 661     else
 662     {
 663         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, tag_ammo);
 664         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 665     }
 666     return ammo_amount;
 667 }
 668 METHOD(Seeker, wr_checkammo2, bool(entity thiswep, entity actor))
 669 {
 670     float ammo_amount;
 671     if(WEP_CVAR(seeker, type) == 1)
 672     {
 673         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, tag_ammo);
 674         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 675     }
 676     else
 677     {
 678         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, flac_ammo);
 679         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, flac_ammo);
 680     }
 681     return ammo_amount;
 682 }
 683 METHOD(Seeker, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 684 {
 685     W_Reload(actor, min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), SND_RELOAD);
 686 }
 687 METHOD(Seeker, wr_suicidemessage, Notification(entity thiswep))
 688 {
 689     return WEAPON_SEEKER_SUICIDE;
 690 }
 691 METHOD(Seeker, wr_killmessage, Notification(entity thiswep))
 692 {
 693     if(w_deathtype & HITTYPE_SECONDARY)
 694         return WEAPON_SEEKER_MURDER_TAG;
 695     else
 696         return WEAPON_SEEKER_MURDER_SPRAY;
 697 }
 698
 699 #endif
 700 #ifdef CSQC
 701
 702 METHOD(Seeker, wr_impacteffect, void(entity thiswep, entity actor))
 703 {
 704     entity this = actor;
 705     vector org2;
 706     org2 = w_org + w_backoff * 6;
 707     if(w_deathtype & HITTYPE_BOUNCE)
 708     {
 709         if(w_deathtype & HITTYPE_SECONDARY)
 710         {
 711             if(!w_issilent)
 712                 sound(self, CH_SHOTS, SND_TAG_IMPACT, 1, ATTEN_NORM);
 713         }
 714         else
 715         {
 716             pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 717             if(!w_issilent)
 718             {
 719                 if(w_random<0.15)
 720                     sound(self, CH_SHOTS, SND_TAGEXP1, 1, ATTEN_NORM);
 721                 else if(w_random<0.7)
 722                     sound(self, CH_SHOTS, SND_TAGEXP2, 1, ATTEN_NORM);
 723                 else
 724                     sound(self, CH_SHOTS, SND_TAGEXP3, 1, ATTEN_NORM);
 725             }
 726         }
 727     }
 728     else
 729     {
 730         pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 731         if(!w_issilent)
 732         {
 733             if(w_random<0.15)
 734                 sound(self, CH_SHOTS, SND_SEEKEREXP1, 1, ATTEN_NORM);
 735             else if(w_random<0.7)
 736                 sound(self, CH_SHOTS, SND_SEEKEREXP2, 1, ATTEN_NORM);
 737             else
 738                 sound(self, CH_SHOTS, SND_SEEKEREXP3, 1, ATTEN_NORM);
 739         }
 740     }
 741 }
 742
 743 #endif
 744 #endif