qcsrc/common/weapons/weapon/seeker.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Seeker, Weapon)
   3 /* ammotype  */ ATTRIB(Seeker, ammo_field, .int, ammo_rockets)
   4 /* impulse   */ ATTRIB(Seeker, impulse, int, 8)
   5 /* flags     */ ATTRIB(Seeker, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Seeker, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Seeker, wpcolor, vector, '0.5 1 0');
   8 /* modelname */ ATTRIB(Seeker, mdl, string, "seeker");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Seeker, m_model, Model, MDL_SEEKER_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Seeker, w_crosshair, string, "gfx/crosshairseeker");
  13 /* crosshair */ ATTRIB(Seeker, w_crosshair_size, float, 0.8);
  14 /* wepimg    */ ATTRIB(Seeker, model2, string, "weaponseeker");
  15 /* refname   */ ATTRIB(Seeker, netname, string, "seeker");
  16 /* wepname   */ ATTRIB(Seeker, m_name, string, _("T.A.G. Seeker"));
  17 ENDCLASS(Seeker)
  18 REGISTER_WEAPON(SEEKER, NEW(Seeker));
  19
  20 #define SEEKER_SETTINGS(w_cvar,w_prop) SEEKER_SETTINGS_LIST(w_cvar, w_prop, SEEKER, seeker)
  21 #define SEEKER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  22         w_cvar(id, sn, NONE, type) \
  23         w_cvar(id, sn, NONE, flac_ammo) \
  24         w_cvar(id, sn, NONE, flac_animtime) \
  25         w_cvar(id, sn, NONE, flac_damage) \
  26         w_cvar(id, sn, NONE, flac_edgedamage) \
  27         w_cvar(id, sn, NONE, flac_force) \
  28         w_cvar(id, sn, NONE, flac_lifetime) \
  29         w_cvar(id, sn, NONE, flac_lifetime_rand) \
  30         w_cvar(id, sn, NONE, flac_radius) \
  31         w_cvar(id, sn, NONE, flac_refire) \
  32         w_cvar(id, sn, NONE, flac_speed) \
  33         w_cvar(id, sn, NONE, flac_speed_up) \
  34         w_cvar(id, sn, NONE, flac_speed_z) \
  35         w_cvar(id, sn, NONE, flac_spread) \
  36         w_cvar(id, sn, NONE, missile_accel) \
  37         w_cvar(id, sn, NONE, missile_ammo) \
  38         w_cvar(id, sn, NONE, missile_animtime) \
  39         w_cvar(id, sn, NONE, missile_count) \
  40         w_cvar(id, sn, NONE, missile_damage) \
  41         w_cvar(id, sn, NONE, missile_damageforcescale) \
  42         w_cvar(id, sn, NONE, missile_decel) \
  43         w_cvar(id, sn, NONE, missile_delay) \
  44         w_cvar(id, sn, NONE, missile_edgedamage) \
  45         w_cvar(id, sn, NONE, missile_force) \
  46         w_cvar(id, sn, NONE, missile_health) \
  47         w_cvar(id, sn, NONE, missile_lifetime) \
  48         w_cvar(id, sn, NONE, missile_proxy) \
  49         w_cvar(id, sn, NONE, missile_proxy_delay) \
  50         w_cvar(id, sn, NONE, missile_proxy_maxrange) \
  51         w_cvar(id, sn, NONE, missile_radius) \
  52         w_cvar(id, sn, NONE, missile_refire) \
  53         w_cvar(id, sn, NONE, missile_smart) \
  54         w_cvar(id, sn, NONE, missile_smart_mindist) \
  55         w_cvar(id, sn, NONE, missile_smart_trace_max) \
  56         w_cvar(id, sn, NONE, missile_smart_trace_min) \
  57         w_cvar(id, sn, NONE, missile_speed) \
  58         w_cvar(id, sn, NONE, missile_speed_max) \
  59         w_cvar(id, sn, NONE, missile_speed_up) \
  60         w_cvar(id, sn, NONE, missile_speed_z) \
  61         w_cvar(id, sn, NONE, missile_spread) \
  62         w_cvar(id, sn, NONE, missile_turnrate) \
  63         w_cvar(id, sn, NONE, tag_ammo) \
  64         w_cvar(id, sn, NONE, tag_animtime) \
  65         w_cvar(id, sn, NONE, tag_damageforcescale) \
  66         w_cvar(id, sn, NONE, tag_health) \
  67         w_cvar(id, sn, NONE, tag_lifetime) \
  68         w_cvar(id, sn, NONE, tag_refire) \
  69         w_cvar(id, sn, NONE, tag_speed) \
  70         w_cvar(id, sn, NONE, tag_spread) \
  71         w_cvar(id, sn, NONE, tag_tracker_lifetime) \
  72         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  73         w_prop(id, sn, float,  reloading_time, reload_time) \
  74         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  75         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  76         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  77         w_prop(id, sn, float,  weaponstart, weaponstart) \
  78         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  79         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  80
  81 #ifdef SVQC
  82 SEEKER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  83 .entity tag_target, wps_tag_tracker;
  84 .float tag_time;
  85 #endif
  86 #endif
  87 #ifdef IMPLEMENTATION
  88 #ifdef SVQC
  89 spawnfunc(weapon_seeker) { weapon_defaultspawnfunc(this, WEP_SEEKER); }
  90
  91 // ============================
  92 // Begin: Missile functions, these are general functions to be manipulated by other code
  93 // ============================
  94 void W_Seeker_Missile_Explode()
  95 {SELFPARAM();
  96         self.event_damage = func_null;
  97         RadiusDamage(self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  98
  99         remove(self);
 100 }
 101
 102 void W_Seeker_Missile_Touch()
 103 {
 104         PROJECTILE_TOUCH;
 105
 106         W_Seeker_Missile_Explode();
 107 }
 108
 109 void W_Seeker_Missile_Think()
 110 {SELFPARAM();
 111         entity e;
 112         vector desireddir, olddir, newdir, eorg;
 113         float turnrate;
 114         float dist;
 115         float spd;
 116
 117         if(time > self.cnt)
 118         {
 119                 self.projectiledeathtype |= HITTYPE_SPLASH;
 120                 W_Seeker_Missile_Explode();
 121         }
 122
 123         spd = vlen(self.velocity);
 124         spd = bound(
 125                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 126                 WEP_CVAR(seeker, missile_speed_max),
 127                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 128         );
 129
 130         if(self.enemy != world)
 131                 if(self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 132                         self.enemy = world;
 133
 134         if(self.enemy != world)
 135         {
 136                 e               = self.enemy;
 137                 eorg            = 0.5 * (e.absmin + e.absmax);
 138                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 139                 desireddir      = normalize(eorg - self.origin);
 140                 olddir          = normalize(self.velocity); // get my current direction
 141                 dist            = vlen(eorg - self.origin);
 142
 143                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 144                 if(WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 145                 {
 146                         // Is it a better idea (shorter distance) to trace to the target itself?
 147                         if( vlen(self.origin + olddir * self.wait) < dist)
 148                                 traceline(self.origin, self.origin + olddir * self.wait, false, self);
 149                         else
 150                                 traceline(self.origin, eorg, false, self);
 151
 152                         // Setup adaptive tracelength
 153                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 154
 155                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 156                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 157                 }
 158
 159                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 160                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 161         }
 162         else
 163                 dist = 0;
 164
 165         // Proxy
 166         if(WEP_CVAR(seeker, missile_proxy))
 167         {
 168                 if(dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 169                 {
 170                         if(self.autoswitch == 0)
 171                         {
 172                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 173                         }
 174                         else
 175                         {
 176                                 if(self.autoswitch <= time)
 177                                 {
 178                                         W_Seeker_Missile_Explode();
 179                                         self.autoswitch = 0;
 180                                 }
 181                         }
 182                 }
 183                 else
 184                 {
 185                         if(self.autoswitch != 0)
 186                                 self.autoswitch = 0;
 187                 }
 188         }
 189         ///////////////
 190
 191         if(self.enemy.deadflag != DEAD_NO)
 192         {
 193                 self.enemy = world;
 194                 self.cnt = time + 1 + (random() * 4);
 195                 self.nextthink = self.cnt;
 196                 return;
 197         }
 198
 199         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 200         self.nextthink = time;// + 0.05; // csqc projectiles
 201         UpdateCSQCProjectile(self);
 202 }
 203
 204
 205
 206 void W_Seeker_Missile_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 207 {SELFPARAM();
 208         if(self.health <= 0)
 209                 return;
 210
 211         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 212                 return; // g_projectiles_damage says to halt
 213
 214         if(self.realowner == attacker)
 215                 self.health = self.health - (damage * 0.25);
 216         else
 217                 self.health = self.health - damage;
 218
 219         if(self.health <= 0)
 220                 W_PrepareExplosionByDamage(attacker, W_Seeker_Missile_Explode);
 221 }
 222
 223 /*
 224 void W_Seeker_Missile_Animate()
 225 {
 226         self.frame = self.frame +1;
 227         self.nextthink = time + 0.05;
 228
 229         if(self.enemy != world)
 230                 if(self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 231                         self.enemy = world;
 232
 233         if(self.frame == 5)
 234         {
 235                 self.think           = W_Seeker_Missile_Think;
 236                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 237
 238                 if(autocvar_g_balance_seeker_missile_proxy)
 239                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 240                 else
 241                         self.movetype    = MOVETYPE_FLYMISSILE;
 242         }
 243
 244         UpdateCSQCProjectile(self);
 245 }
 246 */
 247
 248 void W_Seeker_Fire_Missile(Weapon thiswep, vector f_diff, entity m_target)
 249 {SELFPARAM();
 250         entity missile;
 251
 252         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, missile_ammo));
 253
 254         makevectors(self.v_angle);
 255         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND(SEEKER_FIRE), CH_WEAPON_A, 0);
 256         w_shotorg += f_diff;
 257         Send_Effect(EFFECT_SEEKER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 258
 259         //self.detornator         = false;
 260
 261         missile                 = new(seeker_missile);
 262         missile.owner           = missile.realowner = self;
 263         missile.bot_dodge       = true;
 264         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 265
 266         missile.think           = W_Seeker_Missile_Think;
 267         missile.touch           = W_Seeker_Missile_Touch;
 268         missile.event_damage    = W_Seeker_Missile_Damage;
 269         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 270         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 271         missile.enemy           = m_target;
 272         missile.solid           = SOLID_BBOX;
 273         missile.scale           = 2;
 274         missile.takedamage      = DAMAGE_YES;
 275         missile.health          = WEP_CVAR(seeker, missile_health);
 276         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 277         missile.damagedbycontents = true;
 278         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 279
 280         if(missile.enemy != world)
 281                 missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 282         else
 283                 missile.projectiledeathtype = WEP_SEEKER.m_id;
 284
 285
 286         setorigin(missile, w_shotorg);
 287         setsize(missile, '-4 -4 -4', '4 4 4');
 288         missile.movetype    = MOVETYPE_FLYMISSILE;
 289         missile.flags       = FL_PROJECTILE;
 290         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 291
 292         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 293
 294         missile.angles = vectoangles(missile.velocity);
 295
 296         CSQCProjectile(missile, false, PROJECTILE_SEEKER, true);
 297
 298         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 299 }
 300
 301 // ============================
 302 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 303 // ============================
 304 void W_Seeker_Flac_Explode()
 305 {SELFPARAM();
 306         self.event_damage = func_null;
 307
 308         RadiusDamage(self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 309
 310         remove(self);
 311 }
 312
 313 void W_Seeker_Flac_Touch()
 314 {
 315         PROJECTILE_TOUCH;
 316
 317         W_Seeker_Flac_Explode();
 318 }
 319
 320 void W_Seeker_Fire_Flac(Weapon thiswep)
 321 {SELFPARAM();
 322         entity missile;
 323         vector f_diff;
 324         float c;
 325
 326         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, flac_ammo));
 327
 328         c = self.bulletcounter % 4;
 329         switch(c)
 330         {
 331                 case 0:
 332                         f_diff = '-1.25 -3.75 0';
 333                         break;
 334                 case 1:
 335                         f_diff = '+1.25 -3.75 0';
 336                         break;
 337                 case 2:
 338                         f_diff = '-1.25 +3.75 0';
 339                         break;
 340                 case 3:
 341                 default:
 342                         f_diff = '+1.25 +3.75 0';
 343                         break;
 344         }
 345         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND(FLAC_FIRE), CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 346         w_shotorg += f_diff;
 347
 348         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 349
 350         missile                                 = new(missile);
 351         missile.owner                   = missile.realowner = self;
 352         missile.bot_dodge               = true;
 353         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 354         missile.touch                   = W_Seeker_Flac_Explode;
 355         missile.use                     = W_Seeker_Flac_Explode;
 356         missile.think                   = adaptor_think2use_hittype_splash;
 357         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 358         missile.solid                   = SOLID_BBOX;
 359         missile.movetype                = MOVETYPE_FLY;
 360         missile.projectiledeathtype = WEP_SEEKER.m_id;
 361         missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 362         missile.flags                           = FL_PROJECTILE;
 363         missile.missile_flags       = MIF_SPLASH;
 364
 365         // csqc projectiles
 366         //missile.angles                                = vectoangles(missile.velocity);
 367         //missile.scale = 0.4; // BUG: the model is too big
 368
 369         setorigin(missile, w_shotorg);
 370         setsize(missile, '-2 -2 -2', '2 2 2');
 371
 372         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 373         CSQCProjectile(missile, true, PROJECTILE_FLAC, true);
 374
 375         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 376 }
 377
 378 // ============================
 379 // Begin: Tag and rocket controllers
 380 // ============================
 381 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
 382 {
 383         entity tag;
 384         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 385                 if((tag.realowner == isowner) && (tag.tag_target == istarget))
 386                         return tag;
 387
 388         return world;
 389 }
 390
 391 void W_Seeker_Attack()
 392 {SELFPARAM();
 393         entity tracker, closest_target;
 394
 395         closest_target = world;
 396         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 397         {
 398                 if(closest_target)
 399                 {
 400                         if(vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 401                                 closest_target = tracker.tag_target;
 402                 }
 403                 else
 404                         closest_target = tracker.tag_target;
 405         }
 406
 407         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 408         if((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 409                 closest_target = world;
 410
 411         W_Seeker_Fire_Missile(WEP_SEEKER, '0 0 0', closest_target);
 412 }
 413
 414 void W_Seeker_Vollycontroller_Think() // TODO: Merge this with W_Seeker_Attack
 415 {SELFPARAM();
 416         float c;
 417         entity oldenemy;
 418         self.cnt = self.cnt - 1;
 419
 420         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.WEP_AMMO(SEEKER) < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER.m_id))
 421         {
 422                 remove(self);
 423                 return;
 424         }
 425
 426         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 427
 428         setself(self.realowner);
 429
 430         oldenemy = self.enemy;
 431         self.enemy = this.enemy;
 432
 433         c = self.cnt % 4;
 434         switch(c)
 435         {
 436                 case 0:
 437                         W_Seeker_Fire_Missile(WEP_SEEKER, '-1.25 -3.75 0', self.enemy);
 438                         break;
 439                 case 1:
 440                         W_Seeker_Fire_Missile(WEP_SEEKER, '+1.25 -3.75 0', self.enemy);
 441                         break;
 442                 case 2:
 443                         W_Seeker_Fire_Missile(WEP_SEEKER, '-1.25 +3.75 0', self.enemy);
 444                         break;
 445                 case 3:
 446                 default:
 447                         W_Seeker_Fire_Missile(WEP_SEEKER, '+1.25 +3.75 0', self.enemy);
 448                         break;
 449         }
 450
 451         self.enemy = oldenemy;
 452         setself(this);
 453 }
 454
 455 void W_Seeker_Tracker_Think()
 456 {SELFPARAM();
 457         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 458         if((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER.m_id)
 459         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 460         {
 461                 if(self)
 462                 {
 463                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 464                         remove(self);
 465                 }
 466                 return;
 467         }
 468
 469         // Update the think method information
 470         self.nextthink = time;
 471 }
 472
 473 // ============================
 474 // Begin: Tag projectile
 475 // ============================
 476 void W_Seeker_Tag_Explode()
 477 {SELFPARAM();
 478         //if(other==self.realowner)
 479         //    return;
 480         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE, other.species, self);
 481
 482         remove(self);
 483 }
 484
 485 void W_Seeker_Tag_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 486 {SELFPARAM();
 487         if(self.health <= 0)
 488                 return;
 489         self.health = self.health - damage;
 490         if(self.health <= 0)
 491                 W_Seeker_Tag_Explode();
 492 }
 493
 494 void W_Seeker_Tag_Touch()
 495 {SELFPARAM();
 496         vector dir;
 497         vector org2;
 498         entity e;
 499
 500         PROJECTILE_TOUCH;
 501
 502         dir     = normalize(self.realowner.origin - self.origin);
 503         org2    = findbetterlocation(self.origin, 8);
 504
 505         te_knightspike(org2);
 506
 507         self.event_damage = func_null;
 508         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 509
 510         if(other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 511         {
 512                 // check to see if this person is already tagged by me
 513                 entity tag = W_Seeker_Tagged_Info(self.realowner, other);
 514
 515                 if(tag != world)
 516                 {
 517                         if(other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 518                                 WaypointSprite_Kill(other.wps_tag_tracker);
 519
 520                         tag.tag_time = time;
 521                 }
 522                 else
 523                 {
 524                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 525                         e             = new(tag_tracker);
 526                         e.cnt         = WEP_CVAR(seeker, missile_count);
 527                         e.owner       = self.owner;
 528                         e.realowner   = self.realowner;
 529
 530                         if(WEP_CVAR(seeker, type) == 1)
 531                         {
 532                                 e.tag_target  = other;
 533                                 e.tag_time    = time;
 534                                 e.think       = W_Seeker_Tracker_Think;
 535                         }
 536                         else
 537                         {
 538                                 e.enemy     = other;
 539                                 e.think     = W_Seeker_Vollycontroller_Think;
 540                         }
 541
 542                         e.nextthink   = time;
 543                 }
 544
 545                 if(WEP_CVAR(seeker, type) == 1)
 546                 {
 547                         WaypointSprite_Spawn(WP_Seeker, WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, true, RADARICON_TAGGED);
 548                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 549                 }
 550         }
 551
 552         remove(self);
 553         return;
 554 }
 555
 556 void W_Seeker_Fire_Tag(Weapon thiswep)
 557 {SELFPARAM();
 558         entity missile;
 559         W_DecreaseAmmo(thiswep, self, WEP_CVAR(seeker, tag_ammo));
 560
 561         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND(TAG_FIRE), CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 562
 563         missile                 = new(seeker_tag);
 564         missile.owner           = missile.realowner = self;
 565         missile.bot_dodge       = true;
 566         missile.bot_dodgerating = 50;
 567         missile.touch           = W_Seeker_Tag_Touch;
 568         missile.think           = SUB_Remove;
 569         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 570         missile.movetype        = MOVETYPE_FLY;
 571         missile.solid           = SOLID_BBOX;
 572
 573         missile.takedamage       = DAMAGE_YES;
 574         missile.event_damage     = W_Seeker_Tag_Damage;
 575         missile.health           = WEP_CVAR(seeker, tag_health);
 576         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 577
 578         setorigin(missile, w_shotorg);
 579         setsize(missile, '-2 -2 -2', '2 2 2');
 580
 581         missile.flags       = FL_PROJECTILE;
 582         //missile.missile_flags = MIF_..?;
 583
 584         missile.movetype    = MOVETYPE_FLY;
 585         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 586         missile.angles = vectoangles(missile.velocity);
 587
 588         CSQCProjectile(missile, true, PROJECTILE_TAG, false); // has sound
 589
 590         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 591 }
 592
 593 // ============================
 594 // Begin: Genereal weapon functions
 595 // ============================
 596
 597                 METHOD(Seeker, wr_aim, void(entity thiswep))
 598                 {
 599                         if(WEP_CVAR(seeker, type) == 1)
 600                                 if(W_Seeker_Tagged_Info(self, self.enemy) != world)
 601                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), false);
 602                                 else
 603                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 604                         else
 605                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 606                 }
 607                 METHOD(Seeker, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 608                 {
 609                         if(autocvar_g_balance_seeker_reload_ammo && actor.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) { // forced reload
 610                                 Weapon w = get_weaponinfo(actor.weapon);
 611                                 w.wr_reload(w);
 612                         } else if(fire & 1)
 613                         {
 614                                 if(WEP_CVAR(seeker, type) == 1)
 615                                 {
 616                                         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, missile_refire)))
 617                                         {
 618                                                 W_Seeker_Attack();
 619                                                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 620                                         }
 621                                 }
 622                                 else
 623                                 {
 624                                         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 625                                         {
 626                                                 W_Seeker_Fire_Tag(thiswep);
 627                                                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 628                                         }
 629                                 }
 630                         }
 631
 632                         else if(fire & 2)
 633                         {
 634                                 if(WEP_CVAR(seeker, type) == 1)
 635                                 {
 636                                         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 637                                         {
 638                                                 W_Seeker_Fire_Tag(thiswep);
 639                                                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 640                                         }
 641                                 }
 642                                 else
 643                                 {
 644                                         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, flac_refire)))
 645                                         {
 646                                                 W_Seeker_Fire_Flac(thiswep);
 647                                                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 648                                         }
 649                                 }
 650                         }
 651                 }
 652                 METHOD(Seeker, wr_init, void(entity thiswep))
 653                 {
 654                         SEEKER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 655                 }
 656                 METHOD(Seeker, wr_checkammo1, bool(entity thiswep))
 657                 {
 658                         float ammo_amount;
 659                         if(WEP_CVAR(seeker, type) == 1)
 660                         {
 661                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, missile_ammo);
 662                                 ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, missile_ammo);
 663                         }
 664                         else
 665                         {
 666                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 667                                 ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 668                         }
 669                         return ammo_amount;
 670                 }
 671                 METHOD(Seeker, wr_checkammo2, bool(entity thiswep))
 672                 {
 673                         float ammo_amount;
 674                         if(WEP_CVAR(seeker, type) == 1)
 675                         {
 676                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 677                                 ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 678                         }
 679                         else
 680                         {
 681                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, flac_ammo);
 682                                 ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, flac_ammo);
 683                         }
 684                         return ammo_amount;
 685                 }
 686                 METHOD(Seeker, wr_config, void(entity thiswep))
 687                 {
 688                         SEEKER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 689                 }
 690                 METHOD(Seeker, wr_reload, void(entity thiswep))
 691                 {
 692                         W_Reload(self, min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), SND(RELOAD));
 693                 }
 694                 METHOD(Seeker, wr_suicidemessage, int(entity thiswep))
 695                 {
 696                         return WEAPON_SEEKER_SUICIDE;
 697                 }
 698                 METHOD(Seeker, wr_killmessage, int(entity thiswep))
 699                 {
 700                         if(w_deathtype & HITTYPE_SECONDARY)
 701                                 return WEAPON_SEEKER_MURDER_TAG;
 702                         else
 703                                 return WEAPON_SEEKER_MURDER_SPRAY;
 704                 }
 705
 706 #endif
 707 #ifdef CSQC
 708
 709                 METHOD(Seeker, wr_impacteffect, void(entity thiswep))
 710                 {
 711                         vector org2;
 712                         org2 = w_org + w_backoff * 6;
 713                         if(w_deathtype & HITTYPE_BOUNCE)
 714                         {
 715                                 if(w_deathtype & HITTYPE_SECONDARY)
 716                                 {
 717                                         if(!w_issilent)
 718                                                 sound(self, CH_SHOTS, SND_TAG_IMPACT, 1, ATTEN_NORM);
 719                                 }
 720                                 else
 721                                 {
 722                                         pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 723                                         if(!w_issilent)
 724                                         {
 725                                                 if(w_random<0.15)
 726                                                         sound(self, CH_SHOTS, SND_TAGEXP1, 1, ATTEN_NORM);
 727                                                 else if(w_random<0.7)
 728                                                         sound(self, CH_SHOTS, SND_TAGEXP2, 1, ATTEN_NORM);
 729                                                 else
 730                                                         sound(self, CH_SHOTS, SND_TAGEXP3, 1, ATTEN_NORM);
 731                                         }
 732                                 }
 733                         }
 734                         else
 735                         {
 736                                 pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 737                                 if(!w_issilent)
 738                                 {
 739                                         if(w_random<0.15)
 740                                                 sound(self, CH_SHOTS, SND_SEEKEREXP1, 1, ATTEN_NORM);
 741                                         else if(w_random<0.7)
 742                                                 sound(self, CH_SHOTS, SND_SEEKEREXP2, 1, ATTEN_NORM);
 743                                         else
 744                                                 sound(self, CH_SHOTS, SND_SEEKEREXP3, 1, ATTEN_NORM);
 745                                 }
 746                         }
 747                 }
 748
 749 #endif
 750 #endif