qcsrc/common/weapons/weapon/vortex.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Vortex, Weapon)
   3 /* ammotype  */ ATTRIB(Vortex, ammo_field, .int, ammo_cells)
   4 /* impulse   */ ATTRIB(Vortex, impulse, int, 7)
   5 /* flags     */ ATTRIB(Vortex, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN);
   6 /* rating    */ ATTRIB(Vortex, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Vortex, wpcolor, vector, '0.5 1 1');
   8 /* modelname */ ATTRIB(Vortex, mdl, string, "nex");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Vortex, m_model, Model, MDL_VORTEX_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Vortex, w_crosshair, string, "gfx/crosshairnex");
  13 /* crosshair */ ATTRIB(Vortex, w_crosshair_size, float, 0.65);
  14 /* wepimg    */ ATTRIB(Vortex, model2, string, "weaponnex");
  15 /* refname   */ ATTRIB(Vortex, netname, string, "vortex");
  16 /* wepname   */ ATTRIB(Vortex, message, string, _("Vortex"));
  17 ENDCLASS(Vortex)
  18 REGISTER_WEAPON(VORTEX, NEW(Vortex));
  19
  20 #define VORTEX_SETTINGS(w_cvar,w_prop) VORTEX_SETTINGS_LIST(w_cvar, w_prop, VORTEX, vortex)
  21 #define VORTEX_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  22         w_cvar(id, sn, BOTH, ammo) \
  23         w_cvar(id, sn, BOTH, animtime) \
  24         w_cvar(id, sn, BOTH, damage) \
  25         w_cvar(id, sn, BOTH, force) \
  26         w_cvar(id, sn, BOTH, damagefalloff_mindist) \
  27         w_cvar(id, sn, BOTH, damagefalloff_maxdist) \
  28         w_cvar(id, sn, BOTH, damagefalloff_halflife) \
  29         w_cvar(id, sn, BOTH, damagefalloff_forcehalflife) \
  30         w_cvar(id, sn, BOTH, refire) \
  31         w_cvar(id, sn, NONE, charge) \
  32         w_cvar(id, sn, NONE, charge_mindmg) \
  33         w_cvar(id, sn, NONE, charge_shot_multiplier) \
  34         w_cvar(id, sn, NONE, charge_animlimit) \
  35         w_cvar(id, sn, NONE, charge_limit) \
  36         w_cvar(id, sn, NONE, charge_rate) \
  37         w_cvar(id, sn, NONE, charge_rot_rate) \
  38         w_cvar(id, sn, NONE, charge_rot_pause) \
  39         w_cvar(id, sn, NONE, charge_start) \
  40         w_cvar(id, sn, NONE, charge_minspeed) \
  41         w_cvar(id, sn, NONE, charge_maxspeed) \
  42         w_cvar(id, sn, NONE, charge_velocity_rate) \
  43         w_cvar(id, sn, NONE, secondary) \
  44         w_cvar(id, sn, SEC,  chargepool) \
  45         w_cvar(id, sn, SEC,  chargepool_regen) \
  46         w_cvar(id, sn, SEC,  chargepool_pause_regen) \
  47         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  48         w_prop(id, sn, float,  reloading_time, reload_time) \
  49         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  50         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  51         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  52         w_prop(id, sn, float,  weaponstart, weaponstart) \
  53         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  54         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  55
  56 #ifdef SVQC
  57 VORTEX_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  58
  59 .float vortex_lasthit;
  60 #endif
  61 #endif
  62 #ifdef IMPLEMENTATION
  63 #ifdef SVQC
  64 void spawnfunc_weapon_vortex(void) { weapon_defaultspawnfunc(WEP_VORTEX.m_id); }
  65 void spawnfunc_weapon_nex(void) { spawnfunc_weapon_vortex(); }
  66
  67 void SendCSQCVortexBeamParticle(float charge) {
  68         vector v;
  69         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  70         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  71         WriteByte(MSG_BROADCAST, TE_CSQC_VORTEXBEAMPARTICLE);
  72         WriteCoord(MSG_BROADCAST, w_shotorg.x);
  73         WriteCoord(MSG_BROADCAST, w_shotorg.y);
  74         WriteCoord(MSG_BROADCAST, w_shotorg.z);
  75         WriteCoord(MSG_BROADCAST, v.x);
  76         WriteCoord(MSG_BROADCAST, v.y);
  77         WriteCoord(MSG_BROADCAST, v.z);
  78         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  79 }
  80
  81 void W_Vortex_Attack(Weapon thiswep, float issecondary)
  82 {SELFPARAM();
  83         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
  84
  85         mydmg = WEP_CVAR_BOTH(vortex, !issecondary, damage);
  86         myforce = WEP_CVAR_BOTH(vortex, !issecondary, force);
  87         mymindist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_mindist);
  88         mymaxdist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_maxdist);
  89         myhalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_halflife);
  90         myforcehalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_forcehalflife);
  91         myammo = WEP_CVAR_BOTH(vortex, !issecondary, ammo);
  92
  93         float flying;
  94         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  95
  96         if(WEP_CVAR(vortex, charge))
  97         {
  98                 charge = WEP_CVAR(vortex, charge_mindmg) / mydmg + (1 - WEP_CVAR(vortex, charge_mindmg) / mydmg) * self.vortex_charge;
  99                 self.vortex_charge *= WEP_CVAR(vortex, charge_shot_multiplier); // do this AFTER setting mydmg/myforce
 100                 // O RLY? -- divVerent
 101                 // YA RLY -- FruitieX
 102         }
 103         else
 104                 charge = 1;
 105         mydmg *= charge;
 106         myforce *= charge;
 107
 108         W_SetupShot(self, true, 5, SND(NEXFIRE), CH_WEAPON_A, mydmg);
 109         if(charge > WEP_CVAR(vortex, charge_animlimit) && WEP_CVAR(vortex, charge_animlimit)) // if the Vortex is overcharged, we play an extra sound
 110         {
 111                 sound(self, CH_WEAPON_B, SND_NEXCHARGE, VOL_BASE * (charge - 0.5 * WEP_CVAR(vortex, charge_animlimit)) / (1 - 0.5 * WEP_CVAR(vortex, charge_animlimit)), ATTN_NORM);
 112         }
 113
 114         yoda = 0;
 115         damage_goodhits = 0;
 116         FireRailgunBullet(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_VORTEX.m_id);
 117
 118         if(yoda && flying)
 119                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 120         if(damage_goodhits && self.vortex_lasthit)
 121         {
 122                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 123                 damage_goodhits = 0; // only every second time
 124         }
 125
 126         self.vortex_lasthit = damage_goodhits;
 127
 128         //beam and muzzle flash done on client
 129         SendCSQCVortexBeamParticle(charge);
 130
 131         W_DecreaseAmmo(thiswep, myammo);
 132 }
 133
 134 .float vortex_chargepool_pauseregen_finished;
 135
 136                 METHOD(Vortex, wr_aim, bool(entity thiswep))
 137                 {
 138                         if(bot_aim(1000000, 0, 1, false))
 139                                 self.BUTTON_ATCK = true;
 140                         else
 141                         {
 142                                 if(WEP_CVAR(vortex, charge))
 143                                         self.BUTTON_ATCK2 = true;
 144                         }
 145                         return true;
 146                 }
 147                 METHOD(Vortex, wr_think, bool(entity thiswep, bool fire1, bool fire2))
 148                 {
 149                         if(WEP_CVAR(vortex, charge) && self.vortex_charge < WEP_CVAR(vortex, charge_limit))
 150                                 self.vortex_charge = min(1, self.vortex_charge + WEP_CVAR(vortex, charge_rate) * frametime / W_TICSPERFRAME);
 151
 152                         if(WEP_CVAR_SEC(vortex, chargepool))
 153                                 if(self.vortex_chargepool_ammo < 1)
 154                                 {
 155                                         if(self.vortex_chargepool_pauseregen_finished < time)
 156                                                 self.vortex_chargepool_ammo = min(1, self.vortex_chargepool_ammo + WEP_CVAR_SEC(vortex, chargepool_regen) * frametime / W_TICSPERFRAME);
 157                                         self.pauseregen_finished = max(self.pauseregen_finished, time + WEP_CVAR_SEC(vortex, chargepool_pause_regen));
 158                                 }
 159
 160                         if(autocvar_g_balance_vortex_reload_ammo && self.clip_load < min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo))) { // forced reload
 161                                 Weapon w = get_weaponinfo(self.weapon);
 162                                 w.wr_reload(w);
 163                         } else
 164                         {
 165                                 if(fire1)
 166                                 {
 167                                         if(weapon_prepareattack(false, WEP_CVAR_PRI(vortex, refire)))
 168                                         {
 169                                                 W_Vortex_Attack(thiswep, 0);
 170                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(vortex, animtime), w_ready);
 171                                         }
 172                                 }
 173                                 if((WEP_CVAR(vortex, charge) && !WEP_CVAR(vortex, secondary)) ? (self.BUTTON_ZOOM | self.BUTTON_ZOOMSCRIPT) : fire2)
 174                                 {
 175                                         if(WEP_CVAR(vortex, charge))
 176                                         {
 177                                                 self.vortex_charge_rottime = time + WEP_CVAR(vortex, charge_rot_pause);
 178                                                 float dt = frametime / W_TICSPERFRAME;
 179
 180                                                 if(self.vortex_charge < 1)
 181                                                 {
 182                                                         if(WEP_CVAR_SEC(vortex, chargepool))
 183                                                         {
 184                                                                 if(WEP_CVAR_SEC(vortex, ammo))
 185                                                                 {
 186                                                                         // always deplete if secondary is held
 187                                                                         self.vortex_chargepool_ammo = max(0, self.vortex_chargepool_ammo - WEP_CVAR_SEC(vortex, ammo) * dt);
 188
 189                                                                         dt = min(dt, (1 - self.vortex_charge) / WEP_CVAR(vortex, charge_rate));
 190                                                                         self.vortex_chargepool_pauseregen_finished = time + WEP_CVAR_SEC(vortex, chargepool_pause_regen);
 191                                                                         dt = min(dt, self.vortex_chargepool_ammo);
 192                                                                         dt = max(0, dt);
 193
 194                                                                         self.vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 195                                                                 }
 196                                                         }
 197
 198                                                         else if(WEP_CVAR_SEC(vortex, ammo))
 199                                                         {
 200                                                                 if(fire2) // only eat ammo when the button is pressed
 201                                                                 {
 202                                                                         dt = min(dt, (1 - self.vortex_charge) / WEP_CVAR(vortex, charge_rate));
 203                                                                         if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 204                                                                         {
 205                                                                                 // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 206                                                                                 if(autocvar_g_balance_vortex_reload_ammo)
 207                                                                                 {
 208                                                                                         dt = min(dt, (self.clip_load - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 209                                                                                         dt = max(0, dt);
 210                                                                                         if(dt > 0)
 211                                                                                         {
 212                                                                                                 self.clip_load = max(WEP_CVAR_SEC(vortex, ammo), self.clip_load - WEP_CVAR_SEC(vortex, ammo) * dt);
 213                                                                                         }
 214                                                                                         self.(weapon_load[WEP_VORTEX.m_id]) = self.clip_load;
 215                                                                                 }
 216                                                                                 else
 217                                                                                 {
 218                                                                                         dt = min(dt, (self.WEP_AMMO(VORTEX) - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 219                                                                                         dt = max(0, dt);
 220                                                                                         if(dt > 0)
 221                                                                                         {
 222                                                                                                 self.WEP_AMMO(VORTEX) = max(WEP_CVAR_SEC(vortex, ammo), self.WEP_AMMO(VORTEX) - WEP_CVAR_SEC(vortex, ammo) * dt);
 223                                                                                         }
 224                                                                                 }
 225                                                                         }
 226                                                                         self.vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 227                                                                 }
 228                                                         }
 229
 230                                                         else
 231                                                         {
 232                                                                 dt = min(dt, (1 - self.vortex_charge) / WEP_CVAR(vortex, charge_rate));
 233                                                                 self.vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 234                                                         }
 235                                                 }
 236                                         }
 237                                         else if(WEP_CVAR(vortex, secondary))
 238                                         {
 239                                                 if(weapon_prepareattack(false, WEP_CVAR_SEC(vortex, refire)))
 240                                                 {
 241                                                         W_Vortex_Attack(thiswep, 1);
 242                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_SEC(vortex, animtime), w_ready);
 243                                                 }
 244                                         }
 245                                 }
 246                         }
 247
 248                         return true;
 249                 }
 250                 METHOD(Vortex, wr_init, bool(entity thiswep))
 251                 {
 252                         VORTEX_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 253                         return true;
 254                 }
 255                 METHOD(Vortex, wr_setup, bool(entity thiswep))
 256                 {
 257                         self.vortex_lasthit = 0;
 258                         return true;
 259                 }
 260                 METHOD(Vortex, wr_checkammo1, bool(entity thiswep))
 261                 {
 262                         float ammo_amount = self.WEP_AMMO(VORTEX) >= WEP_CVAR_PRI(vortex, ammo);
 263                         ammo_amount += (autocvar_g_balance_vortex_reload_ammo && self.(weapon_load[WEP_VORTEX.m_id]) >= WEP_CVAR_PRI(vortex, ammo));
 264                         return ammo_amount;
 265                 }
 266                 METHOD(Vortex, wr_checkammo2, bool(entity thiswep))
 267                 {
 268                         if(WEP_CVAR(vortex, secondary))
 269                         {
 270                                 // don't allow charging if we don't have enough ammo
 271                                 float ammo_amount = self.WEP_AMMO(VORTEX) >= WEP_CVAR_SEC(vortex, ammo);
 272                                 ammo_amount += self.(weapon_load[WEP_VORTEX.m_id]) >= WEP_CVAR_SEC(vortex, ammo);
 273                                 return ammo_amount;
 274                         }
 275                         else
 276                         {
 277                                 return false; // zoom is not a fire mode
 278                         }
 279                 }
 280                 METHOD(Vortex, wr_config, bool(entity thiswep))
 281                 {
 282                         VORTEX_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 283                         return true;
 284                 }
 285                 METHOD(Vortex, wr_resetplayer, bool(entity thiswep))
 286                 {
 287                         self.vortex_lasthit = 0;
 288                         return true;
 289                 }
 290                 METHOD(Vortex, wr_reload, bool(entity thiswep))
 291                 {
 292                         W_Reload(min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo)), SND(RELOAD));
 293                         return true;
 294                 }
 295                 METHOD(Vortex, wr_suicidemessage, bool(entity thiswep))
 296                 {
 297                         return WEAPON_THINKING_WITH_PORTALS;
 298                 }
 299                 METHOD(Vortex, wr_killmessage, bool(entity thiswep))
 300                 {
 301                         return WEAPON_VORTEX_MURDER;
 302                 }
 303
 304 #endif
 305 #ifdef CSQC
 306 float autocvar_g_balance_vortex_secondary = 0; // WEAPONTODO
 307
 308                 METHOD(Vortex, wr_impacteffect, bool(entity thiswep))
 309                 {
 310                         vector org2;
 311                         org2 = w_org + w_backoff * 6;
 312                         pointparticles(particleeffectnum(EFFECT_VORTEX_IMPACT), org2, '0 0 0', 1);
 313                         if(!w_issilent)
 314                                 sound(self, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM);
 315
 316                         return true;
 317                 }
 318                 METHOD(Vortex, wr_init, bool(entity thiswep))
 319                 {
 320                         if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 321                         {
 322                                 precache_pic("gfx/reticle_nex");
 323                         }
 324                         return true;
 325                 }
 326                 METHOD(Vortex, wr_zoomreticle, bool(entity thiswep))
 327                 {
 328                         if(button_zoom || zoomscript_caught || (!WEP_CVAR(vortex, secondary) && button_attack2))
 329                         {
 330                                 reticle_image = "gfx/reticle_nex";
 331                                 return true;
 332                         }
 333                         else
 334                         {
 335                                 // no weapon specific image for this weapon
 336                                 return false;
 337                         }
 338                 }
 339
 340 #endif
 341 #endif