qcsrc/common/weapons/weapon/vaporizer.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Vaporizer, Weapon)
   3 /* ammotype  */ ATTRIB(Vaporizer, ammo_field, .int, ammo_cells)
   4 /* impulse   */ ATTRIB(Vaporizer, impulse, int, 7)
   5 /* flags     */ ATTRIB(Vaporizer, spawnflags, int, WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN);
   6 /* rating    */ ATTRIB(Vaporizer, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Vaporizer, wpcolor, vector, '0.5 1 1');
   8 /* modelname */ ATTRIB(Vaporizer, mdl, string, "minstanex");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Vaporizer, m_model, Model, MDL_VAPORIZER_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Vaporizer, w_crosshair, string, "gfx/crosshairminstanex");
  13 /* crosshair */ ATTRIB(Vaporizer, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(Vaporizer, model2, string, "weaponminstanex");
  15 /* refname   */ ATTRIB(Vaporizer, netname, string, "vaporizer");
  16 /* wepname   */ ATTRIB(Vaporizer, m_name, string, _("Vaporizer"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, ammo, float, PRI) \
  21         P(class, prefix, animtime, float, PRI) \
  22         P(class, prefix, damage, float, PRI) \
  23         P(class, prefix, refire, float, PRI) \
  24         P(class, prefix, ammo, float, SEC) \
  25         P(class, prefix, animtime, float, SEC) \
  26         P(class, prefix, damage, float, SEC) \
  27         P(class, prefix, delay, float, SEC) \
  28         P(class, prefix, edgedamage, float, SEC) \
  29         P(class, prefix, force, float, SEC) \
  30         P(class, prefix, lifetime, float, SEC) \
  31         P(class, prefix, radius, float, SEC) \
  32         P(class, prefix, refire, float, SEC) \
  33         P(class, prefix, shotangle, float, SEC) \
  34         P(class, prefix, speed, float, SEC) \
  35         P(class, prefix, spread, float, SEC) \
  36         P(class, prefix, reload_ammo, float, NONE) \
  37         P(class, prefix, reload_time, float, NONE) \
  38         P(class, prefix, switchdelay_raise, float, NONE) \
  39         P(class, prefix, switchdelay_drop, float, NONE) \
  40         P(class, prefix, weaponreplace, string, NONE) \
  41         P(class, prefix, weaponstart, float, NONE) \
  42         P(class, prefix, weaponstartoverride, float, NONE) \
  43         P(class, prefix, weaponthrowable, float, NONE) \
  44         END()
  45     W_PROPS(X, Vaporizer, vaporizer)
  46 #undef X
  47
  48 ENDCLASS(Vaporizer)
  49 REGISTER_WEAPON(VAPORIZER, vaporizer, NEW(Vaporizer));
  50
  51
  52 #ifdef SVQC
  53 .float vaporizer_lasthit;
  54 .float jump_interval;
  55 .float jump_interval2;
  56 .bool held_down;
  57 .float rm_force;
  58 .float rm_damage;
  59 .float rm_edmg;
  60 #endif
  61 #endif
  62 #ifdef IMPLEMENTATION
  63
  64 REGISTER_NET_TEMP(TE_CSQC_VAPORBEAMPARTICLE)
  65
  66 #if defined(SVQC)
  67 void SendCSQCVaporizerBeamParticle(entity player, int hit) {
  68         vector v;
  69         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  70         WriteHeader(MSG_BROADCAST, TE_CSQC_VAPORBEAMPARTICLE);
  71         WriteCoord(MSG_BROADCAST, w_shotorg.x);
  72         WriteCoord(MSG_BROADCAST, w_shotorg.y);
  73         WriteCoord(MSG_BROADCAST, w_shotorg.z);
  74         WriteCoord(MSG_BROADCAST, v.x);
  75         WriteCoord(MSG_BROADCAST, v.y);
  76         WriteCoord(MSG_BROADCAST, v.z);
  77         WriteByte(MSG_BROADCAST, hit);
  78         WriteByte(MSG_BROADCAST, etof(player));
  79         WriteByte(MSG_BROADCAST, player.team);
  80 }
  81 #elif defined(CSQC)
  82 bool autocvar_cl_vaporizerbeam_particle = false;
  83 float autocvar_cl_vaporizerbeam_lifetime = 0.8;
  84 float autocvar_cl_vaporizerbeam_colorboost = 0.7;
  85
  86 string Draw_VaporizerBeam_trace_callback_tex;
  87 float Draw_VaporizerBeam_trace_callback_rnd;
  88 vector Draw_VaporizerBeam_trace_callback_rgb;
  89 float Draw_VaporizerBeam_trace_callback_a;
  90 void Draw_VaporizerBeam_trace_callback(vector start, vector hit, vector end)
  91 {
  92         float i;
  93         vector vorg;
  94         vorg = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
  95         for(i = 0; i < Draw_VaporizerBeam_trace_callback_a; ++i)
  96                 Draw_CylindricLine(hit, start, 8, Draw_VaporizerBeam_trace_callback_tex, 0.25, Draw_VaporizerBeam_trace_callback_rnd, Draw_VaporizerBeam_trace_callback_rgb, min(1, Draw_VaporizerBeam_trace_callback_a - i), DRAWFLAG_NORMAL, vorg);
  97         Draw_VaporizerBeam_trace_callback_rnd += 0.25 * vlen(hit - start) / 8;
  98 }
  99
 100 .vector vorg1, vorg2;
 101 .float spawn_time;
 102 void VaporizerBeam_Draw(entity this)
 103 {
 104         //draw either the old v2.3 beam or the new beam
 105         particles_alphamin = particles_alphamax = particles_fade = 1;
 106
 107         string tex = "particles/lgbeam";
 108         if(this.cnt)
 109                 tex = "particles/gauntletbeam";
 110         vector rgb;
 111         //entity e = CSQCModel_server2csqc(this.sv_entnum - 1);
 112         //if (e == NULL)
 113         //{
 114                 rgb = colormapPaletteColor(stof(getplayerkeyvalue(this.sv_entnum - 1, "colors")) & 0x0F, true);
 115                 //rgb = '1 1 1';
 116         //}
 117         //else
 118         //      rgb = e.glowmod;
 119         rgb *= (1 + autocvar_cl_vaporizerbeam_colorboost);
 120
 121         float fail = (this.nextthink - time);
 122
 123         Draw_VaporizerBeam_trace_callback_tex = tex;
 124         Draw_VaporizerBeam_trace_callback_rnd = 0;
 125         Draw_VaporizerBeam_trace_callback_rgb = rgb;
 126         Draw_VaporizerBeam_trace_callback_a = bound(0, fail, 1);
 127         WarpZone_TraceBox_ThroughZone(this.vorg1, '0 0 0', '0 0 0', this.vorg2, MOVE_NOTHING, NULL, NULL, Draw_VaporizerBeam_trace_callback);
 128         Draw_VaporizerBeam_trace_callback_tex = string_null;
 129
 130         /*if(!MUTATOR_CALLHOOK(Particles_VaporizerBeam, this.vorg1, this.vorg2))
 131         if(autocvar_cl_particles_oldvortexbeam && (STAT(ALLOW_OLDVORTEXBEAM) || isdemo()))
 132                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), this.vorg1, this.vorg2, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
 133         else
 134                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM), this.vorg1, this.vorg2, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);*/
 135 }
 136
 137 NET_HANDLE(TE_CSQC_VAPORBEAMPARTICLE, bool isNew)
 138 {
 139         Net_Accept(vortex_beam);
 140         setthink(this, SUB_Remove);
 141         this.nextthink = time + bound(0, autocvar_cl_vaporizerbeam_lifetime, 10);
 142         this.draw = VaporizerBeam_Draw;
 143         this.drawmask = MASK_NORMAL;
 144
 145         this.vorg1_x = ReadCoord(); this.vorg1_y = ReadCoord(); this.vorg1_z = ReadCoord();
 146         this.vorg2_x = ReadCoord(); this.vorg2_y = ReadCoord(); this.vorg2_z = ReadCoord();
 147         this.cnt = ReadByte();
 148         int myowner = ReadByte();
 149         this.owner = playerslots[myowner - 1];
 150         this.sv_entnum = myowner;
 151         this.team = ReadByte() - 1;
 152
 153         pointparticles(EFFECT_VORTEX_MUZZLEFLASH, this.vorg1, normalize(this.vorg2 - this.vorg1) * 1000, 1);
 154
 155         if(autocvar_cl_vaporizerbeam_particle)
 156         {
 157                 WarpZone_TrailParticles(NULL, particleeffectnum(((this.cnt) ? EFFECT_VAPORIZER_HIT(this.team) : EFFECT_VAPORIZER(this.team))), this.vorg1, this.vorg2);
 158                 this.draw = func_null;
 159                 this.drawmask = MASK_NORMAL;
 160                 remove(this);
 161         }
 162
 163         return true;
 164 }
 165 #endif
 166
 167 #ifdef SVQC
 168 spawnfunc(weapon_vaporizer) { weapon_defaultspawnfunc(this, WEP_VAPORIZER); }
 169 spawnfunc(weapon_minstanex) { spawnfunc_weapon_vaporizer(this); }
 170
 171 void W_RocketMinsta_Explosion(entity actor, vector loc)
 172 {
 173         if(accuracy_canbegooddamage(actor))
 174                 accuracy_add(actor, WEP_DEVASTATOR.m_id, autocvar_g_rm_damage, 0);
 175         entity dmgent = spawn();
 176         dmgent.owner = dmgent.realowner = actor;
 177         setorigin(dmgent, loc);
 178         RadiusDamage (dmgent, actor, autocvar_g_rm_damage, autocvar_g_rm_edgedamage, autocvar_g_rm_radius, NULL, NULL, autocvar_g_rm_force, WEP_DEVASTATOR.m_id | HITTYPE_SPLASH, other);
 179         remove(dmgent);
 180 }
 181
 182 void W_Vaporizer_Attack(Weapon thiswep, entity actor)
 183 {
 184         bool flying = IsFlying(actor); // do this BEFORE to make the trace values from FireRailgunBullet last
 185         float vaporizer_damage = ((WEP_CVAR_PRI(vaporizer, damage) > 0) ? WEP_CVAR_PRI(vaporizer, damage) : 10000);
 186
 187         W_SetupShot(actor, true, 0, SND_Null, CH_WEAPON_A, vaporizer_damage);
 188         // handle sound separately so we can change the volume
 189         // added bonus: no longer plays the strength sound (strength gives no bonus to instakill anyway)
 190         sound (actor, CH_WEAPON_A, SND_MINSTANEXFIRE, VOL_BASE * 0.8, ATTEN_NORM);
 191
 192         yoda = 0;
 193         damage_goodhits = 0;
 194         FireRailgunBullet(actor, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, vaporizer_damage, 800, 0, 0, 0, 0, WEP_VAPORIZER.m_id);
 195
 196         // do this now, as goodhits is disabled below
 197         SendCSQCVaporizerBeamParticle(actor, damage_goodhits);
 198
 199         if(yoda && flying)
 200                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 201         if(damage_goodhits && actor.vaporizer_lasthit)
 202         {
 203                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 204                 damage_goodhits = 0; // only every second time
 205         }
 206
 207         actor.vaporizer_lasthit = damage_goodhits;
 208
 209         if(autocvar_g_rm)
 210         if(!(trace_dphitq3surfaceflags & (Q3SURFACEFLAG_SKY | Q3SURFACEFLAG_NOIMPACT)))
 211                 W_RocketMinsta_Explosion(actor, trace_endpos);
 212
 213         W_DecreaseAmmo(thiswep, actor, ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)));
 214 }
 215
 216 void W_RocketMinsta_Laser_Explode (entity this)
 217 {
 218         if(other.takedamage == DAMAGE_AIM)
 219                 if(IS_PLAYER(other))
 220                         if(DIFF_TEAM(this.realowner, other))
 221                                 if(!IS_DEAD(other))
 222                                         if(IsFlying(other))
 223                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
 224
 225         this.event_damage = func_null;
 226         this.takedamage = DAMAGE_NO;
 227         RadiusDamage (this, this.realowner, this.rm_damage, this.rm_edmg, autocvar_g_rm_laser_radius, NULL, NULL, this.rm_force, this.projectiledeathtype, other);
 228         remove(this);
 229 }
 230
 231 void W_RocketMinsta_Laser_Explode_use(entity this, entity actor, entity trigger)
 232 {
 233         W_RocketMinsta_Laser_Explode(this);
 234 }
 235
 236 void W_RocketMinsta_Laser_Touch(entity this, entity toucher)
 237 {
 238         PROJECTILE_TOUCH(this, toucher);
 239         //W_RocketMinsta_Laser_Explode ();
 240         RadiusDamage(this, this.realowner, this.rm_damage, this.rm_edmg, autocvar_g_rm_laser_radius, NULL, NULL, this.rm_force, this.projectiledeathtype, toucher);
 241         remove(this);
 242 }
 243
 244 void W_RocketMinsta_Attack2(entity actor)
 245 {
 246         makevectors(actor.v_angle);
 247
 248         entity proj;
 249         float counter = 0;
 250         float total = autocvar_g_rm_laser_count;
 251         float spread = autocvar_g_rm_laser_spread;
 252         float rndspread = autocvar_g_rm_laser_spread_random;
 253
 254         Weapon w = PS(actor).m_weapon;
 255         PS(actor).m_weapon = WEP_ELECTRO;
 256         W_SetupShot_ProjectileSize (actor, '0 0 -3', '0 0 -3', false, 2, SND_CRYLINK_FIRE, CH_WEAPON_A, autocvar_g_rm_laser_damage);
 257         PS(actor).m_weapon = w;
 258
 259         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 260
 261     while(counter < total)
 262         {
 263         proj = new(plasma_prim);
 264         proj.owner = proj.realowner = actor;
 265         proj.bot_dodge = true;
 266         proj.bot_dodgerating = autocvar_g_rm_laser_damage;
 267         proj.use = W_RocketMinsta_Laser_Explode_use;
 268         setthink(proj, adaptor_think2use_hittype_splash);
 269         proj.nextthink = time + autocvar_g_rm_laser_lifetime;
 270         PROJECTILE_MAKETRIGGER(proj);
 271         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 272         setorigin(proj, w_shotorg);
 273
 274                 proj.rm_force = autocvar_g_rm_laser_force / total;
 275                 proj.rm_damage = autocvar_g_rm_laser_damage / total;
 276                 proj.rm_edmg = proj.rm_damage;
 277
 278         //W_SetupProjectileVelocity(proj, autocvar_g_rm_laser_speed, spread * (rndspread ? random() : 1) * autocvar_g_rm_laser_speed);
 279
 280         proj.movetype = MOVETYPE_BOUNCEMISSILE;
 281         //W_SETUPPROJECTILEVELOCITY(proj, g_balance_minstanex_laser);
 282                 proj.velocity = (w_shotdir + (((counter + 0.5) / total) * 2 - 1) * v_right * (spread * (rndspread ? random() : 1))) * cvar("g_rm_laser_speed");
 283                 proj.velocity_z = proj.velocity_z + cvar("g_rm_laser_zspread") * (random() - 0.5);
 284                 proj.velocity = W_CalculateProjectileVelocity(actor, actor.velocity, proj.velocity, true);
 285         proj.angles = vectoangles(proj.velocity);
 286         settouch(proj, W_RocketMinsta_Laser_Touch);
 287         setsize(proj, '0 0 -3', '0 0 -3');
 288         proj.flags = FL_PROJECTILE;
 289         proj.missile_flags = MIF_SPLASH;
 290
 291         CSQCProjectile(proj, true, PROJECTILE_ROCKETMINSTA_LASER, true);
 292
 293         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 294         counter++;
 295     }
 296 }
 297
 298 void W_RocketMinsta_Attack3 (entity actor)
 299 {
 300         makevectors(actor.v_angle);
 301
 302         entity proj;
 303         float counter = 0;
 304         float total = 1;
 305
 306         Weapon w = PS(actor).m_weapon;
 307         PS(actor).m_weapon = WEP_ELECTRO;
 308         W_SetupShot_ProjectileSize (actor, '0 0 -3', '0 0 -3', false, 2, SND_ELECTRO_FIRE2, CH_WEAPON_A, autocvar_g_rm_laser_damage);
 309         PS(actor).m_weapon = w;
 310
 311         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 312
 313     while(counter < total)
 314         {
 315         proj = new(plasma_prim);
 316         proj.owner = proj.realowner = actor;
 317         proj.bot_dodge = true;
 318         proj.bot_dodgerating = autocvar_g_rm_laser_damage;
 319         proj.use = W_RocketMinsta_Laser_Explode_use;
 320         setthink(proj, adaptor_think2use_hittype_splash);
 321         proj.nextthink = time + autocvar_g_rm_laser_lifetime;
 322         PROJECTILE_MAKETRIGGER(proj);
 323         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 324         setorigin(proj, w_shotorg);
 325
 326                 proj.rm_force = autocvar_g_rm_laser_force / total;
 327                 proj.rm_damage = autocvar_g_rm_laser_damage / total;
 328                 proj.rm_edmg = proj.rm_damage;
 329
 330         //W_SetupProjectileVelocity(proj, autocvar_g_rm_laser_speed, spread * (rndspread ? random() : 1) * autocvar_g_rm_laser_speed);
 331
 332         proj.movetype = MOVETYPE_BOUNCEMISSILE;
 333                 proj.velocity = w_shotdir * autocvar_g_rm_laser_speed;
 334                 proj.velocity = W_CalculateProjectileVelocity(actor, actor.velocity, proj.velocity, true);
 335         proj.angles = vectoangles(proj.velocity);
 336         settouch(proj, W_RocketMinsta_Laser_Touch);
 337         setsize(proj, '0 0 -3', '0 0 -3');
 338         proj.flags = FL_PROJECTILE;
 339         proj.missile_flags = MIF_SPLASH;
 340
 341         CSQCProjectile(proj, true, PROJECTILE_ROCKETMINSTA_LASER, true);
 342
 343         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 344         counter++;
 345     }
 346 }
 347
 348 METHOD(Vaporizer, wr_aim, void(entity thiswep, entity actor))
 349 {
 350     if(actor.(thiswep.ammo_field) > 0)
 351         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, 1000000, 0, 1, false);
 352     else
 353         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), false); // WEAPONTODO: replace with proper vaporizer cvars
 354 }
 355 METHOD(Vaporizer, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 356 {
 357     float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 358     // if the laser uses load, we also consider its ammo for reloading
 359     if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && actor.clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) { // forced reload
 360         thiswep.wr_reload(thiswep, actor, weaponentity);
 361     } else if(WEP_CVAR(vaporizer, reload_ammo) && actor.clip_load < vaporizer_ammo) { // forced reload
 362         thiswep.wr_reload(thiswep, actor, weaponentity);
 363     }
 364     if((fire & 1) && (actor.ammo_cells || !autocvar_g_rm) && !forbidWeaponUse(actor))
 365     {
 366         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vaporizer, refire)))
 367         {
 368             W_Vaporizer_Attack(thiswep, actor);
 369             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 370         }
 371     }
 372     if((fire & 2) || ((fire & 1) && !actor.ammo_cells && autocvar_g_rm))
 373     {
 374         if((autocvar_g_rm && autocvar_g_rm_laser) || autocvar_g_rm_laser == 2)
 375         {
 376             bool rapid = autocvar_g_rm_laser_rapid;
 377             if(actor.jump_interval <= time && !actor.held_down)
 378             {
 379                 if(rapid)
 380                     actor.held_down = true;
 381                 actor.jump_interval = time + autocvar_g_rm_laser_refire;
 382                 actor.jump_interval2 = time + autocvar_g_rm_laser_rapid_delay;
 383                 damage_goodhits = 0;
 384                 W_RocketMinsta_Attack2(actor);
 385             }
 386             else if(rapid && actor.jump_interval2 <= time && actor.held_down)
 387             {
 388                 actor.jump_interval2 = time + autocvar_g_rm_laser_rapid_refire;
 389                 damage_goodhits = 0;
 390                 W_RocketMinsta_Attack3(actor);
 391                 //weapon_thinkf(actor, WFRAME_FIRE2, autocvar_g_rm_laser_rapid_animtime, w_ready);
 392             }
 393         }
 394         else if (actor.jump_interval <= time)
 395         {
 396             // handle refire manually, so that primary and secondary can be fired without conflictions (important for instagib)
 397             actor.jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor(actor);
 398
 399             // decrease ammo for the laser?
 400             if(WEP_CVAR_SEC(vaporizer, ammo))
 401                 W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(vaporizer, ammo));
 402
 403             // ugly instagib hack to reuse the fire mode of the laser
 404             makevectors(actor.v_angle);
 405             Weapon oldwep = PS(actor).m_weapon; // we can't avoid this hack
 406             PS(actor).m_weapon = WEP_BLASTER;
 407             W_Blaster_Attack(
 408                 actor,
 409                 WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 410                 WEP_CVAR_SEC(vaporizer, shotangle),
 411                 WEP_CVAR_SEC(vaporizer, damage),
 412                 WEP_CVAR_SEC(vaporizer, edgedamage),
 413                 WEP_CVAR_SEC(vaporizer, radius),
 414                 WEP_CVAR_SEC(vaporizer, force),
 415                 WEP_CVAR_SEC(vaporizer, speed),
 416                 WEP_CVAR_SEC(vaporizer, spread),
 417                 WEP_CVAR_SEC(vaporizer, delay),
 418                 WEP_CVAR_SEC(vaporizer, lifetime)
 419             );
 420             PS(actor).m_weapon = oldwep;
 421
 422             // now do normal refire
 423             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 424         }
 425     }
 426     else
 427         actor.held_down = false;
 428 }
 429 METHOD(Vaporizer, wr_setup, void(entity thiswep, entity actor))
 430 {
 431     actor.ammo_field = (thiswep.ammo_field);
 432     actor.vaporizer_lasthit = 0;
 433 }
 434 METHOD(Vaporizer, wr_checkammo1, bool(entity thiswep, entity actor))
 435 {
 436     float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 437     float ammo_amount = actor.(thiswep.ammo_field) >= vaporizer_ammo;
 438     ammo_amount += actor.(weapon_load[WEP_VAPORIZER.m_id]) >= vaporizer_ammo;
 439     return ammo_amount;
 440 }
 441 METHOD(Vaporizer, wr_checkammo2, bool(entity thiswep, entity actor))
 442 {
 443     if(!WEP_CVAR_SEC(vaporizer, ammo))
 444         return true;
 445     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(vaporizer, ammo);
 446     ammo_amount += actor.(weapon_load[WEP_VAPORIZER.m_id]) >= WEP_CVAR_SEC(vaporizer, ammo);
 447     return ammo_amount;
 448 }
 449 METHOD(Vaporizer, wr_resetplayer, void(entity thiswep, entity actor))
 450 {
 451     actor.vaporizer_lasthit = 0;
 452 }
 453 METHOD(Vaporizer, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 454 {
 455     float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 456     float used_ammo;
 457     if(WEP_CVAR_SEC(vaporizer, ammo))
 458         used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 459     else
 460         used_ammo = vaporizer_ammo;
 461
 462     W_Reload(actor, used_ammo, SND_RELOAD);
 463 }
 464 METHOD(Vaporizer, wr_suicidemessage, Notification(entity thiswep))
 465 {
 466     return WEAPON_THINKING_WITH_PORTALS;
 467 }
 468 METHOD(Vaporizer, wr_killmessage, Notification(entity thiswep))
 469 {
 470     return WEAPON_VAPORIZER_MURDER;
 471 }
 472
 473 #endif
 474 #ifdef CSQC
 475
 476 METHOD(Vaporizer, wr_impacteffect, void(entity thiswep, entity actor))
 477 {
 478     vector org2 = w_org + w_backoff * 6;
 479     if(w_deathtype & HITTYPE_SECONDARY)
 480     {
 481         pointparticles(EFFECT_BLASTER_IMPACT, org2, w_backoff * 1000, 1);
 482         if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 483     }
 484     else
 485     {
 486         pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 487         if(!w_issilent) { sound(actor, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM); }
 488     }
 489 }
 490 METHOD(Vaporizer, wr_init, void(entity thiswep))
 491 {
 492     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 493     {
 494         precache_pic("gfx/reticle_nex");
 495     }
 496 }
 497 METHOD(Vaporizer, wr_zoomreticle, bool(entity thiswep))
 498 {
 499     if(button_zoom || zoomscript_caught)
 500     {
 501         reticle_image = "gfx/reticle_nex";
 502         return true;
 503     }
 504     else
 505     {
 506         // no weapon specific image for this weapon
 507         return false;
 508     }
 509 }
 510
 511 #endif
 512 #endif