Hook: merge offhand and weapon behaviour
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / shotgun.qc
1 #ifndef IMPLEMENTATION
2 CLASS(Shotgun, Weapon)
3 /* ammotype  */ ATTRIB(Shotgun, ammo_field, .int, ammo_shells)
4 /* impulse   */ ATTRIB(Shotgun, impulse, int, 2)
5 /* flags     */ ATTRIB(Shotgun, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN);
6 /* rating    */ ATTRIB(Shotgun, bot_pickupbasevalue, float, BOT_PICKUP_RATING_LOW);
7 /* color     */ ATTRIB(Shotgun, wpcolor, vector, '0.5 0.25 0');
8 /* modelname */ ATTRIB(Shotgun, mdl, string, "shotgun");
9 #ifndef MENUQC
10 /* model     */ ATTRIB(Shotgun, m_model, Model, MDL_SHOTGUN_ITEM);
11 #endif
12 /* crosshair */ ATTRIB(Shotgun, w_crosshair, string, "gfx/crosshairshotgun");
13 /* crosshair */ ATTRIB(Shotgun, w_crosshair_size, float, 0.65);
14 /* wepimg    */ ATTRIB(Shotgun, model2, string, "weaponshotgun");
15 /* refname   */ ATTRIB(Shotgun, netname, string, "shotgun");
16 /* wepname   */ ATTRIB(Shotgun, message, string, _("Shotgun"));
17 ENDCLASS(Shotgun)
18 REGISTER_WEAPON(SHOTGUN, NEW(Shotgun));
19
20 #define SHOTGUN_SETTINGS(w_cvar,w_prop) SHOTGUN_SETTINGS_LIST(w_cvar, w_prop, SHOTGUN, shotgun)
21 #define SHOTGUN_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
22         w_cvar(id, sn, PRI,  ammo) \
23         w_cvar(id, sn, BOTH, animtime) \
24         w_cvar(id, sn, BOTH, refire) \
25         w_cvar(id, sn, PRI,  bullets) \
26         w_cvar(id, sn, BOTH, damage) \
27         w_cvar(id, sn, BOTH, force) \
28         w_cvar(id, sn, PRI,  solidpenetration) \
29         w_cvar(id, sn, PRI,  spread) \
30         w_cvar(id, sn, NONE, secondary) \
31         w_cvar(id, sn, SEC,  melee_time) \
32         w_cvar(id, sn, SEC,  melee_no_doubleslap) \
33         w_cvar(id, sn, SEC,  melee_traces) \
34         w_cvar(id, sn, SEC,  melee_swing_up) \
35         w_cvar(id, sn, SEC,  melee_swing_side) \
36         w_cvar(id, sn, SEC,  melee_nonplayerdamage) \
37         w_cvar(id, sn, SEC,  melee_multihit) \
38         w_cvar(id, sn, SEC,  melee_delay) \
39         w_cvar(id, sn, SEC,  melee_range) \
40         w_cvar(id, sn, SEC,  alt_animtime) \
41         w_cvar(id, sn, SEC,  alt_refire) \
42         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
43         w_prop(id, sn, float,  reloading_time, reload_time) \
44         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
45         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
46         w_prop(id, sn, string, weaponreplace, weaponreplace) \
47         w_prop(id, sn, float,  weaponstart, weaponstart) \
48         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
49         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
50
51 #ifdef SVQC
52 SHOTGUN_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
53 #endif
54 #endif
55 #ifdef IMPLEMENTATION
56 #ifdef SVQC
57 spawnfunc(weapon_shotgun) { weapon_defaultspawnfunc(WEP_SHOTGUN.m_id); }
58
59 void W_Shotgun_Attack(Weapon thiswep, float isprimary)
60 {SELFPARAM();
61         float   sc;
62         entity flash;
63
64         W_DecreaseAmmo(thiswep, self, WEP_CVAR_PRI(shotgun, ammo));
65
66         W_SetupShot(self, true, 5, SND(SHOTGUN_FIRE), ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), WEP_CVAR_PRI(shotgun, damage) * WEP_CVAR_PRI(shotgun, bullets));
67         for(sc = 0;sc < WEP_CVAR_PRI(shotgun, bullets);sc = sc + 1)
68                 fireBullet(w_shotorg, w_shotdir, WEP_CVAR_PRI(shotgun, spread), WEP_CVAR_PRI(shotgun, solidpenetration), WEP_CVAR_PRI(shotgun, damage), WEP_CVAR_PRI(shotgun, force), WEP_SHOTGUN.m_id, 0);
69
70         Send_Effect(EFFECT_SHOTGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, WEP_CVAR_PRI(shotgun, ammo));
71
72         // casing code
73         if(autocvar_g_casings >= 1)
74                 for(sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
75                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
76
77         // muzzle flash for 1st person view
78         flash = spawn();
79         setmodel(flash, MDL_SHOTGUN_MUZZLEFLASH); // precision set below
80         flash.think = SUB_Remove;
81         flash.nextthink = time + 0.06;
82         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
83         W_AttachToShotorg(self, flash, '5 0 0');
84 }
85
86 .float swing_prev;
87 .entity swing_alreadyhit;
88 void W_Shotgun_Melee_Think(void)
89 {SELFPARAM();
90         // declarations
91         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
92         entity target_victim;
93         vector targpos;
94
95         if(!self.cnt) // set start time of melee
96         {
97                 self.cnt = time;
98                 W_PlayStrengthSound(self.realowner);
99         }
100
101         makevectors(self.realowner.v_angle); // update values for v_* vectors
102
103         // calculate swing percentage based on time
104         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor();
105         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
106         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
107
108         // check to see if we can still continue, otherwise give up now
109         if((self.realowner.deadflag != DEAD_NO) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
110         {
111                 remove(self);
112                 return;
113         }
114
115         // if okay, perform the traces needed for this frame
116         for(i=self.swing_prev; i < f; ++i)
117         {
118                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
119
120                 targpos = (self.realowner.origin + self.realowner.view_ofs
121                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
122                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
123                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
124
125                 WarpZone_traceline_antilag(self, self.realowner.origin + self.realowner.view_ofs, targpos, false, self, ANTILAG_LATENCY(self.realowner));
126
127                 // draw lightning beams for debugging
128                 //te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
129                 //te_customflash(targpos, 40,  2, '1 1 1');
130
131                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
132
133                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
134                         && (trace_ent.takedamage == DAMAGE_AIM)
135                         && (trace_ent != self.swing_alreadyhit)
136                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
137                 {
138                         target_victim = trace_ent; // so it persists through other calls
139
140                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
141                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
142                         else
143                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
144
145                         //print(strcat(self.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
146
147                         Damage(target_victim, self.realowner, self.realowner,
148                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY,
149                                 self.realowner.origin + self.realowner.view_ofs,
150                                 v_forward * WEP_CVAR_SEC(shotgun, force));
151
152                         if(accuracy_isgooddamage(self.realowner, target_victim)) { accuracy_add(self.realowner, WEP_SHOTGUN.m_id, 0, swing_damage); }
153
154                         // draw large red flash for debugging
155                         //te_customflash(targpos, 200, 2, '15 0 0');
156
157                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
158                         {
159                                 self.swing_alreadyhit = target_victim;
160                                 continue; // move along to next trace
161                         }
162                         else
163                         {
164                                 remove(self);
165                                 return;
166                         }
167                 }
168         }
169
170         if(time >= self.cnt + meleetime)
171         {
172                 // melee is finished
173                 remove(self);
174                 return;
175         }
176         else
177         {
178                 // set up next frame
179                 self.swing_prev = i;
180                 self.nextthink = time;
181         }
182 }
183
184 void W_Shotgun_Attack2(Weapon thiswep, entity actor, bool fire1, bool fire2)
185 {
186         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
187         weapon_thinkf(actor, WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
188
189         entity meleetemp;
190         meleetemp = spawn();
191         meleetemp.realowner = actor;
192         meleetemp.think = W_Shotgun_Melee_Think;
193         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor();
194         W_SetupShot_Range(actor, true, 0, "", 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range));
195 }
196
197 // alternate secondary weapon frames
198 void W_Shotgun_Attack3_Frame2(Weapon thiswep, entity actor, bool fire1, bool fire2)
199 {
200         Weapon w = get_weaponinfo(actor.weapon);
201         if (!w.wr_checkammo2(w))
202         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
203         {
204                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
205                 w_ready(thiswep, actor, fire1, fire2);
206                 return;
207         }
208
209         sound(actor, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
210         W_Shotgun_Attack(WEP_SHOTGUN, true); // actually is secondary, but we trick the last shot into playing full reload sound
211         weapon_thinkf(actor, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
212 }
213 void W_Shotgun_Attack3_Frame1(Weapon thiswep, entity actor, bool fire1, bool fire2)
214 {
215         Weapon w = get_weaponinfo(actor.weapon);
216         if (!w.wr_checkammo2(w))
217         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
218         {
219                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
220                 w_ready(thiswep, actor, fire1, fire2);
221                 return;
222         }
223
224         W_Shotgun_Attack(WEP_SHOTGUN, false);
225         weapon_thinkf(actor, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
226 }
227
228 .float shotgun_primarytime;
229
230                 METHOD(Shotgun, wr_aim, void(entity thiswep))
231                 {
232                         if(vlen(self.origin-self.enemy.origin) <= WEP_CVAR_SEC(shotgun, melee_range))
233                                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, false);
234                         else
235                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, false);
236                 }
237                 METHOD(Shotgun, wr_think, void(entity thiswep, entity actor, bool fire1, bool fire2))
238                 {
239                         if(WEP_CVAR(shotgun, reload_ammo) && actor.clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
240                         {
241                                 // don't force reload an empty shotgun if its melee attack is active
242                                 if(WEP_CVAR(shotgun, secondary) < 2) {
243                                         Weapon w = get_weaponinfo(actor.weapon);
244                                         w.wr_reload(w);
245                                 }
246                         }
247                         else
248                         {
249                                 if(fire1)
250                                 {
251                                         if(time >= actor.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
252                                         {
253                                                 if(weapon_prepareattack(thiswep, actor, false, WEP_CVAR_PRI(shotgun, animtime)))
254                                                 {
255                                                         W_Shotgun_Attack(thiswep, true);
256                                                         actor.shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor();
257                                                         weapon_thinkf(actor, WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
258                                                 }
259                                         }
260                                 }
261                                 else if(fire2 && WEP_CVAR(shotgun, secondary) == 2)
262                                 {
263                                         if(time >= actor.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
264                                         {
265                                                 if(weapon_prepareattack(thiswep, actor, false, WEP_CVAR_SEC(shotgun, alt_animtime)))
266                                                 {
267                                                         W_Shotgun_Attack(thiswep, false);
268                                                         actor.shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor();
269                                                         weapon_thinkf(actor, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
270                                                 }
271                                         }
272                                 }
273                         }
274                         if(actor.clip_load >= 0) // we are not currently reloading
275                         if(!actor.crouch) // no crouchmelee please
276                         if(WEP_CVAR(shotgun, secondary) == 1)
277                         if((fire1 && actor.WEP_AMMO(SHOTGUN) <= 0 && !(actor.items & IT_UNLIMITED_WEAPON_AMMO)) || fire2)
278                         if(weapon_prepareattack(thiswep, actor, true, WEP_CVAR_SEC(shotgun, refire)))
279                         {
280                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
281                                 weapon_thinkf(actor, WFRAME_FIRE1, 0, W_Shotgun_Attack2);
282                         }
283                 }
284                 METHOD(Shotgun, wr_init, void(entity thiswep))
285                 {
286                         SHOTGUN_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
287                 }
288                 METHOD(Shotgun, wr_setup, void(entity thiswep))
289                 {
290                         self.ammo_field = ammo_none;
291                 }
292                 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep))
293                 {
294                         float ammo_amount = self.WEP_AMMO(SHOTGUN) >= WEP_CVAR_PRI(shotgun, ammo);
295                         ammo_amount += self.(weapon_load[WEP_SHOTGUN.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
296                         return ammo_amount;
297                 }
298                 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep))
299                 {
300                         if(IS_BOT_CLIENT(self))
301                         if(vlen(self.origin-self.enemy.origin) > WEP_CVAR_SEC(shotgun, melee_range))
302                                 return false; // bots cannot use secondary out of range (fixes constant melee when out of ammo)
303                         switch(WEP_CVAR(shotgun, secondary))
304                         {
305                                 case 1: return true; // melee does not use ammo
306                                 case 2: // secondary triple shot
307                                 {
308                                         float ammo_amount = self.WEP_AMMO(SHOTGUN) >= WEP_CVAR_PRI(shotgun, ammo);
309                                         ammo_amount += self.(weapon_load[WEP_SHOTGUN.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
310                                         return ammo_amount;
311                                 }
312                                 default: return false; // secondary unavailable
313                         }
314                 }
315                 METHOD(Shotgun, wr_config, void(entity thiswep))
316                 {
317                         SHOTGUN_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
318                 }
319                 METHOD(Shotgun, wr_reload, void(entity thiswep))
320                 {
321                         W_Reload(self, WEP_CVAR_PRI(shotgun, ammo), SND(RELOAD)); // WEAPONTODO
322                 }
323                 METHOD(Shotgun, wr_suicidemessage, int(entity thiswep))
324                 {
325                         return WEAPON_THINKING_WITH_PORTALS;
326                 }
327                 METHOD(Shotgun, wr_killmessage, int(entity thiswep))
328                 {
329                         if(w_deathtype & HITTYPE_SECONDARY)
330                                 return WEAPON_SHOTGUN_MURDER_SLAP;
331                         else
332                                 return WEAPON_SHOTGUN_MURDER;
333                 }
334
335 #endif
336 #ifdef CSQC
337 .float prevric;
338
339                 METHOD(Shotgun, wr_impacteffect, void(entity thiswep))
340                 {
341                         vector org2 = w_org + w_backoff * 2;
342                         pointparticles(particleeffectnum(EFFECT_SHOTGUN_IMPACT), org2, w_backoff * 1000, 1);
343                         if(!w_issilent && time - self.prevric > 0.25)
344                         {
345                                 if(w_random < 0.0165)
346                                         sound(self, CH_SHOTS, SND_RIC1, VOL_BASE, ATTEN_NORM);
347                                 else if(w_random < 0.033)
348                                         sound(self, CH_SHOTS, SND_RIC2, VOL_BASE, ATTEN_NORM);
349                                 else if(w_random < 0.05)
350                                         sound(self, CH_SHOTS, SND_RIC3, VOL_BASE, ATTEN_NORM);
351                                 self.prevric = time;
352                         }
353                 }
354
355 #endif
356 #endif