22c9288415f7636b6df39cd67277afc5c4d91022
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / shotgun.qc
1 #include "shotgun.qh"
2
3 #ifdef SVQC
4
5 METHOD(Shotgun, m_spawnfunc_hookreplace, Weapon(Shotgun this, entity e))
6 {
7         if (autocvar_sv_q3acompat_machineshotgunswap && !Item_IsLoot(e))
8         {
9                 return WEP_MACHINEGUN;
10         }
11         return this;
12 }
13
14 void W_Shotgun_Attack(Weapon thiswep, entity actor, .entity weaponentity, float isprimary, float ammocount, float damage, float bullets, float spread, float solidpenetration, float force, entity bullet_trail_effect)
15 {
16         W_DecreaseAmmo(thiswep, actor, ammocount, weaponentity);
17
18         W_SetupShot(actor, weaponentity, true, 5, SND_SHOTGUN_FIRE, ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), damage * bullets, thiswep.m_id);
19         for(int sc = 0;sc < bullets;sc = sc + 1)
20                 fireBullet(actor, weaponentity, w_shotorg, w_shotdir, spread, solidpenetration, damage, force, thiswep.m_id, bullet_trail_effect);
21
22         Send_Effect(EFFECT_SHOTGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, ammocount);
23
24         // casing code
25         if(autocvar_g_casings >= 1)
26         {
27                 makevectors(actor.v_angle); // for some reason, this is lost
28                 //for(int sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
29                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, actor, weaponentity);
30         }
31
32         // muzzle flash for 1st person view
33         entity flash = spawn();
34         setmodel(flash, MDL_SHOTGUN_MUZZLEFLASH); // precision set below
35         setthink(flash, SUB_Remove);
36         flash.nextthink = time + 0.06;
37         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
38         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
39 }
40
41 .float swing_prev;
42 .entity swing_alreadyhit;
43 void W_Shotgun_Melee_Think(entity this)
44 {
45         // declarations
46         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
47         entity target_victim;
48         vector targpos;
49
50         if(!this.cnt) // set start time of melee
51         {
52                 this.cnt = time;
53                 W_PlayStrengthSound(this.realowner);
54         }
55
56         makevectors(this.realowner.v_angle); // update values for v_* vectors
57
58         // calculate swing percentage based on time
59         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor(this.realowner);
60         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
61         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
62
63         // check to see if we can still continue, otherwise give up now
64         if(IS_DEAD(this.realowner) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
65         {
66                 delete(this);
67                 return;
68         }
69
70         // if okay, perform the traces needed for this frame
71         for(i=this.swing_prev; i < f; ++i)
72         {
73                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
74
75                 targpos = (this.realowner.origin + this.realowner.view_ofs
76                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
77                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
78                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
79
80                 WarpZone_traceline_antilag(this.realowner, this.realowner.origin + this.realowner.view_ofs, targpos, false, this.realowner, ((IS_CLIENT(this.realowner)) ? ANTILAG_LATENCY(this.realowner) : 0));
81
82                 // draw lightning beams for debugging
83                 //te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
84                 //te_customflash(targpos, 40,  2, '1 1 1');
85
86                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
87
88                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this
89                         && (trace_ent.takedamage != DAMAGE_NO)
90                         && (trace_ent != this.swing_alreadyhit)
91                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
92                 {
93                         target_victim = trace_ent; // so it persists through other calls
94
95                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
96                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
97                         else
98                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
99
100                         //print(strcat(this.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
101
102                         Damage(target_victim, this.realowner, this.realowner,
103                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY, this.weaponentity_fld,
104                                 this.realowner.origin + this.realowner.view_ofs,
105                                 v_forward * WEP_CVAR_SEC(shotgun, force));
106
107                         if(accuracy_isgooddamage(this.realowner, target_victim)) { accuracy_add(this.realowner, WEP_SHOTGUN, 0, swing_damage); }
108
109                         // draw large red flash for debugging
110                         //te_customflash(targpos, 200, 2, '15 0 0');
111
112                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
113                         {
114                                 this.swing_alreadyhit = target_victim;
115                                 continue; // move along to next trace
116                         }
117                         else
118                         {
119                                 delete(this);
120                                 return;
121                         }
122                 }
123         }
124
125         if(time >= this.cnt + meleetime)
126         {
127                 // melee is finished
128                 delete(this);
129                 return;
130         }
131         else
132         {
133                 // set up next frame
134                 this.swing_prev = i;
135                 this.nextthink = time;
136         }
137 }
138
139 void W_Shotgun_Attack2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
140 {
141         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
142         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
143
144         entity meleetemp = new_pure(meleetemp);
145         meleetemp.realowner = actor;
146         setthink(meleetemp, W_Shotgun_Melee_Think);
147         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor(actor);
148         meleetemp.weaponentity_fld = weaponentity;
149         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range), WEP_SHOTGUN.m_id | HITTYPE_SECONDARY);
150 }
151
152 // alternate secondary weapon frames
153 void W_Shotgun_Attack3_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
154 {
155         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
156         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
157         {
158                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
159                 w_ready(thiswep, actor, weaponentity, fire);
160                 return;
161         }
162
163         sound(actor, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
164         W_Shotgun_Attack(thiswep, actor, weaponentity, true,
165                 WEP_CVAR_PRI(shotgun, ammo),
166                 WEP_CVAR_PRI(shotgun, damage),
167                 WEP_CVAR_PRI(shotgun, bullets),
168                 WEP_CVAR_PRI(shotgun, spread),
169                 WEP_CVAR_PRI(shotgun, solidpenetration),
170                 WEP_CVAR_PRI(shotgun, force),
171                 EFFECT_BULLET_WEAK); // actually is secondary, but we trick the last shot into playing full reload sound
172         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
173 }
174 void W_Shotgun_Attack3_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
175 {
176         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
177         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
178         {
179                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
180                 w_ready(thiswep, actor, weaponentity, fire);
181                 return;
182         }
183
184         W_Shotgun_Attack(thiswep, actor, weaponentity, false,
185                 WEP_CVAR_PRI(shotgun, ammo),
186                 WEP_CVAR_PRI(shotgun, damage),
187                 WEP_CVAR_PRI(shotgun, bullets),
188                 WEP_CVAR_PRI(shotgun, spread),
189                 WEP_CVAR_PRI(shotgun, solidpenetration),
190                 WEP_CVAR_PRI(shotgun, force),
191                 EFFECT_BULLET_WEAK);
192         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
193 }
194
195 .float shotgun_primarytime;
196
197 METHOD(Shotgun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
198 {
199     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR_SEC(shotgun, melee_range)))
200         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
201     else
202         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
203 }
204
205 METHOD(Shotgun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
206 {
207     if(WEP_CVAR(shotgun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
208     {
209         // don't force reload an empty shotgun if its melee attack is active
210         if(WEP_CVAR(shotgun, secondary) < 2) {
211             thiswep.wr_reload(thiswep, actor, weaponentity);
212         }
213     }
214     else
215     {
216         if(fire & 1)
217         {
218             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
219             {
220                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(shotgun, animtime)))
221                 {
222                     W_Shotgun_Attack(thiswep, actor, weaponentity, true,
223                                                 WEP_CVAR_PRI(shotgun, ammo),
224                                                 WEP_CVAR_PRI(shotgun, damage),
225                                                 WEP_CVAR_PRI(shotgun, bullets),
226                                                 WEP_CVAR_PRI(shotgun, spread),
227                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
228                                                 WEP_CVAR_PRI(shotgun, force),
229                                                 EFFECT_BULLET_WEAK);
230                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor(actor);
231                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
232                 }
233             }
234         }
235         else if((fire & 2) && WEP_CVAR(shotgun, secondary) == 2)
236         {
237             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
238             {
239                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(shotgun, alt_animtime)))
240                 {
241                     W_Shotgun_Attack(thiswep, actor, weaponentity, false,
242                                                 WEP_CVAR_PRI(shotgun, ammo),
243                                                 WEP_CVAR_PRI(shotgun, damage),
244                                                 WEP_CVAR_PRI(shotgun, bullets),
245                                                 WEP_CVAR_PRI(shotgun, spread),
246                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
247                                                 WEP_CVAR_PRI(shotgun, force),
248                                                 EFFECT_BULLET_WEAK);
249                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor(actor);
250                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
251                 }
252             }
253         }
254     }
255     if(actor.(weaponentity).clip_load >= 0) // we are not currently reloading
256     if(WEP_CVAR(shotgun, secondary) == 1)
257     if(((fire & 1) && GetResource(actor, thiswep.ammo_type) <= 0 && !(actor.items & IT_UNLIMITED_WEAPON_AMMO)) || (fire & 2))
258     if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(shotgun, refire)))
259     {
260         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
261         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shotgun_Attack2);
262     }
263 }
264 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
265 {
266     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
267     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
268     return ammo_amount;
269 }
270 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
271 {
272     if(IS_BOT_CLIENT(actor))
273     if(vdist(actor.origin - actor.enemy.origin, >, WEP_CVAR_SEC(shotgun, melee_range)))
274         return false; // bots cannot use secondary out of range (fixes constant melee when out of ammo)
275     switch(WEP_CVAR(shotgun, secondary))
276     {
277         case 1: return true; // melee does not use ammo
278         case 2: // secondary triple shot
279         {
280             float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
281             ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
282             return ammo_amount;
283         }
284         default: return false; // secondary unavailable
285     }
286 }
287 METHOD(Shotgun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
288 {
289     W_Reload(actor, weaponentity, WEP_CVAR_PRI(shotgun, ammo), SND_RELOAD); // WEAPONTODO
290 }
291 METHOD(Shotgun, wr_suicidemessage, Notification(entity thiswep))
292 {
293     return WEAPON_THINKING_WITH_PORTALS;
294 }
295 METHOD(Shotgun, wr_killmessage, Notification(entity thiswep))
296 {
297     if(w_deathtype & HITTYPE_SECONDARY)
298         return WEAPON_SHOTGUN_MURDER_SLAP;
299     else
300         return WEAPON_SHOTGUN_MURDER;
301 }
302
303 #endif
304 #ifdef CSQC
305 .float prevric;
306
307 METHOD(Shotgun, wr_impacteffect, void(entity thiswep, entity actor))
308 {
309     vector org2 = w_org + w_backoff * 2;
310     pointparticles(EFFECT_SHOTGUN_IMPACT, org2, w_backoff * 1000, 1);
311     if(!w_issilent && time - actor.prevric > 0.25)
312     {
313         if(w_random < 0.05)
314             sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
315         actor.prevric = time;
316     }
317 }
318
319 #endif