qcsrc/common/weapons/weapon/vortex.qc

   1 #include "vortex.qh"
   2
   3 //REGISTER_STAT(WEP_CVAR_vortex_charge, bool, WEP_CVAR(vortex, charge))
   4 //REGISTER_STAT(WEP_CVAR_vortex_charge_animlimit, float, WEP_CVAR(vortex, charge_animlimit))
   5
   6 #if defined(GAMEQC)
   7 float autocvar_g_weapon_charge_colormod_red_full;
   8 float autocvar_g_weapon_charge_colormod_red_half;
   9 float autocvar_g_weapon_charge_colormod_green_full;
  10 float autocvar_g_weapon_charge_colormod_blue_full;
  11 float autocvar_g_weapon_charge_colormod_blue_half;
  12 float autocvar_g_weapon_charge_colormod_green_half;
  13 float autocvar_g_weapon_charge_colormod_hdrmultiplier;
  14
  15 METHOD(Vortex, wr_glow, vector(Vortex this, entity actor, entity wepent))
  16 {
  17         if (!WEP_CVAR(vortex, charge)) return '0 0 0';
  18         float charge = wepent.vortex_charge;
  19         float animlimit = WEP_CVAR(vortex, charge_animlimit);
  20         vector g;
  21         g.x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, charge / animlimit);
  22         g.y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, charge / animlimit);
  23         g.z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, charge / animlimit);
  24         if (charge > animlimit)
  25         {
  26                 g.x += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (charge - animlimit) / (1 - animlimit);
  27                 g.y += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (charge - animlimit) / (1 - animlimit);
  28                 g.z += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (charge - animlimit) / (1 - animlimit);
  29         }
  30         return g;
  31 }
  32 #endif
  33
  34 REGISTER_NET_TEMP(TE_CSQC_VORTEXBEAMPARTICLE)
  35
  36 #if defined(SVQC)
  37 void SendCSQCVortexBeamParticle(float charge) {
  38         vector v;
  39         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  40         WriteHeader(MSG_BROADCAST, TE_CSQC_VORTEXBEAMPARTICLE);
  41         WriteVector(MSG_BROADCAST, w_shotorg);
  42         WriteVector(MSG_BROADCAST, v);
  43         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  44 }
  45 #elif defined(CSQC)
  46 NET_HANDLE(TE_CSQC_VORTEXBEAMPARTICLE, bool isNew)
  47 {
  48         float charge;
  49     vector shotorg = ReadVector();
  50     vector endpos = ReadVector();
  51         charge = ReadByte() / 255.0;
  52
  53         pointparticles(EFFECT_VORTEX_MUZZLEFLASH, shotorg, normalize(endpos - shotorg) * 1000, 1);
  54
  55         //draw either the old v2.3 beam or the new beam
  56         charge = sqrt(charge); // divide evenly among trail spacing and alpha
  57         particles_alphamin = particles_alphamax = particles_fade = charge;
  58
  59         if(!MUTATOR_CALLHOOK(Particles_VortexBeam, shotorg, endpos))
  60         if(autocvar_cl_particles_oldvortexbeam && (STAT(ALLOW_OLDVORTEXBEAM) || isdemo()))
  61                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  62         else
  63                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  64         return true;
  65 }
  66 #endif
  67
  68 #ifdef SVQC
  69
  70 REGISTER_MUTATOR(vortex_charge, true);
  71
  72 MUTATOR_HOOKFUNCTION(vortex_charge, GetPressedKeys)
  73 {
  74     entity player = M_ARGV(0, entity);
  75
  76         // WEAPONTODO
  77     if(!WEP_CVAR(vortex, charge) || !WEP_CVAR(vortex, charge_velocity_rate))
  78         return;
  79
  80     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  81     {
  82         .entity weaponentity = weaponentities[slot];
  83
  84         if (player.(weaponentity).m_weapon == WEP_VORTEX && WEP_CVAR(vortex, charge) && WEP_CVAR(vortex, charge_velocity_rate) && vdist(vec2(player.velocity), >, WEP_CVAR(vortex, charge_minspeed)))
  85         {
  86             float xyspeed = vlen(vec2(player.velocity));
  87                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
  88                 xyspeed = min(xyspeed, WEP_CVAR(vortex, charge_maxspeed));
  89                 float f = (xyspeed - WEP_CVAR(vortex, charge_minspeed)) / (WEP_CVAR(vortex, charge_maxspeed) - WEP_CVAR(vortex, charge_minspeed));
  90                 // add the extra charge
  91                 player.(weaponentity).vortex_charge = min(1, player.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_velocity_rate) * f * PHYS_INPUT_TIMELENGTH);
  92         }
  93     }
  94 }
  95
  96 void W_Vortex_Attack(Weapon thiswep, entity actor, .entity weaponentity, float issecondary)
  97 {
  98         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
  99
 100         mydmg = WEP_CVAR_BOTH(vortex, !issecondary, damage);
 101         myforce = WEP_CVAR_BOTH(vortex, !issecondary, force);
 102         mymindist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_mindist);
 103         mymaxdist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_maxdist);
 104         myhalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_halflife);
 105         myforcehalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_forcehalflife);
 106         myammo = WEP_CVAR_BOTH(vortex, !issecondary, ammo);
 107
 108         float flying;
 109         flying = IsFlying(actor); // do this BEFORE to make the trace values from FireRailgunBullet last
 110
 111         if(WEP_CVAR(vortex, charge))
 112         {
 113                 charge = WEP_CVAR(vortex, charge_mindmg) / mydmg + (1 - WEP_CVAR(vortex, charge_mindmg) / mydmg) * actor.(weaponentity).vortex_charge;
 114                 actor.(weaponentity).vortex_charge *= WEP_CVAR(vortex, charge_shot_multiplier); // do this AFTER setting mydmg/myforce
 115                 // O RLY? -- divVerent
 116                 // YA RLY -- FruitieX
 117         }
 118         else
 119                 charge = 1;
 120         mydmg *= charge;
 121         myforce *= charge;
 122
 123         W_SetupShot(actor, weaponentity, true, 5, SND_NEXFIRE, CH_WEAPON_A, mydmg, WEP_VORTEX.m_id);
 124         if(charge > WEP_CVAR(vortex, charge_animlimit) && WEP_CVAR(vortex, charge_animlimit)) // if the Vortex is overcharged, we play an extra sound
 125         {
 126                 sound(actor, CH_WEAPON_B, SND_NEXCHARGE, VOL_BASE * (charge - 0.5 * WEP_CVAR(vortex, charge_animlimit)) / (1 - 0.5 * WEP_CVAR(vortex, charge_animlimit)), ATTN_NORM);
 127         }
 128
 129         yoda = 0;
 130         damage_goodhits = 0;
 131         FireRailgunBullet(actor, weaponentity, w_shotorg, w_shotorg + w_shotdir * max_shot_distance, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_VORTEX.m_id);
 132
 133         if(yoda && flying)
 134                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 135         if(damage_goodhits && actor.vortex_lasthit)
 136         {
 137                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 138                 damage_goodhits = 0; // only every second time
 139         }
 140
 141         actor.vortex_lasthit = damage_goodhits;
 142
 143         //beam and muzzle flash done on client
 144         SendCSQCVortexBeamParticle(charge);
 145
 146         W_DecreaseAmmo(thiswep, actor, myammo, weaponentity);
 147 }
 148
 149 .float vortex_chargepool_pauseregen_finished;
 150
 151 METHOD(Vortex, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 152 {
 153     if(bot_aim(actor, weaponentity, 1000000, 0, 1, false))
 154         PHYS_INPUT_BUTTON_ATCK(actor) = true;
 155     else
 156     {
 157         if(WEP_CVAR(vortex, charge))
 158             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 159     }
 160 }
 161 METHOD(Vortex, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 162 {
 163     if(WEP_CVAR(vortex, charge) && actor.(weaponentity).vortex_charge < WEP_CVAR(vortex, charge_limit))
 164         actor.(weaponentity).vortex_charge = min(1, actor.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_rate) * frametime / W_TICSPERFRAME);
 165
 166     if(WEP_CVAR_SEC(vortex, chargepool))
 167         if(actor.(weaponentity).vortex_chargepool_ammo < 1)
 168         {
 169             if(actor.vortex_chargepool_pauseregen_finished < time)
 170                 actor.(weaponentity).vortex_chargepool_ammo = min(1, actor.(weaponentity).vortex_chargepool_ammo + WEP_CVAR_SEC(vortex, chargepool_regen) * frametime / W_TICSPERFRAME);
 171             actor.pauseregen_finished = max(actor.pauseregen_finished, time + WEP_CVAR_SEC(vortex, chargepool_pause_regen));
 172         }
 173
 174     if(autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo))) { // forced reload
 175         thiswep.wr_reload(thiswep, actor, weaponentity);
 176     } else
 177     {
 178         if(fire & 1)
 179         {
 180             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vortex, refire)))
 181             {
 182                 W_Vortex_Attack(thiswep, actor, weaponentity, 0);
 183                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vortex, animtime), w_ready);
 184             }
 185         }
 186         if((WEP_CVAR(vortex, charge) && !WEP_CVAR(vortex, secondary)) ? (PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) : (fire & 2))
 187         {
 188             if(WEP_CVAR(vortex, charge))
 189             {
 190                 actor.(weaponentity).vortex_charge_rottime = time + WEP_CVAR(vortex, charge_rot_pause);
 191                 float dt = frametime / W_TICSPERFRAME;
 192
 193                 if(actor.(weaponentity).vortex_charge < 1)
 194                 {
 195                     if(WEP_CVAR_SEC(vortex, chargepool))
 196                     {
 197                         if(WEP_CVAR_SEC(vortex, ammo))
 198                         {
 199                             // always deplete if secondary is held
 200                             actor.(weaponentity).vortex_chargepool_ammo = max(0, actor.(weaponentity).vortex_chargepool_ammo - WEP_CVAR_SEC(vortex, ammo) * dt);
 201
 202                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 203                             actor.vortex_chargepool_pauseregen_finished = time + WEP_CVAR_SEC(vortex, chargepool_pause_regen);
 204                             dt = min(dt, actor.(weaponentity).vortex_chargepool_ammo);
 205                             dt = max(0, dt);
 206
 207                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 208                         }
 209                     }
 210
 211                     else if(WEP_CVAR_SEC(vortex, ammo))
 212                     {
 213                         if(fire & 2) // only eat ammo when the button is pressed
 214                         {
 215                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 216                             if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 217                             {
 218                                 // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 219                                 if(autocvar_g_balance_vortex_reload_ammo)
 220                                 {
 221                                     dt = min(dt, (actor.(weaponentity).clip_load - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 222                                     dt = max(0, dt);
 223                                     if(dt > 0)
 224                                     {
 225                                         actor.(weaponentity).clip_load = max(WEP_CVAR_SEC(vortex, ammo), actor.(weaponentity).clip_load - WEP_CVAR_SEC(vortex, ammo) * dt);
 226                                     }
 227                                     actor.(weaponentity).(weapon_load[WEP_VORTEX.m_id]) = actor.(weaponentity).clip_load;
 228                                 }
 229                                 else
 230                                 {
 231                                     dt = min(dt, (GetResourceAmount(actor, thiswep.ammo_type) - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 232                                     dt = max(0, dt);
 233                                     if(dt > 0)
 234                                     {
 235                                         SetResourceAmount(actor, thiswep.ammo_type, max(WEP_CVAR_SEC(vortex, ammo), GetResourceAmount(actor, thiswep.ammo_type) - WEP_CVAR_SEC(vortex, ammo) * dt));
 236                                     }
 237                                 }
 238                             }
 239                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 240                         }
 241                     }
 242
 243                     else
 244                     {
 245                         dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 246                         actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 247                     }
 248                 }
 249             }
 250             else if(WEP_CVAR(vortex, secondary))
 251             {
 252                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(vortex, refire)))
 253                 {
 254                     W_Vortex_Attack(thiswep, actor, weaponentity, 1);
 255                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(vortex, animtime), w_ready);
 256                 }
 257             }
 258         }
 259     }
 260 }
 261 METHOD(Vortex, wr_setup, void(entity thiswep, entity actor, .entity weaponentity))
 262 {
 263     actor.vortex_lasthit = 0;
 264 }
 265 METHOD(Vortex, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 266 {
 267     float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(vortex, ammo);
 268     ammo_amount += (autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).(weapon_load[WEP_VORTEX.m_id]) >= WEP_CVAR_PRI(vortex, ammo));
 269     return ammo_amount;
 270 }
 271 METHOD(Vortex, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 272 {
 273     if(WEP_CVAR(vortex, secondary))
 274     {
 275         // don't allow charging if we don't have enough ammo
 276         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(vortex, ammo);
 277         ammo_amount += actor.(weaponentity).(weapon_load[WEP_VORTEX.m_id]) >= WEP_CVAR_SEC(vortex, ammo);
 278         return ammo_amount;
 279     }
 280     else
 281     {
 282         return false; // zoom is not a fire mode
 283     }
 284 }
 285 METHOD(Vortex, wr_resetplayer, void(entity thiswep, entity actor))
 286 {
 287     if (WEP_CVAR(vortex, charge)) {
 288         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 289         {
 290             .entity weaponentity = weaponentities[slot];
 291             actor.(weaponentity).vortex_charge = WEP_CVAR(vortex, charge_start);
 292
 293             if (WEP_CVAR_SEC(vortex, chargepool))
 294                 actor.(weaponentity).vortex_chargepool_ammo = 1;
 295         }
 296     }
 297     actor.vortex_lasthit = 0;
 298 }
 299 METHOD(Vortex, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 300 {
 301     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo)), SND_RELOAD);
 302 }
 303 METHOD(Vortex, wr_suicidemessage, Notification(entity thiswep))
 304 {
 305     return WEAPON_THINKING_WITH_PORTALS;
 306 }
 307 METHOD(Vortex, wr_killmessage, Notification(entity thiswep))
 308 {
 309     return WEAPON_VORTEX_MURDER;
 310 }
 311 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 312 {
 313     return PHYS_INPUT_BUTTON_ATCK2(actor) && !WEP_CVAR(vortex, secondary);
 314 }
 315
 316 #endif
 317 #ifdef CSQC
 318
 319 METHOD(Vortex, wr_impacteffect, void(entity thiswep, entity actor))
 320 {
 321     entity this = actor;
 322     vector org2 = w_org + w_backoff * 6;
 323     pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 324     if(!w_issilent)
 325         sound(this, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM);
 326 }
 327 METHOD(Vortex, wr_init, void(entity thiswep))
 328 {
 329     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 330     {
 331         precache_pic("gfx/reticle_nex");
 332     }
 333 }
 334 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 335 {
 336     if(button_zoom || zoomscript_caught || (!WEP_CVAR(vortex, secondary) && button_attack2))
 337     {
 338         return true;
 339     }
 340     else
 341     {
 342         // no weapon specific image for this weapon
 343         return false;
 344     }
 345 }
 346 METHOD(Vortex, wr_zoomdir, bool(entity thiswep))
 347 {
 348     return button_attack2 && !WEP_CVAR(vortex, secondary);
 349 }
 350
 351 #endif