e577aa1258724ead82187d1455a6027420a7a1f1
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / shotgun.qc
1 #ifndef IMPLEMENTATION
2 CLASS(Shotgun, Weapon)
3 /* ammotype  */ ATTRIB(Shotgun, ammo_field, .int, ammo_shells)
4 /* impulse   */ ATTRIB(Shotgun, impulse, int, 2)
5 /* flags     */ ATTRIB(Shotgun, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN);
6 /* rating    */ ATTRIB(Shotgun, bot_pickupbasevalue, float, BOT_PICKUP_RATING_LOW);
7 /* color     */ ATTRIB(Shotgun, wpcolor, vector, '0.5 0.25 0');
8 /* modelname */ ATTRIB(Shotgun, mdl, string, "shotgun");
9 #ifndef MENUQC
10 /* model     */ ATTRIB(Shotgun, m_model, Model, MDL_SHOTGUN_ITEM);
11 #endif
12 /* crosshair */ ATTRIB(Shotgun, w_crosshair, string, "gfx/crosshairshotgun");
13 /* crosshair */ ATTRIB(Shotgun, w_crosshair_size, float, 0.65);
14 /* wepimg    */ ATTRIB(Shotgun, model2, string, "weaponshotgun");
15 /* refname   */ ATTRIB(Shotgun, netname, string, "shotgun");
16 /* wepname   */ ATTRIB(Shotgun, message, string, _("Shotgun"));
17 ENDCLASS(Shotgun)
18 REGISTER_WEAPON(SHOTGUN, NEW(Shotgun));
19
20 #define SHOTGUN_SETTINGS(w_cvar,w_prop) SHOTGUN_SETTINGS_LIST(w_cvar, w_prop, SHOTGUN, shotgun)
21 #define SHOTGUN_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
22         w_cvar(id, sn, PRI,  ammo) \
23         w_cvar(id, sn, BOTH, animtime) \
24         w_cvar(id, sn, BOTH, refire) \
25         w_cvar(id, sn, PRI,  bullets) \
26         w_cvar(id, sn, BOTH, damage) \
27         w_cvar(id, sn, BOTH, force) \
28         w_cvar(id, sn, PRI,  solidpenetration) \
29         w_cvar(id, sn, PRI,  spread) \
30         w_cvar(id, sn, NONE, secondary) \
31         w_cvar(id, sn, SEC,  melee_time) \
32         w_cvar(id, sn, SEC,  melee_no_doubleslap) \
33         w_cvar(id, sn, SEC,  melee_traces) \
34         w_cvar(id, sn, SEC,  melee_swing_up) \
35         w_cvar(id, sn, SEC,  melee_swing_side) \
36         w_cvar(id, sn, SEC,  melee_nonplayerdamage) \
37         w_cvar(id, sn, SEC,  melee_multihit) \
38         w_cvar(id, sn, SEC,  melee_delay) \
39         w_cvar(id, sn, SEC,  melee_range) \
40         w_cvar(id, sn, SEC,  alt_animtime) \
41         w_cvar(id, sn, SEC,  alt_refire) \
42         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
43         w_prop(id, sn, float,  reloading_time, reload_time) \
44         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
45         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
46         w_prop(id, sn, string, weaponreplace, weaponreplace) \
47         w_prop(id, sn, float,  weaponstart, weaponstart) \
48         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
49         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
50
51 #ifdef SVQC
52 SHOTGUN_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
53 #endif
54 #endif
55 #ifdef IMPLEMENTATION
56 #ifdef SVQC
57 void spawnfunc_weapon_shotgun(void) { weapon_defaultspawnfunc(WEP_SHOTGUN.m_id); }
58
59 void W_Shotgun_Attack(Weapon thiswep, float isprimary)
60 {SELFPARAM();
61         float   sc;
62         entity flash;
63
64         W_DecreaseAmmo(thiswep, WEP_CVAR_PRI(shotgun, ammo));
65
66         W_SetupShot(self, true, 5, SND(SHOTGUN_FIRE), ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), WEP_CVAR_PRI(shotgun, damage) * WEP_CVAR_PRI(shotgun, bullets));
67         for(sc = 0;sc < WEP_CVAR_PRI(shotgun, bullets);sc = sc + 1)
68                 fireBullet(w_shotorg, w_shotdir, WEP_CVAR_PRI(shotgun, spread), WEP_CVAR_PRI(shotgun, solidpenetration), WEP_CVAR_PRI(shotgun, damage), WEP_CVAR_PRI(shotgun, force), WEP_SHOTGUN.m_id, 0);
69
70         Send_Effect(EFFECT_SHOTGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, WEP_CVAR_PRI(shotgun, ammo));
71
72         // casing code
73         if(autocvar_g_casings >= 1)
74                 for(sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
75                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
76
77         // muzzle flash for 1st person view
78         flash = spawn();
79         setmodel(flash, MDL_SHOTGUN_MUZZLEFLASH); // precision set below
80         flash.think = SUB_Remove;
81         flash.nextthink = time + 0.06;
82         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
83         W_AttachToShotorg(flash, '5 0 0');
84 }
85
86 .float swing_prev;
87 .entity swing_alreadyhit;
88 void W_Shotgun_Melee_Think(void)
89 {SELFPARAM();
90         // declarations
91         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
92         entity target_victim;
93         vector targpos;
94
95         if(!self.cnt) // set start time of melee
96         {
97                 self.cnt = time;
98                 W_PlayStrengthSound(self.realowner);
99         }
100
101         makevectors(self.realowner.v_angle); // update values for v_* vectors
102
103         // calculate swing percentage based on time
104         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor();
105         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
106         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
107
108         // check to see if we can still continue, otherwise give up now
109         if((self.realowner.deadflag != DEAD_NO) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
110         {
111                 remove(self);
112                 return;
113         }
114
115         // if okay, perform the traces needed for this frame
116         for(i=self.swing_prev; i < f; ++i)
117         {
118                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
119
120                 targpos = (self.realowner.origin + self.realowner.view_ofs
121                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
122                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
123                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
124
125                 WarpZone_traceline_antilag(self, self.realowner.origin + self.realowner.view_ofs, targpos, false, self, ANTILAG_LATENCY(self.realowner));
126
127                 // draw lightning beams for debugging
128                 //te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
129                 //te_customflash(targpos, 40,  2, '1 1 1');
130
131                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
132
133                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
134                         && (trace_ent.takedamage == DAMAGE_AIM)
135                         && (trace_ent != self.swing_alreadyhit)
136                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
137                 {
138                         target_victim = trace_ent; // so it persists through other calls
139
140                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
141                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
142                         else
143                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
144
145                         //print(strcat(self.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
146
147                         Damage(target_victim, self.realowner, self.realowner,
148                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY,
149                                 self.realowner.origin + self.realowner.view_ofs,
150                                 v_forward * WEP_CVAR_SEC(shotgun, force));
151
152                         if(accuracy_isgooddamage(self.realowner, target_victim)) { accuracy_add(self.realowner, WEP_SHOTGUN.m_id, 0, swing_damage); }
153
154                         // draw large red flash for debugging
155                         //te_customflash(targpos, 200, 2, '15 0 0');
156
157                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
158                         {
159                                 self.swing_alreadyhit = target_victim;
160                                 continue; // move along to next trace
161                         }
162                         else
163                         {
164                                 remove(self);
165                                 return;
166                         }
167                 }
168         }
169
170         if(time >= self.cnt + meleetime)
171         {
172                 // melee is finished
173                 remove(self);
174                 return;
175         }
176         else
177         {
178                 // set up next frame
179                 self.swing_prev = i;
180                 self.nextthink = time;
181         }
182 }
183
184 void W_Shotgun_Attack2(Weapon thiswep, bool fire1, bool fire2)
185 {SELFPARAM();
186         sound(self, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
187         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
188
189         entity meleetemp;
190         meleetemp = spawn();
191         meleetemp.realowner = self;
192         meleetemp.think = W_Shotgun_Melee_Think;
193         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor();
194         W_SetupShot_Range(self, true, 0, "", 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range));
195 }
196
197 // alternate secondary weapon frames
198 void W_Shotgun_Attack3_Frame2(Weapon thiswep, bool fire1, bool fire2)
199 {SELFPARAM();
200         if (!_WEP_ACTION(self.weapon, WR_CHECKAMMO2))
201         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
202         {
203                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
204                 w_ready(thiswep, fire1, fire2);
205                 return;
206         }
207
208         sound(self, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
209         W_Shotgun_Attack(WEP_SHOTGUN, true); // actually is secondary, but we trick the last shot into playing full reload sound
210         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
211 }
212 void W_Shotgun_Attack3_Frame1(Weapon thiswep, bool fire1, bool fire2)
213 {SELFPARAM();
214         if (!_WEP_ACTION(self.weapon, WR_CHECKAMMO2))
215         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
216         {
217                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
218                 w_ready(thiswep, fire1, fire2);
219                 return;
220         }
221
222         W_Shotgun_Attack(WEP_SHOTGUN, false);
223         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
224 }
225
226 .float shotgun_primarytime;
227
228                 METHOD(Shotgun, wr_aim, bool(entity thiswep))
229                 {
230                         if(vlen(self.origin-self.enemy.origin) <= WEP_CVAR_SEC(shotgun, melee_range))
231                                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, false);
232                         else
233                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, false);
234
235                         return true;
236                 }
237                 METHOD(Shotgun, wr_think, bool(entity thiswep, bool fire1, bool fire2))
238                 {
239                         if(WEP_CVAR(shotgun, reload_ammo) && self.clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
240                         {
241                                 // don't force reload an empty shotgun if its melee attack is active
242                                 if(WEP_CVAR(shotgun, secondary) < 2)
243                                         _WEP_ACTION(self.weapon, WR_RELOAD);
244                         }
245                         else
246                         {
247                                 if(fire1)
248                                 {
249                                         if(time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
250                                         {
251                                                 if(weapon_prepareattack(false, WEP_CVAR_PRI(shotgun, animtime)))
252                                                 {
253                                                         W_Shotgun_Attack(thiswep, true);
254                                                         self.shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor();
255                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
256                                                 }
257                                         }
258                                 }
259                                 else if(fire2 && WEP_CVAR(shotgun, secondary) == 2)
260                                 {
261                                         if(time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
262                                         {
263                                                 if(weapon_prepareattack(false, WEP_CVAR_SEC(shotgun, alt_animtime)))
264                                                 {
265                                                         W_Shotgun_Attack(thiswep, false);
266                                                         self.shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor();
267                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
268                                                 }
269                                         }
270                                 }
271                         }
272                         if(self.clip_load >= 0) // we are not currently reloading
273                         if(!self.crouch) // no crouchmelee please
274                         if(WEP_CVAR(shotgun, secondary) == 1)
275                         if((fire1 && self.WEP_AMMO(SHOTGUN) <= 0 && !(self.items & IT_UNLIMITED_WEAPON_AMMO)) || fire2)
276                         if(weapon_prepareattack(true, WEP_CVAR_SEC(shotgun, refire)))
277                         {
278                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
279                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
280                         }
281
282                         return true;
283                 }
284                 METHOD(Shotgun, wr_init, bool(entity thiswep))
285                 {
286                         SHOTGUN_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
287                         return true;
288                 }
289                 METHOD(Shotgun, wr_setup, bool(entity thiswep))
290                 {
291                         self.ammo_field = ammo_none;
292                         return true;
293                 }
294                 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep))
295                 {
296                         float ammo_amount = self.WEP_AMMO(SHOTGUN) >= WEP_CVAR_PRI(shotgun, ammo);
297                         ammo_amount += self.(weapon_load[WEP_SHOTGUN.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
298                         return ammo_amount;
299                 }
300                 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep))
301                 {
302                         if(IS_BOT_CLIENT(self))
303                         if(vlen(self.origin-self.enemy.origin) > WEP_CVAR_SEC(shotgun, melee_range))
304                                 return false; // bots cannot use secondary out of range (fixes constant melee when out of ammo)
305                         switch(WEP_CVAR(shotgun, secondary))
306                         {
307                                 case 1: return true; // melee does not use ammo
308                                 case 2: // secondary triple shot
309                                 {
310                                         float ammo_amount = self.WEP_AMMO(SHOTGUN) >= WEP_CVAR_PRI(shotgun, ammo);
311                                         ammo_amount += self.(weapon_load[WEP_SHOTGUN.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
312                                         return ammo_amount;
313                                 }
314                                 default: return false; // secondary unavailable
315                         }
316                 }
317                 METHOD(Shotgun, wr_config, bool(entity thiswep))
318                 {
319                         SHOTGUN_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
320                         return true;
321                 }
322                 METHOD(Shotgun, wr_reload, bool(entity thiswep))
323                 {
324                         W_Reload(WEP_CVAR_PRI(shotgun, ammo), SND(RELOAD)); // WEAPONTODO
325                         return true;
326                 }
327                 METHOD(Shotgun, wr_suicidemessage, bool(entity thiswep))
328                 {
329                         return WEAPON_THINKING_WITH_PORTALS;
330                 }
331                 METHOD(Shotgun, wr_killmessage, bool(entity thiswep))
332                 {
333                         if(w_deathtype & HITTYPE_SECONDARY)
334                                 return WEAPON_SHOTGUN_MURDER_SLAP;
335                         else
336                                 return WEAPON_SHOTGUN_MURDER;
337                 }
338
339 #endif
340 #ifdef CSQC
341 .float prevric;
342
343                 METHOD(Shotgun, wr_impacteffect, bool(entity thiswep))
344                 {
345                         vector org2;
346                         org2 = w_org + w_backoff * 2;
347                         pointparticles(particleeffectnum(EFFECT_SHOTGUN_IMPACT), org2, w_backoff * 1000, 1);
348                         if(!w_issilent && time - self.prevric > 0.25)
349                         {
350                                 if(w_random < 0.0165)
351                                         sound(self, CH_SHOTS, SND_RIC1, VOL_BASE, ATTEN_NORM);
352                                 else if(w_random < 0.033)
353                                         sound(self, CH_SHOTS, SND_RIC2, VOL_BASE, ATTEN_NORM);
354                                 else if(w_random < 0.05)
355                                         sound(self, CH_SHOTS, SND_RIC3, VOL_BASE, ATTEN_NORM);
356                                 self.prevric = time;
357                         }
358
359                         return true;
360                 }
361                 METHOD(Shotgun, wr_init, bool(entity thiswep))
362                 {
363                         return true;
364                 }
365                 METHOD(Shotgun, wr_zoomreticle, bool(entity thiswep))
366                 {
367                         // no weapon specific image for this weapon
368                         return false;
369                 }
370
371 #endif
372 #endif