qcsrc/common/weapons/weapon/shotgun.qc

   1 #include "shotgun.qh"
   2
   3 #ifdef SVQC
   4
   5 void W_Shotgun_Attack(Weapon thiswep, entity actor, .entity weaponentity, float isprimary, float ammocount, float damage, float bullets, float spread, float solidpenetration, float force)
   6 {
   7         W_DecreaseAmmo(thiswep, actor, ammocount, weaponentity);
   8
   9         W_SetupShot(actor, weaponentity, true, 5, SND_SHOTGUN_FIRE, ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), damage * bullets, thiswep.m_id);
  10         for(int sc = 0;sc < bullets;sc = sc + 1)
  11                 fireBullet(actor, weaponentity, w_shotorg, w_shotdir, spread, solidpenetration, damage, force, thiswep.m_id, 0);
  12
  13
  14         Send_Effect(EFFECT_SHOTGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, ammocount);
  15
  16         // casing code
  17         if(autocvar_g_casings >= 1)
  18         {
  19                 makevectors(actor.v_angle); // for some reason, this is lost
  20                 //for(int sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
  21                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, actor, weaponentity);
  22         }
  23
  24         // muzzle flash for 1st person view
  25         entity flash = spawn();
  26         setmodel(flash, MDL_SHOTGUN_MUZZLEFLASH); // precision set below
  27         setthink(flash, SUB_Remove);
  28         flash.nextthink = time + 0.06;
  29         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  30         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
  31 }
  32
  33 .float swing_prev;
  34 .entity swing_alreadyhit;
  35 void W_Shotgun_Melee_Think(entity this)
  36 {
  37         // declarations
  38         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  39         entity target_victim;
  40         vector targpos;
  41
  42         if(!this.cnt) // set start time of melee
  43         {
  44                 this.cnt = time;
  45                 W_PlayStrengthSound(this.realowner);
  46         }
  47
  48         makevectors(this.realowner.v_angle); // update values for v_* vectors
  49
  50         // calculate swing percentage based on time
  51         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor(this.realowner);
  52         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
  53         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
  54
  55         // check to see if we can still continue, otherwise give up now
  56         if(IS_DEAD(this.realowner) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
  57         {
  58                 delete(this);
  59                 return;
  60         }
  61
  62         // if okay, perform the traces needed for this frame
  63         for(i=this.swing_prev; i < f; ++i)
  64         {
  65                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
  66
  67                 targpos = (this.realowner.origin + this.realowner.view_ofs
  68                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
  69                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
  70                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
  71
  72                 WarpZone_traceline_antilag(this.realowner, this.realowner.origin + this.realowner.view_ofs, targpos, false, this.realowner, ((IS_CLIENT(this.realowner)) ? ANTILAG_LATENCY(this.realowner) : 0));
  73
  74                 // draw lightning beams for debugging
  75                 //te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
  76                 //te_customflash(targpos, 40,  2, '1 1 1');
  77
  78                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
  79
  80                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this
  81                         && (trace_ent.takedamage != DAMAGE_NO)
  82                         && (trace_ent != this.swing_alreadyhit)
  83                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
  84                 {
  85                         target_victim = trace_ent; // so it persists through other calls
  86
  87                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
  88                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
  89                         else
  90                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
  91
  92                         //print(strcat(this.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
  93
  94                         Damage(target_victim, this.realowner, this.realowner,
  95                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY, this.weaponentity_fld,
  96                                 this.realowner.origin + this.realowner.view_ofs,
  97                                 v_forward * WEP_CVAR_SEC(shotgun, force));
  98
  99                         if(accuracy_isgooddamage(this.realowner, target_victim)) { accuracy_add(this.realowner, WEP_SHOTGUN.m_id, 0, swing_damage); }
 100
 101                         // draw large red flash for debugging
 102                         //te_customflash(targpos, 200, 2, '15 0 0');
 103
 104                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 105                         {
 106                                 this.swing_alreadyhit = target_victim;
 107                                 continue; // move along to next trace
 108                         }
 109                         else
 110                         {
 111                                 delete(this);
 112                                 return;
 113                         }
 114                 }
 115         }
 116
 117         if(time >= this.cnt + meleetime)
 118         {
 119                 // melee is finished
 120                 delete(this);
 121                 return;
 122         }
 123         else
 124         {
 125                 // set up next frame
 126                 this.swing_prev = i;
 127                 this.nextthink = time;
 128         }
 129 }
 130
 131 void W_Shotgun_Attack2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 132 {
 133         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
 134         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
 135
 136         entity meleetemp = new_pure(meleetemp);
 137         meleetemp.realowner = actor;
 138         setthink(meleetemp, W_Shotgun_Melee_Think);
 139         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor(actor);
 140         meleetemp.weaponentity_fld = weaponentity;
 141         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range), WEP_SHOTGUN.m_id | HITTYPE_SECONDARY);
 142 }
 143
 144 // alternate secondary weapon frames
 145 void W_Shotgun_Attack3_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 146 {
 147         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 148         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 149         {
 150                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 151                 w_ready(thiswep, actor, weaponentity, fire);
 152                 return;
 153         }
 154
 155         sound(actor, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
 156         W_Shotgun_Attack(WEP_SHOTGUN, actor, weaponentity, true,
 157                 WEP_CVAR_PRI(shotgun, ammo),
 158                 WEP_CVAR_PRI(shotgun, damage),
 159                 WEP_CVAR_PRI(shotgun, bullets),
 160                 WEP_CVAR_PRI(shotgun, spread),
 161                 WEP_CVAR_PRI(shotgun, solidpenetration),
 162                 WEP_CVAR_PRI(shotgun, force)); // actually is secondary, but we trick the last shot into playing full reload sound
 163         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
 164 }
 165 void W_Shotgun_Attack3_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 166 {
 167         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 168         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 169         {
 170                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 171                 w_ready(thiswep, actor, weaponentity, fire);
 172                 return;
 173         }
 174
 175         W_Shotgun_Attack(WEP_SHOTGUN, actor, weaponentity, false,
 176                 WEP_CVAR_PRI(shotgun, ammo),
 177                 WEP_CVAR_PRI(shotgun, damage),
 178                 WEP_CVAR_PRI(shotgun, bullets),
 179                 WEP_CVAR_PRI(shotgun, spread),
 180                 WEP_CVAR_PRI(shotgun, solidpenetration),
 181                 WEP_CVAR_PRI(shotgun, force));
 182         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
 183 }
 184
 185 .float shotgun_primarytime;
 186
 187 METHOD(Shotgun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 188 {
 189     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR_SEC(shotgun, melee_range)))
 190         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 191     else
 192         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 193 }
 194
 195 METHOD(Shotgun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 196 {
 197     if(WEP_CVAR(shotgun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
 198     {
 199         // don't force reload an empty shotgun if its melee attack is active
 200         if(WEP_CVAR(shotgun, secondary) < 2) {
 201             thiswep.wr_reload(thiswep, actor, weaponentity);
 202         }
 203     }
 204     else
 205     {
 206         if(fire & 1)
 207         {
 208             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 209             {
 210                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(shotgun, animtime)))
 211                 {
 212                     W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 213                                                 WEP_CVAR_PRI(shotgun, ammo),
 214                                                 WEP_CVAR_PRI(shotgun, damage),
 215                                                 WEP_CVAR_PRI(shotgun, bullets),
 216                                                 WEP_CVAR_PRI(shotgun, spread),
 217                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 218                                                 WEP_CVAR_PRI(shotgun, force));
 219                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor(actor);
 220                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
 221                 }
 222             }
 223         }
 224         else if((fire & 2) && WEP_CVAR(shotgun, secondary) == 2)
 225         {
 226             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 227             {
 228                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(shotgun, alt_animtime)))
 229                 {
 230                     W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 231                                                 WEP_CVAR_PRI(shotgun, ammo),
 232                                                 WEP_CVAR_PRI(shotgun, damage),
 233                                                 WEP_CVAR_PRI(shotgun, bullets),
 234                                                 WEP_CVAR_PRI(shotgun, spread),
 235                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 236                                                 WEP_CVAR_PRI(shotgun, force));
 237                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor(actor);
 238                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
 239                 }
 240             }
 241         }
 242     }
 243     if(actor.(weaponentity).clip_load >= 0) // we are not currently reloading
 244     if(WEP_CVAR(shotgun, secondary) == 1)
 245     if(((fire & 1) && GetResourceAmount(actor, thiswep.ammo_type) <= 0 && !(actor.items & IT_UNLIMITED_WEAPON_AMMO)) || (fire & 2))
 246     if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(shotgun, refire)))
 247     {
 248         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 249         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 250     }
 251 }
 252 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 253 {
 254     float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 255     ammo_amount += actor.(weaponentity).(weapon_load[WEP_SHOTGUN.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 256     return ammo_amount;
 257 }
 258 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 259 {
 260     if(IS_BOT_CLIENT(actor))
 261     if(vdist(actor.origin - actor.enemy.origin, >, WEP_CVAR_SEC(shotgun, melee_range)))
 262         return false; // bots cannot use secondary out of range (fixes constant melee when out of ammo)
 263     switch(WEP_CVAR(shotgun, secondary))
 264     {
 265         case 1: return true; // melee does not use ammo
 266         case 2: // secondary triple shot
 267         {
 268             float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 269             ammo_amount += actor.(weaponentity).(weapon_load[WEP_SHOTGUN.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 270             return ammo_amount;
 271         }
 272         default: return false; // secondary unavailable
 273     }
 274 }
 275 METHOD(Shotgun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 276 {
 277     W_Reload(actor, weaponentity, WEP_CVAR_PRI(shotgun, ammo), SND_RELOAD); // WEAPONTODO
 278 }
 279 METHOD(Shotgun, wr_suicidemessage, Notification(entity thiswep))
 280 {
 281     return WEAPON_THINKING_WITH_PORTALS;
 282 }
 283 METHOD(Shotgun, wr_killmessage, Notification(entity thiswep))
 284 {
 285     if(w_deathtype & HITTYPE_SECONDARY)
 286         return WEAPON_SHOTGUN_MURDER_SLAP;
 287     else
 288         return WEAPON_SHOTGUN_MURDER;
 289 }
 290
 291 #endif
 292 #ifdef CSQC
 293 .float prevric;
 294
 295 METHOD(Shotgun, wr_impacteffect, void(entity thiswep, entity actor))
 296 {
 297     vector org2 = w_org + w_backoff * 2;
 298     pointparticles(EFFECT_SHOTGUN_IMPACT, org2, w_backoff * 1000, 1);
 299     if(!w_issilent && time - actor.prevric > 0.25)
 300     {
 301         if(w_random < 0.05)
 302             sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 303         actor.prevric = time;
 304     }
 305 }
 306
 307 #endif