qcsrc/common/weapons/weapon/vortex.qc

   1 #include "vortex.qh"
   2
   3 //REGISTER_STAT(WEP_CVAR_vortex_charge, bool, WEP_CVAR(vortex, charge))
   4 //REGISTER_STAT(WEP_CVAR_vortex_charge_animlimit, float, WEP_CVAR(vortex, charge_animlimit))
   5
   6 #if defined(GAMEQC)
   7 float autocvar_g_weapon_charge_colormod_red_full;
   8 float autocvar_g_weapon_charge_colormod_red_half;
   9 float autocvar_g_weapon_charge_colormod_green_full;
  10 float autocvar_g_weapon_charge_colormod_blue_full;
  11 float autocvar_g_weapon_charge_colormod_blue_half;
  12 float autocvar_g_weapon_charge_colormod_green_half;
  13 float autocvar_g_weapon_charge_colormod_hdrmultiplier;
  14
  15 METHOD(Vortex, wr_glow, vector(Vortex this, entity actor, entity wepent))
  16 {
  17         if (!WEP_CVAR(vortex, charge)) return '0 0 0';
  18         float charge = wepent.vortex_charge;
  19         float animlimit = WEP_CVAR(vortex, charge_animlimit);
  20         vector g;
  21         g.x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, charge / animlimit);
  22         g.y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, charge / animlimit);
  23         g.z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, charge / animlimit);
  24         if (charge > animlimit)
  25         {
  26                 g.x += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (charge - animlimit) / (1 - animlimit);
  27                 g.y += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (charge - animlimit) / (1 - animlimit);
  28                 g.z += autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (charge - animlimit) / (1 - animlimit);
  29         }
  30         return g;
  31 }
  32 #endif
  33
  34 REGISTER_NET_TEMP(TE_CSQC_VORTEXBEAMPARTICLE)
  35
  36 #if defined(SVQC)
  37 void SendCSQCVortexBeamParticle(float charge) {
  38         vector v;
  39         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  40         WriteHeader(MSG_BROADCAST, TE_CSQC_VORTEXBEAMPARTICLE);
  41         WriteCoord(MSG_BROADCAST, w_shotorg.x);
  42         WriteCoord(MSG_BROADCAST, w_shotorg.y);
  43         WriteCoord(MSG_BROADCAST, w_shotorg.z);
  44         WriteCoord(MSG_BROADCAST, v.x);
  45         WriteCoord(MSG_BROADCAST, v.y);
  46         WriteCoord(MSG_BROADCAST, v.z);
  47         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  48 }
  49 #elif defined(CSQC)
  50 NET_HANDLE(TE_CSQC_VORTEXBEAMPARTICLE, bool isNew)
  51 {
  52         vector shotorg, endpos;
  53         float charge;
  54         shotorg.x = ReadCoord(); shotorg.y = ReadCoord(); shotorg.z = ReadCoord();
  55         endpos.x = ReadCoord(); endpos.y = ReadCoord(); endpos.z = ReadCoord();
  56         charge = ReadByte() / 255.0;
  57
  58         pointparticles(EFFECT_VORTEX_MUZZLEFLASH, shotorg, normalize(endpos - shotorg) * 1000, 1);
  59
  60         //draw either the old v2.3 beam or the new beam
  61         charge = sqrt(charge); // divide evenly among trail spacing and alpha
  62         particles_alphamin = particles_alphamax = particles_fade = charge;
  63
  64         if(!MUTATOR_CALLHOOK(Particles_VortexBeam, shotorg, endpos))
  65         if(autocvar_cl_particles_oldvortexbeam && (STAT(ALLOW_OLDVORTEXBEAM) || isdemo()))
  66                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  67         else
  68                 WarpZone_TrailParticles_WithMultiplier(NULL, particleeffectnum(EFFECT_VORTEX_BEAM), shotorg, endpos, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
  69         return true;
  70 }
  71 #endif
  72
  73 #ifdef SVQC
  74 spawnfunc(weapon_vortex) { weapon_defaultspawnfunc(this, WEP_VORTEX); }
  75 spawnfunc(weapon_nex) { spawnfunc_weapon_vortex(this); }
  76
  77 REGISTER_MUTATOR(vortex_charge, true);
  78
  79 MUTATOR_HOOKFUNCTION(vortex_charge, GetPressedKeys)
  80 {
  81     entity player = M_ARGV(0, entity);
  82
  83         // WEAPONTODO
  84     if(!WEP_CVAR(vortex, charge) || !WEP_CVAR(vortex, charge_velocity_rate))
  85         return;
  86
  87     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  88     {
  89         .entity weaponentity = weaponentities[slot];
  90
  91         if (player.(weaponentity).m_weapon == WEP_VORTEX && WEP_CVAR(vortex, charge) && WEP_CVAR(vortex, charge_velocity_rate) && vdist(vec2(player.velocity), >, WEP_CVAR(vortex, charge_minspeed)))
  92         {
  93             float xyspeed = vlen(vec2(player.velocity));
  94                 // add a maximum of charge_velocity_rate when going fast (f = 1), gradually increasing from minspeed (f = 0) to maxspeed
  95                 xyspeed = min(xyspeed, WEP_CVAR(vortex, charge_maxspeed));
  96                 float f = (xyspeed - WEP_CVAR(vortex, charge_minspeed)) / (WEP_CVAR(vortex, charge_maxspeed) - WEP_CVAR(vortex, charge_minspeed));
  97                 // add the extra charge
  98                 player.(weaponentity).vortex_charge = min(1, player.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_velocity_rate) * f * PHYS_INPUT_TIMELENGTH);
  99         }
 100     }
 101 }
 102
 103 void W_Vortex_Attack(Weapon thiswep, entity actor, .entity weaponentity, float issecondary)
 104 {
 105         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
 106
 107         mydmg = WEP_CVAR_BOTH(vortex, !issecondary, damage);
 108         myforce = WEP_CVAR_BOTH(vortex, !issecondary, force);
 109         mymindist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_mindist);
 110         mymaxdist = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_maxdist);
 111         myhalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_halflife);
 112         myforcehalflife = WEP_CVAR_BOTH(vortex, !issecondary, damagefalloff_forcehalflife);
 113         myammo = WEP_CVAR_BOTH(vortex, !issecondary, ammo);
 114
 115         float flying;
 116         flying = IsFlying(actor); // do this BEFORE to make the trace values from FireRailgunBullet last
 117
 118         if(WEP_CVAR(vortex, charge))
 119         {
 120                 charge = WEP_CVAR(vortex, charge_mindmg) / mydmg + (1 - WEP_CVAR(vortex, charge_mindmg) / mydmg) * actor.(weaponentity).vortex_charge;
 121                 actor.(weaponentity).vortex_charge *= WEP_CVAR(vortex, charge_shot_multiplier); // do this AFTER setting mydmg/myforce
 122                 // O RLY? -- divVerent
 123                 // YA RLY -- FruitieX
 124         }
 125         else
 126                 charge = 1;
 127         mydmg *= charge;
 128         myforce *= charge;
 129
 130         W_SetupShot(actor, weaponentity, true, 5, SND_NEXFIRE, CH_WEAPON_A, mydmg);
 131         if(charge > WEP_CVAR(vortex, charge_animlimit) && WEP_CVAR(vortex, charge_animlimit)) // if the Vortex is overcharged, we play an extra sound
 132         {
 133                 sound(actor, CH_WEAPON_B, SND_NEXCHARGE, VOL_BASE * (charge - 0.5 * WEP_CVAR(vortex, charge_animlimit)) / (1 - 0.5 * WEP_CVAR(vortex, charge_animlimit)), ATTN_NORM);
 134         }
 135
 136         yoda = 0;
 137         damage_goodhits = 0;
 138         FireRailgunBullet(actor, weaponentity, w_shotorg, w_shotorg + w_shotdir * max_shot_distance, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_VORTEX.m_id);
 139
 140         if(yoda && flying)
 141                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 142         if(damage_goodhits && actor.vortex_lasthit)
 143         {
 144                 Send_Notification(NOTIF_ONE, actor, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 145                 damage_goodhits = 0; // only every second time
 146         }
 147
 148         actor.vortex_lasthit = damage_goodhits;
 149
 150         //beam and muzzle flash done on client
 151         SendCSQCVortexBeamParticle(charge);
 152
 153         W_DecreaseAmmo(thiswep, actor, myammo, weaponentity);
 154 }
 155
 156 .float vortex_chargepool_pauseregen_finished;
 157
 158 METHOD(Vortex, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 159 {
 160     if(bot_aim(actor, weaponentity, 1000000, 0, 1, false))
 161         PHYS_INPUT_BUTTON_ATCK(actor) = true;
 162     else
 163     {
 164         if(WEP_CVAR(vortex, charge))
 165             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 166     }
 167 }
 168 METHOD(Vortex, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 169 {
 170     if(WEP_CVAR(vortex, charge) && actor.(weaponentity).vortex_charge < WEP_CVAR(vortex, charge_limit))
 171         actor.(weaponentity).vortex_charge = min(1, actor.(weaponentity).vortex_charge + WEP_CVAR(vortex, charge_rate) * frametime / W_TICSPERFRAME);
 172
 173     if(weaponslot(weaponentity) == 0)
 174         actor.vortex_charge = actor.(weaponentity).vortex_charge;
 175
 176     if(WEP_CVAR_SEC(vortex, chargepool))
 177         if(actor.(weaponentity).vortex_chargepool_ammo < 1)
 178         {
 179             if(actor.vortex_chargepool_pauseregen_finished < time)
 180                 actor.(weaponentity).vortex_chargepool_ammo = min(1, actor.(weaponentity).vortex_chargepool_ammo + WEP_CVAR_SEC(vortex, chargepool_regen) * frametime / W_TICSPERFRAME);
 181             actor.pauseregen_finished = max(actor.pauseregen_finished, time + WEP_CVAR_SEC(vortex, chargepool_pause_regen));
 182         }
 183
 184     if(weaponslot(weaponentity) == 0)
 185         actor.vortex_chargepool_ammo = actor.(weaponentity).vortex_chargepool_ammo;
 186
 187     if(autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo))) { // forced reload
 188         thiswep.wr_reload(thiswep, actor, weaponentity);
 189     } else
 190     {
 191         if(fire & 1)
 192         {
 193             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vortex, refire)))
 194             {
 195                 W_Vortex_Attack(thiswep, actor, weaponentity, 0);
 196                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vortex, animtime), w_ready);
 197             }
 198         }
 199         if((WEP_CVAR(vortex, charge) && !WEP_CVAR(vortex, secondary)) ? (PHYS_INPUT_BUTTON_ZOOM(actor) | PHYS_INPUT_BUTTON_ZOOMSCRIPT(actor)) : (fire & 2))
 200         {
 201             if(WEP_CVAR(vortex, charge))
 202             {
 203                 actor.(weaponentity).vortex_charge_rottime = time + WEP_CVAR(vortex, charge_rot_pause);
 204                 float dt = frametime / W_TICSPERFRAME;
 205
 206                 if(actor.(weaponentity).vortex_charge < 1)
 207                 {
 208                     if(WEP_CVAR_SEC(vortex, chargepool))
 209                     {
 210                         if(WEP_CVAR_SEC(vortex, ammo))
 211                         {
 212                             // always deplete if secondary is held
 213                             actor.vortex_chargepool_ammo = max(0, actor.vortex_chargepool_ammo - WEP_CVAR_SEC(vortex, ammo) * dt);
 214
 215                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 216                             actor.vortex_chargepool_pauseregen_finished = time + WEP_CVAR_SEC(vortex, chargepool_pause_regen);
 217                             dt = min(dt, actor.vortex_chargepool_ammo);
 218                             dt = max(0, dt);
 219
 220                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 221                         }
 222                     }
 223
 224                     else if(WEP_CVAR_SEC(vortex, ammo))
 225                     {
 226                         if(fire & 2) // only eat ammo when the button is pressed
 227                         {
 228                             dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 229                             if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 230                             {
 231                                 // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 232                                 if(autocvar_g_balance_vortex_reload_ammo)
 233                                 {
 234                                     dt = min(dt, (actor.(weaponentity).clip_load - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 235                                     dt = max(0, dt);
 236                                     if(dt > 0)
 237                                     {
 238                                         actor.(weaponentity).clip_load = max(WEP_CVAR_SEC(vortex, ammo), actor.(weaponentity).clip_load - WEP_CVAR_SEC(vortex, ammo) * dt);
 239                                     }
 240                                     actor.(weaponentity).(weapon_load[WEP_VORTEX.m_id]) = actor.(weaponentity).clip_load;
 241                                 }
 242                                 else
 243                                 {
 244                                     dt = min(dt, (actor.(thiswep.ammo_field) - WEP_CVAR_PRI(vortex, ammo)) / WEP_CVAR_SEC(vortex, ammo));
 245                                     dt = max(0, dt);
 246                                     if(dt > 0)
 247                                     {
 248                                         actor.(thiswep.ammo_field) = max(WEP_CVAR_SEC(vortex, ammo), actor.(thiswep.ammo_field) - WEP_CVAR_SEC(vortex, ammo) * dt);
 249                                     }
 250                                 }
 251                             }
 252                             actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 253                         }
 254                     }
 255
 256                     else
 257                     {
 258                         dt = min(dt, (1 - actor.(weaponentity).vortex_charge) / WEP_CVAR(vortex, charge_rate));
 259                         actor.(weaponentity).vortex_charge += dt * WEP_CVAR(vortex, charge_rate);
 260                     }
 261                 }
 262             }
 263             else if(WEP_CVAR(vortex, secondary))
 264             {
 265                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(vortex, refire)))
 266                 {
 267                     W_Vortex_Attack(thiswep, actor, weaponentity, 1);
 268                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(vortex, animtime), w_ready);
 269                 }
 270             }
 271         }
 272     }
 273 }
 274 METHOD(Vortex, wr_setup, void(entity thiswep, entity actor, .entity weaponentity))
 275 {
 276     actor.vortex_lasthit = 0;
 277 }
 278 METHOD(Vortex, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 279 {
 280     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(vortex, ammo);
 281     ammo_amount += (autocvar_g_balance_vortex_reload_ammo && actor.(weaponentity).(weapon_load[WEP_VORTEX.m_id]) >= WEP_CVAR_PRI(vortex, ammo));
 282     return ammo_amount;
 283 }
 284 METHOD(Vortex, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 285 {
 286     if(WEP_CVAR(vortex, secondary))
 287     {
 288         // don't allow charging if we don't have enough ammo
 289         float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(vortex, ammo);
 290         ammo_amount += actor.(weaponentity).(weapon_load[WEP_VORTEX.m_id]) >= WEP_CVAR_SEC(vortex, ammo);
 291         return ammo_amount;
 292     }
 293     else
 294     {
 295         return false; // zoom is not a fire mode
 296     }
 297 }
 298 METHOD(Vortex, wr_resetplayer, void(entity thiswep, entity actor))
 299 {
 300     if (WEP_CVAR(vortex, charge)) {
 301         if (WEP_CVAR_SEC(vortex, chargepool)) {
 302             actor.vortex_chargepool_ammo = 1;
 303         }
 304         actor.vortex_charge = WEP_CVAR(vortex, charge_start);
 305         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 306         {
 307             .entity weaponentity = weaponentities[slot];
 308             actor.(weaponentity).vortex_charge = WEP_CVAR(vortex, charge_start);
 309
 310             if (WEP_CVAR_SEC(vortex, chargepool))
 311                 actor.(weaponentity).vortex_chargepool_ammo = 1;
 312         }
 313     }
 314     actor.vortex_lasthit = 0;
 315 }
 316 METHOD(Vortex, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 317 {
 318     W_Reload(actor, weaponentity, min(WEP_CVAR_PRI(vortex, ammo), WEP_CVAR_SEC(vortex, ammo)), SND_RELOAD);
 319 }
 320 METHOD(Vortex, wr_suicidemessage, Notification(entity thiswep))
 321 {
 322     return WEAPON_THINKING_WITH_PORTALS;
 323 }
 324 METHOD(Vortex, wr_killmessage, Notification(entity thiswep))
 325 {
 326     return WEAPON_VORTEX_MURDER;
 327 }
 328 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 329 {
 330     return PHYS_INPUT_BUTTON_ATCK2(actor) && !WEP_CVAR(vortex, secondary);
 331 }
 332
 333 #endif
 334 #ifdef CSQC
 335
 336 METHOD(Vortex, wr_impacteffect, void(entity thiswep, entity actor))
 337 {
 338     entity this = actor;
 339     vector org2 = w_org + w_backoff * 6;
 340     pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 341     if(!w_issilent)
 342         sound(this, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM);
 343 }
 344 METHOD(Vortex, wr_init, void(entity thiswep))
 345 {
 346     if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 347     {
 348         precache_pic("gfx/reticle_nex");
 349     }
 350 }
 351 METHOD(Vortex, wr_zoom, bool(entity thiswep, entity actor))
 352 {
 353     if(button_zoom || zoomscript_caught || (!WEP_CVAR(vortex, secondary) && button_attack2))
 354     {
 355         return true;
 356     }
 357     else
 358     {
 359         // no weapon specific image for this weapon
 360         return false;
 361     }
 362 }
 363
 364 #endif