qcsrc/common/weapons/weapon/shockwave.qc

   1 #include "shockwave.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Shockwave, Weapon)
   4 /* ammotype  */ //ATTRIB(Shockwave, ammo_field, .int, ammo_none);
   5 /* impulse   */ ATTRIB(Shockwave, impulse, int, 2);
   6 /* flags     */ ATTRIB(Shockwave, spawnflags, int, WEP_TYPE_HITSCAN | WEP_FLAG_CANCLIMB | WEP_TYPE_MELEE_SEC);
   7 /* rating    */ ATTRIB(Shockwave, bot_pickupbasevalue, float, 3000);
   8 /* color     */ ATTRIB(Shockwave, wpcolor, vector, '0.5 0.25 0');
   9 /* modelname */ ATTRIB(Shockwave, mdl, string, "shotgun");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Shockwave, m_model, Model, MDL_SHOCKWAVE_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Shockwave, w_crosshair, string, "gfx/crosshairshotgun");
  14 /* crosshair */ ATTRIB(Shockwave, w_crosshair_size, float, 0.7);
  15 /* wepimg    */ ATTRIB(Shockwave, model2, string, "weaponshockwave");
  16 /* refname   */ ATTRIB(Shockwave, netname, string, "shockwave");
  17 /* wepname   */ ATTRIB(Shockwave, m_name, string, _("Shockwave"));
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21                 P(class, prefix, blast_animtime, float, NONE) \
  22                 P(class, prefix, blast_damage, float, NONE) \
  23                 P(class, prefix, blast_distance, float, NONE) \
  24                 P(class, prefix, blast_edgedamage, float, NONE) \
  25                 P(class, prefix, blast_force, float, NONE) \
  26                 P(class, prefix, blast_force_forwardbias, float, NONE) \
  27                 P(class, prefix, blast_force_zscale, float, NONE) \
  28                 P(class, prefix, blast_jump_damage, float, NONE) \
  29                 P(class, prefix, blast_jump_edgedamage, float, NONE) \
  30                 P(class, prefix, blast_jump_force, float, NONE) \
  31                 P(class, prefix, blast_jump_force_velocitybias, float, NONE) \
  32                 P(class, prefix, blast_jump_force_zscale, float, NONE) \
  33                 P(class, prefix, blast_jump_multiplier_accuracy, float, NONE) \
  34                 P(class, prefix, blast_jump_multiplier_distance, float, NONE) \
  35                 P(class, prefix, blast_jump_multiplier_min, float, NONE) \
  36                 P(class, prefix, blast_jump_radius, float, NONE) \
  37                 P(class, prefix, blast_multiplier_accuracy, float, NONE) \
  38                 P(class, prefix, blast_multiplier_distance, float, NONE) \
  39                 P(class, prefix, blast_multiplier_min, float, NONE) \
  40                 P(class, prefix, blast_refire, float, NONE) \
  41                 P(class, prefix, blast_splash_damage, float, NONE) \
  42                 P(class, prefix, blast_splash_edgedamage, float, NONE) \
  43                 P(class, prefix, blast_splash_force, float, NONE) \
  44                 P(class, prefix, blast_splash_force_forwardbias, float, NONE) \
  45                 P(class, prefix, blast_splash_multiplier_accuracy, float, NONE) \
  46                 P(class, prefix, blast_splash_multiplier_distance, float, NONE) \
  47                 P(class, prefix, blast_splash_multiplier_min, float, NONE) \
  48                 P(class, prefix, blast_splash_radius, float, NONE) \
  49                 P(class, prefix, blast_spread_max, float, NONE) \
  50                 P(class, prefix, blast_spread_min, float, NONE) \
  51                 P(class, prefix, melee_animtime, float, NONE) \
  52                 P(class, prefix, melee_damage, float, NONE) \
  53                 P(class, prefix, melee_delay, float, NONE) \
  54                 P(class, prefix, melee_force, float, NONE) \
  55                 P(class, prefix, melee_multihit, float, NONE) \
  56                 P(class, prefix, melee_no_doubleslap, float, NONE) \
  57                 P(class, prefix, melee_nonplayerdamage, float, NONE) \
  58                 P(class, prefix, melee_range, float, NONE) \
  59                 P(class, prefix, melee_refire, float, NONE) \
  60                 P(class, prefix, melee_swing_side, float, NONE) \
  61                 P(class, prefix, melee_swing_up, float, NONE) \
  62                 P(class, prefix, melee_time, float, NONE) \
  63                 P(class, prefix, melee_traces, float, NONE) \
  64                 P(class, prefix, switchdelay_raise, float, NONE) \
  65         P(class, prefix, switchdelay_drop, float, NONE) \
  66         P(class, prefix, weaponreplace, string, NONE) \
  67         P(class, prefix, weaponstart, float, NONE) \
  68         P(class, prefix, weaponstartoverride, float, NONE) \
  69         P(class, prefix, weaponthrowable, float, NONE) \
  70         END()
  71     W_PROPS(X, Shockwave, shockwave)
  72 #undef X
  73
  74 ENDCLASS(Shockwave)
  75 REGISTER_WEAPON(SHOCKWAVE, shockwave, NEW(Shockwave));
  76
  77
  78 #ifdef CSQC
  79 void Net_ReadShockwaveParticle();
  80 .vector sw_shotorg;
  81 .vector sw_shotdir;
  82 .float sw_distance;
  83 .float sw_spread_max;
  84 .float sw_spread_min;
  85 .float sw_time;
  86 #endif
  87 #endif
  88 #ifdef IMPLEMENTATION
  89
  90 REGISTER_NET_TEMP(TE_CSQC_SHOCKWAVEPARTICLE)
  91
  92 #ifdef SVQC
  93 spawnfunc(weapon_shockwave)
  94 {
  95         //if(autocvar_sv_q3acompat_machineshockwaveswap) // WEAPONTODO
  96         if(autocvar_sv_q3acompat_machineshotgunswap)
  97         if(this.classname != "droppedweapon")
  98         {
  99                 weapon_defaultspawnfunc(this, WEP_MACHINEGUN);
 100                 return;
 101         }
 102         weapon_defaultspawnfunc(this, WEP_SHOCKWAVE);
 103 }
 104
 105 const float MAX_SHOCKWAVE_HITS = 10;
 106 //#define DEBUG_SHOCKWAVE
 107
 108 .float swing_prev;
 109 .entity swing_alreadyhit;
 110 .float shockwave_blasttime;
 111 entity shockwave_hit[MAX_SHOCKWAVE_HITS];
 112 float shockwave_hit_damage[MAX_SHOCKWAVE_HITS];
 113 vector shockwave_hit_force[MAX_SHOCKWAVE_HITS];
 114
 115 // MELEE ATTACK MODE
 116 void W_Shockwave_Melee_Think(entity this)
 117 {
 118         // declarations
 119         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
 120         entity target_victim;
 121         vector targpos;
 122
 123         // check to see if we can still continue, otherwise give up now
 124         if(IS_DEAD(this.realowner) && WEP_CVAR(shockwave, melee_no_doubleslap))
 125         {
 126                 delete(this);
 127                 return;
 128         }
 129
 130         // set start time of melee
 131         if(!this.cnt)
 132         {
 133                 this.cnt = time;
 134                 W_PlayStrengthSound(this.realowner);
 135         }
 136
 137         // update values for v_* vectors
 138         makevectors(this.realowner.v_angle);
 139
 140         // calculate swing percentage based on time
 141         meleetime = WEP_CVAR(shockwave, melee_time) * W_WeaponRateFactor(this.realowner);
 142         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
 143         f = ((1 - swing) * WEP_CVAR(shockwave, melee_traces));
 144
 145         // perform the traces needed for this frame
 146         for(i=this.swing_prev; i < f; ++i)
 147         {
 148                 swing_factor = ((1 - (i / WEP_CVAR(shockwave, melee_traces))) * 2 - 1);
 149
 150                 targpos = (this.realowner.origin + this.realowner.view_ofs
 151                         + (v_forward * WEP_CVAR(shockwave, melee_range))
 152                         + (v_up * swing_factor * WEP_CVAR(shockwave, melee_swing_up))
 153                         + (v_right * swing_factor * WEP_CVAR(shockwave, melee_swing_side)));
 154
 155                 WarpZone_traceline_antilag(
 156                         this.realowner,
 157                         (this.realowner.origin + this.realowner.view_ofs),
 158                         targpos,
 159                         false,
 160                         this.realowner,
 161                         ANTILAG_LATENCY(this.realowner)
 162                 );
 163
 164                 // draw lightning beams for debugging
 165 #ifdef DEBUG_SHOCKWAVE
 166                 te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
 167                 te_customflash(targpos, 40,  2, '1 1 1');
 168 #endif
 169
 170                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
 171
 172                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this if necessary
 173                         && (trace_ent.takedamage == DAMAGE_AIM)
 174                         && (trace_ent != this.swing_alreadyhit)
 175                         && (is_player || WEP_CVAR(shockwave, melee_nonplayerdamage)))
 176                 {
 177                         target_victim = trace_ent; // so it persists through other calls
 178
 179                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught
 180                                 swing_damage = (WEP_CVAR(shockwave, melee_damage) * min(1, swing_factor + 1));
 181                         else
 182                                 swing_damage = (WEP_CVAR(shockwave, melee_nonplayerdamage) * min(1, swing_factor + 1));
 183
 184                         // trigger damage with this calculated info
 185                         Damage(
 186                                 target_victim,
 187                                 this.realowner,
 188                                 this.realowner,
 189                                 swing_damage,
 190                                 (WEP_SHOCKWAVE.m_id | HITTYPE_SECONDARY),
 191                                 (this.realowner.origin + this.realowner.view_ofs),
 192                                 (v_forward * WEP_CVAR(shockwave, melee_force))
 193                         );
 194
 195                         // handle accuracy
 196                         if(accuracy_isgooddamage(this.realowner, target_victim))
 197                                 { accuracy_add(this.realowner, WEP_SHOCKWAVE.m_id, 0, swing_damage); }
 198
 199                         #ifdef DEBUG_SHOCKWAVE
 200                         LOG_INFO(sprintf(
 201                                 "MELEE: %s hitting %s with %f damage (factor: %f) at %f time.\n",
 202                                 this.realowner.netname,
 203                                 target_victim.netname,
 204                                 swing_damage,
 205                                 swing_factor,
 206                                 time
 207                         ));
 208                         #endif
 209
 210                         // allow multiple hits with one swing, but not against the same player twice
 211                         if(WEP_CVAR(shockwave, melee_multihit))
 212                         {
 213                                 this.swing_alreadyhit = target_victim;
 214                                 continue; // move along to next trace
 215                         }
 216                         else
 217                         {
 218                                 delete(this);
 219                                 return;
 220                         }
 221                 }
 222         }
 223
 224         if(time >= this.cnt + meleetime)
 225         {
 226                 // melee is finished
 227                 delete(this);
 228                 return;
 229         }
 230         else
 231         {
 232                 // set up next frame
 233                 this.swing_prev = i;
 234                 this.nextthink = time;
 235         }
 236 }
 237
 238 void W_Shockwave_Melee(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 239 {
 240         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTN_NORM);
 241         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(shockwave, melee_animtime), w_ready);
 242
 243         entity meleetemp = new_pure(meleetemp);
 244         meleetemp.owner = meleetemp.realowner = actor;
 245         setthink(meleetemp, W_Shockwave_Melee_Think);
 246         meleetemp.nextthink = time + WEP_CVAR(shockwave, melee_delay) * W_WeaponRateFactor(actor);
 247         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR(shockwave, melee_damage), WEP_CVAR(shockwave, melee_range));
 248 }
 249
 250 // SHOCKWAVE ATTACK MODE
 251 float W_Shockwave_Attack_CheckSpread(
 252         vector targetorg,
 253         vector nearest_on_line,
 254         vector sw_shotorg,
 255         vector attack_endpos)
 256 {
 257         float spreadlimit;
 258         float distance_of_attack = vlen(sw_shotorg - attack_endpos);
 259         float distance_from_line = vlen(targetorg - nearest_on_line);
 260
 261         spreadlimit = (distance_of_attack ? min(1, (vlen(sw_shotorg - nearest_on_line) / distance_of_attack)) : 1);
 262         spreadlimit =
 263                 (
 264                         (WEP_CVAR(shockwave, blast_spread_min) * (1 - spreadlimit))
 265                         +
 266                         (WEP_CVAR(shockwave, blast_spread_max) * spreadlimit)
 267                 );
 268
 269         if(
 270                 (spreadlimit && (distance_from_line <= spreadlimit))
 271                 &&
 272                 ((vlen(normalize(targetorg - sw_shotorg) - normalize(attack_endpos - sw_shotorg)) * RAD2DEG) <= 90)
 273         )
 274                 { return bound(0, (distance_from_line / spreadlimit), 1); }
 275         else
 276                 { return false; }
 277 }
 278
 279 float W_Shockwave_Attack_IsVisible(
 280         entity actor,
 281         entity head,
 282         vector nearest_on_line,
 283         vector sw_shotorg,
 284         vector attack_endpos)
 285 {
 286         vector nearest_to_attacker = head.WarpZone_findradius_nearest;
 287         vector center = (head.origin + (head.mins + head.maxs) * 0.5);
 288         vector corner;
 289         float i;
 290
 291         // STEP ONE: Check if the nearest point is clear
 292         if(W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, sw_shotorg, attack_endpos))
 293         {
 294                 WarpZone_TraceLine(sw_shotorg, nearest_to_attacker, MOVE_NOMONSTERS, actor);
 295                 if(trace_fraction == 1) { return true; } // yes, the nearest point is clear and we can allow the damage
 296         }
 297
 298         // STEP TWO: Check if shotorg to center point is clear
 299         if(W_Shockwave_Attack_CheckSpread(center, nearest_on_line, sw_shotorg, attack_endpos))
 300         {
 301                 WarpZone_TraceLine(sw_shotorg, center, MOVE_NOMONSTERS, actor);
 302                 if(trace_fraction == 1) { return true; } // yes, the center point is clear and we can allow the damage
 303         }
 304
 305         // STEP THREE: Check each corner to see if they are clear
 306         for(i=1; i<=8; ++i)
 307         {
 308                 corner = get_corner_position(head, i);
 309                 if(W_Shockwave_Attack_CheckSpread(corner, nearest_on_line, sw_shotorg, attack_endpos))
 310                 {
 311                         WarpZone_TraceLine(sw_shotorg, corner, MOVE_NOMONSTERS, actor);
 312                         if(trace_fraction == 1) { return true; } // yes, this corner is clear and we can allow the damage
 313                 }
 314         }
 315
 316         return false;
 317 }
 318
 319 float W_Shockwave_Attack_CheckHit(
 320         float queue,
 321         entity head,
 322         vector final_force,
 323         float final_damage)
 324 {
 325         if(!head) { return false; }
 326         float i;
 327
 328         for(i = 0; i <= queue; ++i)
 329         {
 330                 if(shockwave_hit[i] == head)
 331                 {
 332                         if(vlen2(final_force) > vlen2(shockwave_hit_force[i])) { shockwave_hit_force[i] = final_force; }
 333                         if(final_damage > shockwave_hit_damage[i]) { shockwave_hit_damage[i] = final_damage; }
 334                         return false;
 335                 }
 336         }
 337
 338         shockwave_hit[queue] = head;
 339         shockwave_hit_force[queue] = final_force;
 340         shockwave_hit_damage[queue] = final_damage;
 341         return true;
 342 }
 343
 344 void W_Shockwave_Send(entity actor)
 345 {
 346         WriteHeader(MSG_BROADCAST, TE_CSQC_SHOCKWAVEPARTICLE);
 347         WriteCoord(MSG_BROADCAST, w_shotorg.x);
 348         WriteCoord(MSG_BROADCAST, w_shotorg.y);
 349         WriteCoord(MSG_BROADCAST, w_shotorg.z);
 350         WriteCoord(MSG_BROADCAST, w_shotdir.x);
 351         WriteCoord(MSG_BROADCAST, w_shotdir.y);
 352         WriteCoord(MSG_BROADCAST, w_shotdir.z);
 353         WriteShort(MSG_BROADCAST, WEP_CVAR(shockwave, blast_distance));
 354         WriteByte(MSG_BROADCAST, bound(0, WEP_CVAR(shockwave, blast_spread_max), 255));
 355         WriteByte(MSG_BROADCAST, bound(0, WEP_CVAR(shockwave, blast_spread_min), 255));
 356         WriteByte(MSG_BROADCAST, etof(actor));
 357 }
 358
 359 void W_Shockwave_Attack(entity actor, .entity weaponentity)
 360 {
 361         // declarations
 362         float multiplier, multiplier_from_accuracy, multiplier_from_distance;
 363         float final_damage;
 364         vector final_force, center, vel;
 365         entity head;
 366
 367         float i, queue = 0;
 368
 369         // set up the shot direction
 370         W_SetupShot(actor, weaponentity, true, 3, SND_LASERGUN_FIRE, CH_WEAPON_B, WEP_CVAR(shockwave, blast_damage));
 371         vector attack_endpos = (w_shotorg + (w_shotdir * WEP_CVAR(shockwave, blast_distance)));
 372         WarpZone_TraceLine(w_shotorg, attack_endpos, MOVE_NOMONSTERS, actor);
 373         vector attack_hitpos = trace_endpos;
 374         float distance_to_end = vlen(w_shotorg - attack_endpos);
 375         float distance_to_hit = vlen(w_shotorg - attack_hitpos);
 376         //entity transform = WarpZone_trace_transform;
 377
 378         // do the firing effect now
 379         W_Shockwave_Send(actor);
 380         Damage_DamageInfo(
 381                 attack_hitpos,
 382                 WEP_CVAR(shockwave, blast_splash_damage),
 383                 WEP_CVAR(shockwave, blast_splash_edgedamage),
 384                 WEP_CVAR(shockwave, blast_splash_radius),
 385                 w_shotdir * WEP_CVAR(shockwave, blast_splash_force),
 386                 WEP_SHOCKWAVE.m_id,
 387                 0,
 388                 actor
 389         );
 390
 391         // splash damage/jumping trace
 392         head = WarpZone_FindRadius(
 393                 attack_hitpos,
 394                 max(
 395                         WEP_CVAR(shockwave, blast_splash_radius),
 396                         WEP_CVAR(shockwave, blast_jump_radius)
 397                 ),
 398                 false
 399         );
 400
 401         float lag = ((IS_REAL_CLIENT(actor)) ? ANTILAG_LATENCY(actor) : 0);
 402         bool noantilag = ((IS_CLIENT(actor)) ? CS(actor).cvar_cl_noantilag : false);
 403         if(lag < 0.001)
 404                 lag = 0;
 405         if(autocvar_g_antilag == 0 || noantilag)
 406                 lag = 0; // only do hitscan, but no antilag
 407         if(lag)
 408         {
 409                 FOREACH_CLIENT(IS_PLAYER(it) && it != actor, antilag_takeback(it, CS(it), time - lag));
 410                 IL_EACH(g_monsters, it != actor,
 411                 {
 412                         antilag_takeback(it, it, time - lag);
 413                 });
 414         }
 415
 416         while(head)
 417         {
 418                 if(head.takedamage)
 419                 {
 420                         float distance_to_head = vlen(attack_hitpos - head.WarpZone_findradius_nearest);
 421
 422                         if((head == actor) && (distance_to_head <= WEP_CVAR(shockwave, blast_jump_radius)))
 423                         {
 424                                 // ========================
 425                                 //  BLAST JUMP CALCULATION
 426                                 // ========================
 427
 428                                 // calculate importance of distance and accuracy for this attack
 429                                 multiplier_from_accuracy = (1 -
 430                                         (distance_to_head ?
 431                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_jump_radius)))
 432                                                 :
 433                                                 0
 434                                         )
 435                                 );
 436                                 multiplier_from_distance = (1 -
 437                                         (distance_to_hit ?
 438                                                 min(1, (distance_to_hit / distance_to_end))
 439                                                 :
 440                                                 0
 441                                         )
 442                                 );
 443                                 multiplier =
 444                                         max(
 445                                                 WEP_CVAR(shockwave, blast_jump_multiplier_min),
 446                                                 (
 447                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_jump_multiplier_accuracy))
 448                                                         +
 449                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_jump_multiplier_distance))
 450                                                 )
 451                                         );
 452
 453                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 454                                 final_damage =
 455                                         (
 456                                                 (WEP_CVAR(shockwave, blast_jump_damage) * multiplier)
 457                                                 +
 458                                                 (WEP_CVAR(shockwave, blast_jump_edgedamage) * (1 - multiplier))
 459                                         );
 460
 461                                 // figure out the direction of force
 462                                 vel = normalize(vec2(head.velocity));
 463                                 vel *=
 464                                         (
 465                                                 bound(0, (vlen(vel) / autocvar_sv_maxspeed), 1)
 466                                                 *
 467                                                 WEP_CVAR(shockwave, blast_jump_force_velocitybias)
 468                                         );
 469                                 final_force = normalize((CENTER_OR_VIEWOFS(head) - attack_hitpos) + vel);
 470
 471                                 // now multiply the direction by force units
 472                                 final_force *= (WEP_CVAR(shockwave, blast_jump_force) * multiplier);
 473                                 final_force.z *= WEP_CVAR(shockwave, blast_jump_force_zscale);
 474
 475                                 // trigger damage with this calculated info
 476                                 Damage(
 477                                         head,
 478                                         actor,
 479                                         actor,
 480                                         final_damage,
 481                                         WEP_SHOCKWAVE.m_id,
 482                                         head.origin,
 483                                         final_force
 484                                 );
 485
 486                                 #ifdef DEBUG_SHOCKWAVE
 487                                 LOG_INFO(sprintf(
 488                                         "SELF HIT: multiplier = %f, damage = %f, force = %f... "
 489                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 490                                         multiplier,
 491                                         final_damage,
 492                                         vlen(final_force),
 493                                         multiplier_from_accuracy,
 494                                         multiplier_from_distance
 495                                 ));
 496                                 #endif
 497                         }
 498                         else if(distance_to_head <= WEP_CVAR(shockwave, blast_splash_radius))
 499                         {
 500                                 // ==========================
 501                                 //  BLAST SPLASH CALCULATION
 502                                 // ==========================
 503
 504                                 // calculate importance of distance and accuracy for this attack
 505                                 multiplier_from_accuracy = (1 -
 506                                         (distance_to_head ?
 507                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_splash_radius)))
 508                                                 :
 509                                                 0
 510                                         )
 511                                 );
 512                                 multiplier_from_distance = (1 -
 513                                         (distance_to_hit ?
 514                                                 min(1, (distance_to_hit / distance_to_end))
 515                                                 :
 516                                                 0
 517                                         )
 518                                 );
 519                                 multiplier =
 520                                         max(
 521                                                 WEP_CVAR(shockwave, blast_splash_multiplier_min),
 522                                                 (
 523                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_splash_multiplier_accuracy))
 524                                                         +
 525                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_splash_multiplier_distance))
 526                                                 )
 527                                         );
 528
 529                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 530                                 final_damage =
 531                                         (
 532                                                 (WEP_CVAR(shockwave, blast_splash_damage) * multiplier)
 533                                                 +
 534                                                 (WEP_CVAR(shockwave, blast_splash_edgedamage) * (1 - multiplier))
 535                                         );
 536
 537                                 // figure out the direction of force
 538                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_splash_force_forwardbias));
 539                                 final_force = normalize(CENTER_OR_VIEWOFS(head) - (attack_hitpos - final_force));
 540                                 //te_lightning2(NULL, attack_hitpos, (attack_hitpos + (final_force * 200)));
 541
 542                                 // now multiply the direction by force units
 543                                 final_force *= (WEP_CVAR(shockwave, blast_splash_force) * multiplier);
 544                                 final_force.z *= WEP_CVAR(shockwave, blast_force_zscale);
 545
 546                                 // queue damage with this calculated info
 547                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { queue = min(queue + 1, MAX_SHOCKWAVE_HITS); }
 548
 549                                 #ifdef DEBUG_SHOCKWAVE
 550                                 LOG_INFO(sprintf(
 551                                         "SPLASH HIT: multiplier = %f, damage = %f, force = %f... "
 552                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 553                                         multiplier,
 554                                         final_damage,
 555                                         vlen(final_force),
 556                                         multiplier_from_accuracy,
 557                                         multiplier_from_distance
 558                                 ));
 559                                 #endif
 560                         }
 561                 }
 562                 head = head.chain;
 563         }
 564
 565         // cone damage trace
 566         head = WarpZone_FindRadius(w_shotorg, WEP_CVAR(shockwave, blast_distance), false);
 567         while(head)
 568         {
 569                 if((head != actor) && head.takedamage)
 570                 {
 571                         // ========================
 572                         //  BLAST CONE CALCULATION
 573                         // ========================
 574
 575                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 576                         center = CENTER_OR_VIEWOFS(head);
 577
 578                         // find the closest point on the enemy to the center of the attack
 579                         float h; // hypotenuse, which is the distance between attacker to head
 580                         float a; // adjacent side, which is the distance between attacker and the point on w_shotdir that is closest to head.origin
 581
 582                         h = vlen(center - actor.origin);
 583                         a = h * (normalize(center - actor.origin) * w_shotdir);
 584                         // WEAPONTODO: replace with simpler method
 585
 586                         vector nearest_on_line = (w_shotorg + a * w_shotdir);
 587                         vector nearest_to_attacker = WarpZoneLib_NearestPointOnBox(center + head.mins, center + head.maxs, nearest_on_line);
 588
 589                         if((vdist(head.WarpZone_findradius_dist, <=, WEP_CVAR(shockwave, blast_distance)))
 590                                 && (W_Shockwave_Attack_IsVisible(actor, head, nearest_on_line, w_shotorg, attack_endpos)))
 591                         {
 592                                 // calculate importance of distance and accuracy for this attack
 593                                 multiplier_from_accuracy = (1 -
 594                                         W_Shockwave_Attack_CheckSpread(
 595                                                 nearest_to_attacker,
 596                                                 nearest_on_line,
 597                                                 w_shotorg,
 598                                                 attack_endpos
 599                                         )
 600                                 );
 601                                 multiplier_from_distance = (1 -
 602                                         (distance_to_hit ?
 603                                                 min(1, (vlen(head.WarpZone_findradius_dist) / distance_to_end))
 604                                                 :
 605                                                 0
 606                                         )
 607                                 );
 608                                 multiplier =
 609                                         max(
 610                                                 WEP_CVAR(shockwave, blast_multiplier_min),
 611                                                 (
 612                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_multiplier_accuracy))
 613                                                         +
 614                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_multiplier_distance))
 615                                                 )
 616                                         );
 617
 618                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
 619                                 final_damage =
 620                                         (
 621                                                 (WEP_CVAR(shockwave, blast_damage) * multiplier)
 622                                                 +
 623                                                 (WEP_CVAR(shockwave, blast_edgedamage) * (1 - multiplier))
 624                                         );
 625
 626                                 // figure out the direction of force
 627                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_force_forwardbias));
 628                                 final_force = normalize(center - (nearest_on_line - final_force));
 629                                 //te_lightning2(NULL, nearest_on_line, (attack_hitpos + (final_force * 200)));
 630
 631                                 // now multiply the direction by force units
 632                                 final_force *= (WEP_CVAR(shockwave, blast_force) * multiplier);
 633                                 final_force.z *= WEP_CVAR(shockwave, blast_force_zscale);
 634
 635                                 // queue damage with this calculated info
 636                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { queue = min(queue + 1, MAX_SHOCKWAVE_HITS); }
 637
 638                                 #ifdef DEBUG_SHOCKWAVE
 639                                 LOG_INFO(sprintf(
 640                                         "BLAST HIT: multiplier = %f, damage = %f, force = %f... "
 641                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
 642                                         multiplier,
 643                                         final_damage,
 644                                         vlen(final_force),
 645                                         multiplier_from_accuracy,
 646                                         multiplier_from_distance
 647                                 ));
 648                                 #endif
 649                         }
 650                 }
 651                 head = head.chain;
 652         }
 653
 654         for(i = 1; i <= queue; ++i)
 655         {
 656                 head = shockwave_hit[i-1];
 657                 final_force = shockwave_hit_force[i-1];
 658                 final_damage = shockwave_hit_damage[i-1];
 659
 660                 Damage(
 661                         head,
 662                         actor,
 663                         actor,
 664                         final_damage,
 665                         WEP_SHOCKWAVE.m_id,
 666                         head.origin,
 667                         final_force
 668                 );
 669
 670                 if(accuracy_isgooddamage(actor, head))
 671                         accuracy_add(actor, WEP_SHOCKWAVE.m_id, 0, final_damage);
 672
 673                 #ifdef DEBUG_SHOCKWAVE
 674                 LOG_INFO(sprintf(
 675                         "SHOCKWAVE by %s: damage = %f, force = %f.\n",
 676                         actor.netname,
 677                         final_damage,
 678                         vlen(final_force)
 679                 ));
 680                 #endif
 681
 682                 shockwave_hit[i-1] = NULL;
 683                 shockwave_hit_force[i-1] = '0 0 0';
 684                 shockwave_hit_damage[i-1] = 0;
 685         }
 686
 687         if(lag)
 688         {
 689                 FOREACH_CLIENT(IS_PLAYER(it) && it != actor, antilag_restore(it, CS(it)));
 690                 IL_EACH(g_monsters, it != actor,
 691                 {
 692                         antilag_restore(it, it);
 693                 });
 694         }
 695 }
 696
 697 METHOD(Shockwave, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 698 {
 699     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR(shockwave, melee_range)))
 700         { PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false); }
 701     else
 702         { PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false); }
 703 }
 704 METHOD(Shockwave, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 705 {
 706     if(fire & 1)
 707     {
 708         if(time >= actor.(weaponentity).shockwave_blasttime) // handle refire separately so the secondary can be fired straight after a primary
 709         {
 710             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(shockwave, blast_animtime)))
 711             {
 712                 W_Shockwave_Attack(actor, weaponentity);
 713                 actor.(weaponentity).shockwave_blasttime = time + WEP_CVAR(shockwave, blast_refire) * W_WeaponRateFactor(actor);
 714                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(shockwave, blast_animtime), w_ready);
 715             }
 716         }
 717     }
 718     else if(fire & 2)
 719     {
 720         //if(actor.clip_load >= 0) // we are not currently reloading
 721         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR(shockwave, melee_refire)))
 722         {
 723             // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 724             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shockwave_Melee);
 725         }
 726     }
 727 }
 728 METHOD(Shockwave, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 729 {
 730     return true; // infinite ammo
 731 }
 732 METHOD(Shockwave, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 733 {
 734     // shockwave has infinite ammo
 735     return true;
 736 }
 737 METHOD(Shockwave, wr_suicidemessage, Notification(entity thiswep))
 738 {
 739     return WEAPON_THINKING_WITH_PORTALS;
 740 }
 741 METHOD(Shockwave, wr_killmessage, Notification(entity thiswep))
 742 {
 743     if(w_deathtype & HITTYPE_SECONDARY)
 744         return WEAPON_SHOCKWAVE_MURDER_SLAP;
 745     else
 746         return WEAPON_SHOCKWAVE_MURDER;
 747 }
 748
 749 #endif
 750 #ifdef CSQC
 751 // WEAPONTODO: add client side settings for these
 752 const float SW_MAXALPHA = 0.5;
 753 const float SW_FADETIME = 0.4;
 754 const float SW_DISTTOMIN = 200;
 755 void Draw_Shockwave(entity this)
 756 {
 757         // fading/removal control
 758         float a = bound(0, (SW_MAXALPHA - ((time - this.sw_time) / SW_FADETIME)), SW_MAXALPHA);
 759         if(a < ALPHA_MIN_VISIBLE) { delete(this); }
 760
 761         // WEAPONTODO: save this only once when creating the entity
 762         vector sw_color = entcs_GetColor(this.sv_entnum - 1); // GetTeamRGB(entcs_GetTeam(this.sv_entnum));
 763
 764         // WEAPONTODO: trace to find what we actually hit
 765         vector endpos = (this.sw_shotorg + (this.sw_shotdir * this.sw_distance));
 766
 767         vectorvectors(this.sw_shotdir);
 768         vector right = v_right; // save this for when we do makevectors later
 769         vector up = v_up; // save this for when we do makevectors later
 770
 771         // WEAPONTODO: combine and simplify these calculations
 772         vector min_end = ((this.sw_shotorg + (this.sw_shotdir * SW_DISTTOMIN)) + (up * this.sw_spread_min));
 773         vector max_end = (endpos + (up * this.sw_spread_max));
 774         float spread_to_min = vlen(normalize(min_end - this.sw_shotorg) - this.sw_shotdir);
 775         float spread_to_max = vlen(normalize(max_end - min_end) - this.sw_shotdir);
 776
 777         vector first_min_end = '0 0 0', prev_min_end = '0 0 0', new_min_end = '0 0 0';
 778         vector first_max_end = '0 0 0', prev_max_end = '0 0 0', new_max_end = '0 0 0';
 779         float new_max_dist, new_min_dist;
 780
 781         vector deviation, angle = '0 0 0';
 782         float counter, divisions = 20;
 783         for(counter = 0; counter < divisions; ++counter)
 784         {
 785                 // perfect circle effect lines
 786                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / divisions));
 787                 angle.y = v_forward.x;
 788                 angle.z = v_forward.y;
 789
 790                 // first do the spread_to_min effect
 791                 deviation = angle * spread_to_min;
 792                 deviation = ((this.sw_shotdir + (right * deviation.y) + (up * deviation.z)));
 793                 new_min_dist = SW_DISTTOMIN;
 794                 new_min_end = (this.sw_shotorg + (deviation * new_min_dist));
 795                 //te_lightning2(NULL, new_min_end, this.sw_shotorg);
 796
 797                 // then calculate spread_to_max effect
 798                 deviation = angle * spread_to_max;
 799                 deviation = ((this.sw_shotdir + (right * deviation.y) + (up * deviation.z)));
 800                 new_max_dist = vlen(new_min_end - endpos);
 801                 new_max_end = (new_min_end + (deviation * new_max_dist));
 802                 //te_lightning2(NULL, new_end, prev_min_end);
 803
 804
 805                 if(counter == 0)
 806                 {
 807                         first_min_end = new_min_end;
 808                         first_max_end = new_max_end;
 809                 }
 810
 811                 if(counter >= 1)
 812                 {
 813                         // draw from shot origin to min spread radius
 814                         R_BeginPolygon("", DRAWFLAG_NORMAL);
 815                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
 816                         R_PolygonVertex(new_min_end, '0 0 0', sw_color, a);
 817                         R_PolygonVertex(this.sw_shotorg, '0 0 0', sw_color, a);
 818                         R_EndPolygon();
 819
 820                         // draw from min spread radius to max spread radius
 821                         R_BeginPolygon("", DRAWFLAG_NORMAL);
 822                         R_PolygonVertex(new_min_end, '0 0 0', sw_color, a);
 823                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
 824                         R_PolygonVertex(prev_max_end, '0 0 0', sw_color, a);
 825                         R_PolygonVertex(new_max_end, '0 0 0', sw_color, a);
 826                         R_EndPolygon();
 827                 }
 828
 829                 prev_min_end = new_min_end;
 830                 prev_max_end = new_max_end;
 831
 832                 // last division only
 833                 if((counter + 1) == divisions)
 834                 {
 835                         // draw from shot origin to min spread radius
 836                         R_BeginPolygon("", DRAWFLAG_NORMAL);
 837                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
 838                         R_PolygonVertex(first_min_end, '0 0 0', sw_color, a);
 839                         R_PolygonVertex(this.sw_shotorg, '0 0 0', sw_color, a);
 840                         R_EndPolygon();
 841
 842                         // draw from min spread radius to max spread radius
 843                         R_BeginPolygon("", DRAWFLAG_NORMAL);
 844                         R_PolygonVertex(first_min_end, '0 0 0', sw_color, a);
 845                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
 846                         R_PolygonVertex(prev_max_end, '0 0 0', sw_color, a);
 847                         R_PolygonVertex(first_max_end, '0 0 0', sw_color, a);
 848                         R_EndPolygon();
 849                 }
 850         }
 851 }
 852
 853 NET_HANDLE(TE_CSQC_SHOCKWAVEPARTICLE, bool isNew)
 854 {
 855         Net_ReadShockwaveParticle();
 856         return true;
 857 }
 858
 859 void Net_ReadShockwaveParticle()
 860 {
 861         entity shockwave;
 862         shockwave = spawn();
 863         shockwave.draw = Draw_Shockwave;
 864         IL_PUSH(g_drawables, shockwave);
 865
 866         shockwave.sw_shotorg_x = ReadCoord(); shockwave.sw_shotorg_y = ReadCoord(); shockwave.sw_shotorg_z = ReadCoord();
 867         shockwave.sw_shotdir_x = ReadCoord(); shockwave.sw_shotdir_y = ReadCoord(); shockwave.sw_shotdir_z = ReadCoord();
 868
 869         shockwave.sw_distance = ReadShort();
 870         shockwave.sw_spread_max = ReadByte();
 871         shockwave.sw_spread_min = ReadByte();
 872
 873         shockwave.sv_entnum = ReadByte();
 874
 875         shockwave.sw_time = time;
 876 }
 877
 878 METHOD(Shockwave, wr_impacteffect, void(entity thiswep, entity actor))
 879 {
 880     // handled by Net_ReadShockwaveParticle
 881     //vector org2;
 882     //org2 = w_org + w_backoff * 2;
 883     //pointparticles(EFFECT_BLASTER_IMPACT, org2, w_backoff * 1000, 1);
 884 }
 885
 886 #endif
 887 #endif