qcsrc/common/weapons/weapon/vortex.qc

   1 #include "vortex.qh"
   2
   3 //REGISTER_STAT(WEP_CVAR_vortex_charge, bool, WEP_CVAR(vortex, charge))
   4 //REGISTER_STAT(WEP_CVAR_vortex_charge_animlimit, float, WEP_CVAR(vortex, charge_animlimit))
   5
   6 #if defined(GAMEQC)
   7 float autocvar_g_weapon_charge_colormod_red_full;
   8 float autocvar_g_weapon_charge_colormod_red_half;
   9 float autocvar_g_weapon_charge_colormod_green_full;
  10 float autocvar_g_weapon_charge_colormod_blue_full;
  11 float autocvar_g_weapon_charge_colormod_blue_half;
  12 float autocvar_g_weapon_charge_colormod_green_half;
  13 float autocvar_g_weapon_charge_colormod_hdrmultiplier;
  14
  15 METHOD(Vortex, wr_glow, vector(Vortex this, entity actor, entity wepent))
  16 {
  17         if (!WEP_CVAR(vortex, charge)) return '0 0 0';
  18         float charge = wepent.vortex_charge;
  19         float animlimit = WEP_CVAR(vortex, charge_animlimit);
  20         vector g;
  21         g.x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, charge / animlimit);
  22         g.y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, charge / animlimit);
  23         g.z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, charge / animlimit);
  24         if (charge > animlimit)
  25         {
  26                 g.x += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (charge - animlimit) / (1 - animlimit);
  27                 g.y += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (charge - animlimit) / (1 - animlimit);
  28                 g.z += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (charge - animlimit) / (1 - animlimit);
  29         }
  30         return g;
  31 }
  32 #endif
  33
  34 REGISTER_NET_TEMP(TE_CSQC_VORTEXBEAMPARTICLE)
  35
  36 #if defined(SVQC)
  37 void SendCSQCVortexBeamParticle(float charge) {
  38         vector v;
  39         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  40         WriteHeader(MSG_BROADCAST, TE_CSQC_VORTEXBEAMPARTICLE);
  41         WriteVector(MSG_BROADCAST, w_shotorg);
  42         WriteVector(MSG_BROADCAST, v);
  43         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  44 }
  45 #elif defined(CSQC)
  46 NET_HANDLE(TE_CSQC_VORTEXBEAMPARTICLE, bool isNew)
  47 {
  48         float charge;
  49     vector shotorg = ReadVector();
  50     vector endpos = ReadVector();
  51         charge = ReadByte() / 255.0;
  52
  53         pointparticles(EFFECT_VORTEX_MUZZLEFLASH, shotorg, normalize(endpos - shotorg) * 1000, 1);
  54
  55         //draw either the old v2.3 beam or the new beam
  56         charge = sqrt(charge); // divide evenly among trail spacing and alpha
  57         particles_alphamin = particles_alphamax = particles_fade = charge;
  58
  59         if(!MUTATOR_CALLHOOK(Particles_VortexBeam, shotorg, endpos))
  60         if(autocvar_cl_particles_oldvortexbeam && (STAT(ALLOW_OLDVORTEXBEAM) || isdemo()))
  61                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  62         else
  63                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  64         return true;
  65 }
  66 #endif
  67
  68 #ifdef SVQC
  69
  70 REGISTER_MUTATOR(vortex_charge, true);
  71
  72 MUTATOR_HOOKFUNCTION(vortex_charge, GetPressedKeys)
  73 {
  74     entity player = M_ARGV(0, entity);
  75
  76         // WEAPONTODO
  77     if(!WEP_CVAR(vortex, charge) || !WEP_CVAR(vortex, charge_velocity_rate))
  78         return;
  79
  80     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  81     {
  82         .entity weaponentity = weaponentities[slot];
  83
  84         if (player.(weaponentity).m_weapon == WEP_VORTEX && WEP_CVAR(vortex, charge) && WEP_CVAR(vortex, charge_velocity_rate) && vdist(vec2(player.velocity), >, WEP_CVAR(vortex, charge_minspeed)))
  85         {
  86             float xyspeed = vlen(vec2(player.velocity));
  87                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
  88                 xyspeed = min(xyspeed, WEP_CVAR(vortex, charge_maxspeed));
  89                 float f = (xyspeed - WEP_CVAR(vortex, charge_minspeed)) / (WEP_CVAR(vortex, charge_maxspeed) - WEP_CVAR(vortex, charge_minspeed));
  90                 // add the extra charge
  91                 player.(weaponentity).vortex_charge = min(1, player.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_velocity_rate) * f * PHYS_INPUT_TIMELENGTH);
  92         }
  93     }
  94 }
  95
  96 void W_Vortex_Attack(Weapon thiswep, entity actor, .entity weaponentity, float issecondary)
  97 {
  98         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
  99
 100         mydmg = WEP_CVAR_BOTH(vortex, !issecondary, damage);
 101         myforce = WEP_CVAR_BOTH(vortex, !issecondary, force);
 102         mymindist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_mindist);
 103         mymaxdist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_maxdist);
 104         myhalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_halflife);
 105         myforcehalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_forcehalflife);
 106         myammo = WEP_CVAR_BOTH(vortex, !issecondary, ammo);
 107
 108     float dtype = thiswep.m_id;
 109     if(WEP_CVAR_BOTH(vortex, !issecondary, armorpierce))
 110         dtype |= HITTYPE_ARMORPIERCE;
 111
 112         float flying;
 113         flying = IsFlying(actor); // do this BEFORE to make the trace values from FireRailgunBullet last
 114
 115         if(WEP_CVAR(vortex, charge))
 116         {
 117                 charge = WEP_CVAR(vortex, charge_mindmg) / mydmg + (1 - WEP_CVAR(vortex, charge_mindmg) / mydmg) * actor.(weaponentity).vortex_charge;
 118                 actor.(weaponentity).vortex_charge *= WEP_CVAR(vortex, charge_shot_multiplier); // do this AFTER setting mydmg/myforce
 119                 // O RLY? -- divVerent
 120                 // YA RLY -- FruitieX
 121         }
 122         else
 123                 charge = 1;
 124         mydmg *= charge;
 125         myforce *= charge;
 126
 127         W_SetupShot(actor, weaponentity, true, 5, SND_NEXFIRE, CH_WEAPON_A, mydmg, dtype);
 128         if(charge > WEP_CVAR(vortex, charge_animlimit) && WEP_CVAR(vortex, charge_animlimit)) // if the Vortex is overcharged, we play an extra sound
 129         {
 130                 sound(actor, CH_WEAPON_B, SND_NEXCHARGE, VOL_BASE * (charge - 0.5 * WEP_CVAR(vortex, charge_animlimit)) / (1 - 0.5 * WEP_CVAR(vortex, charge_animlimit)), ATTN_NORM);
 131         }
 132
 133         yoda = 0;
 134         damage_goodhits = 0;
 135         FireRailgunBullet(actor, weaponentity, w_shotorg, w_shotorg + w_shotdir * max_shot_distance, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, dtype);
 136
 137         if(yoda && flying)
 138                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 139         if(damage_goodhits && actor.vortex_lasthit)
 140         {
 141                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 142                 damage_goodhits = 0; // only every second time
 143         }
 144
 145         actor.vortex_lasthit = damage_goodhits;
 146
 147         //beam and muzzle flash done on client
 148         SendCSQCVortexBeamParticle(charge);
 149
 150         W_DecreaseAmmo(thiswep, actor, myammo, weaponentity);
 151 }
 152
 153 .float vortex_chargepool_pauseregen_finished;
 154
 155 METHOD(Vortex, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 156 {
 157     if(bot_aim(actor, weaponentity, 1000000, 0, 1, false))
 158         PHYS_INPUT_BUTTON_ATCK(actor) = true;
 159     else
 160     {
 161         if(WEP_CVAR(vortex, charge))
 162             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 163     }
 164 }
 165 METHOD(Vortex, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 166 {
 167     if(WEP_CVAR(vortex, charge) && actor.(weaponentity).vortex_charge < WEP_CVAR(vortex, charge_limit))
 168         actor.(weaponentity).vortex_charge = min(1, actor.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_rate) * frametime / W_TICSPERFRAME);
 169
 170     if(WEP_CVAR_SEC(vortex, chargepool))
 171         if(actor.(weaponentity).vortex_chargepool_ammo < 1)
 172         {
 173             if(actor.vortex_chargepool_pauseregen_finished < time)
 174                 actor.(weaponentity).vortex_chargepool_ammo = min(1, actor.(weaponentity).vortex_chargepool_ammo + WEP_CVAR_SEC(vortex, chargepool_regen) * frametime / W_TICSPERFRAME);
 175             actor.pauseregen_finished = max(actor.pauseregen_finished, time + WEP_CVAR_SEC(vortex, chargepool_pause_regen));
 176         }
 177
 178     if(autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo))) { // forced reload
 179         thiswep.wr_reload(thiswep, actor, weaponentity);
 180     } else
 181     {
 182         if(fire & 1)
 183         {
 184             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vortex, refire)))
 185             {
 186                 W_Vortex_Attack(thiswep, actor, weaponentity, 0);
 187                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vortex, animtime), w_ready);
 188             }
 189         }
 190         if((WEP_CVAR(vortex, charge) && !WEP_CVAR(vortex, secondary)) ? (PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) : (fire & 2))
 191         {
 192             if(WEP_CVAR(vortex, charge))
 193             {
 194                 actor.(weaponentity).vortex_charge_rottime = time + WEP_CVAR(vortex, charge_rot_pause);
 195                 float dt = frametime / W_TICSPERFRAME;
 196
 197                 if(actor.(weaponentity).vortex_charge < 1)
 198                 {
 199                     if(WEP_CVAR_SEC(vortex, chargepool))
 200                     {
 201                         if(WEP_CVAR_SEC(vortex, ammo))
 202                         {
 203                             // always deplete if secondary is held
 204                             actor.(weaponentity).vortex_chargepool_ammo = max(0, actor.(weaponentity).vortex_chargepool_ammo - WEP_CVAR_SEC(vortex, ammo) * dt);
 205
 206                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 207                             actor.vortex_chargepool_pauseregen_finished = time + WEP_CVAR_SEC(vortex, chargepool_pause_regen);
 208                             dt = min(dt, actor.(weaponentity).vortex_chargepool_ammo);
 209                             dt = max(0, dt);
 210
 211                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 212                         }
 213                     }
 214
 215                     else if(WEP_CVAR_SEC(vortex, ammo))
 216                     {
 217                         if(fire & 2) // only eat ammo when the button is pressed
 218                         {
 219                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 220                             if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 221                             {
 222                                 // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 223                                 if(autocvar_g_balance_vortex_reload_ammo)
 224                                 {
 225                                     dt = min(dt, (actor.(weaponentity).clip_load - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 226                                     dt = max(0, dt);
 227                                     if(dt > 0)
 228                                     {
 229                                         actor.(weaponentity).clip_load = max(WEP_CVAR_SEC(vortex, ammo), actor.(weaponentity).clip_load - WEP_CVAR_SEC(vortex, ammo) * dt);
 230                                     }
 231                                     actor.(weaponentity).(weapon_load[thiswep.m_id]) = actor.(weaponentity).clip_load;
 232                                 }
 233                                 else
 234                                 {
 235                                     dt = min(dt, (GetResourceAmount(actor, thiswep.ammo_type) - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 236                                     dt = max(0, dt);
 237                                     if(dt > 0)
 238                                     {
 239                                         SetResourceAmount(actor, thiswep.ammo_type, max(WEP_CVAR_SEC(vortex, ammo), GetResourceAmount(actor, thiswep.ammo_type) - WEP_CVAR_SEC(vortex, ammo) * dt));
 240                                     }
 241                                 }
 242                             }
 243                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 244                         }
 245                     }
 246
 247                     else
 248                     {
 249                         dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 250                         actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 251                     }
 252                 }
 253             }
 254             else if(WEP_CVAR(vortex, secondary))
 255             {
 256                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(vortex, refire)))
 257                 {
 258                     W_Vortex_Attack(thiswep, actor, weaponentity, 1);
 259                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(vortex, animtime), w_ready);
 260                 }
 261             }
 262         }
 263     }
 264 }
 265 METHOD(Vortex, wr_setup, void(entity thiswep, entity actor, .entity weaponentity))
 266 {
 267     actor.vortex_lasthit = 0;
 268 }
 269 METHOD(Vortex, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 270 {
 271     float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(vortex, ammo);
 272     ammo_amount += (autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(vortex, ammo));
 273     return ammo_amount;
 274 }
 275 METHOD(Vortex, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 276 {
 277     if(WEP_CVAR(vortex, secondary))
 278     {
 279         // don't allow charging if we don't have enough ammo
 280         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(vortex, ammo);
 281         ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_SEC(vortex, ammo);
 282         return ammo_amount;
 283     }
 284     else
 285     {
 286         return false; // zoom is not a fire mode
 287     }
 288 }
 289 METHOD(Vortex, wr_resetplayer, void(entity thiswep, entity actor))
 290 {
 291     if (WEP_CVAR(vortex, charge)) {
 292         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 293         {
 294             .entity weaponentity = weaponentities[slot];
 295             actor.(weaponentity).vortex_charge = WEP_CVAR(vortex, charge_start);
 296
 297             if (WEP_CVAR_SEC(vortex, chargepool))
 298                 actor.(weaponentity).vortex_chargepool_ammo = 1;
 299         }
 300     }
 301     actor.vortex_lasthit = 0;
 302 }
 303 METHOD(Vortex, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 304 {
 305     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo)), SND_RELOAD);
 306 }
 307 METHOD(Vortex, wr_suicidemessage, Notification(entity thiswep))
 308 {
 309     return WEAPON_THINKING_WITH_PORTALS;
 310 }
 311 METHOD(Vortex, wr_killmessage, Notification(entity thiswep))
 312 {
 313     return WEAPON_VORTEX_MURDER;
 314 }
 315 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 316 {
 317     return PHYS_INPUT_BUTTON_ATCK2(actor) && !WEP_CVAR(vortex, secondary);
 318 }
 319
 320 #endif
 321 #ifdef CSQC
 322
 323 METHOD(Vortex, wr_impacteffect, void(entity thiswep, entity actor))
 324 {
 325     entity this = actor;
 326     vector org2 = w_org + w_backoff * 6;
 327     pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 328     if(!w_issilent)
 329         sound(this, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM);
 330 }
 331 METHOD(Vortex, wr_init, void(entity thiswep))
 332 {
 333     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 334     {
 335         precache_pic("gfx/reticle_nex");
 336     }
 337 }
 338 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 339 {
 340     if(button_zoom || zoomscript_caught || (!WEP_CVAR(vortex, secondary) && button_attack2))
 341     {
 342         return true;
 343     }
 344     else
 345     {
 346         // no weapon specific image for this weapon
 347         return false;
 348     }
 349 }
 350 METHOD(Vortex, wr_zoomdir, bool(entity thiswep))
 351 {
 352     return button_attack2 && !WEP_CVAR(vortex, secondary);
 353 }
 354
 355 #endif