Transifex autosync
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / shockwave.qc
1 #include "shockwave.qh"
2
3 REGISTER_NET_TEMP(TE_CSQC_SHOCKWAVEPARTICLE)
4
5 #ifdef SVQC
6 METHOD(Shockwave, m_spawnfunc_hookreplace, Weapon(Shockwave this, entity e))
7 {
8         //if(autocvar_sv_q3acompat_machineshockwaveswap) // WEAPONTODO
9         if (autocvar_sv_q3acompat_machineshotgunswap && !Item_IsLoot(e))
10         {
11                 return WEP_MACHINEGUN;
12         }
13         return this;
14 }
15
16 const float MAX_SHOCKWAVE_HITS = 10;
17 //#define DEBUG_SHOCKWAVE
18
19 .float swing_prev;
20 .entity swing_alreadyhit;
21 .float shockwave_blasttime;
22 entity shockwave_hit[MAX_SHOCKWAVE_HITS];
23 float shockwave_hit_damage[MAX_SHOCKWAVE_HITS];
24 vector shockwave_hit_force[MAX_SHOCKWAVE_HITS];
25
26 // MELEE ATTACK MODE
27 void W_Shockwave_Melee_Think(entity this)
28 {
29         // declarations
30         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
31         entity target_victim;
32         vector targpos;
33
34         // check to see if we can still continue, otherwise give up now
35         if(IS_DEAD(this.realowner) && WEP_CVAR(shockwave, melee_no_doubleslap))
36         {
37                 delete(this);
38                 return;
39         }
40
41         // set start time of melee
42         if(!this.cnt)
43         {
44                 this.cnt = time;
45                 W_PlayStrengthSound(this.realowner);
46         }
47
48         // update values for v_* vectors
49         makevectors(this.realowner.v_angle);
50
51         // calculate swing percentage based on time
52         meleetime = WEP_CVAR(shockwave, melee_time) * W_WeaponRateFactor(this.realowner);
53         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
54         f = ((1 - swing) * WEP_CVAR(shockwave, melee_traces));
55
56         // perform the traces needed for this frame
57         for(i=this.swing_prev; i < f; ++i)
58         {
59                 swing_factor = ((1 - (i / WEP_CVAR(shockwave, melee_traces))) * 2 - 1);
60
61                 targpos = (this.realowner.origin + this.realowner.view_ofs
62                         + (v_forward * WEP_CVAR(shockwave, melee_range))
63                         + (v_up * swing_factor * WEP_CVAR(shockwave, melee_swing_up))
64                         + (v_right * swing_factor * WEP_CVAR(shockwave, melee_swing_side)));
65
66                 WarpZone_traceline_antilag(
67                         this.realowner,
68                         (this.realowner.origin + this.realowner.view_ofs),
69                         targpos,
70                         false,
71                         this.realowner,
72                         ANTILAG_LATENCY(this.realowner)
73                 );
74
75                 // draw lightning beams for debugging
76 #ifdef DEBUG_SHOCKWAVE
77                 te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
78                 te_customflash(targpos, 40,  2, '1 1 1');
79 #endif
80
81                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
82
83                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this if necessary
84                         && (trace_ent.takedamage == DAMAGE_AIM)
85                         && (trace_ent != this.swing_alreadyhit)
86                         && (is_player || WEP_CVAR(shockwave, melee_nonplayerdamage)))
87                 {
88                         target_victim = trace_ent; // so it persists through other calls
89
90                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught
91                                 swing_damage = (WEP_CVAR(shockwave, melee_damage) * min(1, swing_factor + 1));
92                         else
93                                 swing_damage = (WEP_CVAR(shockwave, melee_nonplayerdamage) * min(1, swing_factor + 1));
94
95                         // trigger damage with this calculated info
96                         Damage(
97                                 target_victim,
98                                 this.realowner,
99                                 this.realowner,
100                                 swing_damage,
101                                 (WEP_SHOCKWAVE.m_id | HITTYPE_SECONDARY),
102                                 this.weaponentity_fld,
103                                 (this.realowner.origin + this.realowner.view_ofs),
104                                 (v_forward * WEP_CVAR(shockwave, melee_force))
105                         );
106
107                         // handle accuracy
108                         if(accuracy_isgooddamage(this.realowner, target_victim))
109                                 { accuracy_add(this.realowner, WEP_SHOCKWAVE, 0, swing_damage); }
110
111                         #ifdef DEBUG_SHOCKWAVE
112                         LOG_INFOF(
113                                 "MELEE: %s hitting %s with %f damage (factor: %f) at %f time.",
114                                 this.realowner.netname,
115                                 target_victim.netname,
116                                 swing_damage,
117                                 swing_factor,
118                                 time
119                         );
120                         #endif
121
122                         // allow multiple hits with one swing, but not against the same player twice
123                         if(WEP_CVAR(shockwave, melee_multihit))
124                         {
125                                 this.swing_alreadyhit = target_victim;
126                                 continue; // move along to next trace
127                         }
128                         else
129                         {
130                                 delete(this);
131                                 return;
132                         }
133                 }
134         }
135
136         if(time >= this.cnt + meleetime)
137         {
138                 // melee is finished
139                 delete(this);
140                 return;
141         }
142         else
143         {
144                 // set up next frame
145                 this.swing_prev = i;
146                 this.nextthink = time;
147         }
148 }
149
150 void W_Shockwave_Melee(Weapon thiswep, entity actor, .entity weaponentity, int fire)
151 {
152         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTN_NORM);
153         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(shockwave, melee_animtime), w_ready);
154
155         entity meleetemp = new_pure(meleetemp);
156         meleetemp.owner = meleetemp.realowner = actor;
157         setthink(meleetemp, W_Shockwave_Melee_Think);
158         meleetemp.nextthink = time + WEP_CVAR(shockwave, melee_delay) * W_WeaponRateFactor(actor);
159         meleetemp.weaponentity_fld = weaponentity;
160         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR(shockwave, melee_damage), WEP_CVAR(shockwave, melee_range), thiswep.m_id | HITTYPE_SECONDARY);
161 }
162
163 // SHOCKWAVE ATTACK MODE
164 float W_Shockwave_Attack_CheckSpread(
165         vector targetorg,
166         vector nearest_on_line,
167         vector sw_shotorg,
168         vector attack_endpos)
169 {
170         float spreadlimit;
171         float distance_of_attack = vlen(sw_shotorg - attack_endpos);
172         float distance_from_line = vlen(targetorg - nearest_on_line);
173
174         spreadlimit = (distance_of_attack ? min(1, (vlen(sw_shotorg - nearest_on_line) / distance_of_attack)) : 1);
175         spreadlimit =
176                 (
177                         (WEP_CVAR(shockwave, blast_spread_min) * (1 - spreadlimit))
178                         +
179                         (WEP_CVAR(shockwave, blast_spread_max) * spreadlimit)
180                 );
181
182         if(
183                 (spreadlimit && (distance_from_line <= spreadlimit))
184                 &&
185                 ((vlen(normalize(targetorg - sw_shotorg) - normalize(attack_endpos - sw_shotorg)) * RAD2DEG) <= 90)
186         )
187                 { return bound(0, (distance_from_line / spreadlimit), 1); }
188         else
189                 { return false; }
190 }
191
192 float W_Shockwave_Attack_IsVisible(
193         entity actor,
194         entity head,
195         vector nearest_on_line,
196         vector sw_shotorg,
197         vector attack_endpos)
198 {
199         vector nearest_to_attacker = head.WarpZone_findradius_nearest;
200         vector center = (head.origin + (head.mins + head.maxs) * 0.5);
201         vector corner;
202         float i;
203
204         // STEP ONE: Check if the nearest point is clear
205         if(W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, sw_shotorg, attack_endpos))
206         {
207                 WarpZone_TraceLine(sw_shotorg, nearest_to_attacker, MOVE_NOMONSTERS, actor);
208                 if(trace_fraction == 1) { return true; } // yes, the nearest point is clear and we can allow the damage
209         }
210
211         // STEP TWO: Check if shotorg to center point is clear
212         if(W_Shockwave_Attack_CheckSpread(center, nearest_on_line, sw_shotorg, attack_endpos))
213         {
214                 WarpZone_TraceLine(sw_shotorg, center, MOVE_NOMONSTERS, actor);
215                 if(trace_fraction == 1) { return true; } // yes, the center point is clear and we can allow the damage
216         }
217
218         // STEP THREE: Check each corner to see if they are clear
219         for(i=1; i<=8; ++i)
220         {
221                 corner = get_corner_position(head, i);
222                 if(W_Shockwave_Attack_CheckSpread(corner, nearest_on_line, sw_shotorg, attack_endpos))
223                 {
224                         WarpZone_TraceLine(sw_shotorg, corner, MOVE_NOMONSTERS, actor);
225                         if(trace_fraction == 1) { return true; } // yes, this corner is clear and we can allow the damage
226                 }
227         }
228
229         return false;
230 }
231
232 float W_Shockwave_Attack_CheckHit(
233         float queue,
234         entity head,
235         vector final_force,
236         float final_damage)
237 {
238         if(!head) { return false; }
239         float i;
240
241         for(i = 0; i <= queue; ++i)
242         {
243                 if(shockwave_hit[i] == head)
244                 {
245                         if(vlen2(final_force) > vlen2(shockwave_hit_force[i])) { shockwave_hit_force[i] = final_force; }
246                         if(final_damage > shockwave_hit_damage[i]) { shockwave_hit_damage[i] = final_damage; }
247                         return false;
248                 }
249         }
250
251         shockwave_hit[queue] = head;
252         shockwave_hit_force[queue] = final_force;
253         shockwave_hit_damage[queue] = final_damage;
254         return true;
255 }
256
257 void W_Shockwave_Send(entity actor)
258 {
259         WriteHeader(MSG_BROADCAST, TE_CSQC_SHOCKWAVEPARTICLE);
260         WriteVector(MSG_BROADCAST, w_shotorg);
261         WriteVector(MSG_BROADCAST, w_shotdir);
262         WriteShort(MSG_BROADCAST, WEP_CVAR(shockwave, blast_distance));
263         WriteByte(MSG_BROADCAST, bound(0, WEP_CVAR(shockwave, blast_spread_max), 255));
264         WriteByte(MSG_BROADCAST, bound(0, WEP_CVAR(shockwave, blast_spread_min), 255));
265         WriteByte(MSG_BROADCAST, etof(actor));
266 }
267
268 void W_Shockwave_Attack(Weapon thiswep, entity actor, .entity weaponentity)
269 {
270         // declarations
271         float multiplier, multiplier_from_accuracy, multiplier_from_distance;
272         float final_damage;
273         vector final_force, center, vel;
274         entity head;
275
276         float i, queue = 0;
277
278         // set up the shot direction
279         W_SetupShot(actor, weaponentity, true, 3, SND_LASERGUN_FIRE, CH_WEAPON_B, WEP_CVAR(shockwave, blast_damage), thiswep.m_id);
280         vector attack_endpos = (w_shotorg + (w_shotdir * WEP_CVAR(shockwave, blast_distance)));
281         WarpZone_TraceLine(w_shotorg, attack_endpos, MOVE_NOMONSTERS, actor);
282         vector attack_hitpos = trace_endpos;
283         float distance_to_end = vlen(w_shotorg - attack_endpos);
284         float distance_to_hit = vlen(w_shotorg - attack_hitpos);
285         //entity transform = WarpZone_trace_transform;
286
287         // do the firing effect now
288         W_Shockwave_Send(actor);
289         Damage_DamageInfo(
290                 attack_hitpos,
291                 WEP_CVAR(shockwave, blast_splash_damage),
292                 WEP_CVAR(shockwave, blast_splash_edgedamage),
293                 WEP_CVAR(shockwave, blast_splash_radius),
294                 w_shotdir * WEP_CVAR(shockwave, blast_splash_force),
295                 thiswep.m_id,
296                 0,
297                 actor
298         );
299
300         // splash damage/jumping trace
301         head = WarpZone_FindRadius(
302                 attack_hitpos,
303                 max(
304                         WEP_CVAR(shockwave, blast_splash_radius),
305                         WEP_CVAR(shockwave, blast_jump_radius)
306                 ),
307                 false
308         );
309
310         float lag = ((IS_REAL_CLIENT(actor)) ? ANTILAG_LATENCY(actor) : 0);
311         bool noantilag = ((IS_CLIENT(actor)) ? CS(actor).cvar_cl_noantilag : false);
312         if(lag < 0.001)
313                 lag = 0;
314         if(autocvar_g_antilag == 0 || noantilag)
315                 lag = 0; // only do hitscan, but no antilag
316         if(lag)
317                 antilag_takeback_all(actor, lag);
318
319         while(head)
320         {
321                 if(head.takedamage)
322                 {
323                         float distance_to_head = vlen(attack_hitpos - head.WarpZone_findradius_nearest);
324
325                         if((head == actor) && (distance_to_head <= WEP_CVAR(shockwave, blast_jump_radius)))
326                         {
327                                 // ========================
328                                 //  BLAST JUMP CALCULATION
329                                 // ========================
330
331                                 // calculate importance of distance and accuracy for this attack
332                                 multiplier_from_accuracy = (1 -
333                                         (distance_to_head ?
334                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_jump_radius)))
335                                                 :
336                                                 0
337                                         )
338                                 );
339                                 multiplier_from_distance = (1 -
340                                         (distance_to_hit ?
341                                                 min(1, (distance_to_hit / distance_to_end))
342                                                 :
343                                                 0
344                                         )
345                                 );
346                                 multiplier =
347                                         max(
348                                                 WEP_CVAR(shockwave, blast_jump_multiplier_min),
349                                                 (
350                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_jump_multiplier_accuracy))
351                                                         +
352                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_jump_multiplier_distance))
353                                                 )
354                                         );
355
356                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
357                                 final_damage =
358                                         (
359                                                 (WEP_CVAR(shockwave, blast_jump_damage) * multiplier)
360                                                 +
361                                                 (WEP_CVAR(shockwave, blast_jump_edgedamage) * (1 - multiplier))
362                                         );
363
364                                 // figure out the direction of force
365                                 vel = normalize(vec2(head.velocity));
366                                 vel *=
367                                         (
368                                                 bound(0, (vlen(vel) / autocvar_sv_maxspeed), 1)
369                                                 *
370                                                 WEP_CVAR(shockwave, blast_jump_force_velocitybias)
371                                         );
372                                 final_force = normalize((CENTER_OR_VIEWOFS(head) - attack_hitpos) + vel);
373
374                                 // now multiply the direction by force units
375                                 final_force *= (WEP_CVAR(shockwave, blast_jump_force) * multiplier);
376                                 final_force.z *= WEP_CVAR(shockwave, blast_jump_force_zscale);
377
378                                 // trigger damage with this calculated info
379                                 Damage(
380                                         head,
381                                         actor,
382                                         actor,
383                                         final_damage,
384                                         thiswep.m_id,
385                                         weaponentity,
386                                         head.origin,
387                                         final_force
388                                 );
389
390                                 #ifdef DEBUG_SHOCKWAVE
391                                 LOG_INFOF(
392                                         "SELF HIT: multiplier = %f, damage = %f, force = %f... "
393                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.",
394                                         multiplier,
395                                         final_damage,
396                                         vlen(final_force),
397                                         multiplier_from_accuracy,
398                                         multiplier_from_distance
399                                 );
400                                 #endif
401                         }
402                         else if(distance_to_head <= WEP_CVAR(shockwave, blast_splash_radius))
403                         {
404                                 // ==========================
405                                 //  BLAST SPLASH CALCULATION
406                                 // ==========================
407
408                                 // calculate importance of distance and accuracy for this attack
409                                 multiplier_from_accuracy = (1 -
410                                         (distance_to_head ?
411                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_splash_radius)))
412                                                 :
413                                                 0
414                                         )
415                                 );
416                                 multiplier_from_distance = (1 -
417                                         (distance_to_hit ?
418                                                 min(1, (distance_to_hit / distance_to_end))
419                                                 :
420                                                 0
421                                         )
422                                 );
423                                 multiplier =
424                                         max(
425                                                 WEP_CVAR(shockwave, blast_splash_multiplier_min),
426                                                 (
427                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_splash_multiplier_accuracy))
428                                                         +
429                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_splash_multiplier_distance))
430                                                 )
431                                         );
432
433                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
434                                 final_damage =
435                                         (
436                                                 (WEP_CVAR(shockwave, blast_splash_damage) * multiplier)
437                                                 +
438                                                 (WEP_CVAR(shockwave, blast_splash_edgedamage) * (1 - multiplier))
439                                         );
440
441                                 // figure out the direction of force
442                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_splash_force_forwardbias));
443                                 final_force = normalize(CENTER_OR_VIEWOFS(head) - (attack_hitpos - final_force));
444                                 //te_lightning2(NULL, attack_hitpos, (attack_hitpos + (final_force * 200)));
445
446                                 // now multiply the direction by force units
447                                 final_force *= (WEP_CVAR(shockwave, blast_splash_force) * multiplier);
448                                 final_force.z *= WEP_CVAR(shockwave, blast_force_zscale);
449
450                                 // queue damage with this calculated info
451                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { queue = min(queue + 1, MAX_SHOCKWAVE_HITS); }
452
453                                 #ifdef DEBUG_SHOCKWAVE
454                                 LOG_INFOF(
455                                         "SPLASH HIT: multiplier = %f, damage = %f, force = %f... "
456                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.",
457                                         multiplier,
458                                         final_damage,
459                                         vlen(final_force),
460                                         multiplier_from_accuracy,
461                                         multiplier_from_distance
462                                 );
463                                 #endif
464                         }
465                 }
466                 head = head.chain;
467         }
468
469         // cone damage trace
470         head = WarpZone_FindRadius(w_shotorg, WEP_CVAR(shockwave, blast_distance), false);
471         while(head)
472         {
473                 if((head != actor) && head.takedamage)
474                 {
475                         // ========================
476                         //  BLAST CONE CALCULATION
477                         // ========================
478
479                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
480                         center = CENTER_OR_VIEWOFS(head);
481
482                         // find the closest point on the enemy to the center of the attack
483                         float h; // hypotenuse, which is the distance between attacker to head
484                         float a; // adjacent side, which is the distance between attacker and the point on w_shotdir that is closest to head.origin
485
486                         h = vlen(center - actor.origin);
487                         a = h * (normalize(center - actor.origin) * w_shotdir);
488                         // WEAPONTODO: replace with simpler method
489
490                         vector nearest_on_line = (w_shotorg + a * w_shotdir);
491                         vector nearest_to_attacker = WarpZoneLib_NearestPointOnBox(center + head.mins, center + head.maxs, nearest_on_line);
492
493                         if((vdist(head.WarpZone_findradius_dist, <=, WEP_CVAR(shockwave, blast_distance)))
494                                 && (W_Shockwave_Attack_IsVisible(actor, head, nearest_on_line, w_shotorg, attack_endpos)))
495                         {
496                                 // calculate importance of distance and accuracy for this attack
497                                 multiplier_from_accuracy = (1 -
498                                         W_Shockwave_Attack_CheckSpread(
499                                                 nearest_to_attacker,
500                                                 nearest_on_line,
501                                                 w_shotorg,
502                                                 attack_endpos
503                                         )
504                                 );
505                                 multiplier_from_distance = (1 -
506                                         (distance_to_hit ?
507                                                 min(1, (vlen(head.WarpZone_findradius_dist) / distance_to_end))
508                                                 :
509                                                 0
510                                         )
511                                 );
512                                 multiplier =
513                                         max(
514                                                 WEP_CVAR(shockwave, blast_multiplier_min),
515                                                 (
516                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_multiplier_accuracy))
517                                                         +
518                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_multiplier_distance))
519                                                 )
520                                         );
521
522                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
523                                 final_damage =
524                                         (
525                                                 (WEP_CVAR(shockwave, blast_damage) * multiplier)
526                                                 +
527                                                 (WEP_CVAR(shockwave, blast_edgedamage) * (1 - multiplier))
528                                         );
529
530                                 // figure out the direction of force
531                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_force_forwardbias));
532                                 final_force = normalize(center - (nearest_on_line - final_force));
533                                 //te_lightning2(NULL, nearest_on_line, (attack_hitpos + (final_force * 200)));
534
535                                 // now multiply the direction by force units
536                                 final_force *= (WEP_CVAR(shockwave, blast_force) * multiplier);
537                                 final_force.z *= WEP_CVAR(shockwave, blast_force_zscale);
538
539                                 // queue damage with this calculated info
540                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { queue = min(queue + 1, MAX_SHOCKWAVE_HITS); }
541
542                                 #ifdef DEBUG_SHOCKWAVE
543                                 LOG_INFOF(
544                                         "BLAST HIT: multiplier = %f, damage = %f, force = %f... "
545                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.",
546                                         multiplier,
547                                         final_damage,
548                                         vlen(final_force),
549                                         multiplier_from_accuracy,
550                                         multiplier_from_distance
551                                 );
552                                 #endif
553                         }
554                 }
555                 head = head.chain;
556         }
557
558         for(i = 1; i <= queue; ++i)
559         {
560                 head = shockwave_hit[i-1];
561                 final_force = shockwave_hit_force[i-1];
562                 final_damage = shockwave_hit_damage[i-1];
563
564                 Damage(
565                         head,
566                         actor,
567                         actor,
568                         final_damage,
569                         thiswep.m_id,
570                         weaponentity,
571                         head.origin,
572                         final_force
573                 );
574
575                 if(accuracy_isgooddamage(actor, head))
576                         accuracy_add(actor, thiswep, 0, final_damage);
577
578                 #ifdef DEBUG_SHOCKWAVE
579                 LOG_INFOF(
580                         "SHOCKWAVE by %s: damage = %f, force = %f.",
581                         actor.netname,
582                         final_damage,
583                         vlen(final_force)
584                 );
585                 #endif
586
587                 shockwave_hit[i-1] = NULL;
588                 shockwave_hit_force[i-1] = '0 0 0';
589                 shockwave_hit_damage[i-1] = 0;
590         }
591
592         if(lag)
593                 antilag_restore_all(actor);
594 }
595
596 METHOD(Shockwave, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
597 {
598     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR(shockwave, melee_range)))
599         { PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false); }
600     else
601         { PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false); }
602 }
603 METHOD(Shockwave, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
604 {
605     if(fire & 1)
606     {
607         if(time >= actor.(weaponentity).shockwave_blasttime) // handle refire separately so the secondary can be fired straight after a primary
608         {
609             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(shockwave, blast_animtime)))
610             {
611                 W_Shockwave_Attack(thiswep, actor, weaponentity);
612                 actor.(weaponentity).shockwave_blasttime = time + WEP_CVAR(shockwave, blast_refire) * W_WeaponRateFactor(actor);
613                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(shockwave, blast_animtime), w_ready);
614             }
615         }
616     }
617     else if(fire & 2)
618     {
619         //if(actor.clip_load >= 0) // we are not currently reloading
620         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR(shockwave, melee_refire)))
621         {
622             // attempt forcing playback of the anim by switching to another anim (that we never play) here...
623             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shockwave_Melee);
624         }
625     }
626 }
627 METHOD(Shockwave, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
628 {
629     return true; // infinite ammo
630 }
631 METHOD(Shockwave, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
632 {
633     // shockwave has infinite ammo
634     return true;
635 }
636 METHOD(Shockwave, wr_suicidemessage, Notification(entity thiswep))
637 {
638     return WEAPON_THINKING_WITH_PORTALS;
639 }
640 METHOD(Shockwave, wr_killmessage, Notification(entity thiswep))
641 {
642     if(w_deathtype & HITTYPE_SECONDARY)
643         return WEAPON_SHOCKWAVE_MURDER_SLAP;
644     else
645         return WEAPON_SHOCKWAVE_MURDER;
646 }
647
648 #endif
649 #ifdef CSQC
650 // WEAPONTODO: add client side settings for these
651 const float SW_MAXALPHA = 0.5;
652 const float SW_FADETIME = 0.4;
653 const float SW_DISTTOMIN = 200;
654 void Draw_Shockwave(entity this)
655 {
656         // fading/removal control
657         float a = bound(0, (SW_MAXALPHA - ((time - this.sw_time) / SW_FADETIME)), SW_MAXALPHA);
658         if(a < ALPHA_MIN_VISIBLE) { delete(this); }
659
660         // WEAPONTODO: save this only once when creating the entity
661         vector sw_color = entcs_GetColor(this.sv_entnum - 1); // Team_ColorRGB(entcs_GetTeam(this.sv_entnum));
662
663         // WEAPONTODO: trace to find what we actually hit
664         vector endpos = (this.sw_shotorg + (this.sw_shotdir * this.sw_distance));
665
666         vectorvectors(this.sw_shotdir);
667         vector right = v_right; // save this for when we do makevectors later
668         vector up = v_up; // save this for when we do makevectors later
669
670         // WEAPONTODO: combine and simplify these calculations
671         vector min_end = ((this.sw_shotorg + (this.sw_shotdir * SW_DISTTOMIN)) + (up * this.sw_spread_min));
672         vector max_end = (endpos + (up * this.sw_spread_max));
673         float spread_to_min = vlen(normalize(min_end - this.sw_shotorg) - this.sw_shotdir);
674         float spread_to_max = vlen(normalize(max_end - min_end) - this.sw_shotdir);
675
676         vector first_min_end = '0 0 0', prev_min_end = '0 0 0', new_min_end = '0 0 0';
677         vector first_max_end = '0 0 0', prev_max_end = '0 0 0', new_max_end = '0 0 0';
678         float new_max_dist, new_min_dist;
679
680         vector deviation, angle = '0 0 0';
681         float counter, divisions = 20;
682         for(counter = 0; counter < divisions; ++counter)
683         {
684                 // perfect circle effect lines
685                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / divisions));
686                 angle.y = v_forward.x;
687                 angle.z = v_forward.y;
688
689                 // first do the spread_to_min effect
690                 deviation = angle * spread_to_min;
691                 deviation = ((this.sw_shotdir + (right * deviation.y) + (up * deviation.z)));
692                 new_min_dist = SW_DISTTOMIN;
693                 new_min_end = (this.sw_shotorg + (deviation * new_min_dist));
694                 //te_lightning2(NULL, new_min_end, this.sw_shotorg);
695
696                 // then calculate spread_to_max effect
697                 deviation = angle * spread_to_max;
698                 deviation = ((this.sw_shotdir + (right * deviation.y) + (up * deviation.z)));
699                 new_max_dist = vlen(new_min_end - endpos);
700                 new_max_end = (new_min_end + (deviation * new_max_dist));
701                 //te_lightning2(NULL, new_end, prev_min_end);
702
703
704                 if(counter == 0)
705                 {
706                         first_min_end = new_min_end;
707                         first_max_end = new_max_end;
708                 }
709
710                 if(counter >= 1)
711                 {
712                         // draw from shot origin to min spread radius
713                         R_BeginPolygon("", DRAWFLAG_NORMAL);
714                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
715                         R_PolygonVertex(new_min_end, '0 0 0', sw_color, a);
716                         R_PolygonVertex(this.sw_shotorg, '0 0 0', sw_color, a);
717                         R_EndPolygon();
718
719                         // draw from min spread radius to max spread radius
720                         R_BeginPolygon("", DRAWFLAG_NORMAL);
721                         R_PolygonVertex(new_min_end, '0 0 0', sw_color, a);
722                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
723                         R_PolygonVertex(prev_max_end, '0 0 0', sw_color, a);
724                         R_PolygonVertex(new_max_end, '0 0 0', sw_color, a);
725                         R_EndPolygon();
726                 }
727
728                 prev_min_end = new_min_end;
729                 prev_max_end = new_max_end;
730
731                 // last division only
732                 if((counter + 1) == divisions)
733                 {
734                         // draw from shot origin to min spread radius
735                         R_BeginPolygon("", DRAWFLAG_NORMAL);
736                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
737                         R_PolygonVertex(first_min_end, '0 0 0', sw_color, a);
738                         R_PolygonVertex(this.sw_shotorg, '0 0 0', sw_color, a);
739                         R_EndPolygon();
740
741                         // draw from min spread radius to max spread radius
742                         R_BeginPolygon("", DRAWFLAG_NORMAL);
743                         R_PolygonVertex(first_min_end, '0 0 0', sw_color, a);
744                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
745                         R_PolygonVertex(prev_max_end, '0 0 0', sw_color, a);
746                         R_PolygonVertex(first_max_end, '0 0 0', sw_color, a);
747                         R_EndPolygon();
748                 }
749         }
750 }
751
752 NET_HANDLE(TE_CSQC_SHOCKWAVEPARTICLE, bool isNew)
753 {
754         Net_ReadShockwaveParticle();
755         return true;
756 }
757
758 void Net_ReadShockwaveParticle()
759 {
760         entity shockwave;
761         shockwave = spawn();
762         shockwave.draw = Draw_Shockwave;
763         IL_PUSH(g_drawables, shockwave);
764
765         shockwave.sw_shotorg = ReadVector();
766         shockwave.sw_shotdir = ReadVector();
767
768         shockwave.sw_distance = ReadShort();
769         shockwave.sw_spread_max = ReadByte();
770         shockwave.sw_spread_min = ReadByte();
771
772         shockwave.sv_entnum = ReadByte();
773
774         shockwave.sw_time = time;
775 }
776
777 METHOD(Shockwave, wr_impacteffect, void(entity thiswep, entity actor))
778 {
779     // handled by Net_ReadShockwaveParticle
780     //vector org2;
781     //org2 = w_org + w_backoff * 2;
782     //pointparticles(EFFECT_BLASTER_IMPACT, org2, w_backoff * 1000, 1);
783 }
784
785 #endif