39433dd6fd7272217981c3c7bea49826784ca44c
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / vortex.qc
1 #include "vortex.qh"
2
3 //REGISTER_STAT(WEP_CVAR_vortex_charge, bool, WEP_CVAR(vortex, charge))
4 //REGISTER_STAT(WEP_CVAR_vortex_charge_animlimit, float, WEP_CVAR(vortex, charge_animlimit))
5
6 #if defined(GAMEQC)
7 float autocvar_g_weapon_charge_colormod_red_full;
8 float autocvar_g_weapon_charge_colormod_red_half;
9 float autocvar_g_weapon_charge_colormod_green_full;
10 float autocvar_g_weapon_charge_colormod_blue_full;
11 float autocvar_g_weapon_charge_colormod_blue_half;
12 float autocvar_g_weapon_charge_colormod_green_half;
13 float autocvar_g_weapon_charge_colormod_hdrmultiplier;
14
15 METHOD(Vortex, wr_glow, vector(Vortex this, entity actor, entity wepent))
16 {
17         if (!WEP_CVAR(vortex, charge)) return '0 0 0';
18         float charge = wepent.vortex_charge;
19         float animlimit = WEP_CVAR(vortex, charge_animlimit);
20         vector g;
21         g.x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, charge / animlimit);
22         g.y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, charge / animlimit);
23         g.z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, charge / animlimit);
24         if (charge > animlimit)
25         {
26                 g.x += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (charge - animlimit) / (1 - animlimit);
27                 g.y += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (charge - animlimit) / (1 - animlimit);
28                 g.z += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (charge - animlimit) / (1 - animlimit);
29         }
30         return g;
31 }
32 #endif
33
34 REGISTER_NET_TEMP(TE_CSQC_VORTEXBEAMPARTICLE)
35
36 #if defined(SVQC)
37 void SendCSQCVortexBeamParticle(float charge) {
38         vector v;
39         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
40         WriteHeader(MSG_BROADCAST, TE_CSQC_VORTEXBEAMPARTICLE);
41         WriteCoord(MSG_BROADCAST, w_shotorg.x);
42         WriteCoord(MSG_BROADCAST, w_shotorg.y);
43         WriteCoord(MSG_BROADCAST, w_shotorg.z);
44         WriteCoord(MSG_BROADCAST, v.x);
45         WriteCoord(MSG_BROADCAST, v.y);
46         WriteCoord(MSG_BROADCAST, v.z);
47         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
48 }
49 #elif defined(CSQC)
50 NET_HANDLE(TE_CSQC_VORTEXBEAMPARTICLE, bool isNew)
51 {
52         vector shotorg, endpos;
53         float charge;
54         shotorg.x = ReadCoord(); shotorg.y = ReadCoord(); shotorg.z = ReadCoord();
55         endpos.x = ReadCoord(); endpos.y = ReadCoord(); endpos.z = ReadCoord();
56         charge = ReadByte() / 255.0;
57
58         pointparticles(EFFECT_VORTEX_MUZZLEFLASH, shotorg, normalize(endpos - shotorg) * 1000, 1);
59
60         //draw either the old v2.3 beam or the new beam
61         charge = sqrt(charge); // divide evenly among trail spacing and alpha
62         particles_alphamin = particles_alphamax = particles_fade = charge;
63
64         if(!MUTATOR_CALLHOOK(Particles_VortexBeam, shotorg, endpos))
65         if(autocvar_cl_particles_oldvortexbeam && (STAT(ALLOW_OLDVORTEXBEAM) || isdemo()))
66                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
67         else
68                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
69         return true;
70 }
71 #endif
72
73 #ifdef SVQC
74
75 REGISTER_MUTATOR(vortex_charge, true);
76
77 MUTATOR_HOOKFUNCTION(vortex_charge, GetPressedKeys)
78 {
79     entity player = M_ARGV(0, entity);
80
81         // WEAPONTODO
82     if(!WEP_CVAR(vortex, charge) || !WEP_CVAR(vortex, charge_velocity_rate))
83         return;
84
85     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
86     {
87         .entity weaponentity = weaponentities[slot];
88
89         if (player.(weaponentity).m_weapon == WEP_VORTEX && WEP_CVAR(vortex, charge) && WEP_CVAR(vortex, charge_velocity_rate) && vdist(vec2(player.velocity), >, WEP_CVAR(vortex, charge_minspeed)))
90         {
91             float xyspeed = vlen(vec2(player.velocity));
92                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
93                 xyspeed = min(xyspeed, WEP_CVAR(vortex, charge_maxspeed));
94                 float f = (xyspeed - WEP_CVAR(vortex, charge_minspeed)) / (WEP_CVAR(vortex, charge_maxspeed) - WEP_CVAR(vortex, charge_minspeed));
95                 // add the extra charge
96                 player.(weaponentity).vortex_charge = min(1, player.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_velocity_rate) * f * PHYS_INPUT_TIMELENGTH);
97         }
98     }
99 }
100
101 void W_Vortex_Attack(Weapon thiswep, entity actor, .entity weaponentity, float issecondary)
102 {
103         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
104
105         mydmg = WEP_CVAR_BOTH(vortex, !issecondary, damage);
106         myforce = WEP_CVAR_BOTH(vortex, !issecondary, force);
107         mymindist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_mindist);
108         mymaxdist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_maxdist);
109         myhalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_halflife);
110         myforcehalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_forcehalflife);
111         myammo = WEP_CVAR_BOTH(vortex, !issecondary, ammo);
112
113         float flying;
114         flying = IsFlying(actor); // do this BEFORE to make the trace values from FireRailgunBullet last
115
116         if(WEP_CVAR(vortex, charge))
117         {
118                 charge = WEP_CVAR(vortex, charge_mindmg) / mydmg + (1 - WEP_CVAR(vortex, charge_mindmg) / mydmg) * actor.(weaponentity).vortex_charge;
119                 actor.(weaponentity).vortex_charge *= WEP_CVAR(vortex, charge_shot_multiplier); // do this AFTER setting mydmg/myforce
120                 // O RLY? -- divVerent
121                 // YA RLY -- FruitieX
122         }
123         else
124                 charge = 1;
125         mydmg *= charge;
126         myforce *= charge;
127
128         W_SetupShot(actor, weaponentity, true, 5, SND_NEXFIRE, CH_WEAPON_A, mydmg);
129         if(charge > WEP_CVAR(vortex, charge_animlimit) && WEP_CVAR(vortex, charge_animlimit)) // if the Vortex is overcharged, we play an extra sound
130         {
131                 sound(actor, CH_WEAPON_B, SND_NEXCHARGE, VOL_BASE * (charge - 0.5 * WEP_CVAR(vortex, charge_animlimit)) / (1 - 0.5 * WEP_CVAR(vortex, charge_animlimit)), ATTN_NORM);
132         }
133
134         yoda = 0;
135         damage_goodhits = 0;
136         FireRailgunBullet(actor, weaponentity, w_shotorg, w_shotorg + w_shotdir * max_shot_distance, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_VORTEX.m_id);
137
138         if(yoda && flying)
139                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
140         if(damage_goodhits && actor.vortex_lasthit)
141         {
142                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
143                 damage_goodhits = 0; // only every second time
144         }
145
146         actor.vortex_lasthit = damage_goodhits;
147
148         //beam and muzzle flash done on client
149         SendCSQCVortexBeamParticle(charge);
150
151         W_DecreaseAmmo(thiswep, actor, myammo, weaponentity);
152 }
153
154 .float vortex_chargepool_pauseregen_finished;
155
156 METHOD(Vortex, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
157 {
158     if(bot_aim(actor, weaponentity, 1000000, 0, 1, false))
159         PHYS_INPUT_BUTTON_ATCK(actor) = true;
160     else
161     {
162         if(WEP_CVAR(vortex, charge))
163             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
164     }
165 }
166 METHOD(Vortex, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
167 {
168     if(WEP_CVAR(vortex, charge) && actor.(weaponentity).vortex_charge < WEP_CVAR(vortex, charge_limit))
169         actor.(weaponentity).vortex_charge = min(1, actor.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_rate) * frametime / W_TICSPERFRAME);
170
171     if(weaponslot(weaponentity) == 0)
172         actor.vortex_charge = actor.(weaponentity).vortex_charge;
173
174     if(WEP_CVAR_SEC(vortex, chargepool))
175         if(actor.(weaponentity).vortex_chargepool_ammo < 1)
176         {
177             if(actor.vortex_chargepool_pauseregen_finished < time)
178                 actor.(weaponentity).vortex_chargepool_ammo = min(1, actor.(weaponentity).vortex_chargepool_ammo + WEP_CVAR_SEC(vortex, chargepool_regen) * frametime / W_TICSPERFRAME);
179             actor.pauseregen_finished = max(actor.pauseregen_finished, time + WEP_CVAR_SEC(vortex, chargepool_pause_regen));
180         }
181
182     if(weaponslot(weaponentity) == 0)
183         actor.vortex_chargepool_ammo = actor.(weaponentity).vortex_chargepool_ammo;
184
185     if(autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo))) { // forced reload
186         thiswep.wr_reload(thiswep, actor, weaponentity);
187     } else
188     {
189         if(fire & 1)
190         {
191             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vortex, refire)))
192             {
193                 W_Vortex_Attack(thiswep, actor, weaponentity, 0);
194                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vortex, animtime), w_ready);
195             }
196         }
197         if((WEP_CVAR(vortex, charge) && !WEP_CVAR(vortex, secondary)) ? (PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) : (fire & 2))
198         {
199             if(WEP_CVAR(vortex, charge))
200             {
201                 actor.(weaponentity).vortex_charge_rottime = time + WEP_CVAR(vortex, charge_rot_pause);
202                 float dt = frametime / W_TICSPERFRAME;
203
204                 if(actor.(weaponentity).vortex_charge < 1)
205                 {
206                     if(WEP_CVAR_SEC(vortex, chargepool))
207                     {
208                         if(WEP_CVAR_SEC(vortex, ammo))
209                         {
210                             // always deplete if secondary is held
211                             actor.vortex_chargepool_ammo = max(0, actor.vortex_chargepool_ammo - WEP_CVAR_SEC(vortex, ammo) * dt);
212
213                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
214                             actor.vortex_chargepool_pauseregen_finished = time + WEP_CVAR_SEC(vortex, chargepool_pause_regen);
215                             dt = min(dt, actor.vortex_chargepool_ammo);
216                             dt = max(0, dt);
217
218                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
219                         }
220                     }
221
222                     else if(WEP_CVAR_SEC(vortex, ammo))
223                     {
224                         if(fire & 2) // only eat ammo when the button is pressed
225                         {
226                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
227                             if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
228                             {
229                                 // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
230                                 if(autocvar_g_balance_vortex_reload_ammo)
231                                 {
232                                     dt = min(dt, (actor.(weaponentity).clip_load - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
233                                     dt = max(0, dt);
234                                     if(dt > 0)
235                                     {
236                                         actor.(weaponentity).clip_load = max(WEP_CVAR_SEC(vortex, ammo), actor.(weaponentity).clip_load - WEP_CVAR_SEC(vortex, ammo) * dt);
237                                     }
238                                     actor.(weaponentity).(weapon_load[WEP_VORTEX.m_id]) = actor.(weaponentity).clip_load;
239                                 }
240                                 else
241                                 {
242                                     dt = min(dt, (GetResourceAmount(actor, thiswep.ammo_type) - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
243                                     dt = max(0, dt);
244                                     if(dt > 0)
245                                     {
246                                         SetResourceAmount(actor, thiswep.ammo_type, max(WEP_CVAR_SEC(vortex, ammo), GetResourceAmount(actor, thiswep.ammo_type) - WEP_CVAR_SEC(vortex, ammo) * dt));
247                                     }
248                                 }
249                             }
250                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
251                         }
252                     }
253
254                     else
255                     {
256                         dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
257                         actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
258                     }
259                 }
260             }
261             else if(WEP_CVAR(vortex, secondary))
262             {
263                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(vortex, refire)))
264                 {
265                     W_Vortex_Attack(thiswep, actor, weaponentity, 1);
266                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(vortex, animtime), w_ready);
267                 }
268             }
269         }
270     }
271 }
272 METHOD(Vortex, wr_setup, void(entity thiswep, entity actor, .entity weaponentity))
273 {
274     actor.vortex_lasthit = 0;
275 }
276 METHOD(Vortex, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
277 {
278     float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(vortex, ammo);
279     ammo_amount += (autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).(weapon_load[WEP_VORTEX.m_id]) >= WEP_CVAR_PRI(vortex, ammo));
280     return ammo_amount;
281 }
282 METHOD(Vortex, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
283 {
284     if(WEP_CVAR(vortex, secondary))
285     {
286         // don't allow charging if we don't have enough ammo
287         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(vortex, ammo);
288         ammo_amount += actor.(weaponentity).(weapon_load[WEP_VORTEX.m_id]) >= WEP_CVAR_SEC(vortex, ammo);
289         return ammo_amount;
290     }
291     else
292     {
293         return false; // zoom is not a fire mode
294     }
295 }
296 METHOD(Vortex, wr_resetplayer, void(entity thiswep, entity actor))
297 {
298     if (WEP_CVAR(vortex, charge)) {
299         if (WEP_CVAR_SEC(vortex, chargepool)) {
300             actor.vortex_chargepool_ammo = 1;
301         }
302         actor.vortex_charge = WEP_CVAR(vortex, charge_start);
303         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
304         {
305             .entity weaponentity = weaponentities[slot];
306             actor.(weaponentity).vortex_charge = WEP_CVAR(vortex, charge_start);
307
308             if (WEP_CVAR_SEC(vortex, chargepool))
309                 actor.(weaponentity).vortex_chargepool_ammo = 1;
310         }
311     }
312     actor.vortex_lasthit = 0;
313 }
314 METHOD(Vortex, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
315 {
316     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo)), SND_RELOAD);
317 }
318 METHOD(Vortex, wr_suicidemessage, Notification(entity thiswep))
319 {
320     return WEAPON_THINKING_WITH_PORTALS;
321 }
322 METHOD(Vortex, wr_killmessage, Notification(entity thiswep))
323 {
324     return WEAPON_VORTEX_MURDER;
325 }
326 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
327 {
328     return PHYS_INPUT_BUTTON_ATCK2(actor) && !WEP_CVAR(vortex, secondary);
329 }
330
331 #endif
332 #ifdef CSQC
333
334 METHOD(Vortex, wr_impacteffect, void(entity thiswep, entity actor))
335 {
336     entity this = actor;
337     vector org2 = w_org + w_backoff * 6;
338     pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
339     if(!w_issilent)
340         sound(this, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM);
341 }
342 METHOD(Vortex, wr_init, void(entity thiswep))
343 {
344     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
345     {
346         precache_pic("gfx/reticle_nex");
347     }
348 }
349 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
350 {
351     if(button_zoom || zoomscript_caught || (!WEP_CVAR(vortex, secondary) && button_attack2))
352     {
353         return true;
354     }
355     else
356     {
357         // no weapon specific image for this weapon
358         return false;
359     }
360 }
361 METHOD(Vortex, wr_zoomdir, bool(entity thiswep))
362 {
363     return button_attack2 && !WEP_CVAR(vortex, secondary);
364 }
365
366 #endif