Merge branch 'divVerent/simpler-clipped-rectangle' into 'master'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / shotgun.qc
1 #include "shotgun.qh"
2
3 #ifdef SVQC
4
5 // enable to debug melee range
6 //#define SHOTGUN_MELEEDEBUG
7
8 METHOD(Shotgun, m_spawnfunc_hookreplace, Weapon(Shotgun this, entity e))
9 {
10         if (autocvar_sv_q3acompat_machineshotgunswap && !Item_IsLoot(e))
11         {
12                 return WEP_MACHINEGUN;
13         }
14         return this;
15 }
16
17 void W_Shotgun_Attack(Weapon thiswep, entity actor, .entity weaponentity, float isprimary, float ammocount, float damage, float bullets, float spread, float solidpenetration, float force, entity bullet_trail_effect)
18 {
19         W_DecreaseAmmo(thiswep, actor, ammocount, weaponentity);
20
21         W_SetupShot(actor, weaponentity, true, 5, SND_SHOTGUN_FIRE, ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), damage * bullets, thiswep.m_id);
22
23         // TRICK: do the antilag outside the regular fireBullet function, so it isn't performed unnecessarily on every single bullet!
24         float lag = antilag_getlag(actor);
25         if(lag && bullets > 0)
26                 antilag_takeback_all(actor, lag);
27
28         for(int sc = 0;sc < bullets;sc = sc + 1)
29                 fireBullet_antilag(actor, weaponentity, w_shotorg, w_shotdir, spread, solidpenetration, damage, force, thiswep.m_id, bullet_trail_effect, false);
30         
31         if(lag && bullets > 0)
32                 antilag_restore_all(actor);
33
34         Send_Effect(EFFECT_SHOTGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, ammocount);
35
36         // casing code
37         if(autocvar_g_casings >= 1)
38         {
39                 makevectors(actor.v_angle); // for some reason, this is lost
40                 //for(int sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
41                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, actor, weaponentity);
42         }
43
44         // muzzle flash for 1st person view
45         entity flash = spawn();
46         setmodel(flash, MDL_SHOTGUN_MUZZLEFLASH); // precision set below
47         setthink(flash, SUB_Remove);
48         flash.nextthink = time + 0.06;
49         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
50         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
51 }
52
53 .float swing_prev;
54 .entity swing_alreadyhit;
55 void W_Shotgun_Melee_Think(entity this)
56 {
57         // declarations
58         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
59         entity target_victim;
60         vector targpos;
61
62         if(!this.cnt) // set start time of melee
63         {
64                 this.cnt = time;
65                 W_PlayStrengthSound(this.realowner);
66         }
67
68         makevectors(this.realowner.v_angle); // update values for v_* vectors
69
70         // calculate swing percentage based on time
71         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor(this.realowner);
72         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
73         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
74
75         // check to see if we can still continue, otherwise give up now
76         if(IS_DEAD(this.realowner) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
77         {
78                 delete(this);
79                 return;
80         }
81
82         // if okay, perform the traces needed for this frame
83         for(i=this.swing_prev; i < f; ++i)
84         {
85                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
86
87                 targpos = (this.realowner.origin + this.realowner.view_ofs
88                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
89                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
90                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
91
92                 WarpZone_traceline_antilag(this.realowner, this.realowner.origin + this.realowner.view_ofs, targpos, false, this.realowner, ((IS_CLIENT(this.realowner)) ? ANTILAG_LATENCY(this.realowner) : 0));
93
94                 // draw lightning beams for debugging
95         #ifdef SHOTGUN_MELEEDEBUG
96                 te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
97                 te_customflash(targpos, 40,  2, '1 1 1');
98         #endif
99
100                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
101
102                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this
103                         && (trace_ent.takedamage != DAMAGE_NO)
104                         && (trace_ent != this.swing_alreadyhit)
105                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
106                 {
107                         target_victim = trace_ent; // so it persists through other calls
108
109                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
110                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
111                         else
112                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
113
114                         //print(strcat(this.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
115
116                         Damage(target_victim, this.realowner, this.realowner,
117                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY, this.weaponentity_fld,
118                                 this.realowner.origin + this.realowner.view_ofs,
119                                 v_forward * WEP_CVAR_SEC(shotgun, force));
120
121                         if(accuracy_isgooddamage(this.realowner, target_victim)) { accuracy_add(this.realowner, WEP_SHOTGUN, 0, swing_damage); }
122
123                         // draw large red flash for debugging
124                 #ifdef SHOTGUN_MELEEDEBUG
125                         te_customflash(targpos, 200, 2, '15 0 0');
126                 #endif
127
128                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
129                         {
130                                 this.swing_alreadyhit = target_victim;
131                                 continue; // move along to next trace
132                         }
133                         else
134                         {
135                                 delete(this);
136                                 return;
137                         }
138                 }
139         }
140
141         if(time >= this.cnt + meleetime)
142         {
143                 // melee is finished
144                 delete(this);
145                 return;
146         }
147         else
148         {
149                 // set up next frame
150                 this.swing_prev = i;
151                 this.nextthink = time;
152         }
153 }
154
155 void W_Shotgun_Attack2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
156 {
157         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
158         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
159
160         entity meleetemp = new_pure(meleetemp);
161         meleetemp.realowner = actor;
162         setthink(meleetemp, W_Shotgun_Melee_Think);
163         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor(actor);
164         meleetemp.weaponentity_fld = weaponentity;
165         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range), WEP_SHOTGUN.m_id | HITTYPE_SECONDARY);
166 }
167
168 // alternate secondary weapon frames
169 void W_Shotgun_Attack3_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
170 {
171         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
172         if (!(actor.items & IT_UNLIMITED_AMMO))
173         {
174                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
175                 w_ready(thiswep, actor, weaponentity, fire);
176                 return;
177         }
178
179         sound(actor, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
180         W_Shotgun_Attack(thiswep, actor, weaponentity, true,
181                 WEP_CVAR_PRI(shotgun, ammo),
182                 WEP_CVAR_PRI(shotgun, damage),
183                 WEP_CVAR_PRI(shotgun, bullets),
184                 WEP_CVAR_PRI(shotgun, spread),
185                 WEP_CVAR_PRI(shotgun, solidpenetration),
186                 WEP_CVAR_PRI(shotgun, force),
187                 EFFECT_BULLET_WEAK); // actually is secondary, but we trick the last shot into playing full reload sound
188         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
189 }
190 void W_Shotgun_Attack3_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
191 {
192         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
193         if (!(actor.items & IT_UNLIMITED_AMMO))
194         {
195                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
196                 w_ready(thiswep, actor, weaponentity, fire);
197                 return;
198         }
199
200         W_Shotgun_Attack(thiswep, actor, weaponentity, false,
201                 WEP_CVAR_PRI(shotgun, ammo),
202                 WEP_CVAR_PRI(shotgun, damage),
203                 WEP_CVAR_PRI(shotgun, bullets),
204                 WEP_CVAR_PRI(shotgun, spread),
205                 WEP_CVAR_PRI(shotgun, solidpenetration),
206                 WEP_CVAR_PRI(shotgun, force),
207                 EFFECT_BULLET_WEAK);
208         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
209 }
210
211 .float shotgun_primarytime;
212
213 METHOD(Shotgun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
214 {
215     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR_SEC(shotgun, melee_range)))
216         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
217     else
218         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
219 }
220
221 METHOD(Shotgun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
222 {
223     if(WEP_CVAR(shotgun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
224     {
225         // don't force reload an empty shotgun if its melee attack is active
226         if(WEP_CVAR(shotgun, secondary) < 2) {
227             thiswep.wr_reload(thiswep, actor, weaponentity);
228         }
229     }
230     else
231     {
232         if(fire & 1)
233         {
234             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
235             {
236                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(shotgun, animtime)))
237                 {
238                     W_Shotgun_Attack(thiswep, actor, weaponentity, true,
239                                                 WEP_CVAR_PRI(shotgun, ammo),
240                                                 WEP_CVAR_PRI(shotgun, damage),
241                                                 WEP_CVAR_PRI(shotgun, bullets),
242                                                 WEP_CVAR_PRI(shotgun, spread),
243                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
244                                                 WEP_CVAR_PRI(shotgun, force),
245                                                 EFFECT_BULLET_WEAK);
246                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor(actor);
247                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
248                 }
249             }
250         }
251         else if((fire & 2) && WEP_CVAR(shotgun, secondary) == 2)
252         {
253             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
254             {
255                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(shotgun, alt_animtime)))
256                 {
257                     W_Shotgun_Attack(thiswep, actor, weaponentity, false,
258                                                 WEP_CVAR_PRI(shotgun, ammo),
259                                                 WEP_CVAR_PRI(shotgun, damage),
260                                                 WEP_CVAR_PRI(shotgun, bullets),
261                                                 WEP_CVAR_PRI(shotgun, spread),
262                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
263                                                 WEP_CVAR_PRI(shotgun, force),
264                                                 EFFECT_BULLET_WEAK);
265                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor(actor);
266                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
267                 }
268             }
269         }
270     }
271     if(actor.(weaponentity).clip_load >= 0) // we are not currently reloading
272     if(WEP_CVAR(shotgun, secondary) == 1)
273     if(((fire & 1) && GetResource(actor, thiswep.ammo_type) <= 0 && !(actor.items & IT_UNLIMITED_AMMO)) || (fire & 2))
274     if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(shotgun, refire)))
275     {
276         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
277         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shotgun_Attack2);
278     }
279 }
280 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
281 {
282     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
283     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
284     return ammo_amount;
285 }
286 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
287 {
288     if(IS_BOT_CLIENT(actor))
289     if(vdist(actor.origin - actor.enemy.origin, >, WEP_CVAR_SEC(shotgun, melee_range)))
290         return false; // bots cannot use secondary out of range (fixes constant melee when out of ammo)
291     switch(WEP_CVAR(shotgun, secondary))
292     {
293         case 1: return true; // melee does not use ammo
294         case 2: // secondary triple shot
295         {
296             float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
297             ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
298             return ammo_amount;
299         }
300         default: return false; // secondary unavailable
301     }
302 }
303 METHOD(Shotgun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
304 {
305     W_Reload(actor, weaponentity, WEP_CVAR_PRI(shotgun, ammo), SND_RELOAD); // WEAPONTODO
306 }
307 METHOD(Shotgun, wr_suicidemessage, Notification(entity thiswep))
308 {
309     return WEAPON_THINKING_WITH_PORTALS;
310 }
311 METHOD(Shotgun, wr_killmessage, Notification(entity thiswep))
312 {
313     if(w_deathtype & HITTYPE_SECONDARY)
314         return WEAPON_SHOTGUN_MURDER_SLAP;
315     else
316         return WEAPON_SHOTGUN_MURDER;
317 }
318
319 #endif
320 #ifdef CSQC
321 .float prevric;
322
323 METHOD(Shotgun, wr_impacteffect, void(entity thiswep, entity actor))
324 {
325     vector org2 = w_org + w_backoff * 2;
326     pointparticles(EFFECT_SHOTGUN_IMPACT, org2, w_backoff * 1000, 1);
327     if(!w_issilent && time - actor.prevric > 0.25)
328     {
329         if(w_random < 0.05)
330             sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
331         actor.prevric = time;
332     }
333 }
334
335 #endif